WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

AsymptoticOutputTracker[sys,{f1,…},{p1,…}]

アフィン系 sys の出力に減衰率 pjで基準信号 fiを追跡させる状態フィードバック制御法則を与える．

AsymptoticOutputTracker[{sys,{out1,…},{in1,…}},…]

使用する出力 outiおよび制御入力 injを指定する．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
考えられる問題  
関連項目
関連するガイド
履歴
引用書式

AsymptoticOutputTracker

AsymptoticOutputTracker[sys,{f1,…},{p1,…}]

アフィン系 sys の出力に減衰率 pjで基準信号 fiを追跡させる状態フィードバック制御法則を与える．

AsymptoticOutputTracker[{sys,{out1,…},{in1,…}},…]

使用する出力 outiおよび制御入力 injを指定する．

詳細とオプション

  • 系 sys はStateSpaceModelあるいはAffineStateSpaceModelでよい．
  • 基準信号 fiは1変数の純関数でなければならない．
  • 減衰率 piは閉ループ系の極の位置に対応し，極の数 piはTotal[SystemsModelVectorRelativeOrders[sys]]で与えられる．
  • 出力{out1,…}および入力{in1,…}は部分指定であり，デフォルトではAllであると解釈される．
  • 出力および基準信号の数は同じでなければならない．
  • AsymptoticOutputTrackerはFeedbackLinearizeに基づく．任意の残差ダイナミクスは有効な結果について安定していなければならない． »

例題

すべて開く すべて閉じる

例  (1)

正弦曲線を追跡している単一出力の線形系：

Wolfram Language code: ssm = StateSpaceModel[{{{-3}}, {{1}}, {{1}}, {{0}}}, {{x[t], 2}}, Automatic, Automatic, t, SamplingPeriod -> None, SystemsModelLabels -> None]; ref = Sin[t];

フィードバック法則：

Wolfram Language code: fb = AsymptoticOutputTracker[ssm, ref, {-5}]

閉ループ系：

Wolfram Language code: csys = SystemsModelStateFeedbackConnect[ssm, fb]

初回の過渡電流の後，出力は基準信号を追跡する：

Wolfram Language code: y = OutputResponse[csys, {0}, {t, 0, 8}];
Wolfram Language code: Plot[{y, ref}, {t, 0, 8}, PlotLegends -> {"output", "reference"}]

スコープ  (4)

区分的な一定の信号を追跡しているアフィン系：

Wolfram Language code: assm = AffineStateSpaceModel[{{Subscript[x, 2], Subscript[x, 1] + Subscript[x, 2]}, {{0}, {1 + Subscript[x, 1]}}, {Subscript[x, 1]}, {{0}}}, {{Subscript[x, 1], 1}, {Subscript[x, 2], 0}}, Automatic, {Automatic}, t, SamplingPeriod -> None];
Wolfram Language code: ref = Piecewise[{{1, 0 ≤ t ≤ 5}, {2, 5 < t ≤ 10}, {1, 10 < t ≤ 15}}, 0];
Wolfram Language code: Plot[ref, {t, 0, 20}, PlotStyle -> Thick]

フィードバック法則：

Wolfram Language code: fb = AsymptoticOutputTracker[assm, ref, {-3, -4}]

閉ループ系のシミュレーションを行う：

Wolfram Language code: csys = SystemsModelStateFeedbackConnect[assm, fb]; y = OutputResponse[csys /. Indeterminate -> 0, {0}, {t, 0, 20}];
Wolfram Language code: Plot[y, {t, 0, 20}, PlotRange -> All, AxesOrigin -> {0, 0}]

ランダムな点を通過する軌道を生成する：

Wolfram Language code: pts = Thread[{Range[0, 50, 5], RandomReal[{-10, 10}, 11]}];
Wolfram Language code: ref = Interpolation@pts; Plot[ref[t], {t, 0, 50}]

アフィン系に軌跡を追跡させるフィードバック法則を設計する：

Wolfram Language code: assm = AffineStateSpaceModel[{{Subscript[x, 1] + Subscript[x, 2], Subscript[x, 1] - 2*Subscript[x, 2] - Subscript[x, 1]*Subscript[x, 3], Subscript[x, 1] + Subscript[x, 1]*Subscript[x, 2] - 4*Subscript[x, 3]}, {{0}, {1}, {0}}, {Subscript[x, 1]}, {{0}}}, {Subscript[x, 1], Subscript[x, 2], Subscript[x, 3]}, Automatic, {Automatic}, t, SamplingPeriod -> None];
Wolfram Language code: fb = AsymptoticOutputTracker[assm, ref[t], {-4 + I, -4 - I}];

閉ループ系のシミュレーションを行う：

Wolfram Language code: csys = SystemsModelStateFeedbackConnect[assm, fb]; y = OutputResponse[csys, {0}, {t, 0, 50}];
Wolfram Language code: Plot[y, {t, 0, 50}, Epilog -> {PointSize[Medium], Point[pts]}]

出力よりも入力が多い場合は，フィードバック入力のいくつかはゼロになる：

Wolfram Language code: ssm = StateSpaceModel[{{{-1, 0}, {0, -2}}, {{1, 2}, {1, -1}}, {{1, 2}}, {{0, 0}}}, {{Subscript[x, 1][t], -1}, {Subscript[x, 2][t], 1}}, {Subscript[u, 1][t], Subscript[u, 2][t]}, Automatic, t, SamplingPeriod -> None, SystemsModelLabels -> None]; ref = Sin[t];
Wolfram Language code: fb1 = AsymptoticOutputTracker[ssm, ref, {-5, -8}]

制御フィードバックに使う第2入力を指定する：

Wolfram Language code: fb2 = AsymptoticOutputTracker[{ssm, All, 2}, ref, {-5, -8}]

それぞれのケースで閉ループ系を計算する：

Wolfram Language code: csys1 = SystemsModelStateFeedbackConnect[ssm, fb1]
Wolfram Language code: csys2 = SystemsModelStateFeedbackConnect[ssm, fb2, All, {2}]

どちらの制御器も追跡を行う：

Wolfram Language code: y1 = OutputResponse[csys1, {0}, {t, 0, 12}]; y2 = OutputResponse[csys2, {0}, {t, 0, 12}];
Wolfram Language code: Plot[{y1, y2}, {t, 0, 12}]

追跡する出力を指定して使用する入力を制御する：

Wolfram Language code: ssm = StateSpaceModel[{{{0, 1, 0, 0}, {-2, -3, 0, 0}, {0, 0, 0, 1}, {0, 0, -2, -3}}, {{0, 0}, {1, 0}, {0, 0}, {0, 1}}, {{2, 1, 2, 2}, {1, 1, 2, 1}}, {{0, 0}, {0, 0}}}]; outs = {1}; inps = {2};

フィードバック制御法を設計する：

Wolfram Language code: ref = Sin[t]; fb = AsymptoticOutputTracker[{ssm, {1}, {2}}, ref, {-10, -11}]

閉ループ系：

Wolfram Language code: csys = SystemsModelStateFeedbackConnect[ssm, fb, All, {2}]

最初の出力の応答：

Wolfram Language code: or = OutputResponse[csys, {0, 0}, {t, 0, 10}][[1]]

これは，参照を追跡する：

Wolfram Language code: Plot[{or, ref}, {t, 0, 10}]

アプリケーション  (3)

片端にロードを持ち，指定された軌道を追跡する，柔軟なジョイントのための制御器を設計する：»

系のモデル：

Wolfram Language code: pars = {Subscript[J, m] -> 0.4, k -> 100, Subscript[J, l] -> 1, M -> 1.5, g -> 9.8, L -> 0.4};
Wolfram Language code: assm = AffineStateSpaceModel[{Subscript[J, l] Subscript[θ, l]''[t] + M g L Sin[Subscript[θ, l][t]] + k(Subscript[θ, l][t] - Subscript[θ, m][t]) == 0, Subscript[J, m] Subscript[θ, m]''[t] - k(Subscript[θ, l][t] - Subscript[θ, m][t]) == τ[t]}, {Subscript[θ, l][t], Subscript[θ, l]'[t], Subscript[θ, m][t], Subscript[θ, m]'[t]}, τ[t], {Subscript[θ, l][t]}, t]

5°からまで10秒間で回転させるために必要なジョイント：

Wolfram Language code: traj = 5 ° + -3 ° t^2 / 5 + 1° t^3 / 25; Plot[traj, {t, 0, 10}]

軌跡は滑らかで，速度0から始まって速度0で終る：

Wolfram Language code: {Plot[Evaluate@D[traj, t], {t, 0, 10}], Plot[Evaluate@D[traj, {t, 2}], {t, 0, 10}]}

計算されたトルクの制御法則を得る：

Wolfram Language code: cinps = AsymptoticOutputTracker[assm, #, {-7 + 2I, -7 - 2 I, -9, -10}]& /@ {traj, -15 °}//Flatten;

閉ループ系：

Wolfram Language code: csys = SystemsModelStateFeedbackConnect[assm, {Piecewise[{{cinps[[1]], 0 ≤ t ≤ 10}}, cinps[[2]]]}];

ジョイントは，初期トランジェントの後で軌跡に従い，10秒後にで止まる：

Wolfram Language code: OutputResponse[{csys /. pars, {5 °, 0, 0, 0}}, {0}, {t, 0, 15}];
Wolfram Language code: Plot[Evaluate@{traj, %}, {t, 0, 15}]

ステッピングモーターが，一次系の軌跡に従って，0.1秒でロードを位置1°に置くような制御法則を計算する．モーターのモデル：»

Wolfram Language code: pars = {Subscript[K, m] -> 2 / 10, R -> 45 / 100, L -> 2 / 1000, J -> 65 / 10000, Subscript[n, p] -> 30, B -> 10 / 10000};
Wolfram Language code: asys = AffineStateSpaceModel[ {{(Sin[Subscript[n, p]*θ[t]]* Subscript[K, m]*Subscript[n, p]* ω[t] - R*Subscript[i, a][ t])/L, ((-Cos[Subscript[n, p]*θ[t]])* Subscript[K, m]*Subscript[n, p]* ω[t] - R*Subscript[i, b][ t])/L, ω[t], ((-B)*ω[t] + Cos[Subscript[n, p]*θ[t]]* Subscript[K, m]*Subscript[n, p]* Subscript[i, a][t] - Sin[Subscript[n, p]*θ[t]]* Subscript[K, m]*Subscript[n, p]* Subscript[i, b][t])/J}, {{L^(-1), 0}, {0, L^(-1)}, {0, 0}, {0, 0}}, {θ[t]}, {{0, 0}}}, {{Subscript[i, a][t], 0}, {Subscript[i, b][t], 0}, {θ[t], 0}, {ω[t], 0}}, {{vsa[t], 0}, {vsb[t], 0}}, {Automatic}, t, SamplingPeriod -> None] /. pars;

基準軌跡：

Wolfram Language code: ref = OutputResponse[TransferFunctionModel[{{{1}}, 1 + s/100}, s], UnitStep[t], {t, 0, 0.1}]; Plot[ref, {t, 0, 0.1}, PlotRange -> All]

フィードバック法則：

Wolfram Language code: Short[fb = AsymptoticOutputTracker[asys, ref, {-300, -500, -600}]]

閉ループ系には所望の応答がある：

Wolfram Language code: SystemsModelStateFeedbackConnect[asys, fb];
Wolfram Language code: Plot[Evaluate@OutputResponse[%, {0, 0}, {t, 0, 0.1}], {t, 0, 0.1}, PlotRange -> All]

代謝物 ，，の割合が操作変数とみなされ，，，，が定数とみなされる生化学グリコーゲン経路．0.2，0.5，0.4における代謝物 ，，の値を保つフィードバック法則を設計する：»

この系のモデル：

Wolfram Language code: constants = {Subscript[x, 6][t] -> 3, Subscript[x, 7][t] -> 40, Subscript[x, 9][t] -> 2.86, Subscript[x, 10][t] -> 4};
Wolfram Language code: asys = AffineStateSpaceModel[ {{0.07788*Subscript[x, 4][t]^0.66*Subscript[x, 6][ t] - (1.0627*Subscript[x, 1][t]^1.53* Subscript[x, 7][t])/Subscript[x, 2][t]^ 0.59, (-0.00079*Subscript[x, 2][t]^3.97* Subscript[x, 8][t])/Subscript[x, 3][t]^ 3.06 + (0.585*Subscript[x, 1][t]^0.95* Subscript[x, 5][t]^0.32* Subscript[x, 7][t]^0.62* Subscript[x, 10][t]^0.38)/ Subscript[x, 2][t]^0.41, (0.00079*Subscript[x, 2][t]^3.97*Subscript[x, 8][ t])/Subscript[x, 3][t]^3.06 - 1.0588*Subscript[x, 3][t]^0.3*Subscript[x, 9][ t], 0, 0, 0}, {{0, 0, 0}, {0, 0, 0}, {0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}, {Subscript[x, 1][t], Subscript[x, 2][t], Subscript[x, 3][t]}, {{0, 0, 0}, {0, 0, 0}, {0, 0, 0}}}, {{Subscript[x, 1][t], 0.067}, {Subscript[x, 2][t], 0.465}, {Subscript[x, 3][t], 0.15}, {Subscript[x, 4][t], 10}, {Subscript[x, 5][t], 5}, {Subscript[x, 8][t], 136}}, Automatic, {Automatic, Automatic, Automatic}, t, SamplingPeriod -> None] /. constants;

0.2，0.5，0.4における代謝物 ，，の値を保つフィードバック法則：

Wolfram Language code: fb = AsymptoticOutputTracker[asys, {0.2, 0.5, 0.4}, {-0.5 + I, -0.5 - I, -1 + I , -1 - I, -2, -2.5}];

閉ループ系のシミュレーションを行う：

Wolfram Language code: csys = SystemsModelStateFeedbackConnect[asys, fb]; Plot[Evaluate@OutputResponse[csys, {0, 0, 0}, {t, 0, 7}], {t, 0, 7}]

制御努力：

Wolfram Language code: fb /. Thread[{Subscript[x, 1][t], Subscript[x, 2][t], Subscript[x, 3][t], Subscript[x, 4][t], Subscript[x, 5][t], Subscript[x, 8][t]} -> StateResponse[csys, {0, 0, 0}, {t, 0, 7}]];
Wolfram Language code: GraphicsRow[Table[Plot[i, {t, 0, 7}, PlotRange -> All, ImageSize -> 145], {i, %}]]

特性と関係  (2)

指定される減衰率の数はベクトル相関次数の総和で決定される：

Wolfram Language code: assm = AffineStateSpaceModel[{{-Subscript[x, 1][t], -Subscript[x, 2][t] + Subscript[x, 2][t]^2, 0}, {{1 + Subscript[x, 1][t]}, {1}, {1}}, {Subscript[x, 3][t]}, {{0}}}, {Subscript[x, 1][t], Subscript[x, 2][t], Subscript[x, 3][t]}, {u[t]}, {Automatic}, t, SamplingPeriod -> None];

これは，1つの減衰率が指定されるべきことを示している：

Wolfram Language code: Total@SystemsModelVectorRelativeOrders[assm]
Wolfram Language code: AsymptoticOutputTracker[assm, Sin[t], {-2}]

各出力の減衰率は，その相対次数に基づいて割り当てられる：

Wolfram Language code: assm = AffineStateSpaceModel[{{Subscript[x, 2][t] + Subscript[x, 2][t]^2, Subscript[x, 3][t] - Subscript[x, 1][t]*Subscript[x, 4][t] + Subscript[x, 4][t]*Subscript[x, 5][t], Subscript[x, 2][t]*Subscript[x, 4][t] + Subscript[x, 1][t]*Subscript[x, 5][t] - Subscript[x, 5][t]^2, Subscript[x, 5][t], Subscript[x, 2][t]^2}, {{0, 1}, {0, 0}, {Cos[Subscript[x, 1][t] - Subscript[x, 5][t]], 1}, {0, 0}, {0, 1}}, {Subscript[x, 1][t] - Subscript[x, 5][t], Subscript[x, 4][t]}, {{0, 0}, {0, 0}}}, {{Subscript[x, 1][t], 0.1}, {Subscript[x, 2][t], 0.3}, {Subscript[x, 3][t], 0}, {Subscript[x, 4][t], 0.4}, {Subscript[x, 5][t], 1}}, {Subscript[, 1][t], Subscript[, 2][t]}, {Automatic, Automatic}, t, SamplingPeriod -> None];

出力1には3つの，出力2には2つの減衰率が必要である：

Wolfram Language code: SystemsModelVectorRelativeOrders[assm]

出力1には遅めの率を，出力2には速めの率を指定する：

Wolfram Language code: ref = {Sin[t], Cos[t]}; fb = AsymptoticOutputTracker[assm, ref, {-2, -3, -4, -10, -12}]

出力2は出力1よりも速く追跡する：

Wolfram Language code: or = OutputResponse[SystemsModelStateFeedbackConnect[assm, fb], {0, 0}, {t, 0, 3}];
Wolfram Language code: Plot[{or, ref}, {t, 0, 3}, PlotLegends -> {"output 1", "output 2", "ref 1", "ref 2"}]

考えられる問題  (1)

フィードバック法則が有効となるためには，任意の残差ダイナミクスが安定していなければならない：

Wolfram Language code: asys = AffineStateSpaceModel[{{Subscript[x, 1] - Subscript[x, 2], Subscript[x, 1] - Subscript[x, 2], 3*Subscript[x, 2] + Subscript[x, 3] + (Subscript[x, 1] + Subscript[x, 2] + Subscript[x, 3])^ 2}, {{0}, {-1 - Subscript[x, 1]*Subscript[x, 2]}, {1 + Subscript[x, 1]*Subscript[x, 2]}}, {Subscript[x, 1]}, {{0}}}, {Subscript[x, 1], Subscript[x, 2], Subscript[x, 3]}, {v}, {Automatic}, Automatic, SamplingPeriod -> None];
Wolfram Language code: fb = AsymptoticOutputTracker[asys, 0.1, {-1.5, -0.5}]

このフィードバック法則は有効ではない：

Wolfram Language code: SystemsModelStateFeedbackConnect[asys, fb];
Wolfram Language code: StateResponse[%, 0, {t, 0, 15}];

これは，残差ダイナミクスが不安定なためである：

Wolfram Language code: FeedbackLinearize[asys, Automatic, "ResidualSystem"];
Wolfram Language code: Eigenvalues@First@Normal@StateSpaceModel@%
Wolfram Research (2014), AsymptoticOutputTracker, Wolfram言語関数， https://reference.wolfram.com/language/ref/AsymptoticOutputTracker.html.

テキスト

Wolfram Research (2014), AsymptoticOutputTracker, Wolfram言語関数， https://reference.wolfram.com/language/ref/AsymptoticOutputTracker.html.

CMS

Wolfram Language. 2014. "AsymptoticOutputTracker." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/AsymptoticOutputTracker.html.

APA

Wolfram Language. (2014). AsymptoticOutputTracker. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/AsymptoticOutputTracker.html

BibTeX

@misc{reference.wolfram_2026_asymptoticoutputtracker, author="Wolfram Research", title="{AsymptoticOutputTracker}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/AsymptoticOutputTracker.html}", note=[Accessed: 15-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_asymptoticoutputtracker, organization={Wolfram Research}, title={AsymptoticOutputTracker}, year={2014}, url={https://reference.wolfram.com/language/ref/AsymptoticOutputTracker.html}, note=[Accessed: 15-September-2026]}