WOLFRAM

Wolfram 语言与系统参考资料中心

Band[{i,j}]

表示稀疏数组中以 {i,j} 开始的对角矩阵带的坐标序列.

Band[{imin,jmin,…},{imax,jmax,…}]

表示 {imin,jmin,…} 和 {imax,jmax,…} 之间的坐标.

Band[{imin,jmin,…},{imax,jmax,…},{di,dj,…}]

表示以 {imin,jmin,…} 开始，步长为 {di,dj,…} 的坐标.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
推广和延伸  
应用  
属性和关系  
参见
技术笔记
相关指南
历史
按以下格式引用：

Band

Band[{i,j}]

表示稀疏数组中以 {i,j} 开始的对角矩阵带的坐标序列.

Band[{imin,jmin,…},{imax,jmax,…}]

表示 {imin,jmin,…} 和 {imax,jmax,…} 之间的坐标.

Band[{imin,jmin,…},{imax,jmax,…},{di,dj,…}]

表示以 {imin,jmin,…} 开始，步长为 {di,dj,…} 的坐标.

更多信息

  • Band[pos]->v 表示以 pos 开始，沿着对角带重复的值 v.
  • Band[pos]->{v1,v2,…} 代表沿着始于 pos 坐标的对角带的 vn 值序列.
  • 对于秩数与整个稀疏数组相同的数组 a，Band[start]->a 缺省时在 start 指定的坐标插入 a.
  • 用一个相同秩数的数组 an 作为整个稀疏数组，Band[pos]->{a1,a2,…} 表示一个非重叠子数组的序列.
  • Band[start] 实际上等价于 Band[start,{-1,-1,…}].
  • 对标量值而言，Band[start,end] 等价于 Band[start,end,{1,1,…}].
  • 当任意坐标首次超出 end 中的值时，Band[start,end,step] 即停止.
  • Band[start,end]->{v1,v2,…} 循环重复值 vn ，直到达到 end.
  • Band[start,Automatic,step]->a 持续直到数组的边缘.
  • Band[start,Automatic,step]->{v1,v2,…} 持续直至 vi 耗尽.

范例

打开所有单元 关闭所有单元

基本范例  (1)

生成一个对角矩阵带：

Wolfram Language code: SparseArray[{Band[{1, 1}] -> x, Band[{2, 1}] -> y}, {5, 5}]//MatrixForm

转换为常规列表：

Wolfram Language code: Normal[%]

范围  (11)

指定混合 Band 与其它 SparseArray 元素：

Wolfram Language code: SparseArray[{Band[{1, 1}] -> x, {3, 5} -> b}, {5, 5}]//MatrixForm

明确指定对角线上的值：

Wolfram Language code: SparseArray[Band[{1, 1}] -> {x, y, z}, {5, 5}]//MatrixForm

循环重复值：

Wolfram Language code: SparseArray[Band[{1, 1}, {5, 5}] -> {x, y, z}, {5, 5}]//MatrixForm

在矩阵中以任意坐标开始：

Wolfram Language code: SparseArray[Band[{3, 2}] -> x, {5, 5}]//MatrixForm

指定任意起点和终点坐标：

Wolfram Language code: SparseArray[Band[{1, 2}, {3, 4}] -> x, {5, 5}]//MatrixForm

矩阵带上元素之间的步长为 2：

Wolfram Language code: SparseArray[Band[{1, 1}, {5, 5}, 2] -> x, {5, 5}]//MatrixForm

可以使用任意步长：

Wolfram Language code: SparseArray[Band[{1, 1}, {5, 5}, {1, 2}] -> x, {5, 5}]//MatrixForm

自动持续到数组的边缘：

Wolfram Language code: SparseArray[Band[{1, 1}, Automatic, {1, 2}] -> x, {5, 5}]//MatrixForm

指定某一行的一部分作为矩阵带：

Wolfram Language code: SparseArray[Band[{3, 3}, Automatic, {0, 1}] -> x, {5, 5}]//MatrixForm

建立一个反对角矩阵带：

Wolfram Language code: SparseArray[Band[{1, 5}, Automatic, {1, -1}] -> x, {5, 5}]//MatrixForm

插入一个始于坐标 3，3 的子矩阵：

Wolfram Language code: SparseArray[Band[{3, 3}] -> {{a, b}, {c, d}}, {5, 5}]//MatrixForm

循环重复该子矩阵：

Wolfram Language code: SparseArray[Band[{1, 1}, {5, 5}] -> {{{a, b}, {c, d}}}, {5, 5}]//MatrixForm

用子矩阵作为一个元素，交替该子矩阵：

Wolfram Language code: SparseArray[Band[{1, 1}, {5, 5}] -> {{{a, b}, {c, d}}, {{x}}}, {5, 5}]//MatrixForm

推广和延伸  (2)

Band 对任意秩的稀疏数组中起作用：

Wolfram Language code: Graphics3D[Cuboid /@ Position[Normal[SparseArray[Band[{1, 1, 1}] -> x, {10, 10, 10}]], x]]
Wolfram Language code: Graphics3D[Cuboid /@ Position[Normal[SparseArray[Band[{1, 1, 1}, Automatic, {1, 2, 3}] -> x, {30, 30, 30}]], x]]

将一个平面值填充到一个三维的稀疏数组中：

Wolfram Language code: Graphics3D[Cuboid /@ Position[Normal[SparseArray[Band[{1, 1, 1}] -> Table[x, {10}, {10}]]], x]]

应用  (2)

制作一个三对角矩阵：

Wolfram Language code: SparseArray[{Band[{2, 1}] -> a, Band[{1, 1}] -> b, Band[{1, 2}] -> c}, 5]//MatrixForm

建立一个三对角线性系统：

Wolfram Language code: SparseArray[{Band[{2, 1}] -> a, Band[{1, 1}] -> b, Band[{1, 2}] -> c}, 5].Array[x, 5]

属性和关系  (2)

Band 对 SparseArray 起作用；用 Normal 转换常规列表：

Wolfram Language code: SparseArray[{Band[{1, 1}] -> x, Band[{2, 1}] -> y}, {5, 5}]
Wolfram Language code: Normal[%]

Band 的最简情形等价于 DiagonalMatrix：

Wolfram Language code: DiagonalMatrix[{a, b, c, d, e}]//MatrixForm
Wolfram Language code: SparseArray[Band[{1, 1}] -> {a, b, c, d, e}]//MatrixForm
Wolfram Research (2007)，Band，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Band.html.

文本

Wolfram Research (2007)，Band，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Band.html.

CMS

Wolfram 语言. 2007. "Band." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/Band.html.

APA

Wolfram 语言. (2007). Band. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/Band.html 年

BibTeX

@misc{reference.wolfram_2026_band, author="Wolfram Research", title="{Band}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/Band.html}", note=[Accessed: 15-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_band, organization={Wolfram Research}, title={Band}, year={2007}, url={https://reference.wolfram.com/language/ref/Band.html}, note=[Accessed: 15-August-2026]}