WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

AstroSubpoint[astro]

指定された astro が現在天頂にある地球上の地理位置を返す．

AstroSubpoint[astro,date]

指定された date に astro が天頂にある地球上の地理位置を返す．

AstroSubpoint[astro,{body,date}]

指定されたdate に観測された指定された body の天体サブポイントを返す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

AstroSubpoint

AstroSubpoint[astro]

指定された astro が現在天頂にある地球上の地理位置を返す．

AstroSubpoint[astro,date]

指定された date に astro が天頂にある地球上の地理位置を返す．

AstroSubpoint[astro,{body,date}]

指定されたdate に観測された指定された body の天体サブポイントを返す．

詳細

  • 天体のサブポイントとは，その天体が90度の高度で観測される特定の天体上の位置である．
  • 太陽の天体サブポイントは太陽直下点と呼ばれる．月の天体サブポイントは月直下点と呼ばれる．
  • AstroSubpoint[astro,…]の astro オブジェクトは，Entity["Star","Sun"]やEntity["Planet","Mars"]，太陽系の重心"SSB"のような名前付きの天文位置，あるいは天体の表面近くのGeoPosition位置である．
  • 観測対象の天体からサブポイントまでの線は，サブポイントで水平面に垂直であり，通常は天体が球面である場合を除いて天体の中心と交差しない．
  • AstroSubpoint[astro,{body,date}]は，地理位置をGeoPosition[{lat,lon},body]の形で返す．
  • 指定された天体 body について，AstroSubpoint[astro,body]はAstroSubpoint[astro,{body,Now}]に等しい．

例題

すべて開く すべて閉じる

例  (4)

現在の太陽直下点を求める：

Wolfram Language code: AstroSubpoint[Entity["Star", "Sun"]]

指定した日付における月直下点を計算する：

Wolfram Language code: AstroSubpoint[Entity["PlanetaryMoon", "Moon"], DateObject[{2000, 1, 1, 0, 0, 0}]]

指定した日付に火星が天頂にある地球上の点を求める：

Wolfram Language code: date = DateObject[{2023, 15, 9, 16, 0, 0}]
Wolfram Language code: sp = AstroSubpoint[Entity["Planet", "Mars"], date]

指定の日付に指定の場所で観測した火星の高度が90度であることを確認する：

Wolfram Language code: AstroPosition[Entity["Planet", "Mars"], {sp, date}]["Altitude"]

以下の日付の火星上の太陽直下点を求める：

Wolfram Language code: AstroSubpoint[Entity["Star", "Sun"], {Entity["Planet", "Mars"], DateObject[{2000, 1, 1, 0, 0, 0}]}]

スコープ  (3)

AstroSubpointを任意の天文実体に使う：

Wolfram Language code: AstroSubpoint[Entity["Star", "Sun"]]
Wolfram Language code: AstroSubpoint[Entity["Star", "Betelgeuse"]]

太陽系の重心の現在の下点を計算する：

Wolfram Language code: AstroSubpoint["SSB"]

月面位置の下点を計算する：

Wolfram Language code: date = DateObject[{2023, 5, 13, 16, 50, 4.9221}, "Instant", "Gregorian", -5.];
Wolfram Language code: AstroSubpoint[GeoPosition[{0, 0}, Entity["PlanetaryMoon", "Moon"]], date]

月心の下点である月直下点と比較する：

Wolfram Language code: AstroSubpoint[Entity["PlanetaryMoon", "Moon"], date]
Wolfram Language code: GeoDistance[%, %%]

アプリケーション  (1)

一日の同じ時刻における太陽直下点を1年間に渡って計算する：

Wolfram Language code: sps = Table[AstroSubpoint[Entity["Star", "Sun"], DateObject[{2023, 1, day, 12, 0, 0}]], {day, 1, 365}];

上記はアナレンマを形成する：

Wolfram Language code: GeoGraphics[Point[sps]]

特性と関係  (5)

指定の日付における天体の下点を計算する：

Wolfram Language code: date = Now
Wolfram Language code: sp = AstroSubpoint[Entity["Planet", "Neptune"], date]

その日付にその場所から観測された場合，その天体の高度は90度になる：

Wolfram Language code: AstroPosition[Entity["Planet", "Neptune"], {sp, date}]

北極星の下点は北極の近くにある：

Wolfram Language code: AstroSubpoint[Entity["Star", "Polaris"], DateObject[{2023, 9, 22}]]

指定された日付について，天体の赤道座標と下点を計算する：

Wolfram Language code: date = Now;
Wolfram Language code: ap = AstroPosition[Entity["Star", "Antares"], {"Equatorial", date}]
Wolfram Language code: gp = AstroSubpoint[Entity["Star", "Antares"], date]

オブジェクトの偏角はその下点の緯度と一致する：

Wolfram Language code: {ap["Declination"], gp["Latitude"]}

オブジェクトの赤経はその基点の経度とは直接一致しない：

Wolfram Language code: {ap["RightAscension"], gp["Longitude"]}

差はグリニッジ恒星時によって与えられる：

Wolfram Language code: {Subtract@@%, QuantityMagnitude[SiderealTime[GeoPosition[{0, 0}], date], "AngularDegrees"]}

太陽直下点の緯度限界はカニ座とヤギ座の回帰線を定義する：

Wolfram Language code: Plot[Latitude[AstroSubpoint[Entity["Star", "Sun"], DateObject[{2023, 1, d, 0, 0, 0}]]], {d, 1, 365}]

指定の日付の太陽直下点を計算する：

Wolfram Language code: date = RandomDate[]
Wolfram Language code: ssp = AstroSubpoint[Entity["Star", "Sun"], date]

その場所からのその瞬間の太陽時は常に正午である：

Wolfram Language code: SolarTime[ssp, date]
Wolfram Research (2024), AstroSubpoint, Wolfram言語関数， https://reference.wolfram.com/language/ref/AstroSubpoint.html （2026年に更新）.

テキスト

Wolfram Research (2024), AstroSubpoint, Wolfram言語関数， https://reference.wolfram.com/language/ref/AstroSubpoint.html （2026年に更新）.

CMS

Wolfram Language. 2024. "AstroSubpoint." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2026. https://reference.wolfram.com/language/ref/AstroSubpoint.html.

APA

Wolfram Language. (2024). AstroSubpoint. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/AstroSubpoint.html

BibTeX

@misc{reference.wolfram_2026_astrosubpoint, author="Wolfram Research", title="{AstroSubpoint}", year="2026", howpublished="\url{https://reference.wolfram.com/language/ref/AstroSubpoint.html}", note=[Accessed: 15-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_astrosubpoint, organization={Wolfram Research}, title={AstroSubpoint}, year={2026}, url={https://reference.wolfram.com/language/ref/AstroSubpoint.html}, note=[Accessed: 15-August-2026]}