WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

BarlowProschanImportance[rdist]

ReliabilityDistribution rdist のすべての成分のBarlow–Proschan重要度を与える．

BarlowProschanImportance[fdist]

FailureDistribution fdist のすべての成分のBarlow–Proschan重要度を与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
ReliabilityDistributionモデル  
FailureDistributionモデル  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

BarlowProschanImportance

BarlowProschanImportance[rdist]

ReliabilityDistribution rdist のすべての成分のBarlow–Proschan重要度を与える．

BarlowProschanImportance[fdist]

FailureDistribution fdist のすべての成分のBarlow–Proschan重要度を与える．

詳細

  • 成分 のBarlow–Proschan重要度は成分 の故障が系の故障と一致する確率である．
  • 成分 のBarlow–Proschan重要度は 番目の成分の寿命分布を使った成分 のBirnbaum重要度の期待値で与えられる．
  • 結果は rdist あるいは fdist の分布リストで与えられる成分順序で返される．

例題

すべて開く すべて閉じる

例  (3)

直列で繋がれ，寿命分布が異なる2つの成分：

Wolfram Language code: ℛ = ReliabilityDistribution[x∧y, {{x, ExponentialDistribution[1]}, {y, ExponentialDistribution[2]}}];

結果はReliabilityDistributionにおける分布リストと同じ順番で返される：

Wolfram Language code: {Subscript[bp, x], Subscript[bp, y]} = BarlowProschanImportance[ℛ]
Wolfram Language code: PieChart[{Subscript[bp, x], Subscript[bp, y]}, ChartLabels -> {x, y}]

並列に繋がれ，寿命分布が異なる2つの成分：

Wolfram Language code: ℛ = ReliabilityDistribution[x∨y, {{x, ExponentialDistribution[Subscript[λ, 1]]}, {y, ExponentialDistribution[Subscript[λ, 2]]}}];
Wolfram Language code: BarlowProschanImportance[ℛ]

故障の木に基づいたモデリングを使って系を定義する：

Wolfram Language code: ℱ = FailureDistribution[x∧y, {{x, WeibullDistribution[2, 3]}, {y, WeibullDistribution[4, 5]}}];
Wolfram Language code: BarlowProschanImportance[ℱ]
Wolfram Language code: PieChart[%//N, ChartLabels -> {x, y}]

スコープ  (16)

ReliabilityDistributionモデル  (8)

並列に繋がれ，寿命分布が等しい2つの成分：

Wolfram Language code: ℛ = ReliabilityDistribution[x∨y, {{x, ExponentialDistribution[λ]}, {y, ExponentialDistribution[λ]}}];

重要度は等しい：

Wolfram Language code: BarlowProschanImportance[ℛ]

直列に繋がれ，寿命分布が等しい2つの成分：

Wolfram Language code: ℛ = ReliabilityDistribution[x∧y, {{x, ExponentialDistribution[λ]}, {y, ExponentialDistribution[λ]}}];

重要度は等しい：

Wolfram Language code: BarlowProschanImportance[ℛ]

動くためには3つの成分（寿命分布は等しい）のうち2つが必要な系：

Wolfram Language code: ℛ = ReliabilityDistribution[BooleanCountingFunction[{2, 3}, {x, y, z}], {{x, ExponentialDistribution[λ]}, {y, ExponentialDistribution[λ]}, {z, ExponentialDistribution[λ]}}];

重要度は等しい：

Wolfram Language code: BarlowProschanImportance[ℛ]

寿命分布が等しい単純な混合系：

Wolfram Language code: d = ExponentialDistribution[λ];
Wolfram Language code: ℛ = ReliabilityDistribution[x∧(y∨z), {{x, d}, {y, d}, {z, d}}];

重要度を示す：

Wolfram Language code: PieChart[BarlowProschanImportance[ℛ], ChartLabels -> {x, y, z}]

ある成分と並列に繋がれた直列接続の系：

Wolfram Language code: d = ExponentialDistribution[λ];
Wolfram Language code: ℛ = ReliabilityDistribution[x∨(y∧z), {{x, d}, {y, d}, {z, d}}];

成分 は系にとって決定的に重要な意味を持つものであり，したがってもっとも重要である：

Wolfram Language code: PieChart[BarlowProschanImportance[ℛ], ChartLabels -> {x, y, z}]

単純な混合系におけるパラメータの変更の影響を調べる：

Wolfram Language code: {Subscript[d, 1], Subscript[d, 2], Subscript[d, 3]} = {ExponentialDistribution[Subscript[λ, 1]], ExponentialDistribution[Subscript[λ, 2]], ExponentialDistribution[Subscript[λ, 3]]};
Wolfram Language code: ℛ = ReliabilityDistribution[x∧(y∨z), {{x, Subscript[d, 1]}, {y, Subscript[d, 2]}, {z, Subscript[d, 3]}}];

並列成分の1つを悪化させた場合の重要度の変化を示す：

Wolfram Language code: Table[PieChart[BarlowProschanImportance[ℛ] /. {Subscript[λ, 1] -> 1, Subscript[λ, 2] -> 1, Subscript[λ, 3] -> k}, ChartLabels -> {x, y, z}, PlotLabel -> k], {k, 1, 6, 2}]

任意の有効なReliabilityDistributionを使うことができる：

Wolfram Language code: {Subscript[𝒟, 1], Subscript[𝒟, 2]} = {ExponentialDistribution[1], ExponentialDistribution[1]};
Wolfram Language code: ℛ = ReliabilityDistribution[x∧y, {{x, Subscript[𝒟, 1]}, {y, StandbyDistribution[Subscript[𝒟, 2], {Subscript[𝒟, 2], Subscript[𝒟, 2]}]}}];

あまり信頼性の高くない成分 の故障が系の故障と一致する危険性の方がはるかに高い：

Wolfram Language code: PieChart[BarlowProschanImportance[ℛ], ChartLabels -> {x, y}]

部分系の重要度尺度を得るために系を段階的にモデル化する：

Wolfram Language code: ℛsub = ReliabilityDistribution[x∨y, {{x, ExponentialDistribution[1]}, {y, ExponentialDistribution[1]}}];
Wolfram Language code: ℛ = ReliabilityDistribution[z∧r, {{z, ExponentialDistribution[1]}, {r, ℛsub}}];

部分系はより信頼性が高く，その故障が系の故障と一致する危険性は低い：

Wolfram Language code: PieChart[BarlowProschanImportance[ℛ], ChartLabels -> {z, r}]

FailureDistributionモデル  (8)

2つの基本事象のどちらもが頂上事象に繋がる：

Wolfram Language code: ℱ = FailureDistribution[x∨y, {{x, ExponentialDistribution[λ]}, {y, ExponentialDistribution[λ]}}];

重要度は等しい：

Wolfram Language code: BarlowProschanImportance[ℱ]

基本事象の両方がともに起った場合にのみ頂上事象に繋がる：

Wolfram Language code: ℱ = FailureDistribution[x∧y, {{x, ExponentialDistribution[λ]}, {y, ExponentialDistribution[λ]}}];

重要度は等しい：

Wolfram Language code: BarlowProschanImportance[ℱ]

基本事象の分布が等しいボーティングゲート：

Wolfram Language code: ℱ = FailureDistribution[BooleanCountingFunction[{2, 3}, {x, y, z}], {{x, ExponentialDistribution[λ]}, {y, ExponentialDistribution[λ]}, {z, ExponentialDistribution[λ]}}];

重要度は等しい：

Wolfram Language code: BarlowProschanImportance[ℱ]

AndゲートとOrゲートの両方がある単純な系：

Wolfram Language code: d = ExponentialDistribution[λ];
Wolfram Language code: ℱ = FailureDistribution[x∧(y∨z), {{x, d}, {y, d}, {z, d}}];

重要度を示す：

Wolfram Language code: PieChart[BarlowProschanImportance[ℱ], ChartLabels -> {x, y, z}]

AndゲートとOrゲートの両方がある単純な系：

Wolfram Language code: d = ExponentialDistribution[λ];
Wolfram Language code: ℱ = FailureDistribution[x∨(y∧z), {{x, d}, {y, d}, {z, d}}];

重要度を示す：

Wolfram Language code: PieChart[BarlowProschanImportance[ℱ], ChartLabels -> {x, y, z}]

単純な混合系におけるパラメータ変更の影響を調べる：

Wolfram Language code: {Subscript[d, 1], Subscript[d, 2], Subscript[d, 3]} = {ExponentialDistribution[Subscript[λ, 1]], ExponentialDistribution[Subscript[λ, 2]], ExponentialDistribution[Subscript[λ, 3]]};
Wolfram Language code: ℱ = FailureDistribution[x∧(y∨z), {{x, Subscript[d, 1]}, {y, Subscript[d, 2]}, {z, Subscript[d, 3]}}];

基本事象の一つを悪化させた場合の重要度の変化を示す：

Wolfram Language code: Table[PieChart[BarlowProschanImportance[ℱ] /. {Subscript[λ, 1] -> 1, Subscript[λ, 2] -> 1, Subscript[λ, 3] -> k}, ChartLabels -> {x, y, z}, PlotLabel -> k], {k, 1, 6, 2}]

任意の有効なFailureDistributionを使うことができる：

Wolfram Language code: {Subscript[𝒟, 1], Subscript[𝒟, 2]} = {ExponentialDistribution[1], ExponentialDistribution[2]};
Wolfram Language code: ℱ = FailureDistribution[x∨y, {{x, Subscript[𝒟, 1]}, {y, StandbyDistribution[Subscript[𝒟, 2], {Subscript[𝒟, 2], Subscript[𝒟, 2]}]}}];

待機成分はより重要である：

Wolfram Language code: PieChart[BarlowProschanImportance[ℱ], ChartLabels -> {x, y}]

部分系の重要度尺度を得るために段階を追って系をモデル化する：

Wolfram Language code: ℱsub = FailureDistribution[x∨y, {{x, ExponentialDistribution[1]}, {y, ExponentialDistribution[1]}}];
Wolfram Language code: ℱ = ReliabilityDistribution[z∧f, {{z, ExponentialDistribution[1]}, {f, ℱsub}}];

部分系はより重要である：

Wolfram Language code: PieChart[BarlowProschanImportance[ℱ], ChartLabels -> {z, f}]

アプリケーション  (2)

航空機の離陸時の故障を引き起こす確率が最も高い成分は何かを分析する．格納扉は電動・手動のどちらで開けることもできる：

Wolfram Language code: hangarDoor = power∨manual;

2つの燃料ポンプを動かすためには動力が必要である：

Wolfram Language code: fuelTransferA2 = power∧pumpA2;
Wolfram Language code: fuelTransferB2 = power∧pumpB2;

さらに，次の燃料移送構造で，2つのポンプを信頼できる電池を使って動かすことができる：

Wolfram Language code: fuelTransfer = (pumpA1∧(pumpB1∨fuelTransferB2))∨(fuelTransferA2∧(pumpB1∨fuelTransferB2));

航空機の除氷装置と燃料の収蔵タンクも必要である：

Wolfram Language code: launch = fuelStorage∧fuelTransfer∧hangarDoor∧deicing;

寿命分布を定義する：

Wolfram Language code: vars = {deicing, fuelStorage, manual, power, pumpA1, pumpB1, pumpA2, pumpB2};
Wolfram Language code: lifetimes = ExponentialDistribution /@ {10^-7, 10^-8, 10^-3, 2×10^-4, 5×10^-4, 5×10^-4, 5×10^-4, 5×10^-4};
Wolfram Language code: ℛ = ReliabilityDistribution[launch, Transpose[{vars, lifetimes}]];

重要度を計算する：

Wolfram Language code: BarlowProschanImportance[ℛ];

ポンプが故障すると航空機が離陸に失敗することが多い：

Wolfram Language code: PieChart[%//N, ChartLegends -> vars]

弁が1つで余分なポンプが2つ付いた揚水装置を考える．成分の信頼性は確率で与えられる：

Wolfram Language code: ℛ = ReliabilityDistribution[valve∧(pump1∨pump2), {{valve, BernoulliDistribution[0.99]}, {pump1, BernoulliDistribution[0.97]}, {pump2, BernoulliDistribution[0.97]}}];

弁が故障すると装置が故障することが多い：

Wolfram Language code: PieChart[BarlowProschanImportance[ℛ], ChartLabels -> {valve, pump1, pump2}]

特性と関係  (3)

BarlowProschanImportanceはBirnbaumImportanceのExpectationとして定義される：

Wolfram Language code: {Subscript[𝒟, 1], Subscript[𝒟, 2]} = {ExponentialDistribution[Subscript[λ, 1]], ExponentialDistribution[Subscript[λ, 2]]};
Wolfram Language code: ℛ = ReliabilityDistribution[x∨y, {{x, Subscript[𝒟, 1]}, {y, Subscript[𝒟, 2]}}];
Wolfram Language code: bi = BirnbaumImportance[ℛ, t]
Wolfram Language code: BarlowProschanImportance[ℛ]
Wolfram Language code: Table[Expectation[bi[[i]], tSubscript[𝒟, i]], {i, 1, 2}]
Wolfram Language code: FullSimplify[%% - %]

BarlowProschanImportanceの和は常に1である：

Wolfram Language code: ℛ = ReliabilityDistribution[x∧(y∨z), {{x, ExponentialDistribution[Subscript[λ, 1]]}, {y, WeibullDistribution[1, β]}, {z, ExponentialDistribution[Subscript[λ, 2]]}}];
Wolfram Language code: bpi = BarlowProschanImportance[ℛ]
Wolfram Language code: Total[bpi]//Simplify

無関係な成分の重要度は0である：

Wolfram Language code: 𝒟 = WeibullDistribution[1, 2];
Wolfram Language code: BarlowProschanImportance[ReliabilityDistribution[x∧y, {{x, 𝒟}, {y, 𝒟}, {z, 𝒟}}]]
Wolfram Research (2012), BarlowProschanImportance, Wolfram言語関数， https://reference.wolfram.com/language/ref/BarlowProschanImportance.html.

テキスト

Wolfram Research (2012), BarlowProschanImportance, Wolfram言語関数， https://reference.wolfram.com/language/ref/BarlowProschanImportance.html.

CMS

Wolfram Language. 2012. "BarlowProschanImportance." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/BarlowProschanImportance.html.

APA

Wolfram Language. (2012). BarlowProschanImportance. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/BarlowProschanImportance.html

BibTeX

@misc{reference.wolfram_2026_barlowproschanimportance, author="Wolfram Research", title="{BarlowProschanImportance}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/BarlowProschanImportance.html}", note=[Accessed: 07-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_barlowproschanimportance, organization={Wolfram Research}, title={BarlowProschanImportance}, year={2012}, url={https://reference.wolfram.com/language/ref/BarlowProschanImportance.html}, note=[Accessed: 07-August-2026]}