ArraySymbol
ArraySymbol[a]
表示名为 a 的数组.
ArraySymbol[a,{n1,n2,…}]
表示 n1×n2×… 数组.
ArraySymbol[a,{n1,n2,…},dom]
表示一个元素在域 dom 内的数组.
ArraySymbol[a,{n1,n2,…},dom, sym]
表示具有对称性 sym 的数组.
更多信息
- ArraySymbol[a,{n1,n2,…},dom, sym] 中的名称 a 可以是任意表达式.
- ArraySymbol[a,{n1,n2,…},dom, sym] 中的有效维度规范 ni 为正整数. 也可以使用符号维度规范.
- ArraySymbol[a,{n1,n2,…},dom, sym] 中的元素域规范 dom 包括：
-
Complexes 复数 Integers 整数 Reals 实数 NonNegativeReals 实数 x，且 x≥0 PositiveReals 实数 x，且 x>0 - 一些对称规范有名称：
-
Symmetric[{s1,…,sn}] 在插槽 si 中的完全对称性 Antisymmetric[{s1,…,sn}] 在插槽 si 中的反对称性 - 在算术运算和许多其他使用列表的函数中，ArraySymbol 对象不会自动与其他列表参数结合.
- 优化函数、方程求解器和 D 可以识别出 ArraySymbol 对象代表向量变量.
范例
打开所有单元 关闭所有单元基本范例 (1)
给变量 a 赋值，来表示一个名为 "a" 的 mnp 数组：
a = ArraySymbol["a", {m, n, p}]a + b + {1, 2}a - aD 识别出 a 是一个数组变量：
D[Total[a], a]范围 (7)
a = ArraySymbol["a", {m, n, p}];D[a, a]D[Total[a], a]D[Transpose[a, 2], a]a = ArraySymbol["a", {m, n, p}];
b = ArraySymbol["b", {p, q}];D[a[x].b[x], x]D[TensorProduct[a[x], b[x]], x]D[Tr[a[b]], b]a = ArraySymbol["a", {2, 2, 2}];Minimize[{Tr[a], ArrayDot[a, a, 3] <= 1}, a]a = ArraySymbol["a", {2, 2, 2}];Solve[a.{{1, 2}, {3, 4}} == {{{5, 6}, {7, 8}}, {{9, 10}, {11, 12}}}, a]FindInstance[ArrayDot[a, a, 3] == 1 && Tr[a] >= 1, a, Reals]a = ArraySymbol["a"];a + b + {1, 2}a = ArraySymbol["a", {3, 5, 7}, Reals];Refine 识别数组中的项为实数：
Refine[Element[Indexed[a, {1, 2, 3}], Reals]]a = ArraySymbol["a", {4, 4, 4, 4}, Reals, Symmetric[{1, 2, 4}]];TensorTranspose[a, Cycles[{{2, 4}}]]//TensorReduce应用 (3)
m = ArraySymbol["m", {n, 2}]
dev = m.{-a, 1} - bsquareDeviations = dev.deveqna = D[squareDeviations, a] == 0eqnb = D[squareDeviations, b] == 0n = 200;data = Table[{x, 3x + 20 + RandomReal[{-15, 15}]}, {x, 1, n}];a x + b /. Solve[Normal[{eqna, eqnb}] /. m -> data, {a, b}][[1]]Show[{ListPlot[data], Plot[%, {x, 0, 200}, PlotStyle -> Red]}]
x = ArraySymbol["x", {n}];
μ = ArraySymbol["μ", {n}];
Σ = ArraySymbol["Σ", {n, n}];
Subscript[μ, p] = μ.x;
Subscript[σ, p] = Sqrt[x.Σ.x];目标是当资产权重向量 
满足 Total[x]=1 时，使 
最大化. 约束可用于表示 
，其中无约束向量变量 
由 
的前 
个坐标组成：
A = ArraySymbol["A", {n, n - 1}];
y = ArraySymbol["y", {n - 1}];
b = UnitVector[n, n];
cond = D[Subscript[μ, p] / Subscript[σ, p] /. x -> A.y + b, y] == 0
cond /. A.y + b -> x计算由方程 
表示的线性回归模型的对数似然函数的梯度，其中 
是均值为零、方差为 
的正态分布随机变量：
y = ArraySymbol["y", {n}];
X = ArraySymbol["X", {n, k}];
β = ArraySymbol["β", {k}];
u = ArraySymbol["u", {n}];
l = -n / 2Log[σsquared] - 1 / (2σsquared)u.u
Subscript[l, β] = D[l /. u -> y - X.β, β]
Subscript[l, β] /. y - X.β -> u
Subscript[l, σ^2] = D[l, σsquared]属性和关系 (5)
Use TensorRank to get the rank of an array symbol:
TensorRank[ArraySymbol["a", {j, k, l}]]ArraySymbol["name"] 表示秩未知的数组：
TensorRank[ArraySymbol["a"]]用 TensorDimensions 获取数组符号的维度：
TensorDimensions[ArraySymbol["a", {j, k, l}]]用 TensorSymmetry 获取矩阵符号的对称性：
TensorSymmetry[ArraySymbol["a", {d, d, d}, Reals, Antisymmetric[All]]]TensorSymmetry[ArraySymbol["a", {d, d, d}]]ArraySymbol[a,{m,n}] 和 MatrixSymbol[a,{m,n}] 都表示矩阵：
TensorDimensions[MatrixSymbol["a", {m, n}]] == TensorDimensions[ArraySymbol["a", {m, n}]]但 MatrixSymbol[a,m] 表示方阵：
TensorDimensions[MatrixSymbol["a", m]]而 ArraySymbol[a,m] 表示向量：
TensorDimensions[ArraySymbol["a", m]]ArraySymbol[a,m] 和 VectorSymbol[a,m] 都表示向量：
TensorDimensions[VectorSymbol["a", m]] == TensorDimensions[ArraySymbol["a", m]]文本
Wolfram Research (2024)，ArraySymbol，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ArraySymbol.html.
CMS
Wolfram 语言. 2024. "ArraySymbol." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/ArraySymbol.html.
APA
Wolfram 语言. (2024). ArraySymbol. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/ArraySymbol.html 年