WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Band[{i,j}]

疎な配列で{i,j}から始まる対角帯の一連の位置を表す．

Band[{imin,jmin,…},{imax,jmax,…}]

{imin,jmin,…}と{imax,jmax,…}の間の位置を表す．

Band[{imin,jmin,…},{imax,jmax,…},{di,dj,…}]

{imin,jmin,…}から始まりステップ{di,dj,…}で動く位置を表す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
一般化と拡張  
アプリケーション  
特性と関係  
関連項目
テクニカルノート
関連するガイド
履歴
引用書式

Band

Band[{i,j}]

疎な配列で{i,j}から始まる対角帯の一連の位置を表す．

Band[{imin,jmin,…},{imax,jmax,…}]

{imin,jmin,…}と{imax,jmax,…}の間の位置を表す．

Band[{imin,jmin,…},{imax,jmax,…},{di,dj,…}]

{imin,jmin,…}から始まりステップ{di,dj,…}で動く位置を表す．

詳細

  • Band[pos]->v は，pos から始まって対角帯に沿って繰り返される値 v を表す．
  • Band[pos]->{v1,v2,…}は，pos から始まって対角帯に沿っている一連の値 vnを表す．
  • 疎な配列全体と同じ階数の配列 a の場合，Band[start]->a はデフォルトで start で指定された位置に a を挿入する．
  • 疎な配列全体と同じ階数の配列 anの場合，Band[pos]->{a1,a2,…}は重複しない一連の部分配列を表す．
  • Band[start]は，実質的にBand[start,{-1,-1,…}]と等価である．
  • スカラー値の場合，Band[start,end]はBand[start,end,{1,1,…}]と等価である．
  • Band[start,end,step]は，座標が end における値を超えたところで停止する．
  • Band[start,end]->{v1,v2,…}は，end に達するまで値 vnが循環的に繰り返すと解釈する．
  • Band[start,Automatic,step]->a は，配列の端に達するまで続ける．
  • Band[start,Automatic,step]->{v1,v2,…}は，viがなくなるまで続ける．

例題

すべて開く すべて閉じる

例  (1)

帯対角行列を作成する：

Wolfram Language code: SparseArray[{Band[{1, 1}] -> x, Band[{2, 1}] -> y}, {5, 5}]//MatrixForm

通常のリストに変換する：

Wolfram Language code: Normal[%]

スコープ  (11)

Bandを他のSparseArray要素指定とミックスする：

Wolfram Language code: SparseArray[{Band[{1, 1}] -> x, {3, 5} -> b}, {5, 5}]//MatrixForm

帯上を埋める明示的な値を与える：

Wolfram Language code: SparseArray[Band[{1, 1}] -> {x, y, z}, {5, 5}]//MatrixForm

値を循環的に繰り返す：

Wolfram Language code: SparseArray[Band[{1, 1}, {5, 5}] -> {x, y, z}, {5, 5}]//MatrixForm

行列の任意の位置から帯を始める：

Wolfram Language code: SparseArray[Band[{3, 2}] -> x, {5, 5}]//MatrixForm

任意の開始位置と終了位置を指定する：

Wolfram Language code: SparseArray[Band[{1, 2}, {3, 4}] -> x, {5, 5}]//MatrixForm

帯上の要素間を刻み幅2で：

Wolfram Language code: SparseArray[Band[{1, 1}, {5, 5}, 2] -> x, {5, 5}]//MatrixForm

任意の刻み幅を使うことができる：

Wolfram Language code: SparseArray[Band[{1, 1}, {5, 5}, {1, 2}] -> x, {5, 5}]//MatrixForm

配列の端まで自動的に帯を続ける：

Wolfram Language code: SparseArray[Band[{1, 1}, Automatic, {1, 2}] -> x, {5, 5}]//MatrixForm

行の一部である帯を指定する：

Wolfram Language code: SparseArray[Band[{3, 3}, Automatic, {0, 1}] -> x, {5, 5}]//MatrixForm

非対角行列を指定する：

Wolfram Language code: SparseArray[Band[{1, 5}, Automatic, {1, -1}] -> x, {5, 5}]//MatrixForm

位置3, 3から始まる部分行列を挿入する：

Wolfram Language code: SparseArray[Band[{3, 3}] -> {{a, b}, {c, d}}, {5, 5}]//MatrixForm

部分行列を循環的に繰り返す：

Wolfram Language code: SparseArray[Band[{1, 1}, {5, 5}] -> {{{a, b}, {c, d}}}, {5, 5}]//MatrixForm

部分行列の要素を1つ入れ換える：

Wolfram Language code: SparseArray[Band[{1, 1}, {5, 5}] -> {{{a, b}, {c, d}}, {{x}}}, {5, 5}]//MatrixForm

一般化と拡張  (2)

Bandは，任意の階数の疎な配列に使うことができる：

Wolfram Language code: Graphics3D[Cuboid /@ Position[Normal[SparseArray[Band[{1, 1, 1}] -> x, {10, 10, 10}]], x]]
Wolfram Language code: Graphics3D[Cuboid /@ Position[Normal[SparseArray[Band[{1, 1, 1}, Automatic, {1, 2, 3}] -> x, {30, 30, 30}]], x]]

三次元の疎な配列に値の平面を入れる：

Wolfram Language code: Graphics3D[Cuboid /@ Position[Normal[SparseArray[Band[{1, 1, 1}] -> Table[x, {10}, {10}]]], x]]

アプリケーション  (2)

三角行列を作成する：

Wolfram Language code: SparseArray[{Band[{2, 1}] -> a, Band[{1, 1}] -> b, Band[{1, 2}] -> c}, 5]//MatrixForm

三重対角線形系を構築する：

Wolfram Language code: SparseArray[{Band[{2, 1}] -> a, Band[{1, 1}] -> b, Band[{1, 2}] -> c}, 5].Array[x, 5]

特性と関係  (2)

BandはSparseArrayで使うことができる．Normalを使って通常のリストに変換する：

Wolfram Language code: SparseArray[{Band[{1, 1}] -> x, Band[{2, 1}] -> y}, {5, 5}]
Wolfram Language code: Normal[%]

Bandの最もシンプルなケースはDiagonalMatrixに等しい：

Wolfram Language code: DiagonalMatrix[{a, b, c, d, e}]//MatrixForm
Wolfram Language code: SparseArray[Band[{1, 1}] -> {a, b, c, d, e}]//MatrixForm
Wolfram Research (2007), Band, Wolfram言語関数， https://reference.wolfram.com/language/ref/Band.html.

テキスト

Wolfram Research (2007), Band, Wolfram言語関数， https://reference.wolfram.com/language/ref/Band.html.

CMS

Wolfram Language. 2007. "Band." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/Band.html.

APA

Wolfram Language. (2007). Band. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Band.html

BibTeX

@misc{reference.wolfram_2026_band, author="Wolfram Research", title="{Band}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/Band.html}", note=[Accessed: 13-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_band, organization={Wolfram Research}, title={Band}, year={2007}, url={https://reference.wolfram.com/language/ref/Band.html}, note=[Accessed: 13-August-2026]}