WOLFRAM

Wolfram 语言与系统参考资料中心

AudioBlockMap[f,audio,dur]

将 f 应用于 audio 中无重叠的长度为 t 的分区.

AudioBlockMap[f,audio,{dur,offset}]

将 f 应用于 audio 中位移为 d 的分区.

AudioBlockMap[f,audio,{dur,offset,wfun}]

在应用 wfun 后将 f 用于 audio 中的分区.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
函数规范  
分区规范  
选项  
Alignment  
Padding  
应用  
属性和关系  
互动范例  
巧妙范例  
参见
相关指南
历史
按以下格式引用：

AudioBlockMap

AudioBlockMap[f,audio,dur]

将 f 应用于 audio 中无重叠的长度为 t 的分区.

AudioBlockMap[f,audio,{dur,offset}]

将 f 应用于 audio 中位移为 d 的分区.

AudioBlockMap[f,audio,{dur,offset,wfun}]

在应用 wfun 后将 f 用于 audio 中的分区.

更多信息和选项

  • AudioBlockMap[f,audio,…] 返回 TimeSeries ，其值为应用于 audio 分区的 f 结果. 时间为对应分区的中心.
  • 函数 f 适用于不同形式的使用已命名参数的分区数据：
  • #AudioData 或 #1每个分区的原始音频数据（默认）
    #FourierData每个分区的傅立叶变换
    #MagnitudeSpectrum傅立叶变换的幅值
    #PowerSpectrum每个分区的功率谱
  • 时间变量 dur 和 offset 可用以秒表示的标量形式给出，也可以时间或样本 Quantity 对象的形式给出.
  • 平滑窗 wfun 可用在 到 之间取样的窗函数指定，或用以分区长度为标准重新取样的数值列表指定. 默认情况下，不使用平滑操作，这等价于 DirichletWindow.
  • 可给出下列选项：
  • Alignment Center对齐分区时间戳
    FourierParameters{-1,1}傅立叶参数
    MetaInformationNone包括其他元信息
    MissingDataMethodNone处理缺失值的方法
    Padding Automatic填充设计
    PaddingSizeAutomatic填充量
    ResamplingMethod"Interpolation"用于重采样路径的方法
  • Alignment 的可能设置包括：
  • Left在每个分区的开头返回时间
    Center在每个分区的中间返回时间
    Right在每个分区的结尾返回时间
    a在 -1 （左）和 1 （右）之间缩放对齐
  • Padding 的可能设置包括:
  • None无填充，去除样本较少的分区
    0零（无声）填充
    val恒定值
    "Fixed"边界值的重复
    "Periodic"完整音频的循环重复
    "Reflected"边界上的音频反射
    "Reversed"倒转完整音频

范例

打开所有单元 关闭所有单元

基本范例  (1)

将函数应用于音频对象的分区：

Wolfram Language code: a = \!\(\*AudioBox["![Embedded Audio Player](audio://content-vvehy)"]\);
Wolfram Language code: max = AudioBlockMap[Max, a, Quantity[20, "Milliseconds"]]

绘制包含音频波形的结果：

Wolfram Language code: Show[AudioPlot[a, AspectRatio -> 1 / 2, PlotRange -> All], ListLinePlot[max, PlotStyle -> Red]]

范围  (7)

函数规范  (5)

函数 f 可返回任何 TimeSeries 支持的数值：

Wolfram Language code: a = Import["ExampleData/rule30.wav"]; stdev = AudioBlockMap[StandardDeviation, a, .04]
Wolfram Language code: Show[AudioPlot[a, AspectRatio -> 1 / 2, PlotRange -> All], ListLinePlot[stdev, PlotStyle -> Red, PlotRange -> {-1, 1}]]

计算每段分区的一对最大值和最小值：

Wolfram Language code: minmax = AudioBlockMap[MinMax, a, .04]
Wolfram Language code: Show[AudioPlot[a, AspectRatio -> 1 / 2, PlotRange -> All], ListLinePlot[minmax, PlotStyle -> {Orange, Darker[Green]}, PlotRange -> {-1, 1}]]

函数 f 不必返回数值输出：

Wolfram Language code: a = \!\(\*AudioBox["![Embedded Audio Player](audio://content-sxbd6)"]\);
Wolfram Language code: f[values_] := Blend[{Green, Yellow, Red}, Max[values]]

该函数返回一种与分区的最大值成正比的颜色：

Wolfram Language code: colors = AudioBlockMap[f, AudioNormalize@a, .05]["Values"]

绘制结果与波形：

Wolfram Language code: Column[{AudioPlot[a, FrameTicks -> None, ImageSize -> Medium], ArrayPlot[{colors}, ImageSize -> Medium]}]

函数 f 可对分区数据的傅立叶变换进行操作：

Wolfram Language code: a = \!\(\*AudioBox["![Embedded Audio Player](audio://content-sxbd6)"]\);

计算傅立叶变换的第 100 个分量的相位：

Wolfram Language code: res = AudioBlockMap[Arg@#FourierData[[100]]&, AudioNormalize@a, .05]

绘制结果与波形：

Wolfram Language code: Show[ListLinePlot[res, PlotStyle -> Red, PlotRange -> All], AudioPlot[a, AspectRatio -> 1 / 2, PlotRange -> All]]

函数 f 可对分区数据的幅值频谱进行操作：

Wolfram Language code: a = \!\(\*AudioBox["![Embedded Audio Player](audio://content-sxbd6)"]\);

找出幅值频谱第二大峰值的位置：

Wolfram Language code: res = AudioBlockMap[FindPeaks[#MagnitudeSpectrum][[2, 1]]&, AudioNormalize@a, .05]

绘制结果与波形：

Wolfram Language code: Show[ListLinePlot[res, PlotStyle -> Red, PlotRange -> All], AudioPlot[a, AspectRatio -> 1 / 2, PlotRange -> All]]

函数 f 可对分区数据的功率谱进行操作：

Wolfram Language code: a = \!\(\*AudioBox["![Embedded Audio Player](audio://content-sxbd6)"]\);

使用低通滤波器过滤每个功率谱对结果进行平滑处理：

Wolfram Language code: res = AudioBlockMap[LowpassFilter[#PowerSpectrum, .4]&, AudioNormalize@a, .05]

绘制经过平滑处理的频谱图：

Wolfram Language code: MatrixPlot[Log@res["Values"]]

分区规范  (2)

计算未重复、长度为0.05秒的片段的最大值：

Wolfram Language code: a = \!\(\*AudioBox["![Embedded Audio Player](audio://content-vvehy)"]\);
Wolfram Language code: max = AudioBlockMap[Max, a, 0.05]

绘制包含音频波形的结果：

Wolfram Language code: Show[AudioPlot[a, AspectRatio -> 1 / 2, PlotRange -> All], ListLinePlot[max, PlotStyle -> Red]]

在片段间使用 0.02 秒重叠：

Wolfram Language code: max = AudioBlockMap[Max, a, {0.05, 0.02}]

绘制包含音频波形的结果：

Wolfram Language code: Show[AudioPlot[a, AspectRatio -> 1 / 2, PlotRange -> All], ListLinePlot[max, PlotStyle -> Red]]

使用平滑窗：

Wolfram Language code: max = AudioBlockMap[Max, a, {0.05, 0.02, HammingWindow}]

绘制包含音频波形的结果：

Wolfram Language code: Show[AudioPlot[a, AspectRatio -> 1 / 2, PlotRange -> All], ListLinePlot[max, PlotStyle -> Red]]

分区尺寸和位移可指定为一个时间量 Quantity、样本量 "Samples" Quantity 或一个数字，意思为以秒为单位的持续时间：

Wolfram Language code: a = Import["ExampleData/rule30.wav"]; AudioBlockMap[Max, a, 1]
Wolfram Language code: % == AudioBlockMap[Max, a, Quantity[1, "Seconds"]]

指定每段分区包括的样本数量：

Wolfram Language code: AudioBlockMap[Max, a, Quantity[44100, "Samples"]]

选项  (2)

Alignment  (1)

默认情况下，结果得到的 TimeSeries 的时间戳位于每段分区的中心：

Wolfram Language code: audio = Import["ExampleData/rule30.wav"];
Wolfram Language code: audioplot = AudioPlot[audio, AspectRatio -> 1 / 2, PlotRange -> All, PlotRangePadding -> Scaled[.05], GridLines -> {Table[i, {i, 0, QuantityMagnitude@Duration@audio, .3}], None}];
Wolfram Language code: max = AudioBlockMap[Max, audio, .3]; Show[audioplot, ListPlot[max, PlotStyle -> Red, Filling -> Axis, PlotMarkers -> Automatic, PlotRange -> {-1, 1}]]

中心对齐即为 Alignment->0:

Wolfram Language code: max = AudioBlockMap[Max, audio, .3, Alignment -> 0]; Show[audioplot, ListPlot[max, PlotStyle -> Red, Filling -> Axis, PlotMarkers -> Automatic, PlotRange -> {-1, 1}]]

使用 Alignment->Right 可将返回的结果属性置于每段分区的末尾：

Wolfram Language code: max = AudioBlockMap[Max, audio, .3, Alignment -> Right]; Show[audioplot, ListPlot[max, PlotStyle -> Red, Filling -> Axis, PlotMarkers -> Automatic, PlotRange -> {-1, 1}]]

使用自定义对齐：

Wolfram Language code: max = AudioBlockMap[Max, audio, .3, Alignment -> -.5]; Show[audioplot, ListPlot[max, PlotStyle -> Red, Filling -> Axis, PlotMarkers -> Automatic, PlotRange -> {-1, 1}]]

Padding  (1)

默认情况下，不完整的分区右边填充为 0：

Wolfram Language code: audio = Audio[Range[10.], SampleRate -> 1]; AudioBlockMap[#&, audio, 4, Padding -> Automatic]["Values"]

指定不同的填充设计：

Wolfram Language code: AudioBlockMap[#&, audio, 4, Padding -> "Periodic"]["Values"]

使用 Padding->None 可从计算中去掉不完整分区：

Wolfram Language code: AudioBlockMap[#&, audio, 4, Padding -> None]["Values"]

应用  (3)

以分贝为单位计算瞬时振幅的均方根值：

Wolfram Language code: a = Import["ExampleData/rule30.wav"]; dBrms = AudioBlockMap[20Log10[Sqrt@Mean[# ^ 2]]&, a, {Quantity[50, "Milliseconds"], Quantity[5, "Milliseconds"]}];ListLinePlot[dBrms]

可视化以分贝计量的瞬时振幅均方根值的直方图：

Wolfram Language code: Histogram[dBrms, 40]

估算分布：

Wolfram Language code: 𝒟 = KernelMixtureDistribution[dBrms, 1]

使用得到的分布进行分析，并可视化分布函数：

Wolfram Language code: Table[Plot[f[𝒟, x], {x, -50, 0}, Filling -> Axis, PlotLabel -> f], {f, {PDF, CDF}}]
Wolfram Language code: Moment[𝒟, 1]
Wolfram Language code: Quantile[𝒟, 0.95]//Quiet

创建音频压缩器：

Wolfram Language code: a = \!\(\*AudioBox["![Embedded Audio Player](audio://content-vvehy)"]\); AudioPlot[a]

计算信号的 RMS 幅值，阈值为 0.02：

Wolfram Language code: amplitude = AudioBlockMap[Max[.02, Sqrt@Mean[# ^ 2]]&, a, {.01, .005}]

压缩信号的动态范围：

Wolfram Language code: AudioNormalize[a / Audio[amplitude]]
Wolfram Language code: AudioPlot[%]

可视化音频的幅值：

Wolfram Language code: a = \!\(\*AudioBox["![Embedded Audio Player](audio://content-vvehy)"]\);
Wolfram Language code: m = AudioBlockMap[{Hue[Max@#], Disk[{0, 0}, Max@#]}&, a, {.1, .01, HannWindow}]
Wolfram Language code: Graphics[{Opacity[.5], MapThread[{#1[[1]], Translate[#1[[2]], {#2, 0}]}&, {m["Values"], m["Times"]}]}]

属性和关系  (1)

许多 AudioLocalMeasurements 属性可以使用 AudioBlockMap 进行计算：

Wolfram Language code: a = Import["ExampleData/rule30.wav"];
Wolfram Language code: AudioBlockMap[Max, a, {.5, .5, None}, Padding -> None] == AudioLocalMeasurements[a, "Max", PartitionGranularity -> {.5, .5, None}, PaddingSize -> 0]

互动范例  (1)

动态显示信号的幅值：

Wolfram Language code: a = \!\(\*AudioBox["![Embedded Audio Player](audio://content-sxbd6)"]\);

定义一个颜色函数，0 为绿色，1 为红色：

Wolfram Language code: cf[x_] := Blend[{Green, Yellow, Red}, x] Table[cf[i], {i, 0, 1, .1}]

计算半径与幅度成比例的彩色圆盘列表：

Wolfram Language code: fps = 30;disks = AudioBlockMap[{cf[Max@#], Disk[{0, 0}, Max@#]}&, a, {.1, 1 / fps}]["Values"]; RandomSample[disks, 2]

用动画显示结果：

Wolfram Language code: ListAnimate[Table[ Graphics[d, PlotRange -> 1], {d, disks}], fps, TransitionEffect -> "Fade"]

用动画显示结果，允许部分重叠：

Wolfram Language code: ListAnimate[Table[ Graphics[d, PlotRange -> 1], {d, Rest@FoldList[Flatten@Append[#1 /. Opacity[x_] -> Opacity[Clip[x - .1, {0, 1}]], {Opacity[1], #2}]&, {}, disks]}], fps, TransitionEffect -> "Fade"]

巧妙范例  (1)

逆向排列分区的值，构建新的音频对象：

Wolfram Language code: a = Import["ExampleData/rule30.wav"]; AudioBlockMap[Reverse, a, {0.3, 0.1}]["Values"]//Flatten//Audio
Wolfram Research (2016)，AudioBlockMap，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AudioBlockMap.html （更新于 2019 年）.

文本

Wolfram Research (2016)，AudioBlockMap，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AudioBlockMap.html （更新于 2019 年）.

CMS

Wolfram 语言. 2016. "AudioBlockMap." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2019. https://reference.wolfram.com/language/ref/AudioBlockMap.html.

APA

Wolfram 语言. (2016). AudioBlockMap. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/AudioBlockMap.html 年

BibTeX

@misc{reference.wolfram_2026_audioblockmap, author="Wolfram Research", title="{AudioBlockMap}", year="2019", howpublished="\url{https://reference.wolfram.com/language/ref/AudioBlockMap.html}", note=[Accessed: 13-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_audioblockmap, organization={Wolfram Research}, title={AudioBlockMap}, year={2019}, url={https://reference.wolfram.com/language/ref/AudioBlockMap.html}, note=[Accessed: 13-August-2026]}