WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

BetaRegularized[z,a,b]

正則不完全ベータ関数 TemplateBox[{z, a, b}, BetaRegularized]を与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
数値評価  
特定の値  
可視化  
Show More Show More
関数の特性  
微分  
積分  
級数展開  
関数の恒等式と簡約  
一般化と拡張  
通常の正則不完全ベータ関数  
一般化された正則不完全ベータ関数  
アプリケーション  
特性と関係  
考えられる問題  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

BetaRegularized

BetaRegularized[z,a,b]

正則不完全ベータ関数 TemplateBox[{z, a, b}, BetaRegularized]を与える．

詳細

  • 記号操作・数値操作の両方に適した数学関数である．
  • 非特異な場合，TemplateBox[{z, a, b}, BetaRegularized]=TemplateBox[{z, a, b}, Beta3]/TemplateBox[{a, b}, Beta]となる．
  • BetaRegularized[z0,z1,a,b]は，非特異な場合にBeta[z0,z1,a,b]/Beta[a,b]と定義された一般化された正則不完全ベータ関数を与える．
  • BetaRegularizedに関する引数は，GammaRegularizedと異なった並び順をすることに注意．
  • 特別な引数の場合，BetaRegularizedは，自動的に厳密値を計算する．
  • BetaRegularizedは任意の数値精度で評価できる．
  • BetaRegularizedはリストに対して自動的に縫い込まれる．
  • BetaRegularizedはIntervalオブジェクトおよびCenteredIntervalオブジェクトに使うことができる． »

例題

すべて開く すべて閉じる

例  (6)

数値的に評価する：

Wolfram Language code: BetaRegularized[2, 2.4, 3.2]

実数の部分集合上でプロットする：

Wolfram Language code: Plot[BetaRegularized[z, 3, 1], {z, -3, 3}]

複素数の部分集合上でプロットする：

Wolfram Language code: ComplexPlot3D[BetaRegularized[z, 5, 3], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

原点における級数展開：

Wolfram Language code: Series[BetaRegularized[x, 5, 3], {x, 0, 10}]

Infinityにおける漸近展開：

Wolfram Language code: Series[BetaRegularized[x, 1, -1 / 3], {x, ∞, 3}]//Normal//FullSimplify

特異点における漸近展開：

Wolfram Language code: Series[BetaRegularized[x, 5, 1], {x, 1, 3}]//FullSimplify

スコープ  (36)

数値評価  (6)

数値的に評価する：

Wolfram Language code: BetaRegularized[2, 0.5, 5]
Wolfram Language code: BetaRegularized[1, 0, 5]

高精度で評価する：

Wolfram Language code: N[BetaRegularized[15 / 17, 5, 1], 50]

出力精度は入力精度に従う：

Wolfram Language code: BetaRegularized[0.211111111111111111, 5, 1]

複素数入力：

Wolfram Language code: N[BetaRegularized[23 / 47, 5 - I, 2]]

高精度で効率よく評価する：

Wolfram Language code: BetaRegularized[23 / 47, 5, 1`100]//Timing
Wolfram Language code: BetaRegularized[15 / 71, 5, 1`10000];//Timing

IntervalオブジェクトとCenteredIntervalオブジェクトを使って最悪の場合に保証される区間を計算する：

Wolfram Language code: BetaRegularized[Interval[{1.2, 2.1}], 2, 1]
Wolfram Language code: BetaRegularized[CenteredInterval[2, 1 / 8], 2, 1]

Aroundを使って平均的な場合の統計区間を計算することもできる：

Wolfram Language code: BetaRegularized[ Around[1.2, 0.01], 1, 2]

配列の要素毎の値を計算する：

Wolfram Language code: BetaRegularized[{{1 / 2, -1}, {0, 1 / 2}}, 1, 2]

MatrixFunctionを使って行列のBetaRegularized関数を計算することもできる：

Wolfram Language code: MatrixFunction[BetaRegularized[#, 1, 2]&, {{1 / 2, -1}, {0, 1 / 2}}]//FullSimplify

特定の値  (4)

固定点におけるBetaRegularizedの値：

Wolfram Language code: Table[BetaRegularized[z, 1, 2 ], {z, 1, 5}]
Wolfram Language code: Table[BetaRegularized[1 / z, 1, 2], {z, 2, 4}]

ゼロにおける値：

Wolfram Language code: BetaRegularized[0, 0, 0 ]

無限大における値：

Wolfram Language code: BetaRegularized[ComplexInfinity, 1, 3 ]
Wolfram Language code: BetaRegularized[Infinity, 1, 2 ]

BetaRegularized[z,1,3]=3.5となるような z の値を求める：

Wolfram Language code: zval = z /. FindRoot[BetaRegularized[z, 1, 3] == 3.5, {z, 0.1}]
Wolfram Language code: Plot[BetaRegularized[z, 1, 3], {z, -5, 5}, Epilog -> Style[Point[{zval, BetaRegularized[zval, 1, 3]}], PointSize[Large], Red], PlotRange -> {-20, 20}]

可視化  (3)

BetaRegularized多項式をさまざまなパラメータでプロットする：

Wolfram Language code: Plot[Evaluate[Table[BetaRegularized[z, a, b], {a, 3}, {b, 3}]], {z, -3, 3}]

TemplateBox[{3, a, b}, BetaRegularized]の実部をプロットする：

Wolfram Language code: ContourPlot[Re[BetaRegularized[3, a, b]], {a, -3, 3}, {b, -3, 3}, IconizedObject[«PlotOptions»]]

TemplateBox[{3, a, b}, BetaRegularized]の虚部をプロットする：

Wolfram Language code: ContourPlot[Im[BetaRegularized[3, a, b]], {a, -3, 3}, {b, -3, 3}, IconizedObject[«PlotOptions»]]

関数の特性  (9)

TemplateBox[{z, 1, 1}, BetaRegularized]はすべての実数値と複素値について定義される：

Wolfram Language code: FunctionDomain[BetaRegularized[z, 1, 1], z]
Wolfram Language code: FunctionDomain[BetaRegularized[z, 2, 1], z, Complexes]

TemplateBox[{z, 1, 1}, BetaRegularized]は奇関数である：

Wolfram Language code: BetaRegularized[-z, 1, 1] == -BetaRegularized[z, 1, 1]

正則不完全ベータ関数 TemplateBox[{x, a, 1}, BetaRegularized]は正の整数 についての の解析関数である：

Wolfram Language code: FunctionAnalytic[BetaRegularized[x, a, 1], x, Assumptions -> a > 0 && a∈ℤ]

したがって，そのような関数は特異点も不連続点も持たない：

Wolfram Language code: FunctionSingularities[BetaRegularized[x, 1, 1], x]
Wolfram Language code: FunctionDiscontinuities[BetaRegularized[x, 1, 1], x]

TemplateBox[{x, a, 1}, BetaRegularized]は， のその他の値については解析的でも有理型でもない：

Wolfram Language code: FunctionAnalytic[Beta[x, 1 / 2, 1], x]
Wolfram Language code: FunctionMeromorphic[Beta[x, 1 / 2, 1], x]

TemplateBox[{x, 1, 2}, BetaRegularized]は非増加でも非減少でもない：

Wolfram Language code: FunctionMonotonicity[BetaRegularized[x, 1, 2], x]

TemplateBox[{x, a, 1}, BetaRegularized]は正の奇数 については単射であるが，正の偶数 についてはそうではない：

Wolfram Language code: FunctionInjective[BetaRegularized[x, 2k, 1], x, Assumptions -> k > 0 && k∈ℤ]
Wolfram Language code: FunctionInjective[BetaRegularized[x, 2k + 1, 1], x, Assumptions -> k > 0 && k∈ℤ]
Wolfram Language code: Plot[{BetaRegularized[x, 3, 1], BetaRegularized[x, 4, 1], 5}, {x, -2, 2}]

TemplateBox[{x, a, 1}, BetaRegularized]は正の奇数 については全射であるが正の偶数 についてはそうではない：

Wolfram Language code: Table[FunctionSurjective[BetaRegularized[x, a, 1], x], {a, 5}]
Wolfram Language code: Plot[{BetaRegularized[x, 3, 1], BetaRegularized[x, 4, 1], -5}, {x, -2, 2}]

TemplateBox[{x, a, 1}, BetaRegularized]は正の偶数 については非負であるが奇数 については不定である：

Wolfram Language code: Table[FunctionSign[BetaRegularized[x, a, 1], x], {a, 5}]

TemplateBox[{x, a, 1}, BetaRegularized]は， が偶数値のときは凸である：

Wolfram Language code: FunctionConvexity[BetaRegularized[x, 2k, 1], x, Assumptions -> k > 0 && k∈ℤ]

TraditionalFormによる表示：

Wolfram Language code: BetaRegularized[z, a, b]//TraditionalForm

微分  (3)

z についての一次導関数：

Wolfram Language code: D[BetaRegularized[z, a, b], z]

a についての一次導関数：

Wolfram Language code: D[BetaRegularized[z, a, b], a]

b についての一次導関数：

Wolfram Language code: D[BetaRegularized[z, a, b], b]

z についての高次導関数：

Wolfram Language code: Table[D[BetaRegularized[z, a, b], {z, k}], {k, 1, 3}]//FullSimplify

a=2で b=3のとき，z について高次導関数をプロットする：

Wolfram Language code: Plot[Evaluate[% /. { a -> 2, b -> 3}], {z, -5, 5}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]

z についての 次導関数の式：

Wolfram Language code: D[BetaRegularized[z, a, b], {z, k}]// FullSimplify

積分  (3)

Integrateを使って不定積分を計算する：

Wolfram Language code: Integrate[BetaRegularized[``z, a, b``], z]

不定積分を確かめる：

Wolfram Language code: FullSimplify[D[%, z]]

定積分：

Wolfram Language code: Integrate[BetaRegularized[``z, a, b``], {z, 0, 4}]

その他の積分例：

Wolfram Language code: Integrate[z BetaRegularized[``Sqrt[z], 2, 1``], z]//FullSimplify
Wolfram Language code: Integrate[ z^2 BetaRegularized[``z, 3, 5``], {z, 0, 4}]//FullSimplify

級数展開  (5)

Seriesを使ってテイラー(Taylor)展開を求める：

Wolfram Language code: Series[BetaRegularized[x, a, b], {x, 0, 3}]

の周りの最初の3つの近似をプロットする：

Wolfram Language code: terms = FullSimplify[Normal[Table[Series[BetaRegularized[x, 4, 1], {x, 2, m}], {m, 1, 3, 1}]]]; Plot[{BetaRegularized[x, 4, 1], terms}, {x, -3, 3}]

FourierSeries：

Wolfram Language code: FourierSeries[BetaRegularized[x, 1, 3], x, 1]// FullSimplify

Infinityにおける級数展開を求める：

Wolfram Language code: Series[BetaRegularized[x, a, b], {x, Infinity, 0}]

任意の記号方向 についての級数展開を求める：

Wolfram Language code: Series[BetaRegularized[x, a, b], {x, DirectedInfinity[z], 1}, Assumptions -> x > 0]// FullSimplify

生成点における級数展開：

Wolfram Language code: Series[BetaRegularized[x, a, b], {x, x0, 2}]// FullSimplify

関数の恒等式と簡約  (3)

正規化された不完全ベータ関数は不完全ベータ関数と関係がある：

Wolfram Language code: BetaRegularized[x, y, a, b]//FunctionExpand

漸化式：

Wolfram Language code: BetaRegularized[x, a + 1, b] == BetaRegularized[x, a, b] - (x ^ a (1 - x) ^ b/a Beta[a, b])//FullSimplify

BetaRegularizedはより簡単な形に簡約できることがある：

Wolfram Language code: BetaRegularized[x, 1, b]

一般化と拡張  (8)

通常の正則不完全ベータ関数  (5)

整数と半整数の引数について評価する：

Wolfram Language code: BetaRegularized[z, 2, 5]//FunctionExpand
Wolfram Language code: BetaRegularized[z, 1 / 2, 3 / 2]//FunctionExpand

無限大の引数は記号的な結果を返す：

Wolfram Language code: BetaRegularized[Infinity, 1, 2]

BetaRegularizedはリストに対して要素単位で適用される：

Wolfram Language code: BetaRegularized[{2, 3, 5, 7}, 2.5, 0.5]

BetaRegularizedはベキ級数に適用することができる：

Wolfram Language code: BetaRegularized[1 + x + O[x]^2, a, 5 / 2]

無限大における級数展開：

Wolfram Language code: Series[BetaRegularized[z, a, b], {z, Infinity, 2}]

任意の記号的方向についての結果を与える：

Wolfram Language code: Series[BetaRegularized[z, a, b], {z, DirectedInfinity[x], 2}]

一般化された正則不完全ベータ関数  (3)

整数と半整数の引数について評価する：

Wolfram Language code: BetaRegularized[z, 2, 7 / 2, 1 / 2]//FunctionExpand//Simplify

生成点における級数展開：

Wolfram Language code: Series[BetaRegularized[z0, z1, a, b], {z0, ζ, 2}]
Wolfram Language code: Series[BetaRegularized[z0, z1, a, b], {a, α, 1}]

無限大における級数展開：

Wolfram Language code: Series[BetaRegularized[z0, z1, a, b], {z1, Infinity, 2}]

アプリケーション  (4)

複素平面におけるBetaRegularizedの絶対値をプロットする：

Wolfram Language code: Plot3D[Abs[BetaRegularized[x + I y, -1.5, 3]], {x, -2, 2}, {y, -1, 1}]
Wolfram Language code: Plot3D[Re[BetaRegularized[2, ax + I ay, I]], {ax, -5, 2}, {ay, -1, 1}]

d 次元の超球における点のすべてのペアの平均距離 s の分布：

Wolfram Language code: p[d_, s_] := d s ^ (d - 1) BetaRegularized[1 - s ^ 2 / 4, (d + 1) / 2, 1 / 2]

低次元の分布は初等関数で表すことができる：

Wolfram Language code: Table[FullSimplify[FunctionExpand[p[d, s]], s > 0], {d, 3}]

分布をプロットする：

Wolfram Language code: Plot[Evaluate[Table[p[d, s], {d, 10}]], {s, 0, 2}]

StudentTDistributionの累積分布関数はBetaRegularized関数によって与えられる：

Wolfram Language code: p[n_, r_] = CDF[StudentTDistribution[n], r]

PDFをさまざまなパラメータについてプロットする：

Wolfram Language code: Plot[Evaluate[Table[p[ν, x], {ν, 1, 6}]] , {x, 0, 5}]

逆確率：

Wolfram Language code: 1 - CDF[StudentTDistribution[n], r]//PiecewiseExpand

StudentTDistributionの累積分布関数はBetaRegularized関数によって与えられる：

Wolfram Language code: p[n_, m_, r_] = CDF[FRatioDistribution[n, m], r]

分子と分母の自由度のさまざまな値について累積分布関数をプロットする：

Wolfram Language code: Plot[Table[p[n, 10, x], {n, {2, 5, 20}}]//Evaluate, {x, 0, 2}, Exclusions -> None]
Wolfram Language code: Plot[Table[p[10, m, x], {m, {1, 5, 20}}]//Evaluate, {x, 0, 2}, Exclusions -> None]

特性と関係  (3)

FunctionExpandを用いてGamma関数とBeta関数を通して表す：

Wolfram Language code: FunctionExpand[BetaRegularized[z, a, b]]

超越関数の根を数値的に求める：

Wolfram Language code: FindRoot[BetaRegularized[z, 2, 3] - 4 BetaRegularized[2, z + 2, 3] + z == 6, {z, 1}]

逆関数で構成する：

Wolfram Language code: BetaRegularized[InverseBetaRegularized[z, a, b], a, b]

PowerExpandを使って多価性の曖昧性を無視する：

Wolfram Language code: PowerExpand[%]

考えられる問題  (3)

大きい引数は，厳密計算するのには小さすぎる結果を与えることがある：

Wolfram Language code: BetaRegularized[10 ^ 20., 10 ^ 30., 10. ^ 20.]

機械数の入力が高精度の結果を与えることがある：

Wolfram Language code: BetaRegularized[10. ^ 1, 10. ^ 3, 10. ^ 2]
Wolfram Language code: MachineNumberQ[%]

一般に，FullSimplifyでは正則ベータ関数は生成されない：

Wolfram Language code: FunctionExpand[BetaRegularized[z, a, b]]
Wolfram Language code: FullSimplify[%]
Wolfram Research (1991), BetaRegularized, Wolfram言語関数， https://reference.wolfram.com/language/ref/BetaRegularized.html （2022年に更新）.

テキスト

Wolfram Research (1991), BetaRegularized, Wolfram言語関数， https://reference.wolfram.com/language/ref/BetaRegularized.html （2022年に更新）.

CMS

Wolfram Language. 1991. "BetaRegularized." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2022. https://reference.wolfram.com/language/ref/BetaRegularized.html.

APA

Wolfram Language. (1991). BetaRegularized. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/BetaRegularized.html

BibTeX

@misc{reference.wolfram_2026_betaregularized, author="Wolfram Research", title="{BetaRegularized}", year="2022", howpublished="\url{https://reference.wolfram.com/language/ref/BetaRegularized.html}", note=[Accessed: 05-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_betaregularized, organization={Wolfram Research}, title={BetaRegularized}, year={2022}, url={https://reference.wolfram.com/language/ref/BetaRegularized.html}, note=[Accessed: 05-September-2026]}