WOLFRAM

Wolfram 语言与系统参考资料中心

AskFunction[body]

计算 body，交互式地询问由 Ask[…] 及相关结构指定的值.

AskFunction[{"key1"spec1,"key2"spec2,…},body]

指定如何询问与 keyi 关联的值.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
属性和关系  
可能存在的问题  
参见
相关指南
相关的工作流程
历史
按以下格式引用：

AskFunction

AskFunction[body]

计算 body，交互式地询问由 Ask[…] 及相关结构指定的值.

AskFunction[{"key1"spec1,"key2"spec2,…},body]

指定如何询问与 keyi 关联的值.

更多信息和选项

范例

打开所有单元 关闭所有单元

基本范例  (1)

设置 AskFunction：

Wolfram Language code: ask = AskFunction[Ask["x" -> "Number"] + Ask["y" -> "Number"]];

激活它，并填入输入：

Wolfram Language code: ask[]

或者在云端部署：

Wolfram Language code: CloudDeploy[ask]

可以程序式地提供已知值：

Wolfram Language code: ask2 = ask[<|"x" -> "3"|>]

现在仅询问第二个问题：

Wolfram Language code: ask2[]

范围  (3)

为 AskFunction 提供第一个参数，指定如何询问值：

Wolfram Language code: CloudDeploy[AskFunction[<|"x" -> "Number", "y" -> "Number"|>, Ask["x"] ^ Ask["y"]]]

AskFunction 使用 Wolfram 语言的运算语义来跳过不需要的问题：

Wolfram Language code: CloudDeploy[AskFunction[If[Ask[{"married", "Are you married?"} -> {"Yes" -> True, "No" -> False}], Ask[{"spouse-name", "What is the name of your spouse?"} -> "String"]]; Style["Thank you for taking our survey!", Bold, 36]]]

选择 No 跳过关于配偶姓名的问题：

使用相同的语法作为 FormFunction 和 FormObject 来指定问题的外观：

Wolfram Language code: CloudDeploy[AskFunction[Ask["n" -> <|"Interpreter" -> Restricted["Integer", {1, 20}], "Control" -> Slider|>]!]]

属性和关系  (7)

将 AskFunction 与 Ask 结合，用于简单的问题或者获取与键关联的值：

Wolfram Language code: CloudDeploy[AskFunction[Ask[{"x", "Input a number"} -> "Integer"]; Ask["x"] ^ 2]]

AskConfirm 可用于将运算倒转回值已知之前的点：

Wolfram Language code: CloudDeploy[AskFunction[Ask[{"sum", "what is 2+2?"} -> "Number"]; If[Ask["sum"] ≠ 4, AskConfirm["sum", "are you sure 2+2 = `value`?"]; "wrong", "correct"]]]

使用 AskAppend 累积输入：

Wolfram Language code: CloudDeploy[AskFunction[AskDisplay["Enter three countries"];Do[AskAppend["country" -> "Country"], {3}];Ask["country"]]]

使用 AskDisplay 显示消息：

Wolfram Language code: CloudDeploy[AskFunction[AskDisplay["Welcome to TaxReturnPro™!"];Ask[{"income", "How much did you make this year?"} -> "CurrencyAmount"];AskDisplay[ If[Ask["income"] > Quantity[1*10^6, "USDollars"], "whoa!", "puny…"]]]]

AskTemplateDisplay 取应用于当前值的函数或模板：

Wolfram Language code: CloudDeploy[AskFunction[Ask[{"n", "How many sides?"} -> Restricted["Integer", {3, Infinity}]]; AskTemplateDisplay[Graphics[RegularPolygon[#n]]&]]]

使用 AskedQ 验证一个键是否已被询问：

Wolfram Language code: CloudDeploy[AskFunction[<|{"name", "What's your name?"} -> "String"|>, While[!AskedQ["name"], Ask["name"]]]]

AskedValue 返回值，而不引起表单的显示：

Wolfram Language code: CloudDeploy[AskFunction[If[Ask[{"age", "How old are you?"} -> "Number"] ≥ 21, Ask[{"drink", "Do you drink?"} -> {"Yes" -> True, "No" -> False}]]; Replace[AskedValue["drink"], { _Missing :> "not applicable", True -> "drinking", False -> "not drinking"}]]]

可能存在的问题  (2)

当 AskFunction 在云端部署时，窗体在每次访问时都在干净内核上被重新运算. 正因为如此，返回随机值的函数可能在每个步骤会返回不同的值:

Wolfram Language code: CloudDeploy[AskFunction[a = RandomInteger[{1, 10}];AskDisplay[a];AskDisplay[a]]]

一个可能的解决方法是使用 SeedRandom 来初始化伪随机数生成器，种子取决于先前的值或诸如 $RequesterAddress 的值：

Wolfram Language code: CloudDeploy[AskFunction[ Ask[{"name", "What's your name?"} -> "String"];SeedRandom[Ask["name"]];a = RandomInteger[{1, 10}];AskDisplay[a];AskDisplay[a] ]]

云计算对内存使用和计算时间有限制. AskFunction 的限制取决于您的云服务计划，具体数值可通过 CloudAccountData 中的 "DeployedMemoryLimit" 和 "DeployedEvaluationTimeLimit" 查询：

Wolfram Language code: CloudAccountData /@ {"DeployedMemoryLimit", "DeployedEvaluationTimeLimit"}
Wolfram Research (2016)，AskFunction，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AskFunction.html.

文本

Wolfram Research (2016)，AskFunction，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AskFunction.html.

CMS

Wolfram 语言. 2016. "AskFunction." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/AskFunction.html.

APA

Wolfram 语言. (2016). AskFunction. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/AskFunction.html 年

BibTeX

@misc{reference.wolfram_2026_askfunction, author="Wolfram Research", title="{AskFunction}", year="2016", howpublished="\url{https://reference.wolfram.com/language/ref/AskFunction.html}", note=[Accessed: 17-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_askfunction, organization={Wolfram Research}, title={AskFunction}, year={2016}, url={https://reference.wolfram.com/language/ref/AskFunction.html}, note=[Accessed: 17-August-2026]}