WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

AudioBlockMap[f,audio,dur]

audio の重なり合ない長さ dur のパーティションに f を 適用する．

AudioBlockMap[f,audio,{dur,offset}]

audio のオフセット offset のパーティションに f を 適用する．

AudioBlockMap[f,audio,{dur,offset,wfun}]

audio のパーティションに wfun を適用した後に f を適用する．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
関数指定  
パーティション指定  
オプション  
Alignment  
Padding  
アプリケーション  
特性と関係  
インタラクティブな例題  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

AudioBlockMap

AudioBlockMap[f,audio,dur]

audio の重なり合ない長さ dur のパーティションに f を 適用する．

AudioBlockMap[f,audio,{dur,offset}]

audio のオフセット offset のパーティションに f を 適用する．

AudioBlockMap[f,audio,{dur,offset,wfun}]

audio のパーティションに wfun を適用した後に f を適用する．

詳細とオプション

  • AudioBlockMap[f,audio,…]は，値が f を audio のパーティションに適用した結果であるTimeSeriesを返す．時点は対応するパーティションの中心である．
  • 関数 f は，名前付きの引数を使ってさまざまな形式のパーティションデータに作用する．
  • #AudioData または #1各パーティションの生の音声データ（デフォルト）
    #FourierData各パーティションのフーリエ変換
    #MagnitudeSpectrumフーリエ変換の大きさ
    #PowerSpectrum各パーティションのパワースペクトル
  • 時間変数 dur と offset は秒単位のスカラー，時点，あるいはQuantityオブジェクトのサンプルとして与えることができる．
  • から まででサンプルされた窓関数，あるいはパーティションの長さにリサンプルされた値のリストを使って平滑化窓 wfun を指定することができる．デフォルトでは平滑化は行われない．これは，DirichletWindowに等しい．
  • 次は使用可能なオプションである．
  • Alignment Centerタイムスタンプとパーティションの揃え方
    FourierParameters{-1,1}フーリエパラメータ
    MetaInformationNone追加的なメタ情報を含む
    MissingDataMethodNone欠落値に使用するメソッド
    Padding Automatic充填スキーム
    PaddingSizeAutomatic充填量
    ResamplingMethod"Interpolation"パスのリサンプリングに使用するメソッド
  • 次は，Alignmentの可能な設定である．
  • Left各パーティションの始まりの時間を返す
    Center各パーティションの中心の時間を返す
    Right各パーティションの終りの時間を返す
    a-1（左）から1（右）までのスケールされた揃え方
  • 次は，Paddingの可能な設定である．
  • None充填は行わず，サンプル数の少ないパーティションを除去する
    0ゼロ（無音）充填
    val一定の値
    "Fixed"境界値の繰返し
    "Periodic"完全な音声の循環的繰り返し
    "Reflected"境界上の音声の鏡映
    "Reversed"完全な音声の反転

例題

すべて開く すべて閉じる

例  (1)

音声オブジェクトのパーティションに関数を適用する：

Wolfram Language code: a = \!\(\*AudioBox["![Embedded Audio Player](audio://content-vvehy)"]\);
Wolfram Language code: max = AudioBlockMap[Max, a, Quantity[20, "Milliseconds"]]

結果を音声の波形とともにプロットする：

Wolfram Language code: Show[AudioPlot[a, AspectRatio -> 1 / 2, PlotRange -> All], ListLinePlot[max, PlotStyle -> Red]]

スコープ  (7)

関数指定  (5)

関数 f はTimeSeriesがサポートする任意の値を返す：

Wolfram Language code: a = Import["ExampleData/rule30.wav"]; stdev = AudioBlockMap[StandardDeviation, a, .04]
Wolfram Language code: Show[AudioPlot[a, AspectRatio -> 1 / 2, PlotRange -> All], ListLinePlot[stdev, PlotStyle -> Red, PlotRange -> {-1, 1}]]

各パーティションの最大値と最小値のペアを計算する：

Wolfram Language code: minmax = AudioBlockMap[MinMax, a, .04]
Wolfram Language code: Show[AudioPlot[a, AspectRatio -> 1 / 2, PlotRange -> All], ListLinePlot[minmax, PlotStyle -> {Orange, Darker[Green]}, PlotRange -> {-1, 1}]]

関数 f は数値出力を返す必要はない：

Wolfram Language code: a = \!\(\*AudioBox["![Embedded Audio Player](audio://content-sxbd6)"]\);
Wolfram Language code: f[values_] := Blend[{Green, Yellow, Red}, Max[values]]

この関数は，パーティション内の最大値に比例する色を返す：

Wolfram Language code: colors = AudioBlockMap[f, AudioNormalize@a, .05]["Values"]

結果を波形とともにプロットする：

Wolfram Language code: Column[{AudioPlot[a, FrameTicks -> None, ImageSize -> Medium], ArrayPlot[{colors}, ImageSize -> Medium]}]

関数 f はパーティションデータのフーリエ変換に使うことができる：

Wolfram Language code: a = \!\(\*AudioBox["![Embedded Audio Player](audio://content-sxbd6)"]\);

フーリエ変換の100番目の成分の位相を計算する：

Wolfram Language code: res = AudioBlockMap[Arg@#FourierData[[100]]&, AudioNormalize@a, .05]

結果を波形とともにプロットする：

Wolfram Language code: Show[ListLinePlot[res, PlotStyle -> Red, PlotRange -> All], AudioPlot[a, AspectRatio -> 1 / 2, PlotRange -> All]]

関数 f はパーティションデータのマグニチュードスペクトルに使うことができる：

Wolfram Language code: a = \!\(\*AudioBox["![Embedded Audio Player](audio://content-sxbd6)"]\);

マグニチュードスペクトルの2番目に大きいピークの位置を求める：

Wolfram Language code: res = AudioBlockMap[FindPeaks[#MagnitudeSpectrum][[2, 1]]&, AudioNormalize@a, .05]

結果を波形とともにプロットする：

Wolfram Language code: Show[ListLinePlot[res, PlotStyle -> Red, PlotRange -> All], AudioPlot[a, AspectRatio -> 1 / 2, PlotRange -> All]]

関数 f はパーティションデータのパワースペクトルに使うことができる：

Wolfram Language code: a = \!\(\*AudioBox["![Embedded Audio Player](audio://content-sxbd6)"]\);

各パワースペクトルにローパスフィルタをかけて，結果を平滑化する：

Wolfram Language code: res = AudioBlockMap[LowpassFilter[#PowerSpectrum, .4]&, AudioNormalize@a, .05]

平滑化したスペクトログラムをプロットする：

Wolfram Language code: MatrixPlot[Log@res["Values"]]

パーティション指定  (2)

0.05秒の重なり合ない部分の最大値を計算する：

Wolfram Language code: a = \!\(\*AudioBox["![Embedded Audio Player](audio://content-vvehy)"]\);
Wolfram Language code: max = AudioBlockMap[Max, a, 0.05]

結果を音声の波形とともにプロットする：

Wolfram Language code: Show[AudioPlot[a, AspectRatio -> 1 / 2, PlotRange -> All], ListLinePlot[max, PlotStyle -> Red]]

部分間に0.02秒重なりを使う：

Wolfram Language code: max = AudioBlockMap[Max, a, {0.05, 0.02}]

結果を音声の波形とともにプロットする：

Wolfram Language code: Show[AudioPlot[a, AspectRatio -> 1 / 2, PlotRange -> All], ListLinePlot[max, PlotStyle -> Red]]

平滑化窓を使う：

Wolfram Language code: max = AudioBlockMap[Max, a, {0.05, 0.02, HammingWindow}]

結果を音声の波形とともにプロットする：

Wolfram Language code: Show[AudioPlot[a, AspectRatio -> 1 / 2, PlotRange -> All], ListLinePlot[max, PlotStyle -> Red]]

パーティションサイズとオフセットは，時間Quantity，"Samples" Quantity，あるいは，秒単位の継続時間として解釈される数で指定することができる：

Wolfram Language code: a = Import["ExampleData/rule30.wav"]; AudioBlockMap[Max, a, 1]
Wolfram Language code: % == AudioBlockMap[Max, a, Quantity[1, "Seconds"]]

各パーティションに含めるサンプル数を指定する：

Wolfram Language code: AudioBlockMap[Max, a, Quantity[44100, "Samples"]]

オプション  (2)

Alignment  (1)

結果のTimeSeriesのタイムスタンプは，デフォルトで，各パーティションの中央に置かれる：

Wolfram Language code: audio = Import["ExampleData/rule30.wav"];
Wolfram Language code: audioplot = AudioPlot[audio, AspectRatio -> 1 / 2, PlotRange -> All, PlotRangePadding -> Scaled[.05], GridLines -> {Table[i, {i, 0, QuantityMagnitude@Duration@audio, .3}], None}];
Wolfram Language code: max = AudioBlockMap[Max, audio, .3]; Show[audioplot, ListPlot[max, PlotStyle -> Red, Filling -> Axis, PlotMarkers -> Automatic, PlotRange -> {-1, 1}]]

中央揃えはAlignment->0と同じである：

Wolfram Language code: max = AudioBlockMap[Max, audio, .3, Alignment -> 0]; Show[audioplot, ListPlot[max, PlotStyle -> Red, Filling -> Axis, PlotMarkers -> Automatic, PlotRange -> {-1, 1}]]

Alignment->Rightを使って計算された特性を各パーティションの末尾に返す：

Wolfram Language code: max = AudioBlockMap[Max, audio, .3, Alignment -> Right]; Show[audioplot, ListPlot[max, PlotStyle -> Red, Filling -> Axis, PlotMarkers -> Automatic, PlotRange -> {-1, 1}]]

カスタムの揃え方を使う：

Wolfram Language code: max = AudioBlockMap[Max, audio, .3, Alignment -> -.5]; Show[audioplot, ListPlot[max, PlotStyle -> Red, Filling -> Axis, PlotMarkers -> Automatic, PlotRange -> {-1, 1}]]

Padding  (1)

デフォルトで，不完全なパーティションは右側を0で充填される：

Wolfram Language code: audio = Audio[Range[10.], SampleRate -> 1]; AudioBlockMap[#&, audio, 4, Padding -> Automatic]["Values"]

別の充填スキームを指定する：

Wolfram Language code: AudioBlockMap[#&, audio, 4, Padding -> "Periodic"]["Values"]

Padding->Noneを使って不完全なパーティションを計算から削除する：

Wolfram Language code: AudioBlockMap[#&, audio, 4, Padding -> None]["Values"]

アプリケーション  (3)

即時振幅をdB RMSで計算する：

Wolfram Language code: a = Import["ExampleData/rule30.wav"]; dBrms = AudioBlockMap[20Log10[Sqrt@Mean[# ^ 2]]&, a, {Quantity[50, "Milliseconds"], Quantity[5, "Milliseconds"]}];ListLinePlot[dBrms]

即時振幅(dB RMS)のヒストグラムを可視化する：

Wolfram Language code: Histogram[dBrms, 40]

分布を推定する：

Wolfram Language code: 𝒟 = KernelMixtureDistribution[dBrms, 1]

結果の分布を使って分布関数の可視化を含む分析を行う：

Wolfram Language code: Table[Plot[f[𝒟, x], {x, -50, 0}, Filling -> Axis, PlotLabel -> f], {f, {PDF, CDF}}]
Wolfram Language code: Moment[𝒟, 1]
Wolfram Language code: Quantile[𝒟, 0.95]//Quiet

音声圧縮器を作る：

Wolfram Language code: a = \!\(\*AudioBox["![Embedded Audio Player](audio://content-vvehy)"]\); AudioPlot[a]

閾値を0.02にして信号のRMS振幅を計算する：

Wolfram Language code: amplitude = AudioBlockMap[Max[.02, Sqrt@Mean[# ^ 2]]&, a, {.01, .005}]

信号の動的範囲を圧縮する：

Wolfram Language code: AudioNormalize[a / Audio[amplitude]]
Wolfram Language code: AudioPlot[%]

音声振幅を可視化する：

Wolfram Language code: a = \!\(\*AudioBox["![Embedded Audio Player](audio://content-vvehy)"]\);
Wolfram Language code: m = AudioBlockMap[{Hue[Max@#], Disk[{0, 0}, Max@#]}&, a, {.1, .01, HannWindow}]
Wolfram Language code: Graphics[{Opacity[.5], MapThread[{#1[[1]], Translate[#1[[2]], {#2, 0}]}&, {m["Values"], m["Times"]}]}]

特性と関係  (1)

AudioBlockMapを使うと多くのAudioLocalMeasurements特性が計算できる：

Wolfram Language code: a = Import["ExampleData/rule30.wav"];
Wolfram Language code: AudioBlockMap[Max, a, {.5, .5, None}, Padding -> None] == AudioLocalMeasurements[a, "Max", PartitionGranularity -> {.5, .5, None}, PaddingSize -> 0]

インタラクティブな例題  (1)

信号の振幅を動的に可視化する：

Wolfram Language code: a = \!\(\*AudioBox["![Embedded Audio Player](audio://content-sxbd6)"]\);

0が緑で1が赤の色関数を定義する：

Wolfram Language code: cf[x_] := Blend[{Green, Yellow, Red}, x] Table[cf[i], {i, 0, 1, .1}]

色のリストと半径が振幅に比例する円板を計算する：

Wolfram Language code: fps = 30;disks = AudioBlockMap[{cf[Max@#], Disk[{0, 0}, Max@#]}&, a, {.1, 1 / fps}]["Values"]; RandomSample[disks, 2]

結果をアニメーションにする：

Wolfram Language code: ListAnimate[Table[ Graphics[d, PlotRange -> 1], {d, disks}], fps, TransitionEffect -> "Fade"]

重複を許してアニメーションにする：

Wolfram Language code: ListAnimate[Table[ Graphics[d, PlotRange -> 1], {d, Rest@FoldList[Flatten@Append[#1 /. Opacity[x_] -> Opacity[Clip[x - .1, {0, 1}]], {Opacity[1], #2}]&, {}, disks]}], fps, TransitionEffect -> "Fade"]

おもしろい例題  (1)

パーティションの値を反転させて新たな音声オブジェクトを作る：

Wolfram Language code: a = Import["ExampleData/rule30.wav"]; AudioBlockMap[Reverse, a, {0.3, 0.1}]["Values"]//Flatten//Audio
Wolfram Research (2016), AudioBlockMap, Wolfram言語関数， https://reference.wolfram.com/language/ref/AudioBlockMap.html （2019年に更新）.

テキスト

Wolfram Research (2016), AudioBlockMap, Wolfram言語関数， https://reference.wolfram.com/language/ref/AudioBlockMap.html （2019年に更新）.

CMS

Wolfram Language. 2016. "AudioBlockMap." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2019. https://reference.wolfram.com/language/ref/AudioBlockMap.html.

APA

Wolfram Language. (2016). AudioBlockMap. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/AudioBlockMap.html

BibTeX

@misc{reference.wolfram_2026_audioblockmap, author="Wolfram Research", title="{AudioBlockMap}", year="2019", howpublished="\url{https://reference.wolfram.com/language/ref/AudioBlockMap.html}", note=[Accessed: 16-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_audioblockmap, organization={Wolfram Research}, title={AudioBlockMap}, year={2019}, url={https://reference.wolfram.com/language/ref/AudioBlockMap.html}, note=[Accessed: 16-August-2026]}