WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

BirnbaumImportance[rdist,t]

時間 t におけるReliabilityDistribution rdist のすべての成分のBirnbaum重要度を与える．

BirnbaumImportance[fdist,t]

時間 t におけるFailureDistribution fdist のすべての成分のBirnbaum重要度を与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
ReliabilityDistributionモデル  
FailureDistributionモデル  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

BirnbaumImportance

BirnbaumImportance[rdist,t]

時間 t におけるReliabilityDistribution rdist のすべての成分のBirnbaum重要度を与える．

BirnbaumImportance[fdist,t]

時間 t におけるFailureDistribution fdist のすべての成分のBirnbaum重要度を与える．

詳細

  • BirnbaumImportanceは信頼性重要度としても知られている．
  • Birnbaum重要度は故障した成分 を完全な成分 で置き換えることによって信頼性を向上させることである．
  • 時間 における成分 のBirnbaum重要度は で与えられる．ただし，は 番目の成分が完全な場合に系が動いている確率，は 番目の成分が故障したときに系が動いている確率である．
  • 結果は rdist あるいは fdist の分布リストにおける成分順で返される．

例題

すべて開く すべて閉じる

例  (3)

直列で繋がれ，寿命分布が異なる2つの成分：

Wolfram Language code: ℛ = ReliabilityDistribution[x∧y, {{x, ExponentialDistribution[1]}, {y, ExponentialDistribution[2]}}];

結果はReliabilityDistributionにおける分布リストと同じ順で返される：

Wolfram Language code: {Subscript[bi, x], Subscript[bi, y]} = BirnbaumImportance[ℛ, t]
Wolfram Language code: Plot[{Subscript[bi, x], Subscript[bi, y]}, {t, 0, 2}, Filling -> Axis, AxesOrigin -> {0, 0}]

並列で繋がれ，寿命分布が異なる2つの成分：

Wolfram Language code: ℛ = ReliabilityDistribution[x∨y, {{x, ExponentialDistribution[Subscript[λ, 1]]}, {y, ExponentialDistribution[Subscript[λ, 2]]}}];
Wolfram Language code: BirnbaumImportance[ℛ, t]

故障の木に基づいたモデリングを使って系を定義する：

Wolfram Language code: ℱ = FailureDistribution[x∧y, {{x, WeibullDistribution[2, 3]}, {y, WeibullDistribution[4, 5]}}];
Wolfram Language code: BirnbaumImportance[ℱ, t]
Wolfram Language code: Plot[Evaluate[%], {t, 0, 7}, Filling -> Axis]

スコープ  (17)

ReliabilityDistributionモデル  (9)

並列で繋がれ，寿命分布が等しい2つの成分：

Wolfram Language code: ℛ = ReliabilityDistribution[x∨y, {{x, ExponentialDistribution[λ]}, {y, ExponentialDistribution[λ]}}];

一方の成分の信頼性を変えると系の信頼性も同じように変わる：

Wolfram Language code: BirnbaumImportance[ℛ, t]

直列で繋がれ，寿命分布が等しい2つの成分：

Wolfram Language code: ℛ = ReliabilityDistribution[x∧y, {{x, ExponentialDistribution[λ]}, {y, ExponentialDistribution[λ]}}];

どちらかの成分の信頼性を変えると系の信頼性も同じように変わる：

Wolfram Language code: BirnbaumImportance[ℛ, t]

寿命分布の等しい3つの成分のうち2つが動いていることが必要な系：

Wolfram Language code: ℛ = ReliabilityDistribution[BooleanCountingFunction[{2, 3}, {x, y, z}], {{x, ExponentialDistribution[λ]}, {y, ExponentialDistribution[λ]}, {z, ExponentialDistribution[λ]}}];

どの成分も同じように重要である：

Wolfram Language code: BirnbaumImportance[ℛ, t]//Simplify

寿命分布が等しい単純な混合系：

Wolfram Language code: d = ExponentialDistribution[1];
Wolfram Language code: ℛ = ReliabilityDistribution[x∧(y∨z), {{x, d}, {y, d}, {z, d}}];

重要度を計算する：

Wolfram Language code: bi = BirnbaumImportance[ℛ, t]

成分 の信頼性を変えると系の信頼性に最も影響が出る：

Wolfram Language code: Plot[Evaluate@MapThread[Tooltip, {bi, {x, y, z}}], {t, 0, 4}, PlotRange -> All]

ある成分と並列に接続された直列接続の系：

Wolfram Language code: d = ExponentialDistribution[1];
Wolfram Language code: ℛ = ReliabilityDistribution[x∨(y∧z), {{x, d}, {y, d}, {z, d}}];

重要度を計算する：

Wolfram Language code: bi = BirnbaumImportance[ℛ, t]

成分を向上させると系の信頼性に最も大きく影響する：

Wolfram Language code: Plot[Evaluate@MapThread[Tooltip, {bi, {x, y, z}}], {t, 0, 4}]

単純な混合系でパラメータの変化が与える影響を調べる：

Wolfram Language code: {Subscript[d, 1], Subscript[d, 2], Subscript[d, 3]} = {ExponentialDistribution[1], ExponentialDistribution[1], ExponentialDistribution[λ]};
Wolfram Language code: ℛ = ReliabilityDistribution[x∧(y∨z), {{x, Subscript[d, 1]}, {y, Subscript[d, 2]}, {z, Subscript[d, 3]}}];

重要度を計算する：

Wolfram Language code: bi = BirnbaumImportance[ℛ, t]

並列成分の一つである を悪化させた場合の重要度の変化を示す：

Wolfram Language code: Table[ Plot[Evaluate@MapThread[Tooltip, {bi /. λ -> k, {x, y, z}}], {t, 0, 4}, PlotRange -> All, PlotLabel -> k] , {k, 1, 5, 2}]

分布が異なる他の2つの成分と並列に接続された1つの成分：

Wolfram Language code: dists = {{x, ExponentialDistribution[1]}, {y, ExponentialDistribution[2]}, {z, ExponentialDistribution[1]}};
Wolfram Language code: ℛ = ReliabilityDistribution[x∧(y∨z), dists];

時間の特定の1点における重要性尺度を厳密な結果として求める：

Wolfram Language code: BirnbaumImportance[ℛ, 3 / 2]

機械精度での結果：

Wolfram Language code: BirnbaumImportance[ℛ, 1.5]

記号式での結果：

Wolfram Language code: BirnbaumImportance[ℛ, t]

任意の有効なReliabilityDistributionを使うことができる：

Wolfram Language code: {Subscript[𝒟, 1], Subscript[𝒟, 2]} = {ExponentialDistribution[1], ExponentialDistribution[2]};
Wolfram Language code: ℛ = ReliabilityDistribution[x∨y, {{x, Subscript[𝒟, 1]}, {y, StandbyDistribution[Subscript[𝒟, 2], {Subscript[𝒟, 2], Subscript[𝒟, 2]}]}}];
Wolfram Language code: BirnbaumImportance[ℛ, t]

寿命の初期に待機成分 の信頼性を変えるとより大きな影響が出る：

Wolfram Language code: Plot[Evaluate[%], {t, 0, 6}, Filling -> Axis]

部分系の重要性尺度を得るために系を段階を追ってモデル化する：

Wolfram Language code: ℛsub = ReliabilityDistribution[x∨y, {{x, ExponentialDistribution[1]}, {y, ExponentialDistribution[1]}}];
Wolfram Language code: ℛ = ReliabilityDistribution[z∧r, {{z, ExponentialDistribution[1]}, {r, ℛsub}}];
Wolfram Language code: bi = BirnbaumImportance[ℛ, t]

時間に沿って重要度をプロットする：

Wolfram Language code: Plot[Evaluate@MapThread[Tooltip, {bi, {z, r}}], {t, 0, 4}]

FailureDistributionモデル  (8)

任意の2つの基本事象で頂上事象が起る：

Wolfram Language code: ℱ = FailureDistribution[x∨y, {{x, ExponentialDistribution[λ]}, {y, ExponentialDistribution[λ]}}];

どちらかの事象の信頼性を変えると頂上事象の信頼性が同じように変わる：

Wolfram Language code: BirnbaumImportance[ℱ, t]

両方の基本事象が一緒に起る場合にのみ，頂上事象が起る：

Wolfram Language code: ℱ = FailureDistribution[x∧y, {{x, ExponentialDistribution[λ]}, {y, ExponentialDistribution[λ]}}];

どちらかの事象の信頼性を変えると頂上事象の信頼性が同じように変わる：

Wolfram Language code: BirnbaumImportance[ℱ, t]

基本事象の分布が等しいボーティングゲート：

Wolfram Language code: ℱ = FailureDistribution[BooleanCountingFunction[{2, 3}, {x, y, z}], {{x, ExponentialDistribution[λ]}, {y, ExponentialDistribution[λ]}, {z, ExponentialDistribution[λ]}}];

事象のいずれかの信頼性を変えると頂上事象の信頼性が同じように変わる：

Wolfram Language code: BirnbaumImportance[ℱ, t]//Simplify

AndゲートとOrゲートの両方がある単純な系：

Wolfram Language code: d = ExponentialDistribution[1];
Wolfram Language code: ℱ = FailureDistribution[x∧(y∨z), {{x, d}, {y, d}, {z, d}}];

基本事象 が最も重要である：

Wolfram Language code: bi = BirnbaumImportance[ℱ, t]

事象 の信頼性を変えると頂上事象の信頼性に最も大きい影響がある：

Wolfram Language code: Plot[Evaluate@MapThread[Tooltip, {bi, {x, y, z}}], {t, 0, 4}, PlotRange -> All]

AndゲートとOrゲートの両方がある単純な系：

Wolfram Language code: d = ExponentialDistribution[1];
Wolfram Language code: ℱ = FailureDistribution[x∨(y∧z), {{x, d}, {y, d}, {z, d}}];

重要度を計算する：

Wolfram Language code: bi = BirnbaumImportance[ℱ, t]

事象 を向上させることが頂上事象の発生防止に最も影響がある：

Wolfram Language code: Plot[Evaluate@MapThread[Tooltip, {bi, {x, y, z}}], {t, 0, 4}, PlotRange -> All]

単純な混合系におけるパラメータの変更の影響を調べる：

Wolfram Language code: {Subscript[d, 1], Subscript[d, 2], Subscript[d, 3]} = {ExponentialDistribution[1], ExponentialDistribution[1], ExponentialDistribution[λ]};
Wolfram Language code: ℱ = FailureDistribution[x∧(y∨z), {{x, Subscript[d, 1]}, {y, Subscript[d, 2]}, {z, Subscript[d, 3]}}];

重要度を計算する：

Wolfram Language code: bi = BirnbaumImportance[ℱ, t]

基本事象の一つである を悪化させることによる重要度の変化を示す：

Wolfram Language code: Table[ Plot[Evaluate@MapThread[Tooltip, {bi /. λ -> k, {x, y, z}}], {t, 0, 2}, PlotRange -> All, PlotLabel -> k] , {k, 1, 5, 2}]

任意の有効なFailureDistributionを使うことができる：

Wolfram Language code: {Subscript[𝒟, 1], Subscript[𝒟, 2]} = {ExponentialDistribution[1], ExponentialDistribution[2]};
Wolfram Language code: ℱ = FailureDistribution[x∧y, {{x, Subscript[𝒟, 1]}, {y, StandbyDistribution[Subscript[𝒟, 2], {Subscript[𝒟, 2], Subscript[𝒟, 2]}]}}];
Wolfram Language code: bi = BirnbaumImportance[ℱ, t]

寿命の初期に待機成分 の信頼性を変えることがより大きく影響する：

Wolfram Language code: Plot[bi, {t, 0, 5}]

部分系の重要性尺度を得るために段階を追って系をモデル化する：

Wolfram Language code: ℱsub = FailureDistribution[x∨y, {{x, ExponentialDistribution[1]}, {y, ExponentialDistribution[1]}}];
Wolfram Language code: ℱ = ReliabilityDistribution[z∧f, {{z, ExponentialDistribution[1]}, {f, ℱsub}}];
Wolfram Language code: bi = BirnbaumImportance[ℱ, t]

時間に沿って重要度をプロットする：

Wolfram Language code: Plot[Evaluate@bi, {t, 0, 4}, PlotLegends -> {"z", "f"}]

アプリケーション  (5)

作業時間が3時間の系を改善するために最適な成分を探す：

Wolfram Language code: {Subscript[𝒟, 1], Subscript[𝒟, 2], Subscript[𝒟, 3], Subscript[𝒟, 4]} = {ExponentialDistribution[1], ExponentialDistribution[2], WeibullDistribution[1, 2], ErlangDistribution[1, 2]};
Wolfram Language code: ℛ = ReliabilityDistribution[(x∨y)∧(z∨v), {{x, Subscript[𝒟, 1]}, {y, Subscript[𝒟, 2]}, {z, Subscript[𝒟, 3]}, {v, Subscript[𝒟, 4]}}];
Wolfram Language code: bi = BirnbaumImportance[ℛ, t]//FunctionExpand//Simplify

時間に沿って重要度を示す：

Wolfram Language code: Plot[Evaluate@MapThread[Tooltip, {bi, {x, y, z, v}}], {t, 0, 4}, Filling -> Axis, PlotRange -> {0, 1}]

作業時間が3時間のとき，成分xを改善すると系全体が最も大きく改善される：

Wolfram Language code: PieChart[bi /. t -> 3//N, ChartLabels -> {x, y, z, v}]

1つの成分が直列接続で2つの成分が並列接続の単純な系を調べる．Birnbaum重要性尺度に照らしてどの成分が最も重要であるかを決定する：

Wolfram Language code: lifetimes = {{x, ExponentialDistribution[10.0]}, {y, ExponentialDistribution[1.2]}, {z, ExponentialDistribution[1]}};
Wolfram Language code: ℛ = ReliabilityDistribution[(x∨y)∧z, lifetimes];
Wolfram Language code: bi = BirnbaumImportance[ℛ, t];
Wolfram Language code: Plot[bi, {t, 0, 6}, Filling -> Axis, PlotRange -> {0, 1}]

寿命全体に渡って累積Birnbaum重要度を求める：

Wolfram Language code: Integrate[bi, {t, 0, ∞}]

累積Birnbaum重要度は故障までの平均時間の違いを与える：

Wolfram Language code: ℛ1 = ReliabilityDistribution[(True∨y)∧z, lifetimes];
Wolfram Language code: ℛ2 = ReliabilityDistribution[(False∨y)∧z, lifetimes];
Wolfram Language code: Mean[ℛ1] - Mean[ℛ2]

以下の系を仮定する：

Wolfram Language code: {Subscript[𝒟, 1], Subscript[𝒟, 2], Subscript[𝒟, 3]} = {ExponentialDistribution[1], ExponentialDistribution[1], ExponentialDistribution[1]};
Wolfram Language code: ℛ = ReliabilityDistribution[x∧(y∨z), {{x, Subscript[𝒟, 1]}, {y, Subscript[𝒟, 2]}, {z, Subscript[𝒟, 3]}}];

任意の成分 の信頼性を向上させるための費用は で与えられる：

Wolfram Language code: {Subscript[α, x], Subscript[α, y], Subscript[α, z]} = {2t, 2t, t};

時間 で最も少ない費用で最高のゲインを得るためにはどの成分を向上させるのがよいかを求める：

Wolfram Language code: BirnbaumImportance[ℛ, t] / {Subscript[α, x], Subscript[α, y], Subscript[α, z]}

成分 を向上させるのが最もよい．成分 より成分 を向上させる方が対費用効果が高い：

Wolfram Language code: Plot[Evaluate@MapThread[Tooltip, {%, {x, y, z}}], {t, 0, 1}]

町中のある2点が水道管網 を介して繋がれている．水の供給のために管理が最も重要なパイプを求める：

Wolfram Language code: dists = ExponentialDistribution[1 / #]& /@ {0.91, 0.33, 0.45, 0.55, 0.1, 0.77};
Wolfram Language code: sys = (Subscript[x, 1]∧Subscript[x, 2])∨(Subscript[x, 1]∧Subscript[x, 5]∧Subscript[x, 6])∨(Subscript[x, 3]∧Subscript[x, 6])∨(Subscript[x, 4]∧Subscript[x, 6])∨(Subscript[x, 3]∧Subscript[x, 5]∧Subscript[x, 2])∨(Subscript[x, 4]∧Subscript[x, 5]∧Subscript[x, 2]);
Wolfram Language code: ℛ = ReliabilityDistribution[sys, Transpose[{Array[Subscript[x, #]&, 6], dists}]];
Wolfram Language code: bi = BirnbaumImportance[ℛ, t];
Wolfram Language code: Plot[Evaluate@bi, {t, 0, 3}, PlotRange -> All]

5つのポンプが付いた原油のパイプライン系がある．この系は，連続する2つのパイプが故障すると動かなくなる．最も大切なパイプを求める：

Wolfram Language code: ℛ = ReliabilityDistribution[BooleanConsecutiveFunction[{2}, {5}, {"Linear"}][Array[Subscript[x, #]&, 5]], Array[{Subscript[x, #], ExponentialDistribution[1]}&, 5]];
Wolfram Language code: bi = BirnbaumImportance[ℛ, t];
Wolfram Language code: Plot[Evaluate@bi, {t, 0, 5}]

特性と関係  (6)

BirnbaumImportanceは確率によって定義することができる：

Wolfram Language code: {Subscript[𝒟, 1], Subscript[𝒟, 2], Subscript[𝒟, 3], Subscript[𝒟, 4]} = {ExponentialDistribution[Subscript[λ, 1]], ExponentialDistribution[Subscript[λ, 2]], ExponentialDistribution[Subscript[λ, 3]], ExponentialDistribution[Subscript[λ, 4]]};
Wolfram Language code: ℛ = ReliabilityDistribution[(x∧y)∨(z∧v), {{x, Subscript[𝒟, 1]}, {y, Subscript[𝒟, 2]}, {z, Subscript[𝒟, 3]}, {v, Subscript[𝒟, 4]}}];
Wolfram Language code: BirnbaumImportance[ℛ, t]

これは完全な成分と故障した成分による系の信頼性の違いである：

Wolfram Language code: Table[Probability[τ > t, τ(ℛ /. c -> True)] - Probability[τ > t, τ(ℛ /. c -> False)], {c, ℛ[[2, All, 1]]}]//Refine[#, t > 0]&
Wolfram Language code: FullSimplify[%% - %]

CriticalityFailureImportanceはBirnbaumImportanceと関係がある：

Wolfram Language code: {𝒟1, 𝒟2} = {ExponentialDistribution[λ], ExponentialDistribution[μ]};
Wolfram Language code: ℛ = ReliabilityDistribution[x∧y, {{x, 𝒟1}, {y, 𝒟2}}];

成分の信頼性の欠如を系の信頼性の欠如で割った成分の重み：

Wolfram Language code: cw = Table[CDF[𝒟, t] / CDF[ℛ, t], {𝒟, {𝒟1, 𝒟2}}]//Refine[#, t > 0]&
Wolfram Language code: BirnbaumImportance[ℛ, t]cw//Simplify

CriticalityFailureImportanceの定義と比較する：

Wolfram Language code: FullSimplify[% - CriticalityFailureImportance[ℛ, t]]

ImprovementImportanceはBirnbaumImportanceと関係がある：

Wolfram Language code: {𝒟1, 𝒟2} = {ExponentialDistribution[λ], ExponentialDistribution[μ]};
Wolfram Language code: ℛ = ReliabilityDistribution[x∨y, {{x, 𝒟1}, {y, 𝒟2}}];

成分の信頼性の欠如：

Wolfram Language code: ur = Table[CDF[𝒟, t], {𝒟, {𝒟1, 𝒟2}}]//Refine[#, t > 0]&

重要度の向上は成分の信頼性の欠如にBirnbaum重要度を掛けたものである：

Wolfram Language code: BirnbaumImportance[ℛ, t] ur//Simplify

ImprovementImportanceの定義と比較する：

Wolfram Language code: FullSimplify[% - ImprovementImportance[ℛ, t]]

成分のBirnbaum重要度はそれ自身の寿命分布から独立している：

Wolfram Language code: ℛ1 = ReliabilityDistribution[x∨y, {{x, ExponentialDistribution[λ]}, {y, ExponentialDistribution[2]}}];
Wolfram Language code: ℛ2 = ReliabilityDistribution[x∨y, {{x, WeibullDistribution[μ, 2]}, {y, ExponentialDistribution[2]}}];
Wolfram Language code: First /@ {BirnbaumImportance[ℛ1, t], BirnbaumImportance[ℛ2, t]}

無関係な成分の重要度は0である：

Wolfram Language code: 𝒟 = ExponentialDistribution[λ];
Wolfram Language code: BirnbaumImportance[ReliabilityDistribution[x∧y, {{x, 𝒟}, {y, 𝒟}, {z, 𝒟}}], t]

StructuralImportanceは成分の信頼性がのBirnbaum重要度である：

Wolfram Language code: bexpr = y∧z;
Wolfram Language code: ℛ = ReliabilityDistribution[bexpr, {{y, BernoulliDistribution[1 / 2]}, {z, BernoulliDistribution[1 / 2]}}];
Wolfram Language code: Refine[BirnbaumImportance[ℛ, t], 0 < t < 1]
Wolfram Language code: StructuralImportance[bexpr, BooleanVariables[bexpr]]
Wolfram Language code: FullSimplify[%% - %]
Wolfram Research (2012), BirnbaumImportance, Wolfram言語関数， https://reference.wolfram.com/language/ref/BirnbaumImportance.html.

テキスト

Wolfram Research (2012), BirnbaumImportance, Wolfram言語関数， https://reference.wolfram.com/language/ref/BirnbaumImportance.html.

CMS

Wolfram Language. 2012. "BirnbaumImportance." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/BirnbaumImportance.html.

APA

Wolfram Language. (2012). BirnbaumImportance. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/BirnbaumImportance.html

BibTeX

@misc{reference.wolfram_2026_birnbaumimportance, author="Wolfram Research", title="{BirnbaumImportance}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/BirnbaumImportance.html}", note=[Accessed: 18-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_birnbaumimportance, organization={Wolfram Research}, title={BirnbaumImportance}, year={2012}, url={https://reference.wolfram.com/language/ref/BirnbaumImportance.html}, note=[Accessed: 18-August-2026]}