Wolfram 语言与系统参考资料中心

AsymptoticLessEqual

AsymptoticLessEqual[f,g,xx^*]

给出当 xx^* 时或的条件.

AsymptoticLessEqual[f,g,{x₁,…,x_n}{,…,}]

给出当 {x₁,…,x_n}{,…,} 时或的条件.

范例

打开所有单元关闭所有单元

基本范例 (2)

验证当时，：

Wolfram Language code: AsymptoticLessEqual[x, x ^ 2, x -> ∞]

可视化两个函数：

Wolfram Language code: Plot[{x, x ^ 2}, {x, 0, 10}, PlotLegends -> "Expressions"]

验证当 {x,y}->∞ 时，：

Wolfram Language code: AsymptoticLessEqual[x + y, x ^ 2 + y ^ 2, {x, y} -> ∞]

可视化两个函数：

Wolfram Language code: Plot3D[{x + y, x ^ 2 + y ^ 2}, {x, 0, 10}, {y, 0, 10}, PlotLegends -> "Expressions"]

范围 (9)

比较不是严格为正 (positive) 的函数:

Wolfram Language code: AsymptoticLessEqual[x, -x ^ 2, x -> ∞]

显示在原点处发散的速度不会快于：

Wolfram Language code: AsymptoticLessEqual[(1/x^2), (1/x Sin[x]), x -> 0]

答案可能是布尔表达式，而不是明确的 True 或 False：

Wolfram Language code: AsymptoticLessEqual[Sin[x - 2], Sinh[p(x - 2)], x -> 2]

当比较有参数的函数时，可能会针对结果给出条件：

Wolfram Language code: AsymptoticLessEqual[(1/(x - 1)^p), (10/x - 1), x -> 1]

缺省情况下，在两个方向上对函数进行比较：

Wolfram Language code: AsymptoticLessEqual[x^4, x^2 UnitStep[x], x -> 0]

当比较较大的值时，确实不大于 $x^2 TemplateBox[{{x}}, UnitStepSeq]$ ：

Wolfram Language code: AsymptoticLessEqual[x^4, x^2 UnitStep[x], x -> 0, Direction -> "FromAbove"]

但对于较小的值，这种关系不再成立：

Wolfram Language code: AsymptoticLessEqual[x^4, x^2 UnitStep[x], x -> 0, Direction -> "FromBelow"]

可视化两个函数：

Wolfram Language code: Plot[{x^4, x^2UnitStep[x]}, {x, -1, 1}, PlotTheme -> {"DashedLines", "Detailed"}]

像 Sqrt 这样的函数可能在负实数的两个实数方向上具有相同的关系：

Wolfram Language code: AsymptoticLessEqual[(Sqrt[z] - I)^3, (z + 1), z -> -1]

如果从复平面的上方接近，可以看到同样的关系：

Wolfram Language code: AsymptoticLessEqual[(Sqrt[z] - I)^3, (z + 1), z -> -1, Direction -> -I]

然而，如果从复平面的下方接近会得到不同的结果：

Wolfram Language code: AsymptoticLessEqual[(Sqrt[z] - I)^3, (z + 1), z -> -1, Direction -> I]

这是由于在与坐标轴相交时 Sqrt 的虚部的符号发生了反转：

Wolfram Language code:

TableForm[Table[{-1 + Δ, Sqrt[-1 + Δ], Abs[Sqrt[-1 + Δ] - I]}, {Δ, {0.01, -0.01, 0.01I, -0.01I}}], TableHeadings -> {None, {z, Sqrt[z], HoldForm@Abs[Sqrt[z] - I]}}]

因而，总的来说，这种关系在复平面上不成立：

Wolfram Language code: AsymptoticLessEqual[(Sqrt[z] - I)^3, (z + 1), z -> -1, Direction -> Complexes]

可视化从四个实方向和虚方向逼近时函数的相对大小：

Wolfram Language code:

Plot[{Abs[ (-1 + Δz/(Sqrt[-1 + Δz] - I)^3)], Abs[ (-1 + I Δz/(Sqrt[-1 + I Δz] - I)^3)]}, {Δz, -1, 1}, IconizedObject[«plot options»]]

比较多变量函数：

Wolfram Language code: AsymptoticLessEqual[(x - 1)^2(y - 2), Sin[ x]Cos[3y / 4], {x, y} -> {1, 2}]

可视化两个函数的范数：

Wolfram Language code:

Show[Plot3D[{Abs[(x - 1)^2(y - 2)], Abs[Sin[ x]Cos[ 3y / 4]]}, {x, y}∈Disk[{1, 2}, .25], PlotTheme -> "Detailed"], Graphics3D[{AbsolutePointSize[7], Point[{1, 2, 0}]}], ViewPoint -> {1.36, -2.75, 1.42}]

在无穷大处比较多变量函数：

Wolfram Language code: AsymptoticLessEqual[ Exp[x]Log[y], x y, {x, y} -> {-∞, ∞}]

在比较多变量函数时使用参数：

Wolfram Language code: AsymptoticLessEqual[Sinh[x]y, Sinh[a x]y ^ 2, {x, y} -> {∞, 1}]

选项 (10)

Assumptions (1)

用 Assumptions 为参数指定条件：

Wolfram Language code: AsymptoticLessEqual[1 + x ^ a, 1, x -> 0, Assumptions -> a ≥ 0]

不同的假设给出不同的结果：

Wolfram Language code: AsymptoticLessEqual[1 + x ^ a, 1, x -> 0, Assumptions -> a < 0]

Direction (5)

从下方测试函数之间的关系：

Wolfram Language code: AsymptoticLessEqual[Sin[x], x UnitStep[x], x -> 0, Direction -> "FromBelow"]

等价于：

Wolfram Language code: AsymptoticLessEqual[Sin[x], x UnitStep[x], x -> 0, Direction -> 1]

从上方测试函数之间的关系：

Wolfram Language code: AsymptoticLessEqual[Sin[x], x UnitStep[x], x -> 0, Direction -> "FromAbove"]

等价于：

Wolfram Language code: AsymptoticLessEqual[Sin[x], x UnitStep[x], x -> 0, Direction -> -1]

测试分段不连续处的关系：

Wolfram Language code: AsymptoticLessEqual[Cos[x / 2], FractionalPart[x ^ 2]Sin[x], x -> 2, Direction -> "FromBelow"]

Wolfram Language code: AsymptoticLessEqual[Cos[x / 2], FractionalPart[x ^ 2]Sin[x], x -> 2, Direction -> "FromAbove"]

由于在一个方向上不成立，两个方向上同样不成立：

Wolfram Language code: AsymptoticLessEqual[Cos[x / 2], FractionalPart[x ^ 2]Sin[x], x -> 2, Direction -> "TwoSided"]

可视化两个函数及它们的比值：

Wolfram Language code:

Plot[{Cos[x / 2], FractionalPart[x ^ 2]Sin[x], Abs[(FractionalPart[x ^ 2]Sin[x]/Cos[x / 2])]}, {x, 1.5, 2.5}, PlotLegends -> "Expressions"]

在简单极点处的关系与逼近的方向无关：

Wolfram Language code: AsymptoticLessEqual[Tan[x], (2/2x - π), x -> π / 2, Direction -> "FromBelow"]

Wolfram Language code: AsymptoticLessEqual[Tan[x], (2/2x - π), x -> π / 2, Direction -> "FromAbove"]

Wolfram Language code: AsymptoticLessEqual[Tan[x], (2/2x - π), x -> π / 2, Direction -> ℝ]

Wolfram Language code: AsymptoticLessEqual[Tan[x], (2/2x - π), x -> π / 2, Direction -> ℂ]

测试分支切割处的关系：

Wolfram Language code: AsymptoticLessEqual[ Sqrt[x - 1] - I, Tanh[x], x -> 0, Direction -> +I]

Wolfram Language code: AsymptoticLessEqual[ Sqrt[x - 1] - I, Tanh[x], x -> 0, Direction -> -I]

Wolfram Language code: AsymptoticLessEqual[ Sqrt[x - 1] - I, Tanh[x], x -> 0, Direction -> Reals]

Wolfram Language code: AsymptoticLessEqual[ Sqrt[x - 1] - I, Tanh[x], x -> 0, Direction -> Complexes]

从不同象限逼近，计算函数之间的关系：

Wolfram Language code: f[x_, y_] := Sin[x y]

Wolfram Language code: g[x_, y_] := x + Abs[y]

从第一象限逼近原点：

Wolfram Language code: AsymptoticLessEqual[f[x, y], g[x, y], {x, y} -> {0, 0}, Direction -> "FromAbove"]

等价于：

Wolfram Language code: AsymptoticLessEqual[f[x, y], g[x, y], {x, y} -> {0, 0}, Direction -> {"FromAbove", "FromAbove"}]

从右半平面逼近原点：

Wolfram Language code: AsymptoticLessEqual[f[x, y], g[x, y], {x, y} -> {0, 0}, Direction -> {"FromAbove", Reals}]

从下半平面逼近原点：

Wolfram Language code: AsymptoticLessEqual[f[x, y], g[x, y], {x, y} -> {0, 0}, Direction -> {Reals, "FromBelow"}]

可视化函数的比值:

Wolfram Language code:

DensityPlot[Abs[Sin[x y] / (x + Abs[y])], {x, -1, 1}, {y, -1, 1}, PlotLegends -> Automatic, ClippingStyle -> Automatic]//Quiet

GenerateConditions (3)

返回结果，不给出条件：

Wolfram Language code: AsymptoticLessEqual[1 + x ^ n, 1, x -> 0, GenerateConditions -> False]

只有在 n>0 时结果才有效：

Wolfram Language code: AsymptoticLessEqual[1 + x ^ n, 1, x -> 0]

如果结果取决于参数的值，不计算，直接返回：

Wolfram Language code: AsymptoticLessEqual[Exp[-a x], 1, x -> ∞, GenerateConditions -> None]

缺省情况下，对能给出结果的情况产生条件：

Wolfram Language code: AsymptoticLessEqual[Exp[-a x], 1, x -> ∞]

缺省情况下，如果结果只在特殊值的时候才无效，不给出条件：

Wolfram Language code: AsymptoticLessEqual[x y, (x - a)^2 + y^2, {x, y} -> {0, 0}]

当 GenerateConditions->True 时，非通用条件也要报告：

Wolfram Language code: AsymptoticLessEqual[x y, (x - a)^2 + y^2, {x, y} -> {0, 0}, GenerateConditions -> True]

PerformanceGoal (1)

用 PerformanceGoal 来避免潜在的巨量计算：

Wolfram Language code:

f = 2 y z^2 - z^3 + y (x - 2 y + 3 z)^2 - z (x - 2 y + 3 z)^2;
g = y^2 - 2 y z + z^2 - y (x - 2 y + 3 z) + z (x - 2 y + 3 z) + (x - 2 y + 3 z)^2;

Wolfram Language code: AsymptoticLessEqual[f, g, {x, y, z} -> {0, 0, 0}, PerformanceGoal -> "Speed"]//AbsoluteTiming

默认设置使用所有可用技术来尝试给出结果：

Wolfram Language code: AsymptoticLessEqual[f, g, {x, y, z} -> {0, 0, 0}]//AbsoluteTiming

应用 (10)

基本应用 (4)

证明在 0 处：

Wolfram Language code: {AsymptoticLessEqual[x^3, x^2, x -> 0], AsymptoticLessEqual[x^2, x, x -> 0], AsymptoticLessEqual[x^1, x^0, x -> 0]}

用符号方式证明：

Wolfram Language code: AsymptoticLessEqual[x^k, x^l, x -> 0, Assumptions -> {k, l}∈ℤ && k ≥ l ≥ 0]

可视化函数：

Wolfram Language code: Plot[{1, Abs[x], Abs[x^2], Abs[x^3]}, {x, -1, 1}, PlotLegends -> "Expressions"]

这种关系对所有实数幂都成立：

Wolfram Language code: AsymptoticLessEqual[x^k, x^l, x -> 0, Assumptions -> k ≥ l]

可视化指数为分数和负数的函数：

Wolfram Language code: Plot[{Abs[1 / x], Abs[1 / Sqrt[x]], 1, Abs[Sqrt[x]], Abs[x]}, {x, -1, 1}, PlotLegends -> "Expressions"]

证明在 ∞ 处：

Wolfram Language code: {AsymptoticLessEqual[1, x, x -> ∞], AsymptoticLessEqual[x, x^2, x -> ∞], AsymptoticLessEqual[x^2, x^3, x -> ∞]}

用符号方式证明：

Wolfram Language code: AsymptoticLessEqual[x^k, x^l, x -> ∞, Assumptions -> {k, l}∈ℤ && 0 ≤ k ≤ l]

用对数图可视化这种关系：

Wolfram Language code: LogPlot[{1, Abs[x], Abs[x^2], Abs[x^3]}, {x, 10, 100}, PlotLegends -> "Expressions"]

这种关系对所有实数幂都成立：

Wolfram Language code: AsymptoticLessEqual[x^k, x^l, x -> ∞, Assumptions -> k ≤ l]

可视化指数为分数和负数的函数：

Wolfram Language code: LogPlot[{Abs[1 / x], Abs[1 / Sqrt[x]], 1, Abs[Sqrt[x]], Abs[x]}, {x, 10, 100}, PlotLegends -> "Expressions"]

证明在 0 处：

Wolfram Language code: AsymptoticLessEqual[x^2, x^2(Sin[1 / x] + 2), x -> 0]

Wolfram Language code: AsymptoticLessEqual[x^2(Sin[1 / x] + 2), x, x -> 0]

可视化三个函数：

Wolfram Language code: Plot[{Abs[x], Abs[x^2(Sin[1 / x] + 2)], x^2}, {x, -1 / 3, 1 / 3}, PlotLegends -> "Expressions"]

证明在 ∞ 处：

Wolfram Language code: AsymptoticLessEqual[x, x^2(Sin[x] + 2), x -> ∞]

Wolfram Language code: AsymptoticLessEqual[x^2(Sin[x] + 2), x^2, x -> ∞]

可视化三个函数：

Wolfram Language code: LogPlot[{x, x^2(Sin[x] + 2), x^2}, {x, 1, 100}, PlotLegends -> "Expressions"]

计算复杂度 (4)

简单的排序算法（冒泡排序，插入排序）需要大约 a n² 个步骤对 n 个对象进行排序，而最优通用算法（堆排序，合并排序）大约需要 b n Log[n] 个步骤来进行排序. 证明，对足够大的对象集合进行排序时，最优算法永远不会更慢：

Wolfram Language code: AsymptoticLessEqual[b n Log[n], a n^2, n -> ∞, Assumptions -> a b > 0]

某些特殊的算法（计数排序，基数排序），在有关可能的输入的信息提前存在的情况下，可在 c n 时间内完成. 证明：

Wolfram Language code: AsymptoticLessEqual[c n, b n Log[n], n -> ∞, Assumptions -> b c > 0]

可视化这三种算法计算时间的增长：

Wolfram Language code:

LogPlot[{n^2, n Log[n], n}, {n, 10, 1000}, PlotLabel -> Row[{n∈HoldForm@O[n Log[n]], n Log[n]∈HoldForm@O[n^2]}, Spacer[10]], PlotLegends -> "Expressions"]

在冒泡排序中，对相邻的项进行比较，如果顺序不对即进行交换. 经过 n-1 次比较后，最大的元素在最后. 然后在剩余的 n-1 个元素上重复该过程，直到开头处只剩下两个元素. 如果比较和交换需要 c 个步骤，则排序需要的总步骤如下所示：

Wolfram Language code: Sum[c(i - 1), {i, n, 2, -1}]

多项式的形式为：

Wolfram Language code: AsymptoticLessEqual[(1/2) (-c n + c n^2), n^2, n -> ∞, Assumptions -> c > 0]

形式也可以为：

Wolfram Language code: AsymptoticGreaterEqual[(1/2) (-c n + c n^2), n^2, n -> ∞, Assumptions -> c > 0]

因此，算法被认为需要二次型时间来完成：

Wolfram Language code: AsymptoticEqual[(1/2) (-c n + c n^2), n^2, n -> ∞, Assumptions -> c > 0]

在合并排序中，元素列表被分成两部分，分别对每部分进行排序，然后合并两个部分. 因此，进行排序的总时间 T[n] 将是用于计算中值的某个固定时间 b 加上对每一半元素进行排序的时间 2T[n/2]，再加上用于将两部分元素合并在一起的时间，即元素个数的倍数 a n：

Wolfram Language code: reqn = T[n] == 2T[n / 2] + a n + b

求解循环方程，计算对 n 个元素进行排序所需的时间 t：

Wolfram Language code: t = RSolveValue[reqn, T[n], n]//Expand

证明：

Wolfram Language code: AsymptoticLessEqual[t, n Log[n], n -> ∞, Assumptions -> a > 0]

反过来，：

Wolfram Language code: AsymptoticGreaterEqual[t, n Log[n], n -> ∞, Assumptions -> a > 0]

因此，算法被认为需要长的时间来完成：

Wolfram Language code: AsymptoticEqual[t, n Log[n], n -> ∞, Assumptions -> a > 0]

旅行推销员问题 (TSP) 需要找到连接个城市的最短路线. 一个朴素的算法是尝试所有个路线. Held–Karp 算法将其减少到大约个步骤. 证明：

Wolfram Language code: AsymptoticLessEqual[n ^ 2 2^n, n!, n -> ∞]

这两种算法都表明，TSP 的计算复杂度类不比 EXPTIME 难，EXPTIME 问题是可以在时间内解决的问题. 对于 Held–Karp 算法，使用就可以了，其中：

Wolfram Language code: AsymptoticLessEqual[n^2 2^n, 2^2n, n -> ∞]

对于阶乘，必须使用高次多项式，如：

Wolfram Language code: AsymptoticLessEqual[n!, 2^n^2, n -> ∞]

可以在时间内找到近似解，所以近似 TSP 属于复杂度类 P 问题，是在多项式时间内可以解决的问题. 任何多项式算法都比指数型算法快，或：

Wolfram Language code: AsymptoticLessEqual[n^k, 2^n, n -> ∞]

收敛性测试 (2)

如果 $sum_(n=1)^inftyTemplateBox[{{a, _, n}}, Abs]<infty$ ，序列被认为是绝对可以求和的. 如果第二个序列，比较测试指出，如果是绝对可以求和的，则也是绝对可以求和的. 通过与的和进行比较，用测试证明收敛：

Wolfram Language code: AsymptoticLessEqual[(1/n^2), (1/n^2 + n + 1), n -> ∞]

因为收敛，所以所求的式子的和也收敛：

Wolfram Language code: Sum[(1/Abs[n^2]), {n, 1, ∞}]

与 SumConvergence 给出的答案比较：

Wolfram Language code: SumConvergence[(1/n^2 + n + 1), n]

另一个与相当的序列是 $TemplateBox[{n}, PrimePi]/(n^3log(n))$ ，因此它也是绝对可以求和的：

Wolfram Language code: AsymptoticLessEqual[(PrimePi[n]/Log[n]n^3), (1/n^2), n -> ∞]

通过与的和比较，证明收敛：

Wolfram Language code: AsymptoticEqual[(1/n^3 / 2), (1/n^2Sin[1 / Sqrt[n]]), n -> ∞]

Wolfram Language code: Sum[(1/Abs[n^3 / 2]), {n, 1, ∞}]

如果 $int_a^bTemplateBox[{{f, , {(, x, )}}}, Abs]dx<infty$ ，函数被认为在上是绝对可积的. 如果和在开区间上是连续的，且在和处有，比较测试指出，如果是绝对可积的，那么也是绝对可积的. 用测试证明在上是绝对可积的：

Wolfram Language code: AsymptoticLessEqual[(ArcCot[x]/x), (1/x^2), x -> ∞]

Wolfram Language code: AsymptoticLessEqual[(ArcCot[x]/x), (1/x^2), x -> 1]

由于和在上是可积的，所以也是如此：

Wolfram Language code: Integrate[(1/x^2), {x, 1, ∞}]

函数在上是绝对可积的：

Wolfram Language code: Integrate[Abs[Exp[-x]], {x, 1, ∞}]

在和处，，因此可知是绝对可积的：

Wolfram Language code: AsymptoticLessEqual[Exp[-x^2]x^k, Exp[-x], x -> ∞]

Wolfram Language code: AsymptoticLessEqual[Exp[-x^2]x^k, Exp[-x], x -> 1]

在处，，其中：

Wolfram Language code: AsymptoticLessEqual[Exp[-x^2]x^k, Exp[-x], x -> 0, Assumptions -> k ≥ 0]

证明由于在上是绝对可积的，下列函数也是绝对可积的：

Wolfram Language code: Integrate[Exp[-x], {x, 0, ∞}]

对于，，所以比较测试无法给出关于收敛性的信息：

Wolfram Language code: AsymptoticLessEqual[Exp[-x^2]x^k, Exp[-x], x -> 0, Assumptions -> k < 0]

属性和关系 (8)

AsymptoticLessEqual 是一种自反关系，即：

Wolfram Language code: AsymptoticLessEqual[f[x], f[x], x -> x0]

还是一种传递关系，即若和成立，则有：

Wolfram Language code: {f, g, h} = {x, x^2, x^3};

Wolfram Language code: {AsymptoticLessEqual[f, g, x -> ∞], AsymptoticLessEqual[g, h, x -> ∞], AsymptoticLessEqual[f, h, x -> ∞]}

然而，它不是对称的，即不意味着：

Wolfram Language code: {AsymptoticLessEqual[f, g, x -> ∞], AsymptoticLessEqual[g, f, x -> ∞]}

当且仅当 MaxLimit[Abs[f[x]/g[x]],xx₀]<∞ 时，AsymptoticLessEqual[f[x],g[x],xx₀] 的结果为：

Wolfram Language code: {f, g} = {x Sin[x], x};

Wolfram Language code: {AsymptoticLessEqual[f, g, x -> ∞], MaxLimit[Abs[f / g], x -> ∞]}

Wolfram Language code: {f, g} = {x Sin[x], Sqrt[x]};

Wolfram Language code: {AsymptoticLessEqual[f, g, x -> ∞], MaxLimit[Abs[f / g], x -> ∞]}

如果 Limit[Abs[f[x]/g[x]],xx₀]<∞，则 AsymptoticLessEqual[f[x],g[x],xx₀] 的结果为：

Wolfram Language code: {f, g} = {x, x^2};

Wolfram Language code: {AsymptoticLessEqual[f, g, x -> ∞], Limit[Abs[f / g], x -> ∞]}

然而，当极限为 Indeterminate 时，结果是不确定的：

Wolfram Language code: {f, g} = {x Sin[x], x};

Wolfram Language code: {AsymptoticLessEqual[f, g, x -> ∞], Limit[Abs[f / g], x -> ∞]}

Wolfram Language code: {f, g} = {x Sin[x], Sqrt[x]};

Wolfram Language code: {AsymptoticLessEqual[f, g, x -> ∞], Limit[Abs[f / g], x -> ∞]}

如果，则：

Wolfram Language code: {f, g} = {x, x^2 / (1 + x)};

Wolfram Language code: {AsymptoticLessEqual[f, g, x -> ∞], AsymptoticGreaterEqual[g, f, x -> ∞]}

如果和，则：

Wolfram Language code: {f, g} = {x, x^2 / (1 + x)};

Wolfram Language code: {AsymptoticLessEqual[f, g, x -> ∞], AsymptoticGreaterEqual[f, g, x -> ∞], AsymptoticEqual[f, g, x -> ∞]}

如果或 , 则 :

Wolfram Language code: {f, g} = {x, x^2 / (1 + x)};

Wolfram Language code: {AsymptoticEqual[f, g, x -> ∞], AsymptoticLessEqual[f, g, x -> ∞]}

Wolfram Language code: {f, g} = {x, x^3 / (1 + x)};

Wolfram Language code: {AsymptoticLess[f, g, x -> ∞], AsymptoticLessEqual[f, g, x -> ∞]}

但是，不意味着或：

Wolfram Language code: {f, g} = {Sin[x] / x, 1 / x};

Wolfram Language code: {AsymptoticLessEqual[f, g, x -> ∞], AsymptoticLess[f, g, x -> ∞], AsymptoticEqual[g, x, x -> ∞]}

如果和 , 则 :

Wolfram Language code: {f, g, h} = {x, x^2, x^3 / (1 + x)};

Wolfram Language code: {AsymptoticLessEqual[f, g, x -> ∞], AsymptoticEqual[g, h, x -> ∞], AsymptoticLessEqual[f, h, x -> ∞]}

如果和，则：

Wolfram Language code: {f, g, h} = {x, x^2, x^3 / (1 + x)};

Wolfram Language code: {AsymptoticLessEqual[f, g, x -> ∞], AsymptoticEquivalent[g, h, x -> ∞], AsymptoticLessEqual[f, h, x -> ∞]}

Top

	AsymptoticLessEqual[f[x],g[x],xx^*]	存在和，使得 $0<TemplateBox[{{x, -, {x, ^, }}}, Abs]<delta(c,x^)$ 意味着成立
	AsymptoticLessEqual[f[x₁,…,x_n],g[x₁,…,x_n],{x₁,…,x_n}{,…,}]	存在和，使得 $0<TemplateBox[{{{, {{{x, _, 1}, -, {x, _, 1, ^, }}, ,, ..., ,, {{x, _, n}, -, {x, _, n, ^, }}}, }}}, Norm]<delta(c,x^*)$ 意味着 $TemplateBox[{{f, (, {{x, _, 1}, ,, ..., ,, {x, _, n}}, )}}, Abs]<=c TemplateBox[{{g, (, {{x, _, 1}, ,, ..., ,, {x, _, n}}, )}}, Abs]$ 成立

	AsymptoticLessEqual[f[x],g[x],x∞]	存在和，使得意味着成立
	AsymptoticLessEqual[f[x₁,…,x_n],g[x₁,…,x_n],{x₁,…,x_n}{∞,…,∞}]	存在和，使得意味着 $TemplateBox[{{f, (, {{x, _, 1}, ,, ..., ,, {x, _, n}}, )}}, Abs]<=c TemplateBox[{{g, (, {{x, _, 1}, ,, ..., ,, {x, _, n}}, )}}, Abs]$ 成立

Assumptions	$Assumptions	对参数的设定
Direction	Reals	趋近极限点的方向
GenerateConditions	Automatic	对参数生成条件
Method	Automatic	所使用的方法
PerformanceGoal	"Quality"	优化目标

	Reals or "TwoSided"	从两个实方向
	"FromAbove" or -1	从上面或较大的值
	"FromBelow" or +1	从下面或较小的值
	Complexes	从所有复方向
	Exp[ θ]	从方向
	{dir₁,…,dir_n}	对变量 x_i 分别使用方向 dir_i

更多学习资源

技术支持

Wolfram 解决方案

Wolfram 的教育解决方案

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

AsymptoticLessEqual

更多信息和选项

范例

基本范例 (2)

范围 (9)

选项 (10)

Assumptions (1)

Direction (5)

GenerateConditions (3)

PerformanceGoal (1)

应用 (10)

基本应用 (4)

计算复杂度 (4)

收敛性测试 (2)

属性和关系 (8)

文本

CMS

APA

BibTeX

BibLaTeX

	Automatic	只给出非通用条件
	True	所有条件
	False	不给出条件
	None	如果需要条件则不经计算直接返回

AsymptoticLessEqual

更多信息和选项

范例

基本范例 (2)

范围 (9)

选项 (10)

Assumptions (1)

Direction (5)

GenerateConditions (3)

PerformanceGoal (1)

应用 (10)

基本应用 (4)

计算复杂度 (4)

收敛性测试 (2)

属性和关系 (8)

参见

相关指南

历史

文本

CMS

APA

BibTeX

BibLaTeX