WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

BesselJZero[n,k]

ベッセル関数 の k 番目の零点を表す．

BesselJZero[n,k,x0]

x0より大きい k 番目の零点を表す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
数値評価  
特定の値  
可視化  
微分と級数展開  
アプリケーション  
特性と関係  
関連項目
テクニカルノート
関連するガイド
履歴
引用書式

BesselJZero

BesselJZero[n,k]

ベッセル関数 の k 番目の零点を表す．

BesselJZero[n,k,x0]

x0より大きい k 番目の零点を表す．

詳細

  • 記号操作・数値操作の両方に適した数学関数である．
  • N[BesselJZero[n,k]]は，指定した零点が存在する限り数値近似を与える．
  • BesselJZero[n,k]は，0より大きい k 番目の零点を表す．
  • BesselJZeroは任意の数値精度で評価できる．
  • BesselJZeroは自動的にリストに縫い込まれる． »

例題

すべて開く すべて閉じる

例  (5)

数値的に評価する：

Wolfram Language code: N[BesselJZero[0, 1]]

記号的に評価する：

Wolfram Language code: BesselJ[0, BesselJZero[0, 1]]

実数の部分集合上でBesselJ関数の零点を表示する：

Wolfram Language code: Plot[BesselJ[1, z], {z, 0, 15}, Epilog -> {PointSize[0.03], Red, Point[Table[{BesselJZero[1, k], 0}, {k, 4}]]}]

原点における級数展開：

Wolfram Language code: Series[BesselJZero[n, x], {x, 0, 1}]

TraditionalFormによる表示：

Wolfram Language code: BesselJZero[ν, k]//TraditionalForm

スコープ  (18)

数値評価  (7)

数値的に評価する：

Wolfram Language code: BesselJZero[0., 2]

の40より大きい最初の零点を求める：

Wolfram Language code: N[BesselJZero[0, 1, 40]]

高精度で評価する：

Wolfram Language code: N[BesselJZero[1, 20, 40], 50]

高精度で効率的に評価する：

Wolfram Language code: N[BesselJZero[0, 1, 40`100]]//Timing
Wolfram Language code: N[BesselJZero[0, 2, 50`1000]];//Timing

非整数の第2引数で評価する：

Wolfram Language code: N[BesselJZero[0, 1 - 2 / 3], 20]

BesselJZero[ν,k-α/π]について，結果は の零点である：

Wolfram Language code: BesselJ[0, %]Cos[2Pi / 3] - BesselY[0, %]Sin[2Pi / 3]

Aroundを使って平均的な場合の統計区間を計算する：

Wolfram Language code: BesselJZero[ 1, Around[2, 0.01]]

自動縫込みを使って配列の要素ごとの値を計算する：

Wolfram Language code: BesselJZero[1 / 2, {{2, 1}, {1, 3}}]//N

MatrixFunctionを使って行列のBesselJZero関数を計算する：

Wolfram Language code: MatrixFunction[BesselJZero[1 / 2, #]&, {{2, 1}, {1, 3}}]//N

特定の値  (3)

無限大における極限値：

Wolfram Language code: Limit[BesselJZero[2, x], x -> Infinity]

最初の3つの零点：

Wolfram Language code: {BesselJZero[0, 1], BesselJZero[0, 2], BesselJZero[0, 3]}//N

Solveを使ってBesselJ[1,x]の最初の零点を求める：

Wolfram Language code: xzero = x /. Solve[BesselJ[1, x] == 0 && 2 < x < 6, x][[1]]
Wolfram Language code: Plot[BesselJ[1, x], {x, 0, 10}, Epilog -> Style[Point[{xzero, BesselJ[1, xzero]}], PointSize[Large], Red]]

可視化  (3)

BesselJの零点を階段関数として可視化する：

Wolfram Language code: Plot[BesselJZero[0, 1, x], {x, 1, 10}]

BesselJ関数の零点を表示する：

Wolfram Language code: Plot[BesselJ[1, z], {z, 0, 20}, Epilog -> {PointSize[0.03], Point[Table[{BesselJZero[1, k], 0}, {k, 6}]]}]

6より大きい最初の零点を示す：

Wolfram Language code: Plot[BesselJ[1, z], {z, 0, 10}, Epilog -> {PointSize[0.03], Red, Point[{BesselJZero[1, 1, 6], 0}]}]

微分と級数展開  (5)

ベッセル関数の零点の導関数を k について求める：

Wolfram Language code: D[BesselJZero[ν, k], k]

二次導関数：

Wolfram Language code: D[BesselJZero[2, x], {x, 2}]// Simplify

Seriesを使ってテイラー(Taylor)展開を求める：

Wolfram Language code: Series[BesselJZero[n, x], {x, 0, 2}]//Normal//Simplify

Infinityにおける級数展開を求める：

Wolfram Language code: Series[BesselJZero[n, x], {x, Infinity, 1}]

生成点におけるテイラー展開：

Wolfram Language code: Series[BesselJZero[n, x], {x, x0, 1}]

アプリケーション  (3)

ディリクレ(Dirichlet)の境界条件を持つ円形ドラムの最初の10個の固有モードを求める：

Wolfram Language code: modes = N[BesselJZero[0, Range[10]]]

ある種のモードの混合からなる振幅を構築する：

Wolfram Language code: ampl[r_] = Sin[modes].BesselJ[0, r modes];

環状密度プロット：

Wolfram Language code: ParametricPlot[{Cos[ϕ] r, Sin[ϕ] r}, {ϕ, 0, 2Pi}, {r, 0, 1}, ColorFunction -> Function[{x, y, ϕ, r}, GrayLevel[ampl[r]]], Mesh -> False, Axes -> False, BoundaryStyle -> None]

放射状ドラム置換プロファイル：

Wolfram Language code: Plot[ampl[r], {r, 0, 1}]

回析限界的な光学系におけるレイリーの基準(Rayleigh criterion)の係数を求める：

Wolfram Language code: BesselJZero[1, 1] / π //N

Laplacianの固有値をDisk上の直交座標で解析的に計算する：

Wolfram Language code: DEigenvalues[{-Laplacian[u[x, y], {x, y}], DirichletCondition[u[x, y] == 0, True]}, u[x, y], {x, y}∈Disk[], 3]

特性と関係  (1)

大きい k についてのBesselJZero[ν,k]の漸近的な動作：

Wolfram Language code: Series[BesselJZero[ν, k], {k, Infinity, 3}]
Wolfram Research (2007), BesselJZero, Wolfram言語関数， https://reference.wolfram.com/language/ref/BesselJZero.html.

テキスト

Wolfram Research (2007), BesselJZero, Wolfram言語関数， https://reference.wolfram.com/language/ref/BesselJZero.html.

CMS

Wolfram Language. 2007. "BesselJZero." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/BesselJZero.html.

APA

Wolfram Language. (2007). BesselJZero. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/BesselJZero.html

BibTeX

@misc{reference.wolfram_2026_besseljzero, author="Wolfram Research", title="{BesselJZero}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/BesselJZero.html}", note=[Accessed: 16-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_besseljzero, organization={Wolfram Research}, title={BesselJZero}, year={2007}, url={https://reference.wolfram.com/language/ref/BesselJZero.html}, note=[Accessed: 16-September-2026]}