WOLFRAM

Wolfram 语言与系统参考资料中心

AsymptoticOutputTracker[sys,{f1,…},{p1,…}]

给出导致仿射系统 sys 的输出跟踪参考信号 fi 的状态反馈控制律，其中衰减度为 pj.

AsymptoticOutputTracker[{sys,{out1,…},{in1,…}},…]

指定所用的输出 outi 和控制输入 inj.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
应用  
属性和关系  
可能存在的问题  
参见
相关指南
历史
按以下格式引用：

AsymptoticOutputTracker

AsymptoticOutputTracker[sys,{f1,…},{p1,…}]

给出导致仿射系统 sys 的输出跟踪参考信号 fi 的状态反馈控制律，其中衰减度为 pj.

AsymptoticOutputTracker[{sys,{out1,…},{in1,…}},…]

指定所用的输出 outi 和控制输入 inj.

更多信息和选项

范例

打开所有单元 关闭所有单元

基本范例  (1)

跟踪正弦曲线的线性单输出系统：

Wolfram Language code: ssm = StateSpaceModel[{{{-3}}, {{1}}, {{1}}, {{0}}}, {{x[t], 2}}, Automatic, Automatic, t, SamplingPeriod -> None, SystemsModelLabels -> None]; ref = Sin[t];

反馈律：

Wolfram Language code: fb = AsymptoticOutputTracker[ssm, ref, {-5}]

闭环系统：

Wolfram Language code: csys = SystemsModelStateFeedbackConnect[ssm, fb]

初始瞬变之后，输出跟踪参考：

Wolfram Language code: y = OutputResponse[csys, {0}, {t, 0, 8}];
Wolfram Language code: Plot[{y, ref}, {t, 0, 8}, PlotLegends -> {"output", "reference"}]

范围  (4)

跟踪分段恒定信号的仿射系统：

Wolfram Language code: assm = AffineStateSpaceModel[{{Subscript[x, 2], Subscript[x, 1] + Subscript[x, 2]}, {{0}, {1 + Subscript[x, 1]}}, {Subscript[x, 1]}, {{0}}}, {{Subscript[x, 1], 1}, {Subscript[x, 2], 0}}, Automatic, {Automatic}, t, SamplingPeriod -> None];
Wolfram Language code: ref = Piecewise[{{1, 0 ≤ t ≤ 5}, {2, 5 < t ≤ 10}, {1, 10 < t ≤ 15}}, 0];
Wolfram Language code: Plot[ref, {t, 0, 20}, PlotStyle -> Thick]

反馈律：

Wolfram Language code: fb = AsymptoticOutputTracker[assm, ref, {-3, -4}]

模拟闭环系统：

Wolfram Language code: csys = SystemsModelStateFeedbackConnect[assm, fb]; y = OutputResponse[csys /. Indeterminate -> 0, {0}, {t, 0, 20}];
Wolfram Language code: Plot[y, {t, 0, 20}, PlotRange -> All, AxesOrigin -> {0, 0}]

生成经过随机点的轨迹：

Wolfram Language code: pts = Thread[{Range[0, 50, 5], RandomReal[{-10, 10}, 11]}];
Wolfram Language code: ref = Interpolation@pts; Plot[ref[t], {t, 0, 50}]

设计一个反馈律，使得仿射系统跟踪轨迹：

Wolfram Language code: assm = AffineStateSpaceModel[{{Subscript[x, 1] + Subscript[x, 2], Subscript[x, 1] - 2*Subscript[x, 2] - Subscript[x, 1]*Subscript[x, 3], Subscript[x, 1] + Subscript[x, 1]*Subscript[x, 2] - 4*Subscript[x, 3]}, {{0}, {1}, {0}}, {Subscript[x, 1]}, {{0}}}, {Subscript[x, 1], Subscript[x, 2], Subscript[x, 3]}, Automatic, {Automatic}, t, SamplingPeriod -> None];
Wolfram Language code: fb = AsymptoticOutputTracker[assm, ref[t], {-4 + I, -4 - I}];

模拟闭环系统：

Wolfram Language code: csys = SystemsModelStateFeedbackConnect[assm, fb]; y = OutputResponse[csys, {0}, {t, 0, 50}];
Wolfram Language code: Plot[y, {t, 0, 50}, Epilog -> {PointSize[Medium], Point[pts]}]

如果输入多于输出，则部分反馈输入是零：

Wolfram Language code: ssm = StateSpaceModel[{{{-1, 0}, {0, -2}}, {{1, 2}, {1, -1}}, {{1, 2}}, {{0, 0}}}, {{Subscript[x, 1][t], -1}, {Subscript[x, 2][t], 1}}, {Subscript[u, 1][t], Subscript[u, 2][t]}, Automatic, t, SamplingPeriod -> None, SystemsModelLabels -> None]; ref = Sin[t];
Wolfram Language code: fb1 = AsymptoticOutputTracker[ssm, ref, {-5, -8}]

指定用于控制反馈的第二个输入：

Wolfram Language code: fb2 = AsymptoticOutputTracker[{ssm, All, 2}, ref, {-5, -8}]

计算在每种情况下的闭环系统：

Wolfram Language code: csys1 = SystemsModelStateFeedbackConnect[ssm, fb1]
Wolfram Language code: csys2 = SystemsModelStateFeedbackConnect[ssm, fb2, All, {2}]

两个控制器均实现跟踪：

Wolfram Language code: y1 = OutputResponse[csys1, {0}, {t, 0, 12}]; y2 = OutputResponse[csys2, {0}, {t, 0, 12}];
Wolfram Language code: Plot[{y1, y2}, {t, 0, 12}]

指定要跟踪的输出和要使用的控制输入：

Wolfram Language code: ssm = StateSpaceModel[{{{0, 1, 0, 0}, {-2, -3, 0, 0}, {0, 0, 0, 1}, {0, 0, -2, -3}}, {{0, 0}, {1, 0}, {0, 0}, {0, 1}}, {{2, 1, 2, 2}, {1, 1, 2, 1}}, {{0, 0}, {0, 0}}}]; outs = {1}; inps = {2};

设计反馈控制方法：

Wolfram Language code: ref = Sin[t]; fb = AsymptoticOutputTracker[{ssm, {1}, {2}}, ref, {-10, -11}]

闭环系统：

Wolfram Language code: csys = SystemsModelStateFeedbackConnect[ssm, fb, All, {2}]

第一个输出的响应：

Wolfram Language code: or = OutputResponse[csys, {0, 0}, {t, 0, 10}][[1]]

可以很好地跟踪参考信号：

Wolfram Language code: Plot[{or, ref}, {t, 0, 10}]

应用  (3)

设计一个柔性接头的控制器，使其在一端承受负载的同时，跟踪指定的轨迹：»

系统模型：

Wolfram Language code: pars = {Subscript[J, m] -> 0.4, k -> 100, Subscript[J, l] -> 1, M -> 1.5, g -> 9.8, L -> 0.4};
Wolfram Language code: assm = AffineStateSpaceModel[{Subscript[J, l] Subscript[θ, l]''[t] + M g L Sin[Subscript[θ, l][t]] + k(Subscript[θ, l][t] - Subscript[θ, m][t]) == 0, Subscript[J, m] Subscript[θ, m]''[t] - k(Subscript[θ, l][t] - Subscript[θ, m][t]) == τ[t]}, {Subscript[θ, l][t], Subscript[θ, l]'[t], Subscript[θ, m][t], Subscript[θ, m]'[t]}, τ[t], {Subscript[θ, l][t]}, t]

接头需要在10秒内从 5° 旋转至 ：

Wolfram Language code: traj = 5 ° + -3 ° t^2 / 5 + 1° t^3 / 25; Plot[traj, {t, 0, 10}]

轨迹以零速度开始和结束，并且是平滑的：

Wolfram Language code: {Plot[Evaluate@D[traj, t], {t, 0, 10}], Plot[Evaluate@D[traj, {t, 2}], {t, 0, 10}]}

得到计算的扭矩控制律：

Wolfram Language code: cinps = AsymptoticOutputTracker[assm, #, {-7 + 2I, -7 - 2 I, -9, -10}]& /@ {traj, -15 °}//Flatten;

闭环系统：

Wolfram Language code: csys = SystemsModelStateFeedbackConnect[assm, {Piecewise[{{cinps[[1]], 0 ≤ t ≤ 10}}, cinps[[2]]]}];

接头在初始瞬变后跟随轨迹，并在10秒后保持在 ：

Wolfram Language code: OutputResponse[{csys /. pars, {5 °, 0, 0, 0}}, {0}, {t, 0, 15}];
Wolfram Language code: Plot[Evaluate@{traj, %}, {t, 0, 15}]

计算步进电机将负荷在0.1秒内沿一阶系统轨迹放置在1°位置的控制律. 电机模型：»

Wolfram Language code: pars = {Subscript[K, m] -> 2 / 10, R -> 45 / 100, L -> 2 / 1000, J -> 65 / 10000, Subscript[n, p] -> 30, B -> 10 / 10000};
Wolfram Language code: asys = AffineStateSpaceModel[ {{(Sin[Subscript[n, p]*θ[t]]* Subscript[K, m]*Subscript[n, p]* ω[t] - R*Subscript[i, a][ t])/L, ((-Cos[Subscript[n, p]*θ[t]])* Subscript[K, m]*Subscript[n, p]* ω[t] - R*Subscript[i, b][ t])/L, ω[t], ((-B)*ω[t] + Cos[Subscript[n, p]*θ[t]]* Subscript[K, m]*Subscript[n, p]* Subscript[i, a][t] - Sin[Subscript[n, p]*θ[t]]* Subscript[K, m]*Subscript[n, p]* Subscript[i, b][t])/J}, {{L^(-1), 0}, {0, L^(-1)}, {0, 0}, {0, 0}}, {θ[t]}, {{0, 0}}}, {{Subscript[i, a][t], 0}, {Subscript[i, b][t], 0}, {θ[t], 0}, {ω[t], 0}}, {{vsa[t], 0}, {vsb[t], 0}}, {Automatic}, t, SamplingPeriod -> None] /. pars;

参考轨迹：

Wolfram Language code: ref = OutputResponse[TransferFunctionModel[{{{1}}, 1 + s/100}, s], UnitStep[t], {t, 0, 0.1}]; Plot[ref, {t, 0, 0.1}, PlotRange -> All]

反馈律：

Wolfram Language code: Short[fb = AsymptoticOutputTracker[asys, ref, {-300, -500, -600}]]

该闭环系统具有所希望的响应：

Wolfram Language code: SystemsModelStateFeedbackConnect[asys, fb];
Wolfram Language code: Plot[Evaluate@OutputResponse[%, {0, 0}, {t, 0, 0.1}], {t, 0, 0.1}, PlotRange -> All]

糖酵解-糖原分解（glycolytic-glycogenolytic）途径，其中代谢产物 、 和 的速率作为被控变量，、、 和 均保持恒定. 设计一个反馈律，使得代谢产物 、 和 的值保持在 0.2，0.5和0.4：»

系统模型：

Wolfram Language code: constants = {Subscript[x, 6][t] -> 3, Subscript[x, 7][t] -> 40, Subscript[x, 9][t] -> 2.86, Subscript[x, 10][t] -> 4};
Wolfram Language code: asys = AffineStateSpaceModel[{{0.07788 Subscript[x, 4][t]^0.66 Subscript[x, 6][t] - (1.0627 Subscript[x, 1][t]^1.53 Subscript[x, 7][t]/Subscript[x, 2][t]^0.59), -(0.00079 Subscript[x, 2][t]^3.97 Subscript[x, 8][t]/Subscript[x, 3][t]^3.06) + (0.585 Subscript[x, 1][t]^0.95 Subscript[x, 5][t]^0.32 Subscript[x, 7][t]^0.62 Subscript[x, 10][t]^0.38/Subscript[x, 2][t]^0.41), (0.00079 Subscript[x, 2][t]^3.97 Subscript[x, 8][t]/Subscript[x, 3][t]^3.06) - 1.0588 Subscript[x, 3][t]^0.3 Subscript[x, 9][t], 0, 0, 0}, {{0, 0, 0}, {0, 0, 0}, {0, 0, 0}, {1, 0, 0}, {0, 1, 0}, {0, 0, 1}}, {Subscript[x, 1][t], Subscript[x, 2][t], Subscript[x, 3][t]}, {{0, 0, 0}, {0, 0, 0}, {0, 0, 0}}}, {{Subscript[x, 1][t], 0.067}, {Subscript[x, 2][t], 0.465}, {Subscript[x, 3][t], 0.15}, {Subscript[x, 4][t], 10}, {Subscript[x, 5][t], 5}, {Subscript[x, 8][t], 136}}, Automatic, {Automatic, Automatic, Automatic}, t, SamplingPeriod -> None] /. constants;

使得 、 和 的值保持在0.2，0.5和0.4的反馈律：

Wolfram Language code: fb = AsymptoticOutputTracker[asys, {0.2, 0.5, 0.4}, {-0.5 + I, -0.5 - I, -1 + I , -1 - I, -2, -2.5}];

模拟闭环系统：

Wolfram Language code: csys = SystemsModelStateFeedbackConnect[asys, fb]; Plot[Evaluate@OutputResponse[csys, {0, 0, 0}, {t, 0, 7}], {t, 0, 7}]

控制力度：

Wolfram Language code: fb /. Thread[{Subscript[x, 1][t], Subscript[x, 2][t], Subscript[x, 3][t], Subscript[x, 4][t], Subscript[x, 5][t], Subscript[x, 8][t]} -> StateResponse[csys, {0, 0, 0}, {t, 0, 7}]];
Wolfram Language code: GraphicsRow[Table[Plot[i, {t, 0, 7}, PlotRange -> All, ImageSize -> 145], {i, %}]]

属性和关系  (2)

待指定的衰减率数目由向量相对阶数之和确定：

Wolfram Language code: assm = AffineStateSpaceModel[{{-Subscript[x, 1][t], -Subscript[x, 2][t] + Subscript[x, 2][t]^2, 0}, {{1 + Subscript[x, 1][t]}, {1}, {1}}, {Subscript[x, 3][t]}, {{0}}}, {Subscript[x, 1][t], Subscript[x, 2][t], Subscript[x, 3][t]}, {u[t]}, {Automatic}, t, SamplingPeriod -> None];

这表明，需要指定单个衰变速率：

Wolfram Language code: Total@SystemsModelVectorRelativeOrders[assm]
Wolfram Language code: AsymptoticOutputTracker[assm, Sin[t], {-2}]

各个输出的衰变速率根据其相对顺序指定：

Wolfram Language code: assm = AffineStateSpaceModel[{{Subscript[x, 2][t] + Subscript[x, 2][t]^2, Subscript[x, 3][t] - Subscript[x, 1][t]*Subscript[x, 4][t] + Subscript[x, 4][t]*Subscript[x, 5][t], Subscript[x, 2][t]*Subscript[x, 4][t] + Subscript[x, 1][t]*Subscript[x, 5][t] - Subscript[x, 5][t]^2, Subscript[x, 5][t], Subscript[x, 2][t]^2}, {{0, 1}, {0, 0}, {Cos[Subscript[x, 1][t] - Subscript[x, 5][t]], 1}, {0, 0}, {0, 1}}, {Subscript[x, 1][t] - Subscript[x, 5][t], Subscript[x, 4][t]}, {{0, 0}, {0, 0}}}, {{Subscript[x, 1][t], 0.1}, {Subscript[x, 2][t], 0.3}, {Subscript[x, 3][t], 0}, {Subscript[x, 4][t], 0.4}, {Subscript[x, 5][t], 1}}, {Subscript[, 1][t], Subscript[, 2][t]}, {Automatic, Automatic}, t, SamplingPeriod -> None];

输出1需要三个衰变速率，输出2需要两个衰变速率：

Wolfram Language code: SystemsModelVectorRelativeOrders[assm]

对输出1指定较慢速率 ，对输出2指定较快速率 ：

Wolfram Language code: ref = {Sin[t], Cos[t]}; fb = AsymptoticOutputTracker[assm, ref, {-2, -3, -4, -10, -12}]

输出2的跟踪将比输出1快：

Wolfram Language code: or = OutputResponse[SystemsModelStateFeedbackConnect[assm, fb], {0, 0}, {t, 0, 3}];
Wolfram Language code: Plot[{or, ref}, {t, 0, 3}, PlotLegends -> {"output 1", "output 2", "ref 1", "ref 2"}]

可能存在的问题  (1)

如要反馈律有效，任何残留动态必须稳定：

Wolfram Language code: asys = AffineStateSpaceModel[{{Subscript[x, 1] - Subscript[x, 2], Subscript[x, 1] - Subscript[x, 2], 3*Subscript[x, 2] + Subscript[x, 3] + (Subscript[x, 1] + Subscript[x, 2] + Subscript[x, 3])^ 2}, {{0}, {-1 - Subscript[x, 1]*Subscript[x, 2]}, {1 + Subscript[x, 1]*Subscript[x, 2]}}, {Subscript[x, 1]}, {{0}}}, {Subscript[x, 1], Subscript[x, 2], Subscript[x, 3]}, {v}, {Automatic}, Automatic, SamplingPeriod -> None];
Wolfram Language code: fb = AsymptoticOutputTracker[asys, 0.1, {-1.5, -0.5}]

反馈律是无效的：

Wolfram Language code: SystemsModelStateFeedbackConnect[asys, fb];
Wolfram Language code: StateResponse[%, 0, {t, 0, 15}];

这是因为残留动态不稳定：

Wolfram Language code: FeedbackLinearize[asys, Automatic, "ResidualSystem"];
Wolfram Language code: Eigenvalues@First@Normal@StateSpaceModel@%
Wolfram Research (2014)，AsymptoticOutputTracker，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AsymptoticOutputTracker.html.

文本

Wolfram Research (2014)，AsymptoticOutputTracker，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AsymptoticOutputTracker.html.

CMS

Wolfram 语言. 2014. "AsymptoticOutputTracker." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/AsymptoticOutputTracker.html.

APA

Wolfram 语言. (2014). AsymptoticOutputTracker. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/AsymptoticOutputTracker.html 年

BibTeX

@misc{reference.wolfram_2026_asymptoticoutputtracker, author="Wolfram Research", title="{AsymptoticOutputTracker}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/AsymptoticOutputTracker.html}", note=[Accessed: 17-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_asymptoticoutputtracker, organization={Wolfram Research}, title={AsymptoticOutputTracker}, year={2014}, url={https://reference.wolfram.com/language/ref/AsymptoticOutputTracker.html}, note=[Accessed: 17-August-2026]}