WOLFRAM

Wolfram 语言与系统参考资料中心
BetaRegularized[z,a,b] 给出正则化的不完全 β 函数 TemplateBox[{z, a, b}, BetaRegularized].
更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
数值运算  
特殊值  
可视化  
Show More Show More
函数的属性  
微分  
积分  
级数展开式  
函数恒等式和化简  
推广和延伸  
常规正则化不完全 β 函数  
广义正则化不完全 β 函数  
应用  
属性和关系  
可能存在的问题  
参见
技术笔记
相关指南
相关链接
历史
按以下格式引用：

BetaRegularized

BetaRegularized[z,a,b] 给出正则化的不完全 β 函数 TemplateBox[{z, a, b}, BetaRegularized].

更多信息

范例

打开所有单元 关闭所有单元

基本范例  (6)

数值运算：

Wolfram Language code: BetaRegularized[2, 2.4, 3.2]

在实数的子集上绘图：

Wolfram Language code: Plot[BetaRegularized[z, 3, 1], {z, -3, 3}]

在复数的子集上绘图：

Wolfram Language code: ComplexPlot3D[BetaRegularized[z, 5, 3], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

在原点的级数展开：

Wolfram Language code: Series[BetaRegularized[x, 5, 3], {x, 0, 10}]

在 Infinity 的级数展开：

Wolfram Language code: Series[BetaRegularized[x, 1, -1 / 3], {x, ∞, 3}]//Normal//FullSimplify

在奇点处的渐近展开式：

Wolfram Language code: Series[BetaRegularized[x, 5, 1], {x, 1, 3}]//FullSimplify

范围  (36)

数值运算  (6)

数值运算：

Wolfram Language code: BetaRegularized[2, 0.5, 5]
Wolfram Language code: BetaRegularized[1, 0, 5]

高精度求值：

Wolfram Language code: N[BetaRegularized[15 / 17, 5, 1], 50]

输出的精度与输入的精度相符：

Wolfram Language code: BetaRegularized[0.211111111111111111, 5, 1]

复数输入：

Wolfram Language code: N[BetaRegularized[23 / 47, 5 - I, 2]]

高效地进行高精度运算：

Wolfram Language code: BetaRegularized[23 / 47, 5, 1`100]//Timing
Wolfram Language code: BetaRegularized[15 / 71, 5, 1`10000];//Timing

使用 Interval 和 CenteredInterval 对象计算最坏情况下的保证区间：

Wolfram Language code: BetaRegularized[Interval[{1.2, 2.1}], 2, 1]
Wolfram Language code: BetaRegularized[CenteredInterval[2, 1 / 8], 2, 1]

或用 Around 计算一般情况下的统计区间：

Wolfram Language code: BetaRegularized[ Around[1.2, 0.01], 1, 2]

计算数组中每个元素的值：

Wolfram Language code: BetaRegularized[{{1 / 2, -1}, {0, 1 / 2}}, 1, 2]

或用 MatrixFunction 计算矩阵形式的 BetaRegularized 函数：

Wolfram Language code: MatrixFunction[BetaRegularized[#, 1, 2]&, {{1 / 2, -1}, {0, 1 / 2}}]//FullSimplify

特殊值  (4)

BetaRegularized 在固定点上的值：

Wolfram Language code: Table[BetaRegularized[z, 1, 2 ], {z, 1, 5}]
Wolfram Language code: Table[BetaRegularized[1 / z, 1, 2], {z, 2, 4}]

在零处的值：

Wolfram Language code: BetaRegularized[0, 0, 0 ]

无穷处的值：

Wolfram Language code: BetaRegularized[ComplexInfinity, 1, 3 ]
Wolfram Language code: BetaRegularized[Infinity, 1, 2 ]

求使得 BetaRegularized[z,1,3]=3.5 成立的 z 值：

Wolfram Language code: zval = z /. FindRoot[BetaRegularized[z, 1, 3] == 3.5, {z, 0.1}]
Wolfram Language code: Plot[BetaRegularized[z, 1, 3], {z, -5, 5}, Epilog -> Style[Point[{zval, BetaRegularized[zval, 1, 3]}], PointSize[Large], Red], PlotRange -> {-20, 20}]

可视化  (3)

绘制各种参数设置下的 BetaRegularized 函数：

Wolfram Language code: Plot[Evaluate[Table[BetaRegularized[z, a, b], {a, 3}, {b, 3}]], {z, -3, 3}]

绘制 TemplateBox[{3, a, b}, BetaRegularized] 的实部：

Wolfram Language code: ContourPlot[Re[BetaRegularized[3, a, b]], {a, -3, 3}, {b, -3, 3}, IconizedObject[«PlotOptions»]]

绘制 TemplateBox[{3, a, b}, BetaRegularized] 的虚部：

Wolfram Language code: ContourPlot[Im[BetaRegularized[3, a, b]], {a, -3, 3}, {b, -3, 3}, IconizedObject[«PlotOptions»]]

函数的属性  (9)

TemplateBox[{z, 1, 1}, BetaRegularized] 的定义域是所有实数和复数：

Wolfram Language code: FunctionDomain[BetaRegularized[z, 1, 1], z]
Wolfram Language code: FunctionDomain[BetaRegularized[z, 2, 1], z, Complexes]

TemplateBox[{z, 1, 1}, BetaRegularized] 是奇函数：

Wolfram Language code: BetaRegularized[-z, 1, 1] == -BetaRegularized[z, 1, 1]

对于正整数 ，正则化的不完全 beta 函数 TemplateBox[{x, a, 1}, BetaRegularized] 是 的解析函数：

Wolfram Language code: FunctionAnalytic[BetaRegularized[x, a, 1], x, Assumptions -> a > 0 && a∈ℤ]

因此，任何这样的函数都没有奇点或断点：

Wolfram Language code: FunctionSingularities[BetaRegularized[x, 1, 1], x]
Wolfram Language code: FunctionDiscontinuities[BetaRegularized[x, 1, 1], x]

取其他值时，TemplateBox[{x, a, 1}, BetaRegularized] 既不是解析函数，也不是亚纯函数：

Wolfram Language code: FunctionAnalytic[Beta[x, 1 / 2, 1], x]
Wolfram Language code: FunctionMeromorphic[Beta[x, 1 / 2, 1], x]

TemplateBox[{x, 1, 2}, BetaRegularized] i既不是非递增，也不是非递减：

Wolfram Language code: FunctionMonotonicity[BetaRegularized[x, 1, 2], x]

如果 为正的奇数，TemplateBox[{x, a, 1}, BetaRegularized] 是单射函数，如果 为正的偶数，则不是单射函数：

Wolfram Language code: FunctionInjective[BetaRegularized[x, 2k, 1], x, Assumptions -> k > 0 && k∈ℤ]
Wolfram Language code: FunctionInjective[BetaRegularized[x, 2k + 1, 1], x, Assumptions -> k > 0 && k∈ℤ]
Wolfram Language code: Plot[{BetaRegularized[x, 3, 1], BetaRegularized[x, 4, 1], 5}, {x, -2, 2}]

如果 为正的奇数，TemplateBox[{x, a, 1}, BetaRegularized] 是满射函数，如果 为正的偶数，则不是满射函数：

Wolfram Language code: Table[FunctionSurjective[BetaRegularized[x, a, 1], x], {a, 5}]
Wolfram Language code: Plot[{BetaRegularized[x, 3, 1], BetaRegularized[x, 4, 1], -5}, {x, -2, 2}]

如果 为正的偶数，TemplateBox[{x, a, 1}, BetaRegularized] 非负，如果 为奇数，则不确定：

Wolfram Language code: Table[FunctionSign[BetaRegularized[x, a, 1], x], {a, 5}]

如果 为正的偶数，TemplateBox[{x, a, 1}, BetaRegularized] 是凸函数：

Wolfram Language code: FunctionConvexity[BetaRegularized[x, 2k, 1], x, Assumptions -> k > 0 && k∈ℤ]

TraditionalForm 格式输出：

Wolfram Language code: BetaRegularized[z, a, b]//TraditionalForm

微分  (3)

关于 z 的一阶导数：

Wolfram Language code: D[BetaRegularized[z, a, b], z]

关于 a 的一阶导数：

Wolfram Language code: D[BetaRegularized[z, a, b], a]

关于 b 的一阶导数：

Wolfram Language code: D[BetaRegularized[z, a, b], b]

关于 z 的高阶导数：

Wolfram Language code: Table[D[BetaRegularized[z, a, b], {z, k}], {k, 1, 3}]//FullSimplify

a=2，b=3，绘制关于 z 的高阶导数：

Wolfram Language code: Plot[Evaluate[% /. { a -> 2, b -> 3}], {z, -5, 5}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]

关于 z 的 阶导数的公式：

Wolfram Language code: D[BetaRegularized[z, a, b], {z, k}]// FullSimplify

积分  (3)

用 Integrate 计算不定积分：

Wolfram Language code: Integrate[BetaRegularized[``z, a, b``], z]

验证反导数：

Wolfram Language code: FullSimplify[D[%, z]]

定积分：

Wolfram Language code: Integrate[BetaRegularized[``z, a, b``], {z, 0, 4}]

更多积分：

Wolfram Language code: Integrate[z BetaRegularized[``Sqrt[z], 2, 1``], z]//FullSimplify
Wolfram Language code: Integrate[ z^2 BetaRegularized[``z, 3, 5``], {z, 0, 4}]//FullSimplify

级数展开式  (5)

用 Series 求泰勒展开式：

Wolfram Language code: Series[BetaRegularized[x, a, b], {x, 0, 3}]

绘制 处的前三个近似式：

Wolfram Language code: terms = FullSimplify[Normal[Table[Series[BetaRegularized[x, 4, 1], {x, 2, m}], {m, 1, 3, 1}]]]; Plot[{BetaRegularized[x, 4, 1], terms}, {x, -3, 3}]

FourierSeries：

Wolfram Language code: FourierSeries[BetaRegularized[x, 1, 3], x, 1]// FullSimplify

求 Infinity 处的级数展开式：

Wolfram Language code: Series[BetaRegularized[x, a, b], {x, Infinity, 0}]

求任意符号方向 上的级数展开式：

Wolfram Language code: Series[BetaRegularized[x, a, b], {x, DirectedInfinity[z], 1}, Assumptions -> x > 0]// FullSimplify

普通点上的泰勒展开式：

Wolfram Language code: Series[BetaRegularized[x, a, b], {x, x0, 2}]// FullSimplify

函数恒等式和化简  (3)

正则化的不完全 beta 函数与不完全 beta 函数有关：

Wolfram Language code: BetaRegularized[x, y, a, b]//FunctionExpand

递归关系：

Wolfram Language code: BetaRegularized[x, a + 1, b] == BetaRegularized[x, a, b] - (x ^ a (1 - x) ^ b/a Beta[a, b])//FullSimplify

BetaRegularized 可被简化为更简单的形式：

Wolfram Language code: BetaRegularized[x, 1, b]

推广和延伸  (8)

常规正则化不完全 β 函数  (5)

对整数和半整数自变量求值：

Wolfram Language code: BetaRegularized[z, 2, 5]//FunctionExpand
Wolfram Language code: BetaRegularized[z, 1 / 2, 3 / 2]//FunctionExpand

无穷自变量得到符号解：

Wolfram Language code: BetaRegularized[Infinity, 1, 2]

BetaRegularized 按元素线性作用于列表：

Wolfram Language code: BetaRegularized[{2, 3, 5, 7}, 2.5, 0.5]

BetaRegularized 可被应用于幂级数：

Wolfram Language code: BetaRegularized[1 + x + O[x]^2, a, 5 / 2]

无穷处的级数展开：

Wolfram Language code: Series[BetaRegularized[z, a, b], {z, Infinity, 2}]

给定一个任意符号方向的解：

Wolfram Language code: Series[BetaRegularized[z, a, b], {z, DirectedInfinity[x], 2}]

广义正则化不完全 β 函数  (3)

对整数和半整数自变量求值：

Wolfram Language code: BetaRegularized[z, 2, 7 / 2, 1 / 2]//FunctionExpand//Simplify

一般点处的级数展开：

Wolfram Language code: Series[BetaRegularized[z0, z1, a, b], {z0, ζ, 2}]
Wolfram Language code: Series[BetaRegularized[z0, z1, a, b], {a, α, 1}]

无穷处的级数展开：

Wolfram Language code: Series[BetaRegularized[z0, z1, a, b], {z1, Infinity, 2}]

应用  (4)

BetaRegularized 在复平面的绝对值图：

Wolfram Language code: Plot3D[Abs[BetaRegularized[x + I y, -1.5, 3]], {x, -2, 2}, {y, -1, 1}]
Wolfram Language code: Plot3D[Re[BetaRegularized[2, ax + I ay, I]], {ax, -5, 2}, {ay, -1, 1}]

全体偶点在一个d 维超球面的平均间隔为 s 的分布：

Wolfram Language code: p[d_, s_] := d s ^ (d - 1) BetaRegularized[1 - s ^ 2 / 4, (d + 1) / 2, 1 / 2]

低维分布可用初等函数表示：

Wolfram Language code: Table[FullSimplify[FunctionExpand[p[d, s]], s > 0], {d, 3}]

绘制分布图：

Wolfram Language code: Plot[Evaluate[Table[p[d, s], {d, 10}]], {s, 0, 2}]

StudentTDistribution 的 CDF 以 BetaRegularized 函数的形式给出：

Wolfram Language code: p[n_, r_] = CDF[StudentTDistribution[n], r]

绘制不同参量的累积分布函数：

Wolfram Language code: Plot[Evaluate[Table[p[ν, x], {ν, 1, 6}]] , {x, 0, 5}]

逆概率：

Wolfram Language code: 1 - CDF[StudentTDistribution[n], r]//PiecewiseExpand

FRatioDistribution 的 CDF 以 BetaRegularized 函数的形式给出：

Wolfram Language code: p[n_, m_, r_] = CDF[FRatioDistribution[n, m], r]

绘制分子和分母自由度不同值情况下的 CDF 图：

Wolfram Language code: Plot[Table[p[n, 10, x], {n, {2, 5, 20}}]//Evaluate, {x, 0, 2}, Exclusions -> None]
Wolfram Language code: Plot[Table[p[10, m, x], {m, {1, 5, 20}}]//Evaluate, {x, 0, 2}, Exclusions -> None]

属性和关系  (3)

由 FunctionExpand 将正则化的不完全 β 函数用 Gamma 和 Beta 函数表示：

Wolfram Language code: FunctionExpand[BetaRegularized[z, a, b]]

求超越方程的数值根：

Wolfram Language code: FindRoot[BetaRegularized[z, 2, 3] - 4 BetaRegularized[2, z + 2, 3] + z == 6, {z, 1}]

与反函数结合：

Wolfram Language code: BetaRegularized[InverseBetaRegularized[z, a, b], a, b]

用 PowerExpand 忽略多值性含糊：

Wolfram Language code: PowerExpand[%]

可能存在的问题  (3)

较大的自变量得到的解太大，以至于不能被明确地计算求出：

Wolfram Language code: BetaRegularized[10 ^ 20., 10 ^ 30., 10. ^ 20.]

机器数的输入能得到高精度的解：

Wolfram Language code: BetaRegularized[10. ^ 1, 10. ^ 3, 10. ^ 2]
Wolfram Language code: MachineNumberQ[%]

FullSimplify 一般不生成正则化的 β 函数：

Wolfram Language code: FunctionExpand[BetaRegularized[z, a, b]]
Wolfram Language code: FullSimplify[%]
Wolfram Research (1991)，BetaRegularized，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BetaRegularized.html （更新于 2022 年）.

文本

Wolfram Research (1991)，BetaRegularized，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BetaRegularized.html （更新于 2022 年）.

CMS

Wolfram 语言. 1991. "BetaRegularized." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2022. https://reference.wolfram.com/language/ref/BetaRegularized.html.

APA

Wolfram 语言. (1991). BetaRegularized. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/BetaRegularized.html 年

BibTeX

@misc{reference.wolfram_2026_betaregularized, author="Wolfram Research", title="{BetaRegularized}", year="2022", howpublished="\url{https://reference.wolfram.com/language/ref/BetaRegularized.html}", note=[Accessed: 14-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_betaregularized, organization={Wolfram Research}, title={BetaRegularized}, year={2022}, url={https://reference.wolfram.com/language/ref/BetaRegularized.html}, note=[Accessed: 14-August-2026]}