WOLFRAM

Wolfram 语言与系统参考资料中心

BarlowProschanImportance[rdist]

给出 ReliabilityDistribution rdist 中所有分量的 Barlow–Proschan 重要度.

BarlowProschanImportance[fdist]

给出 FailureDistribution fdist 中所有分量的 Barlow–Proschan 重要度.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
ReliabilityDistribution 模型  
FailureDistribution 模型  
应用  
属性和关系  
参见
相关指南
历史
按以下格式引用：

BarlowProschanImportance

BarlowProschanImportance[rdist]

给出 ReliabilityDistribution rdist 中所有分量的 Barlow–Proschan 重要度.

BarlowProschanImportance[fdist]

给出 FailureDistribution fdist 中所有分量的 Barlow–Proschan 重要度.

更多信息

  • 分量 的 Barlow–Proschan 重要度指的是分量 的故障与系统故障相一致的概率.
  • 分量 的 Barlow–Proschan 重要度利用第 个分量的寿命分布由分量 的 Birnbaum 重要度的期望给出.
  • 返回的结果按照 rdist 或 fdist 中所列分布的次序给出.

范例

打开所有单元 关闭所有单元

基本范例  (3)

两个寿命分布不同的分量串联：

Wolfram Language code: ℛ = ReliabilityDistribution[x∧y, {{x, ExponentialDistribution[1]}, {y, ExponentialDistribution[2]}}];

结果按照 ReliabilityDistribution 中的分布列表次序给出:

Wolfram Language code: {Subscript[bp, x], Subscript[bp, y]} = BarlowProschanImportance[ℛ]
Wolfram Language code: PieChart[{Subscript[bp, x], Subscript[bp, y]}, ChartLabels -> {x, y}]

两个寿命分布不同的分量并联：

Wolfram Language code: ℛ = ReliabilityDistribution[x∨y, {{x, ExponentialDistribution[Subscript[λ, 1]]}, {y, ExponentialDistribution[Subscript[λ, 2]]}}];
Wolfram Language code: BarlowProschanImportance[ℛ]

使用基于故障树的模型定义系统：

Wolfram Language code: ℱ = FailureDistribution[x∧y, {{x, WeibullDistribution[2, 3]}, {y, WeibullDistribution[4, 5]}}];
Wolfram Language code: BarlowProschanImportance[ℱ]
Wolfram Language code: PieChart[%//N, ChartLabels -> {x, y}]

范围  (16)

ReliabilityDistribution 模型  (8)

两个寿命分布相同的分量并联：

Wolfram Language code: ℛ = ReliabilityDistribution[x∨y, {{x, ExponentialDistribution[λ]}, {y, ExponentialDistribution[λ]}}];

重要度相同：

Wolfram Language code: BarlowProschanImportance[ℛ]

两个寿命分布相同的分量串联：

Wolfram Language code: ℛ = ReliabilityDistribution[x∧y, {{x, ExponentialDistribution[λ]}, {y, ExponentialDistribution[λ]}}];

重要度相同：

Wolfram Language code: BarlowProschanImportance[ℛ]

一个具有相同寿命分布的系统，其中三个分量中的两个需要工作：

Wolfram Language code: ℛ = ReliabilityDistribution[BooleanCountingFunction[{2, 3}, {x, y, z}], {{x, ExponentialDistribution[λ]}, {y, ExponentialDistribution[λ]}, {z, ExponentialDistribution[λ]}}];

重要度相同：

Wolfram Language code: BarlowProschanImportance[ℛ]

一个具有相同寿命分布的简单混合系统：

Wolfram Language code: d = ExponentialDistribution[λ];
Wolfram Language code: ℛ = ReliabilityDistribution[x∧(y∨z), {{x, d}, {y, d}, {z, d}}];

显示重要度：

Wolfram Language code: PieChart[BarlowProschanImportance[ℛ], ChartLabels -> {x, y, z}]

串联再与一个分量并联的系统：

Wolfram Language code: d = ExponentialDistribution[λ];
Wolfram Language code: ℛ = ReliabilityDistribution[x∨(y∧z), {{x, d}, {y, d}, {z, d}}];

分量 对于系统最关键，因此是最重要的：

Wolfram Language code: PieChart[BarlowProschanImportance[ℛ], ChartLabels -> {x, y, z}]

研究简单混合系统中参数变化的影响：

Wolfram Language code: {Subscript[d, 1], Subscript[d, 2], Subscript[d, 3]} = {ExponentialDistribution[Subscript[λ, 1]], ExponentialDistribution[Subscript[λ, 2]], ExponentialDistribution[Subscript[λ, 3]]};
Wolfram Language code: ℛ = ReliabilityDistribution[x∧(y∨z), {{x, Subscript[d, 1]}, {y, Subscript[d, 2]}, {z, Subscript[d, 3]}}];

当并联组件之一恶化时，显示重要度的变化：

Wolfram Language code: Table[PieChart[BarlowProschanImportance[ℛ] /. {Subscript[λ, 1] -> 1, Subscript[λ, 2] -> 1, Subscript[λ, 3] -> k}, ChartLabels -> {x, y, z}, PlotLabel -> k], {k, 1, 6, 2}]

可以使用任何有效的 ReliabilityDistribution：

Wolfram Language code: {Subscript[𝒟, 1], Subscript[𝒟, 2]} = {ExponentialDistribution[1], ExponentialDistribution[1]};
Wolfram Language code: ℛ = ReliabilityDistribution[x∧y, {{x, Subscript[𝒟, 1]}, {y, StandbyDistribution[Subscript[𝒟, 2], {Subscript[𝒟, 2], Subscript[𝒟, 2]}]}}];

较不可靠的分量 与系统故障同时出现的风险要高得多：

Wolfram Language code: PieChart[BarlowProschanImportance[ℛ], ChartLabels -> {x, y}]

分步模拟系统，从而度量子系统的重要度：

Wolfram Language code: ℛsub = ReliabilityDistribution[x∨y, {{x, ExponentialDistribution[1]}, {y, ExponentialDistribution[1]}}];
Wolfram Language code: ℛ = ReliabilityDistribution[z∧r, {{z, ExponentialDistribution[1]}, {r, ℛsub}}];

子系统更可靠，因此与系统故障同时出现的风险较低：

Wolfram Language code: PieChart[BarlowProschanImportance[ℛ], ChartLabels -> {z, r}]

FailureDistribution 模型  (8)

任何两个基本事件导致顶事件：

Wolfram Language code: ℱ = FailureDistribution[x∨y, {{x, ExponentialDistribution[λ]}, {y, ExponentialDistribution[λ]}}];

重要度相同：

Wolfram Language code: BarlowProschanImportance[ℱ]

两个基本事件共同导致顶事件：

Wolfram Language code: ℱ = FailureDistribution[x∧y, {{x, ExponentialDistribution[λ]}, {y, ExponentialDistribution[λ]}}];

重要度相同：

Wolfram Language code: BarlowProschanImportance[ℱ]

表决门，基本事件具有相同的分布：

Wolfram Language code: ℱ = FailureDistribution[BooleanCountingFunction[{2, 3}, {x, y, z}], {{x, ExponentialDistribution[λ]}, {y, ExponentialDistribution[λ]}, {z, ExponentialDistribution[λ]}}];

重要度相同：

Wolfram Language code: BarlowProschanImportance[ℱ]

同时具有 And 和 Or 门的简单系统：

Wolfram Language code: d = ExponentialDistribution[λ];
Wolfram Language code: ℱ = FailureDistribution[x∧(y∨z), {{x, d}, {y, d}, {z, d}}];

显示重要度：

Wolfram Language code: PieChart[BarlowProschanImportance[ℱ], ChartLabels -> {x, y, z}]

同时具有 And 和 Or 门的简单系统：

Wolfram Language code: d = ExponentialDistribution[λ];
Wolfram Language code: ℱ = FailureDistribution[x∨(y∧z), {{x, d}, {y, d}, {z, d}}];

显示重要度：

Wolfram Language code: PieChart[BarlowProschanImportance[ℱ], ChartLabels -> {x, y, z}]

研究简单混合系统中参数变化的影响：

Wolfram Language code: {Subscript[d, 1], Subscript[d, 2], Subscript[d, 3]} = {ExponentialDistribution[Subscript[λ, 1]], ExponentialDistribution[Subscript[λ, 2]], ExponentialDistribution[Subscript[λ, 3]]};
Wolfram Language code: ℱ = FailureDistribution[x∧(y∨z), {{x, Subscript[d, 1]}, {y, Subscript[d, 2]}, {z, Subscript[d, 3]}}];

当基本事件之一恶化时，显示重要度的变化：

Wolfram Language code: Table[PieChart[BarlowProschanImportance[ℱ] /. {Subscript[λ, 1] -> 1, Subscript[λ, 2] -> 1, Subscript[λ, 3] -> k}, ChartLabels -> {x, y, z}, PlotLabel -> k], {k, 1, 6, 2}]

可以使用任何有效的 FailureDistribution：

Wolfram Language code: {Subscript[𝒟, 1], Subscript[𝒟, 2]} = {ExponentialDistribution[1], ExponentialDistribution[2]};
Wolfram Language code: ℱ = FailureDistribution[x∨y, {{x, Subscript[𝒟, 1]}, {y, StandbyDistribution[Subscript[𝒟, 2], {Subscript[𝒟, 2], Subscript[𝒟, 2]}]}}];

待机分量较为重要：

Wolfram Language code: PieChart[BarlowProschanImportance[ℱ], ChartLabels -> {x, y}]

分步模拟系统，从而度量子系统的重要度：

Wolfram Language code: ℱsub = FailureDistribution[x∨y, {{x, ExponentialDistribution[1]}, {y, ExponentialDistribution[1]}}];
Wolfram Language code: ℱ = ReliabilityDistribution[z∧f, {{z, ExponentialDistribution[1]}, {f, ℱsub}}];

子系统较为重要：

Wolfram Language code: PieChart[BarlowProschanImportance[ℱ], ChartLabels -> {z, f}]

应用  (2)

分析哪些组件最有可能导致了飞机启动故障. 机库门可以通过电子或手工方式打开：

Wolfram Language code: hangarDoor = power∨manual;

两个燃油泵需要电力来运行：

Wolfram Language code: fuelTransferA2 = power∧pumpA2;
Wolfram Language code: fuelTransferB2 = power∧pumpB2;

给出以下燃料传输结构，另有两个泵的运行基于可靠的电池：

Wolfram Language code: fuelTransfer = (pumpA1∧(pumpB1∨fuelTransferB2))∨(fuelTransferA2∧(pumpB1∨fuelTransferB2));

还需要飞机除冰和燃料储罐：

Wolfram Language code: launch = fuelStorage∧fuelTransfer∧hangarDoor∧deicing;

定义寿命分布：

Wolfram Language code: vars = {deicing, fuelStorage, manual, power, pumpA1, pumpB1, pumpA2, pumpB2};
Wolfram Language code: lifetimes = ExponentialDistribution /@ {10^-7, 10^-8, 10^-3, 2×10^-4, 5×10^-4, 5×10^-4, 5×10^-4, 5×10^-4};
Wolfram Language code: ℛ = ReliabilityDistribution[launch, Transpose[{vars, lifetimes}]];

计算重要度：

Wolfram Language code: BarlowProschanImportance[ℛ];

非常有可能的是，泵的故障与飞机发射故障一致：

Wolfram Language code: PieChart[%//N, ChartLegends -> vars]

考虑由一个阀门和两个冗余泵组成的抽水系统. 组件的可靠性以概率的形式给出：

Wolfram Language code: ℛ = ReliabilityDistribution[valve∧(pump1∨pump2), {{valve, BernoulliDistribution[0.99]}, {pump1, BernoulliDistribution[0.97]}, {pump2, BernoulliDistribution[0.97]}}];

非常有可能的是，阀门的故障与系统故障一致：

Wolfram Language code: PieChart[BarlowProschanImportance[ℛ], ChartLabels -> {valve, pump1, pump2}]

属性和关系  (3)

BarlowProschanImportance 被定义为 BirnbaumImportance 的期望 Expectation：

Wolfram Language code: {Subscript[𝒟, 1], Subscript[𝒟, 2]} = {ExponentialDistribution[Subscript[λ, 1]], ExponentialDistribution[Subscript[λ, 2]]};
Wolfram Language code: ℛ = ReliabilityDistribution[x∨y, {{x, Subscript[𝒟, 1]}, {y, Subscript[𝒟, 2]}}];
Wolfram Language code: bi = BirnbaumImportance[ℛ, t]
Wolfram Language code: BarlowProschanImportance[ℛ]
Wolfram Language code: Table[Expectation[bi[[i]], tSubscript[𝒟, i]], {i, 1, 2}]
Wolfram Language code: FullSimplify[%% - %]

BarlowProschanImportance 的和恒为 1：

Wolfram Language code: ℛ = ReliabilityDistribution[x∧(y∨z), {{x, ExponentialDistribution[Subscript[λ, 1]]}, {y, WeibullDistribution[1, β]}, {z, ExponentialDistribution[Subscript[λ, 2]]}}];
Wolfram Language code: bpi = BarlowProschanImportance[ℛ]
Wolfram Language code: Total[bpi]//Simplify

无关分量的重要度为 0：

Wolfram Language code: 𝒟 = WeibullDistribution[1, 2];
Wolfram Language code: BarlowProschanImportance[ReliabilityDistribution[x∧y, {{x, 𝒟}, {y, 𝒟}, {z, 𝒟}}]]
Wolfram Research (2012)，BarlowProschanImportance，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BarlowProschanImportance.html.

文本

Wolfram Research (2012)，BarlowProschanImportance，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BarlowProschanImportance.html.

CMS

Wolfram 语言. 2012. "BarlowProschanImportance." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/BarlowProschanImportance.html.

APA

Wolfram 语言. (2012). BarlowProschanImportance. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/BarlowProschanImportance.html 年

BibTeX

@misc{reference.wolfram_2026_barlowproschanimportance, author="Wolfram Research", title="{BarlowProschanImportance}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/BarlowProschanImportance.html}", note=[Accessed: 08-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_barlowproschanimportance, organization={Wolfram Research}, title={BarlowProschanImportance}, year={2012}, url={https://reference.wolfram.com/language/ref/BarlowProschanImportance.html}, note=[Accessed: 08-September-2026]}