WOLFRAM

Wolfram 语言与系统参考资料中心

Axes

是图形函数的一个选项，用以指定是否应该画出坐标轴.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
轴的定位  
轴的风格  
轴的标记和刻度  
属性和关系  
可能存在的问题  
巧妙范例  
参见
技术笔记
相关指南
历史
按以下格式引用：

Axes

Axes

是图形函数的一个选项，用以指定是否应该画出坐标轴.

更多信息

  • Axes->True 画出所有坐标轴.
  • Axes->False 不画坐标轴.
  • Axes->{False,True} 在二维平面上画出 轴而不画出 轴.
  • 在二维平面上，将坐标轴的交点画在由可选项 AxesOrigin 指定的位置上. »
  • 在三维空间中，将坐标轴画在由可选项 AxesEdge 指定的边界框的棱边上. »

范例

打开所有单元 关闭所有单元

基本范例  (4)

画出所有坐标轴：

Wolfram Language code: Graphics[Circle[], Axes -> True]
Wolfram Language code: Graphics3D[Cylinder[], Axes -> True]

画出 轴而不画出 轴：

Wolfram Language code: Plot[Sin[x], {x, 0, 10}, Axes -> {True, False}]

只画出 轴：

Wolfram Language code: Plot3D[Sin[x y], {x, 0, 3}, {y, 0, 3}, Axes -> {False, False, True}]

用 AxesStyle 指定所有坐标轴的风格，包括坐标轴的标记，刻度和刻度标记：

Wolfram Language code: Plot[Sinc[x], {x, 0, 10}, AxesLabel -> {x, y}, AxesStyle -> Directive[Orange, 12]]

范围  (12)

轴的定位  (5)

自动确定 AxesOrigin：

Wolfram Language code: Graphics[Circle[], Axes -> True, AxesOrigin -> Automatic]
Wolfram Language code: Plot[Sin[x], {x, 0, 2Pi}, AxesOrigin -> Automatic]

明确指定 AxesOrigin：

Wolfram Language code: Graphics[Circle[], Axes -> True, AxesOrigin -> {0, -1}]
Wolfram Language code: Plot[Sin[x], {x, 0, 2Pi}, AxesOrigin -> {Pi, 0}]

在三维空间内, 坐标轴被画在边界框的棱边上：

Wolfram Language code: Graphics3D[Cylinder[], Axes -> True]
Wolfram Language code: Plot3D[Sin[x y], {x, 0, Pi}, {y, 0, Pi}]

选择边界框的棱边来自动画出坐标轴：

Wolfram Language code: Graphics3D[Cylinder[], Axes -> True, AxesEdge -> Automatic]

用 AxesEdge 明确指定棱边：

Wolfram Language code: {Graphics3D[Cylinder[], Axes -> True, AxesEdge -> {{-1, 1}, None, None}], Graphics3D[Cylinder[], Axes -> True, AxesEdge -> {None, {1, -1}, None}], Graphics3D[Cylinder[], Axes -> True, AxesEdge -> {None, None, {1, -1}}]}

轴的风格  (2)

指定每条坐标轴的风格：

Wolfram Language code: Plot[Sinc[x], {x, 0, 10}, AxesStyle -> {Directive[Red, 12], Blue}]
Wolfram Language code: Graphics3D[Cylinder[], Axes -> True, AxesStyle -> {Red, Green, Blue}]

隐藏边界框，只显示坐标轴：

Wolfram Language code: Graphics3D[Cylinder[], Axes -> True, Boxed -> False]

轴的标记和刻度  (5)

指定每条坐标轴的标记：

Wolfram Language code: Plot[Sinc[x], {x, 0, 10}, AxesLabel -> {x, Sin[x]}]

用 Plot3D 中的指定变量作为标记：

Wolfram Language code: Plot3D[Sin[θ ρ], {θ, 0, 3}, {ρ, 0, 3}, AxesLabel -> Automatic]

画出无刻度标记的坐标轴：

Wolfram Language code: Plot[Sin[x], {x, 0, 10}, Ticks -> None]

自动放置刻度标记：

Wolfram Language code: Plot[Sin[x], {x, 0, 10}, Ticks -> Automatic]

在指定位置标上刻度标记：

Wolfram Language code: Plot[Sin[x], {x, 0, 10}, Ticks -> {{0, Pi, 2Pi, 3Pi}, {-1, 1}}]
Wolfram Language code: Plot3D[Sin[x y], {x, 0, Pi}, {y, 0, Pi}, Ticks -> {{0, Pi / 2, Pi}, {0, Pi / 2, Pi}, {-1, 0, 1}}]

属性和关系  (5)

在二维平面中，坐标轴被画在图形上：

Wolfram Language code: Graphics[{Pink, Disk[]}, Axes -> True]

Epilog 中的对象被画在所有图形的上面，包括坐标轴：

Wolfram Language code: Graphics[{Pink, Disk[]}, Axes -> True, Epilog -> {Blue, Disk[{0, 0}, .5]}]

如果选项 Frame 设定为 True，则刻度被画在框架的边上：

Wolfram Language code: Graphics[Circle[], Frame -> True, Axes -> True]

GridLines 在图像上绘制网格：

Wolfram Language code: Graphics[Circle[], GridLines -> Automatic, Axes -> True]

在三维空间内，FaceGrids 在边界框的表面绘制网格：

Wolfram Language code: Graphics3D[Cylinder[], FaceGrids -> All, Axes -> True]

缺省情况下, DensityPlot 以及相关的函数仅显示出框架，而不显示坐标轴：

Wolfram Language code: DensityPlot[x Sin[y], {x, -5, 5}, {y, -5, 5}]

可能存在的问题  (1)

如果 Frame 和 Axes 同时出现，坐标轴的刻度将被遮蔽：

Wolfram Language code: DensityPlot[x Sin[y], {x, -5, 5}, {y, -5, 5}, Axes -> True, Frame -> True, Ticks -> True]

巧妙范例  (1)

用定位器移动坐标轴：

Wolfram Language code: Manipulate[Labeled[Framed[Graphics[Circle[{0, 0}, 3], PlotRange -> 3, ImagePadding -> 20, Axes -> True, AxesOrigin -> p]], p], {{p, {0, 0}}, Locator}]
Wolfram Research (1988)，Axes，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Axes.html.

文本

Wolfram Research (1988)，Axes，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Axes.html.

CMS

Wolfram 语言. 1988. "Axes." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/Axes.html.

APA

Wolfram 语言. (1988). Axes. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/Axes.html 年

BibTeX

@misc{reference.wolfram_2026_axes, author="Wolfram Research", title="{Axes}", year="1988", howpublished="\url{https://reference.wolfram.com/language/ref/Axes.html}", note=[Accessed: 15-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_axes, organization={Wolfram Research}, title={Axes}, year={1988}, url={https://reference.wolfram.com/language/ref/Axes.html}, note=[Accessed: 15-August-2026]}