Wolfram 语言与系统参考资料中心

BesselJZero

BesselJZero[n,k]

代表贝塞尔函数的第 k 个零点.

BesselJZero[n,k,x₀]

代表大于 x₀ 的第 k 个零点.

范例

打开所有单元关闭所有单元

基本范例 (5)

数值计算：

Wolfram Language code: N[BesselJZero[0, 1]]

符号计算：

Wolfram Language code: BesselJ[0, BesselJZero[0, 1]]

在实数子集上显示 BesselJ 函数的零点：

Wolfram Language code: Plot[BesselJ[1, z], {z, 0, 15}, Epilog -> {PointSize[0.03], Red, Point[Table[{BesselJZero[1, k], 0}, {k, 4}]]}]

在原点的级数展开：

Wolfram Language code: Series[BesselJZero[n, x], {x, 0, 1}]

TraditionalForm 格式：

Wolfram Language code: BesselJZero[ν, k]//TraditionalForm

范围 (19)

数值计算 (8)

数值化计算：

Wolfram Language code: BesselJZero[0., 2]

求大于 40 的第一个零点：

Wolfram Language code: N[BesselJZero[0, 1, 40]]

高精度计算：

Wolfram Language code: N[BesselJZero[1, 20, 40], 50]

高精度的高效计算：

Wolfram Language code: N[BesselJZero[0, 1, 40`100]]//Timing

Wolfram Language code: N[BesselJZero[0, 2, 50`1000]];//Timing

第二个参数为非整数的情况下进行计算：

Wolfram Language code: N[BesselJZero[0, 1 - 2 / 3], 20]

对于 BesselJZero[ν,k-α/π]，结果为的零点：

Wolfram Language code: BesselJ[0, %]Cos[2Pi / 3] - BesselY[0, %]Sin[2Pi / 3]

或用 Around 计算一般情况下的统计区间：

Wolfram Language code: BesselJZero[ 1, Around[2, 0.01]]

BesselJZero 逐个作用于列表的每个元素：

Wolfram Language code: BesselJZero[0, {1, 2, 3}]//N

自动逐项计算数组中每个元素的值：

Wolfram Language code: BesselJZero[1 / 2, {{2, 1}, {1, 3}}]//N

或用 MatrixFunction 计算矩阵形式的 BesselJZero 函数：

Wolfram Language code: MatrixFunction[BesselJZero[1 / 2, #]&, {{2, 1}, {1, 3}}]//N

特殊值 (3)

无穷处的极限值：

Wolfram Language code: Limit[BesselJZero[2, x], x -> Infinity]

前三个零点：

Wolfram Language code: {BesselJZero[0, 1], BesselJZero[0, 2], BesselJZero[0, 3]}//N

使用 Solve 找到 BesselJ[1,x] 的第一个零点：

Wolfram Language code: xzero = x /. Solve[BesselJ[1, x] == 0 && 2 < x < 6, x][[1]]

Wolfram Language code: Plot[BesselJ[1, x], {x, 0, 10}, Epilog -> Style[Point[{xzero, BesselJ[1, xzero]}], PointSize[Large], Red]]

可视化 (3)

将 BesselJ 的零点可视化为阶跃函数：

Wolfram Language code: Plot[BesselJZero[0, 1, x], {x, 1, 10}]

显示 BesselJ 函数的零点：

Wolfram Language code: Plot[BesselJ[1, z], {z, 0, 20}, Epilog -> {PointSize[0.03], Point[Table[{BesselJZero[1, k], 0}, {k, 6}]]}]

显示大于 6 的第一个零点：

Wolfram Language code: Plot[BesselJ[1, z], {z, 0, 10}, Epilog -> {PointSize[0.03], Red, Point[{BesselJZero[1, 1, 6], 0}]}]

微分和级数展开式 (5)

求 Bessel zero 关于 k 的导数：

Wolfram Language code: D[BesselJZero[ν, k], k]

二阶导：

Wolfram Language code: D[BesselJZero[2, x], {x, 2}]// Simplify

使用 Series 求泰勒展开：

Wolfram Language code: Series[BesselJZero[n, x], {x, 0, 2}]//Normal//Simplify

求在 Infinity 处的级数展开：

Wolfram Language code: Series[BesselJZero[n, x], {x, Infinity, 1}]

普通点的泰勒展开：

Wolfram Language code: Series[BesselJZero[n, x], {x, x0, 1}]

应用 (3)

求出带有狄利克雷边界条件圆鼓的前十个本征模：

Wolfram Language code: modes = N[BesselJZero[0, Range[10]]]

构造一个由一定混合模构成的振幅：

Wolfram Language code: ampl[r_] = Sin[modes].BesselJ[0, r modes];

圆形密度图：

Wolfram Language code:

ParametricPlot[{Cos[ϕ] r, Sin[ϕ] r}, {ϕ, 0, 2Pi}, {r, 0, 1}, ColorFunction -> Function[{x, y, ϕ, r}, GrayLevel[ampl[r]]], Mesh -> False, Axes -> False, BoundaryStyle -> None]

半径鼓位移剖面：

Wolfram Language code: Plot[ampl[r], {r, 0, 1}]

找出 Rayleigh criterion 中的系数用于衍射限光装置：

Wolfram Language code: BesselJZero[1, 1] / π //N

分析计 Disk 上直角坐标中 Laplacian 的特征值：

Wolfram Language code: DEigenvalues[{-Laplacian[u[x, y], {x, y}], DirichletCondition[u[x, y] == 0, True]}, u[x, y], {x, y}∈Disk[], 3]

属性和关系 (1)

k 较大时的 BesselJZero[ν,k] 渐近状态：

Wolfram Language code: Series[BesselJZero[ν, k], {k, Infinity, 3}]

Top

更多学习资源

技术支持

Wolfram 解决方案

Wolfram 的教育解决方案

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

BesselJZero

更多信息

范例

基本范例 (5)