Wolfram言語＆システムドキュメントセンター

ArraySymbol

ArraySymbol[a]

a という名前の配列を表す．

ArraySymbol[a,{n₁,n₂,…}]

n₁×n₂×… 配列を表す．

ArraySymbol[a,{n₁,n₂,…},dom]

領域 dom の要素を持つ配列を表す．

ArraySymbol[a,{n₁,n₂,…},dom, sym]

対称 sym の配列を表す．

詳細

ArraySymbol[a,{n₁,n₂,…},dom, sym]の名前 a は任意の式でよい．
ArraySymbol[a,{n₁,n₂,…},dom, sym]の有効な次元指定 n_iは正の整数である．記号による次元指定を使うこともできる．
ArraySymbol[a,{n₁,n₂,…},dom, sym]における要素の領域指定 dom には以下がある．
Complexes 複素数

Integers 整数

Reals 実数

NonNegativeReals 実数 x (x≥0)

PositiveReals 実数 x (x>0)
対称指定には名前があるものがある．
Symmetric[{s₁,…,s_n}] スロット s_iの完全対称

Antisymmetric[{s₁,…,s_n}] スロット s_iの反対称
リストを扱う算術関数やその他の多くの関数では，ArraySymbolオブジェクトは他のリスト引数とは自動的には結合されない．
最適化関数，方程式ソルバ，Dは，ArraySymbolオブジェクトがベクトル変数を表すことを認識する．

例題

すべて開くすべて閉じる

例 (1)

変数 a に"a"という名前の mnp 配列を表す値を割り当てる：

Wolfram Language code: a = ArraySymbol["a", {m, n, p}]

算術演算は a がスカラーではないことを認識する：

Wolfram Language code: a + b + {1, 2}

Wolfram Language code: a - a

Dは a が配列変数であることを認識する：

Wolfram Language code: D[Total[a], a]

スコープ (7)

配列の変数についての微分を計算する：

Wolfram Language code: a = ArraySymbol["a", {m, n, p}];

Wolfram Language code: D[a, a]

Wolfram Language code: D[Total[a], a]

Wolfram Language code: D[Transpose[a, 2], a]

配列値の関数を含む微分を計算する：

Wolfram Language code:

a = ArraySymbol["a", {m, n, p}];
b = ArraySymbol["b", {p, q}];

Wolfram Language code: D[a[x].b[x], x]

Wolfram Language code: D[TensorProduct[a[x], b[x]], x]

Wolfram Language code: D[Tr[a[b]], b]

最適化に配列変数を使う：

Wolfram Language code: a = ArraySymbol["a", {2, 2, 2}];

Wolfram Language code: Minimize[{Tr[a], ArrayDot[a, a, 3] <= 1}, a]

配列変数を含む方程式と不等式を解く：

Wolfram Language code: a = ArraySymbol["a", {2, 2, 2}];

Wolfram Language code: Solve[a.{{1, 2}, {3, 4}} == {{{5, 6}, {7, 8}}, {{9, 10}, {11, 12}}}, a]

Wolfram Language code: FindInstance[ArrayDot[a, a, 3] == 1 && Tr[a] >= 1, a, Reals]

次元情報が指定されていない配列変数：

Wolfram Language code: a = ArraySymbol["a"];

算術演算は a がスカラーではないかもしれないことを認識する：

Wolfram Language code: a + b + {1, 2}

実数値配列変数：

Wolfram Language code: a = ArraySymbol["a", {3, 5, 7}, Reals];

Refineは配列の項が実数であることを認識する：

Wolfram Language code: Refine[Element[Indexed[a, {1, 2, 3}], Reals]]

3つのスロットで対称な，階数4の実数値配列変数：

Wolfram Language code: a = ArraySymbol["a", {4, 4, 4, 4}, Reals, Symmetric[{1, 2, 4}]];

これらのスロットを含む転置はどれも a に等しい：

Wolfram Language code: TensorTranspose[a, Cycles[{{2, 4}}]]//TensorReduce

アプリケーション (3)

ペアのリストを与えられた場合にデータについての最小二乗解を導出する：

Wolfram Language code: m = ArraySymbol["m", {n, 2}]

上記データについて垂直偏差のベクトルを求める：

Wolfram Language code: dev = m.{-a, 1} - b

データの垂直偏差の平方和を定義する：

Wolfram Language code: squareDeviations = dev.dev

最小二乗方程式を設定する：

Wolfram Language code: eqna = D[squareDeviations, a] == 0

Wolfram Language code: eqnb = D[squareDeviations, b] == 0

いくつかのデータを生成する：

Wolfram Language code: n = 200;data = Table[{x, 3x + 20 + RandomReal[{-15, 15}]}, {x, 1, n}];

このデータについての最小二乗問題を解く：

Wolfram Language code: a x + b /. Solve[Normal[{eqna, eqnb}] /. m -> data, {a, b}][[1]]

Wolfram Language code: Show[{ListPlot[data], Plot[%, {x, 0, 200}, PlotStyle -> Red]}]

期待リターン，標準偏差を使用して，ポートフォリオ最適化問題の最適化条件を求める：

Wolfram Language code:

x = ArraySymbol["x", {n}];
μ = ArraySymbol["μ", {n}];
Σ = ArraySymbol["Σ", {n, n}];
Subscript[μ, p] = μ.x;
Subscript[σ, p] = Sqrt[x.Σ.x];

目標は，アセットの重みベクトルがTotal[x]=1を満たすときにを最大化することである．この制約条件を使用してを表すことができる．ここで，制約のないベクトル変数はの最初の座標で構成される：

Wolfram Language code:

A = ArraySymbol["A", {n, n - 1}];
y = ArraySymbol["y", {n - 1}];
b = UnitVector[n, n];

最大値はの臨界点で出現する：

Wolfram Language code: cond = D[Subscript[μ, p] / Subscript[σ, p] /. x -> A.y + b, y] == 0

制約条件をによって表す：

Wolfram Language code: cond /. A.y + b -> x

方程式で表される線形回帰モデルの対数尤度関数の勾配を計算する．は正規分布に従う，平均が0で分散がの確率変数である：

Wolfram Language code:

y = ArraySymbol["y", {n}];
X = ArraySymbol["X", {n, k}];
β = ArraySymbol["β", {k}];
u = ArraySymbol["u", {n}];

対数尤度関数は以下で与えられる：

Wolfram Language code: l = -n / 2Log[σsquared] - 1 / (2σsquared)u.u

を計算する：

Wolfram Language code: Subscript[l, β] = D[l /. u -> y - X.β, β]

結果をで表す：

Wolfram Language code: Subscript[l, β] /. y - X.β -> u

を計算する：

Wolfram Language code: Subscript[l, σ^2] = D[l, σsquared]

特性と関係 (5)

TensorRankを使って配列の記号表現の階数を取得する：

Wolfram Language code: TensorRank[ArraySymbol["a", {j, k, l}]]

ArraySymbol["name"]は未知の階数の配列を表す：

Wolfram Language code: TensorRank[ArraySymbol["a"]]

TensorDimensionsを使って配列の記号表現の次元を取得する：

Wolfram Language code: TensorDimensions[ArraySymbol["a", {j, k, l}]]

TensorSymmetryを使って行列の記号表現の対称性を取得する：

Wolfram Language code: TensorSymmetry[ArraySymbol["a", {d, d, d}, Reals, Antisymmetric[All]]]

デフォルトで，対称性は仮定されない：

Wolfram Language code: TensorSymmetry[ArraySymbol["a", {d, d, d}]]

ArraySymbol[a,{m,n}]とMatrixSymbol[a,{m,n}]はどちらも行列を表す：

Wolfram Language code: TensorDimensions[MatrixSymbol["a", {m, n}]] == TensorDimensions[ArraySymbol["a", {m, n}]]

しかし，MatrixSymbol[a,m]は正方行列を表す：

Wolfram Language code: TensorDimensions[MatrixSymbol["a", m]]

一方，ArraySymbol[a,m]はベクトルを表す：

Wolfram Language code: TensorDimensions[ArraySymbol["a", m]]

ArraySymbol[a,m]とVectorSymbol[a,m]はどちらもベクトルを表す：

Wolfram Language code: TensorDimensions[VectorSymbol["a", m]] == TensorDimensions[ArraySymbol["a", m]]

Top

その他のラーニングリソース

テクニカルサポート

Wolframソリューション

教育のためのWolframソリューション

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

ArraySymbol

詳細

例題

例 (1)

スコープ (7)

アプリケーション (3)

特性と関係 (5)

テキスト

CMS

APA

BibTeX

BibLaTeX

	Complexes	複素数
	Integers	整数
	Reals	実数
	NonNegativeReals	実数 x (x≥0)
	PositiveReals	実数 x (x>0)

	Symmetric[{s₁,…,s_n}]	スロット s_iの完全対称
	Antisymmetric[{s₁,…,s_n}]	スロット s_iの反対称

ArraySymbol

詳細

例題

例 (1)

スコープ (7)

アプリケーション (3)

特性と関係 (5)

関連項目

関連するガイド

履歴

テキスト

CMS

APA

BibTeX

BibLaTeX