AsymptoticGreaterEqual

xx^*のときにまたはとなる条件を与える．

AsymptoticGreaterEqual[f,g,{x₁,…,x_n}{,…,}]

{x₁,…,x_n}{,…,}のときにまたはとなる条件を与える．

詳細とオプション

「漸近的に以上」は，f が g のbig-omegaである，f の下限は g である，f は最小でも次数 g である，f は少なくとも g と同じぐらいの速さで大きくなる等と表現される．点 x^*はコンテキストから推測されることが多い．
「漸近的に以上」は順序関係で，である定数について x が x^*の近くにあるときにあることを意味する．
点の近くの関数や級数の単純な下限を表すために，また，方程式の解や複雑な計算の単純な下限を表すためにしばしば使われる．
有限極限点の x^*および{,…,}については以下のようになる．

	AsymptoticGreaterEqual[f[x],g[x],xx^*]	$0<TemplateBox[{{x, -, {x, ^, }}}, Abs]<delta(c,x^)$ がを意味するとが存在する
	AsymptoticGreaterEqual[f[x₁,…,x_n],g[x₁,…,x_n],{x₁,…,x_n}{,…,}]	$0<TemplateBox[{{{, {{{x, _, 1}, -, {x, _, 1, ^, }}, ,, ..., ,, {{x, _, n}, -, {x, _, n, ^, }}}, }}}, Norm]<delta(epsilon,x^*)$ が $TemplateBox[{{f, (, {{x, _, 1}, ,, ..., ,, {x, _, n}}, )}}, Abs]>=c TemplateBox[{{g, (, {{x, _, 1}, ,, ..., ,, {x, _, n}}, )}}, Abs]$ を意味するとが存在する

無限極限点については以下のようになる．

	AsymptoticGreaterEqual[f[x],g[x],x∞]	がを意味するとが存在する
	AsymptoticGreaterEqual[f[x₁,…,x_n],g[x₁,…,x_n],{x₁,…,x_n}{∞,…,∞}]	が $TemplateBox[{{f, (, {{x, _, 1}, ,, ..., ,, {x, _, n}}, )}}, Abs]>=c TemplateBox[{{g, (, {{x, _, 1}, ,, ..., ,, {x, _, n}}, )}}, Abs]$ を意味するとが存在する

g[x]が x^*の近くで0の無限集合を持たない場合，AsymptoticGreaterEqual[f[x],g[x],xx^*]はMinLimit[Abs[f[x]/g[x]],xx^*]>0のときかつそのときに限り存在する．
次は，使用可能なオプションである．

Assumptions	$Assumptions	パラメータについての仮定
Direction	Reals	極限点に近付く方向
GenerateConditions	Automatic	パラメータについての条件を生成する
Method	Automatic	使用するメソッド
PerformanceGoal	"Quality"	何を最適化するか

次は，Directionの可能な設定である．

	Reals または "TwoSided"	両実数方向から
	"FromAbove" または -1	上，つまり大きい値から
	"FromBelow" または +1	下，つまりは小さい値から
	Complexes	すべての複素方向から
	Exp[ θ]	の方向
	{dir₁,…,dir_n}	変数 x_iに方向 dir_iを使う

x^*におけるDirectionExp[ θ]は，曲線の接線が極限点 x^*に近付く方向を示す．

次は，GenerateConditionsの可能な設定である．

	Automatic	一般的ではない条件のみ
	True	すべての条件
	False	条件なし
	None	条件が必要な場合には未評価で返す

PerformanceGoalの可能な設定には，$PerformanceGoal，"Quality"，"Speed"がある．"Quality"設定のとき，Limitはより多くの問題を解いたりより簡単な結果を与えたりすることが多いが，より多くの時間とメモリが必要になる可能性がある．

例題

すべて開くすべて閉じる

例 (2)

のときにであることを検証する：

Wolfram Language code: AsymptoticGreaterEqual[x ^ 2 , x, x -> ∞]

2つの関数を可視化する：

Wolfram Language code: Plot[{x ^ 2, x}, {x, 0, 10}, PlotLegends -> "Expressions"]

のときにであることを検証する：

Wolfram Language code: AsymptoticGreaterEqual[x ^ 2 + y ^ 2, x + y, {x, y} -> ∞]

2つの関数を可視化する：

Wolfram Language code: Plot3D[{x ^ 2 + y ^ 2, x + y}, {x, 0, 10}, {y, 0, 10}, PlotLegends -> "Expressions"]

スコープ (9)

厳密には正ではない関数を比較する：

Wolfram Language code: AsymptoticGreaterEqual[x, -x ^ 2, x -> ∞]

が原点で少なくともと同じくらい速く発散することを示す：

Wolfram Language code: AsymptoticGreaterEqual[(1/x^2), (1/x Sin[x]), x -> 0]

答は明示的なTrueまたはFalseではなく，ブール式かもしれない：

Wolfram Language code: AsymptoticGreaterEqual[Sinh[p(x - 2)], Sin[x - 2], x -> 2]

パラメータを含む関数を比較する場合は，結果についての条件が生成されることがある：

Wolfram Language code: AsymptoticGreaterEqual[(1/(x - 1)^p), (10/x - 1), x -> 1]

デフォルトで，関数の両側比較が行われる：

Wolfram Language code: AsymptoticGreaterEqual[x^4, x^2 UnitStep[x], x -> 0]

のより大きい値を比較する場合は，は実際に $x^2 TemplateBox[{{x}}, UnitStepSeq]$ と同じくらいである：

Wolfram Language code: AsymptoticGreaterEqual[x^4, x^2 UnitStep[x], x -> 0, Direction -> "FromBelow"]

この関係は，のより小さい値については成り立たない：

Wolfram Language code: AsymptoticGreaterEqual[x^4, x^2 UnitStep[x], x -> 0, Direction -> "FromAbove"]

2つの関数を可視化する：

Wolfram Language code: Plot[{x^4, x^2UnitStep[x]}, {x, -1, 1}, PlotTheme -> {"DashedLines", "Detailed"}]

Sqrtのような関数は，負の実数に沿って両方の実数方向で同じ関係があるかもしれない：

Wolfram Language code: AsymptoticGreaterEqual[(Sqrt[z] - I)^3, (z + 1), z -> -1]

複素平面で上から近付く場合には，同じ関係が見られる：

Wolfram Language code: AsymptoticGreaterEqual[(Sqrt[z] - I)^3, (z + 1), z -> -1, Direction -> -I]

しかし，複素平面で下から近付く場合は異なる結果になる：

Wolfram Language code: AsymptoticGreaterEqual[(Sqrt[z] - I)^3, (z + 1), z -> -1, Direction -> I]

これは，軸が交差するときにSqrtの虚部の符号が逆になるところで分枝切断されているためである：

Wolfram Language code:

TableForm[Table[{-1 + Δ, Sqrt[-1 + Δ], Abs[Sqrt[-1 + Δ] - I]}, {Δ, {0.01, -0.01, 0.01I, -0.01I}}], TableHeadings -> {None, {z, Sqrt[z], HoldForm@Abs[Sqrt[z] - I]}}]

したがって，この関係は，一般に，複素平面では成り立たない：

Wolfram Language code: AsymptoticGreaterEqual[(Sqrt[z] - I)^3, (z + 1), z -> -1, Direction -> Complexes]

4つの実数および複素数の方向から近付く場合の関数の相対サイズを可視化する：

Wolfram Language code:

Plot[{Abs[ (-1 + Δz/(Sqrt[-1 + Δz] - I)^3)], Abs[ (-1 + I Δz/(Sqrt[-1 + I Δz] - I)^3)]}, {Δz, -1, 1}, IconizedObject[«plot options»]]

多変量関数を比較する：

Wolfram Language code: AsymptoticGreaterEqual[(x - 1)^2(y - 2), Sin[ x]Cos[3y / 4], {x, y} -> {1, 2}]

2つの関数のノルムを可視化する：

Wolfram Language code:

Show[Plot3D[{Abs[(x - 1) ^ 2 (y - 2)], Abs[Sin[x] Cos[3 y / 4]]}, {x, y}∈Disk[{1, 2}, .25], PlotTheme -> "Detailed"], Graphics3D[{AbsolutePointSize[7], Point[{1, 2, 0}]}], ViewPoint -> {1.36, -2.75, 1.42}]

多変量関数を無限大で比較する：

Wolfram Language code: AsymptoticGreaterEqual[Exp[x]Log[y], x y, {x, y} -> {-∞, ∞}]

多変量関数を比較する際にパラメータを使用する：

Wolfram Language code: AsymptoticGreaterEqual[Sinh[x]y, Sinh[a x]Sqrt[y], {x, y} -> {∞, 1}]

オプション (10)

Assumptions (1)

Assumptionsを使ってパラメータについての条件を指定する：

Wolfram Language code: AsymptoticGreaterEqual[1, x ^ a, x -> 0, Assumptions -> a ≥ 0]

仮定が異なると結果も異なるかもしれない：

Wolfram Language code: AsymptoticGreaterEqual[1, x ^ a, x -> 0, Assumptions -> a < 0]

Direction (5)

下からの関係を判定する：

Wolfram Language code: AsymptoticGreaterEqual[x UnitStep[x], Sin[x], x -> 0, Direction -> "FromBelow"]

同様に：

Wolfram Language code: AsymptoticGreaterEqual[x UnitStep[x], Sin[x], x -> 0, Direction -> 1]

上からの関係を判定する：

Wolfram Language code: AsymptoticGreaterEqual[x UnitStep[x], Sin[x], x -> 0, Direction -> "FromAbove"]

同様に：

Wolfram Language code: AsymptoticGreaterEqual[x UnitStep[x], Sin[x], x -> 0, Direction -> -1]

区分ごとの不連続点での関係を判定する：

Wolfram Language code: AsymptoticGreaterEqual[FractionalPart[x ^ 2]Sin[x], Cos[x / 2], x -> 2, Direction -> "FromBelow"]

Wolfram Language code: AsymptoticGreaterEqual[FractionalPart[x ^ 2]Sin[x], Cos[x / 2], x -> 2, Direction -> "FromAbove"]

片方の方向でうまくいかないので，両方からもうまくいかない：

Wolfram Language code: AsymptoticGreaterEqual[FractionalPart[x ^ 2]Sin[x], Cos[x / 2], x -> 2, Direction -> "TwoSided"]

2関数とその割合を可視化する：

Wolfram Language code:

Plot[{FractionalPart[x ^ 2]Sin[x], Cos[x / 2], Abs[(FractionalPart[x ^ 2]Sin[x]/Cos[x / 2])]}, {x, 1.5, 2.5}, PlotLegends -> "Expressions"]

単純極における関係は近付く方向には無関係である：

Wolfram Language code: AsymptoticGreaterEqual[Tan[x], (2/2x - π), x -> π / 2, Direction -> "FromBelow"]

Wolfram Language code: AsymptoticGreaterEqual[Tan[x], (2/2x - π), x -> π / 2, Direction -> "FromAbove"]

Wolfram Language code: AsymptoticGreaterEqual[Tan[x], (2/2x - π), x -> π / 2, Direction -> ℝ]

Wolfram Language code: AsymptoticGreaterEqual[Tan[x], (2/2x - π), x -> π / 2, Direction -> ℂ]

分枝切断線における関係を判定する：

Wolfram Language code: AsymptoticGreaterEqual[Tanh[x], Sqrt[x - 1] - I, x -> 0, Direction -> +I]

Wolfram Language code: AsymptoticGreaterEqual[Tanh[x], Sqrt[x - 1] - I, x -> 0, Direction -> -I]

Wolfram Language code: AsymptoticGreaterEqual[Tanh[x], Sqrt[x - 1] - I, x -> 0, Direction -> Reals]

Wolfram Language code: AsymptoticGreaterEqual[Tanh[x], Sqrt[x - 1] - I, x -> 0, Direction -> Complexes]

異なる象限から近付く際の，この関係を計算する：

Wolfram Language code: f[x_, y_] := x + Abs[y]

Wolfram Language code: g[x_, y_] := Sin[x y]

第1象限から原点に近付く：

Wolfram Language code: AsymptoticGreaterEqual[f[x, y], g[x, y], {x, y} -> {0, 0}, Direction -> "FromAbove"]

同様に：

Wolfram Language code: AsymptoticGreaterEqual[f[x, y], g[x, y], {x, y} -> {0, 0}, Direction -> {"FromAbove", "FromAbove"}]

第4象限から原点に近付く：

Wolfram Language code: AsymptoticGreaterEqual[f[x, y], g[x, y], {x, y} -> {0, 0}, Direction -> {"FromAbove", "FromBelow"}]//Quiet

右半平面から原点に近付く：

Wolfram Language code: AsymptoticGreaterEqual[f[x, y], g[x, y], {x, y} -> {0, 0}, Direction -> {"FromAbove", Reals}]

下半平面から原点に近付く：

Wolfram Language code: AsymptoticGreaterEqual[f[x, y], g[x, y], {x, y} -> {0, 0}, Direction -> {Reals, "FromBelow"}]

関数の割合を可視化する．この割合は，に沿った部分を除いて原点に近付くほど大きくなる：

Wolfram Language code: ContourPlot[Abs[f[x, y] / g[x, y]], {x, -1, 1}, {y, -1, 1}, PlotLegends -> Automatic, ClippingStyle -> Automatic]

GenerateConditions (3)

条件を述べずに結果を返す：

Wolfram Language code: AsymptoticGreaterEqual[1, x ^ n, x -> 0, GenerateConditions -> False]

この結果は n>0のときにのみ有効である：

Wolfram Language code: AsymptoticGreaterEqual[1, x ^ n, x -> 0]

結果がパラメータの値に依存するときは，未評価で返される：

Wolfram Language code: AsymptoticGreaterEqual[Exp[a x], 1, x -> ∞, GenerateConditions -> None]

デフォルトで，結果を保証する条件が生成される：

Wolfram Language code: AsymptoticGreaterEqual[Exp[a x], 1, x -> ∞]

デフォルトで，特殊な値でしか結果が無効にならない場合は，条件は生成されない：

Wolfram Language code: AsymptoticGreaterEqual[(x - a)^2 + y^2, x y, {x, y} -> {0, 0}]

GenerateConditions->Trueのときは，これらの一般的ではない条件も報告される：

Wolfram Language code: AsymptoticGreaterEqual[(x - a)^2 + y^2, x y, {x, y} -> {0, 0}, GenerateConditions -> True]

PerformanceGoal (1)

PerformanceGoalを使って潜在的に高価な計算を避ける：

Wolfram Language code:

f = y^2 - 2 y z + z^2 - y (x - 2 y + 3 z) + z (x - 2 y + 3 z) + (x - 2 y + 3 z)^2;
g = 2 y z^2 - z^3 + y (x - 2 y + 3 z)^2 - z (x - 2 y + 3 z)^2;

Wolfram Language code: AsymptoticGreaterEqual[f, g, {x, y, z} -> {0, 0, 0}, PerformanceGoal -> "Speed"]//AbsoluteTiming

デフォルト設定では，使用可能なすべての手法を使って結果を出そうとする：

Wolfram Language code: AsymptoticGreaterEqual[f, g, {x, y, z} -> {0, 0, 0}]//AbsoluteTiming

アプリケーション (10)

基本的なアプリケーション (4)

0においてであることを示す：

Wolfram Language code: {AsymptoticGreaterEqual[1, x, x -> 0], AsymptoticGreaterEqual[x, x^2, x -> 0], AsymptoticGreaterEqual[x^2, x^3, x -> 0]}

これを記号的に示す：

Wolfram Language code: AsymptoticGreaterEqual[x^k, x^l, x -> 0, Assumptions -> {k, l}∈ℤ && l ≥ k ≥ 0]

関数を可視化する：

Wolfram Language code: Plot[{1, Abs[x], Abs[x^2], Abs[x^3]}, {x, -1, 1}, PlotLegends -> "Expressions"]

この関係はすべての実数ベキに及ぶ：

Wolfram Language code: AsymptoticGreaterEqual[x^k, x^l, x -> 0, Assumptions -> l ≥ k]

分数ベキと負のベキで関数を可視化する：

Wolfram Language code: Plot[{Abs[1 / x], Abs[1 / Sqrt[x]], 1, Abs[Sqrt[x]], Abs[x]}, {x, -1, 1}, PlotLegends -> "Expressions"]

∞においてであることを示す：

Wolfram Language code:

{AsymptoticGreaterEqual[x^3, x^2, x -> ∞], AsymptoticGreaterEqual[x^2, x, x -> ∞], AsymptoticGreaterEqual[x^1, x^0, x -> ∞]}

これを記号的に示す：

Wolfram Language code: AsymptoticGreaterEqual[x^k, x^l, x -> ∞, Assumptions -> {k, l}∈ℤ && 0 ≤ l ≤ k]

この関係を対数プロットで可視化する：

Wolfram Language code: LogPlot[{1, Abs[x], Abs[x^2], Abs[x^3]}, {x, 10, 100}, PlotLegends -> "Expressions"]

この関係はすべての実数ベキに及ぶ：

Wolfram Language code: AsymptoticGreaterEqual[x^k, x^l, x -> ∞, Assumptions -> l ≤ k]

分数ベキと負のベキで関数を可視化する：

Wolfram Language code: LogPlot[{Abs[1 / x], Abs[1 / Sqrt[x]], 1, Abs[Sqrt[x]], Abs[x]}, {x, 10, 100}, PlotLegends -> "Expressions"]

0においてあることを示す：

Wolfram Language code: AsymptoticGreaterEqual[x, x^2(Sin[1 / x] + 2), x -> 0]

Wolfram Language code: AsymptoticGreaterEqual[x^2(Sin[1 / x] + 2), x^2, x -> 0]

3つの関数を可視化する：

Wolfram Language code: Plot[{x^2, x^2(Sin[1 / x] + 2), Abs[x]}, {x, -1 / 3, 1 / 3}, PlotLegends -> "Expressions"]

∞においてであることを示す：

Wolfram Language code: AsymptoticGreaterEqual[x^2, x^2(Sin[x] + 2), x -> ∞]

Wolfram Language code: AsymptoticGreaterEqual[x^2(Sin[x] + 2), x, x -> ∞]

3つの関数を可視化する：

Wolfram Language code: LogPlot[{x^2, x^2(Sin[x] + 2), x}, {x, 1, 100}, PlotLegends -> "Expressions"]

計算の複雑性 (4)

単純なソートアルゴリズム（バブルソート，挿入ソート）は n 個のオブジェクトをソートするのに約 a n²ステップを要する．これに対し，最適化された一般的アルゴリズム（ヒープソート，マージソート）はソートを行うのに約 b n Log[n]のステップを要する．大量のオブジェクトに対しては，最適化されたアルゴリズムの方が常にソート時間が短くて済む，つまりであることを示す：

Wolfram Language code: AsymptoticGreaterEqual[a n^2, b n Log[n], n -> ∞, Assumptions -> a b > 0]

ある種の特別なアルゴリズム（分布数え上げソート，基数ソート）は，考えられる入力についての情報が事前に分かっているので，c n 時間で実行することができる．であることを示す：

Wolfram Language code: AsymptoticGreaterEqual[b n Log[n], c n, n -> ∞, Assumptions -> b c > 0]

3つの時間スケールの増大を可視化する：

Wolfram Language code:

LogPlot[{n^2, n Log[n], n}, {n, 10, 1000}, PlotLegends -> "Expressions", PlotLabel -> Row[{n^2∈Ω[n Log[n]], n Log[n]∈Ω[n]}, Spacer[10]]]

バブルソートでは，隣接近傍が比較され，順序が狂っている場合には入れ替えられる．1回のパス（n-1 回の比較）の後で最大要素が末尾になる．このプロセスが残りの n-1個の要素に対して行われ，先頭の2つの要素が残るまでこれが繰り返される．比較と入替えが c ステップだとすると，ソートのステップ総数は次のようになる：

Wolfram Language code: Sum[c(i - 1), {i, n, 2, -1}]

多項式はにある：

Wolfram Language code: AsymptoticGreaterEqual[(1/2) (-c n + c n^2), n^2, n -> ∞, Assumptions -> c > 0]

にもある：

Wolfram Language code: AsymptoticLessEqual[(1/2) (-c n + c n^2), n^2, n -> ∞, Assumptions -> c > 0]

したがって，であり，このアルゴリズムのランタイムは2次であると言われる：

Wolfram Language code: AsymptoticEqual[(1/2) (-c n + c n^2), n^2, n -> ∞, Assumptions -> c > 0]

マージソートでは，要素のリストが2つに分割され，半分ずつソートされ，最後に2つの部分が結合される．であるから，ソート時間T[n]は中間を計算する一定の時間 b，各半分をソートする時間2T[n/2]，2つの半分を結合するための要素数の倍数 a n の合計になる：

Wolfram Language code: reqn = T[n] == 2T[n / 2] + a n + b

再帰方程式を解いて n 個の要素をソートする時間 t を求める：

Wolfram Language code: t = RSolveValue[reqn, T[n], n]//Expand

であることを示す：

Wolfram Language code: AsymptoticGreaterEqual[t, n Log[n], n -> ∞, Assumptions -> a > 0]

逆に，：

Wolfram Language code: AsymptoticLessEqual[t, n Log[n], n -> ∞, Assumptions -> a > 0]

したがってであり，このアルゴリズムはのランタイムはであると言われる：

Wolfram Language code: AsymptoticEqual[t, n Log[n], n -> ∞, Assumptions -> a > 0]

巡回セールスマン問題(TSP)は個の都市を繋ぐ最短経路を求めるものである．馬鹿正直なアルゴリズムは通りの経路すべてを試そうとする．Held–Karpアルゴリズムは，それよりも効率よく約ステップに短縮する．であることを示す：

Wolfram Language code: AsymptoticGreaterEqual[n!, n ^ 2 2^n, n -> ∞]

どちらのアルゴリズムも巡回セールスマン問題の複雑性クラスは，時間で解ける問題のEXPTIMEと同じくらいであることを示している．Held–Karpアルゴリズムは，のを使うだけで十分である：

Wolfram Language code: AsymptoticGreaterEqual[2^2n, n^2 2^n, n -> ∞]

階乗については，のようにより高次の多項式を使う必要がある：

Wolfram Language code: AsymptoticGreaterEqual[2^n^2, n!, n -> ∞]

解の近似は回で求まるので，巡回セールスマン問題の近似は多項式時間で可解な問題の複雑性クラスPに属する．どの多項式アルゴリズムも指数アルゴリズムより速い．つまりである：

Wolfram Language code: AsymptoticGreaterEqual[2^n, n^k, n -> ∞]

収束判定法 (2)

$sum_(n=1)^inftyTemplateBox[{{a, _, n}}, Abs]<infty$ であれば，列は絶対加算可能であると言われる．第2列とが絶対加算可能でなければ，比較判定法はも絶対加算可能ではないと述べる．この判定法を使って，との比較によって，が発散することを示す：

Wolfram Language code: AsymptoticGreaterEqual[(1/n), ArcCot[n], n -> ∞]

調和級数は発散するので，も発散する：

Wolfram Language code: DiscreteLimit[Sum[(1/n), {n, 1, k}], k -> ∞]

SumConvergenceが与える答と比較する：

Wolfram Language code: SumConvergence[ArcCot[n], n]

と比較可能な別の列にがある．したがって，これも絶対加算可能ではない：

Wolfram Language code: AsymptoticGreaterEqual[(1/PrimePi[n]), (1/n), n -> ∞]

列は，したがって，絶対加算可能ではないことを示す：

Wolfram Language code: AsymptoticGreaterEqual[Log[n, Sqrt[(n + 1/n - 1)]], (1/n Log[n]), n -> ∞]

SumConvergenceが与える答と比較する：

Wolfram Language code: SumConvergence[Abs[(1/n Log[n])], n]

$int_a^bTemplateBox[{{f, , {(, x, )}}}, Abs]dx<infty$ であれば，関数はで完全に積分可能である言われる．とが開区間で連続で，との両方でなら，比較判定法は，が完全に積分可能でないのならも同じであるとする．この判定法を使ってがで完全に積分可能ではないことを示す：

Wolfram Language code: AsymptoticGreaterEqual[ArcCot[x], (1/ x), x -> ∞]

Wolfram Language code: AsymptoticGreaterEqual[ArcCot[x], (1/ x), x -> 1]

とはで積分可能ではないので，も積分可能ではない：

Wolfram Language code: Integrate[Abs[(1/x)], {x, 1, ∞}]

関数はで完全に積分可能ではない：

Wolfram Language code: Integrate[Abs[Exp[(1/x)]], {x, 0, 1}]

との両方で．したがって，の非積分可能性は次のようになる：

Wolfram Language code: AsymptoticGreaterEqual[Exp[1 / x^2]x^k, Exp[1 / x], x -> 0]

Wolfram Language code: AsymptoticGreaterEqual[Exp[1 / x^2]x^k, Exp[1 / x], x -> 1]

において，のとき：

Wolfram Language code: AsymptoticGreaterEqual[Exp[(1/x^2)] x^k, Exp[(1/x)], x -> ∞, Assumptions -> k ≥ 0]

が完全に積分可能ではないので，これらの関数もではそうではないことを示す：

Wolfram Language code: Integrate[Abs[Exp[(1/x)]], {x, 1, ∞}]

のときであるので，比較判定法は収束についての情報を与えない：

Wolfram Language code: AsymptoticGreaterEqual[Exp[(1/x^2)] x^k, Exp[(1/x)], x -> ∞, Assumptions -> k < 0]

特性と関係 (8)

AsymptoticGreaterEqualは反射関係である．つまり，である：

Wolfram Language code: AsymptoticGreaterEqual[f[x], f[x], x -> x0]

推移関係でもある．つまり，かつならを意味する：

Wolfram Language code: {f, g, h} = {x^3, x^2, x};

Wolfram Language code: {AsymptoticGreaterEqual[f, g, x -> ∞], AsymptoticGreaterEqual[g, h, x -> ∞], AsymptoticGreaterEqual[f, h, x -> ∞]}

しかし対称関係ではない．つまり，であるからであるということにはならない：

Wolfram Language code: {AsymptoticGreaterEqual[f, g, x -> ∞], AsymptoticGreaterEqual[g, f, x -> ∞]}

MinLimit[Abs[f[x]/g[x]],xx₀]>0のときかつそのときに限りAsymptoticGreaterEqual[f[x],g[x],xx₀]である：

Wolfram Language code: {f, g} = {x, x Sin[x]};

Wolfram Language code: {AsymptoticGreaterEqual[f, g, x -> ∞], MinLimit[Abs[f / g], x -> ∞]}

Wolfram Language code: {f, g} = {x Sin[x], Sqrt[x]};

Wolfram Language code: {AsymptoticGreaterEqual[f, g, x -> ∞], MinLimit[Abs[f / g], x -> ∞]}

Limit[Abs[f[x]/g[x]],xx₀]>0であればAsymptoticGreaterEqual[f[x],g[x],xx₀]である：

Wolfram Language code: {f, g} = {x^2, x^3 / (1 + x)};

Wolfram Language code: {AsymptoticGreaterEqual[f, g, x -> ∞], Limit[Abs[f / g], x -> ∞]}

しかし，極限がIndeterminateのときは不確定である：

Wolfram Language code: {f, g} = {x, x Sin[x]};

Wolfram Language code: {AsymptoticGreaterEqual[f, g, x -> ∞], Limit[Abs[f / g], x -> ∞]}

Wolfram Language code: {f, g} = {x Sin[x], Sqrt[x]};

Wolfram Language code: {AsymptoticGreaterEqual[f, g, x -> ∞], Limit[Abs[f / g], x -> ∞]}

ならである：

Wolfram Language code: {f, g} = {x, x^2 / (1 + x)};

Wolfram Language code: {AsymptoticGreaterEqual[f, g, x -> ∞], AsymptoticLessEqual[g, f, x -> ∞]}

かつならである：

Wolfram Language code: {f, g} = {x, x^2 / (1 + x)};

Wolfram Language code: {AsymptoticLessEqual[f, g, x -> ∞], AsymptoticGreaterEqual[f, g, x -> ∞], AsymptoticEqual[f, g, x -> ∞]}

またはならである：

Wolfram Language code: {f, g} = {x^2 / (1 + x), x};

Wolfram Language code: {AsymptoticEqual[f, g, x -> ∞], AsymptoticGreaterEqual[f, g, x -> ∞]}

Wolfram Language code: {f, g} = {x^3 / (1 + x), x};

Wolfram Language code: {AsymptoticGreater[f, g, x -> ∞], AsymptoticGreaterEqual[f, g, x -> ∞]}

しかし，はまたはを意味しない：

Wolfram Language code: {f, g} = {1 / x, Sin[x] / x};

Wolfram Language code: {AsymptoticGreaterEqual[f, g, x -> ∞], AsymptoticGreater[f, g, x -> ∞], AsymptoticEqual[g, h, x -> ∞]}

かつならである：

Wolfram Language code: {f, g, h} = {x^2, x, x^3 / (1 + x^2)};

Wolfram Language code: {AsymptoticGreaterEqual[f, g, x -> ∞], AsymptoticEqual[g, h, x -> ∞], AsymptoticGreaterEqual[f, h, x -> ∞]}

かつならである：

Wolfram Language code: {f, g, h} = {x^2, x, x^3 / (1 + x^2)};

Wolfram Language code: {AsymptoticGreaterEqual[f, g, x -> ∞], AsymptoticEquivalent[g, h, x -> ∞], AsymptoticGreaterEqual[f, h, x -> ∞]}

Top

その他のラーニングリソース

テクニカルサポート

Wolframソリューション

教育のためのWolframソリューション

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

AsymptoticGreaterEqual

詳細とオプション

例題

例 (2)

スコープ (9)

オプション (10)

Assumptions (1)

Direction (5)

GenerateConditions (3)

PerformanceGoal (1)

アプリケーション (10)

基本的なアプリケーション (4)

計算の複雑性 (4)

収束判定法 (2)

特性と関係 (8)

テキスト

CMS

APA

BibTeX

BibLaTeX

AsymptoticGreaterEqual

詳細とオプション

例題

例 (2)

スコープ (9)

オプション (10)

Assumptions (1)

Direction (5)

GenerateConditions (3)

PerformanceGoal (1)

アプリケーション (10)

基本的なアプリケーション (4)

計算の複雑性 (4)

収束判定法 (2)

特性と関係 (8)

関連項目

関連するガイド

履歴

テキスト

CMS

APA

BibTeX

BibLaTeX