WOLFRAM

Wolfram 语言与系统参考资料中心

BirnbaumImportance[rdist,t]

给出 ReliabilityDistribution rdist 中所有组分在时刻 t 的 Birnbaum 重要度.

BirnbaumImportance[fdist,t]

给出 FailureDistribution fdist 中所有组分在时刻 t 的 Birnbaum 重要度.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
可靠性分布模型  
失效分布模型  
应用  
属性和关系  
参见
相关指南
历史
按以下格式引用：

BirnbaumImportance

BirnbaumImportance[rdist,t]

给出 ReliabilityDistribution rdist 中所有组分在时刻 t 的 Birnbaum 重要度.

BirnbaumImportance[fdist,t]

给出 FailureDistribution fdist 中所有组分在时刻 t 的 Birnbaum 重要度.

更多信息

  • BirnbaumImportance 也称为可靠性重要度.
  • Birnbaum 重要度通过将故障组分 用完美组分 替换使可靠性得以改善.
  • 组分 在时刻 的 Birnbaum 重要度为 ，其中 是已知第 个组分完美的条件下系统工作的概率， 是第 个组分出现故障的条件下系统工作的概率.
  • 返回的结果按照 rdist 或 fdist 中所列分布的次序给出.

范例

打开所有单元 关闭所有单元

基本范例  (3)

两个寿命分布不同的组分串联：

Wolfram Language code: ℛ = ReliabilityDistribution[x∧y, {{x, ExponentialDistribution[1]}, {y, ExponentialDistribution[2]}}];

结果按照 ReliabilityDistribution 中的分布列表次序给出：

Wolfram Language code: {Subscript[bi, x], Subscript[bi, y]} = BirnbaumImportance[ℛ, t]
Wolfram Language code: Plot[{Subscript[bi, x], Subscript[bi, y]}, {t, 0, 2}, Filling -> Axis, AxesOrigin -> {0, 0}]

两个寿命分布不同的组分并联：

Wolfram Language code: ℛ = ReliabilityDistribution[x∨y, {{x, ExponentialDistribution[Subscript[λ, 1]]}, {y, ExponentialDistribution[Subscript[λ, 2]]}}];
Wolfram Language code: BirnbaumImportance[ℛ, t]

使用基于故障树的模型定义系统：

Wolfram Language code: ℱ = FailureDistribution[x∧y, {{x, WeibullDistribution[2, 3]}, {y, WeibullDistribution[4, 5]}}];
Wolfram Language code: BirnbaumImportance[ℱ, t]
Wolfram Language code: Plot[Evaluate[%], {t, 0, 7}, Filling -> Axis]

范围  (17)

可靠性分布模型  (9)

两个寿命分布相同的组分并联：

Wolfram Language code: ℛ = ReliabilityDistribution[x∨y, {{x, ExponentialDistribution[λ]}, {y, ExponentialDistribution[λ]}}];

任何一个组分的可靠性变化将导致相同的系统可靠性变化：

Wolfram Language code: BirnbaumImportance[ℛ, t]

两个寿命分布相同的组分串联：

Wolfram Language code: ℛ = ReliabilityDistribution[x∧y, {{x, ExponentialDistribution[λ]}, {y, ExponentialDistribution[λ]}}];

任何一个组分的可靠性变化将导致相同的系统可靠性变化：

Wolfram Language code: BirnbaumImportance[ℛ, t]

一个具有相同寿命分布的系统，其中三个组分中的两个需要工作：

Wolfram Language code: ℛ = ReliabilityDistribution[BooleanCountingFunction[{2, 3}, {x, y, z}], {{x, ExponentialDistribution[λ]}, {y, ExponentialDistribution[λ]}, {z, ExponentialDistribution[λ]}}];

重要度相同：

Wolfram Language code: BirnbaumImportance[ℛ, t]//Simplify

一个具有相同寿命分布的简单混合系统：

Wolfram Language code: d = ExponentialDistribution[1];
Wolfram Language code: ℛ = ReliabilityDistribution[x∧(y∨z), {{x, d}, {y, d}, {z, d}}];

计算重要度：

Wolfram Language code: bi = BirnbaumImportance[ℛ, t]

改变组分 的可靠性对系统的可靠性影响最大：

Wolfram Language code: Plot[Evaluate@MapThread[Tooltip, {bi, {x, y, z}}], {t, 0, 4}, PlotRange -> All]

串联再与一个组分并联的系统：

Wolfram Language code: d = ExponentialDistribution[1];
Wolfram Language code: ℛ = ReliabilityDistribution[x∨(y∧z), {{x, d}, {y, d}, {z, d}}];

计算重要度：

Wolfram Language code: bi = BirnbaumImportance[ℛ, t]

改善 组分对系统的可靠性影响最大：

Wolfram Language code: Plot[Evaluate@MapThread[Tooltip, {bi, {x, y, z}}], {t, 0, 4}]

研究简单混合系统中参数变化的影响：

Wolfram Language code: {Subscript[d, 1], Subscript[d, 2], Subscript[d, 3]} = {ExponentialDistribution[1], ExponentialDistribution[1], ExponentialDistribution[λ]};
Wolfram Language code: ℛ = ReliabilityDistribution[x∧(y∨z), {{x, Subscript[d, 1]}, {y, Subscript[d, 2]}, {z, Subscript[d, 3]}}];

计算重要度：

Wolfram Language code: bi = BirnbaumImportance[ℛ, t]

当并联组件之一 恶化时，显示重要度的变化：

Wolfram Language code: Table[ Plot[Evaluate@MapThread[Tooltip, {bi /. λ -> k, {x, y, z}}], {t, 0, 4}, PlotRange -> All, PlotLabel -> k] , {k, 1, 5, 2}]

具有不同分布的一个组分与另外两个组分并联：

Wolfram Language code: dists = {{x, ExponentialDistribution[1]}, {y, ExponentialDistribution[2]}, {z, ExponentialDistribution[1]}};
Wolfram Language code: ℛ = ReliabilityDistribution[x∧(y∨z), dists];

在一个具体时间点处，度量作为精确结果的重要度：

Wolfram Language code: BirnbaumImportance[ℛ, 3 / 2]

作为机器精度结果：

Wolfram Language code: BirnbaumImportance[ℛ, 1.5]

作为符号式表达式：

Wolfram Language code: BirnbaumImportance[ℛ, t]

可以使用任何有效的 ReliabilityDistribution：

Wolfram Language code: {Subscript[𝒟, 1], Subscript[𝒟, 2]} = {ExponentialDistribution[1], ExponentialDistribution[2]};
Wolfram Language code: ℛ = ReliabilityDistribution[x∨y, {{x, Subscript[𝒟, 1]}, {y, StandbyDistribution[Subscript[𝒟, 2], {Subscript[𝒟, 2], Subscript[𝒟, 2]}]}}];
Wolfram Language code: BirnbaumImportance[ℛ, t]

在寿命初期，改变待机组分 的可靠性，将有更多的影响：

Wolfram Language code: Plot[Evaluate[%], {t, 0, 6}, Filling -> Axis]

分步模拟系统，从而度量子系统的重要度：

Wolfram Language code: ℛsub = ReliabilityDistribution[x∨y, {{x, ExponentialDistribution[1]}, {y, ExponentialDistribution[1]}}];
Wolfram Language code: ℛ = ReliabilityDistribution[z∧r, {{z, ExponentialDistribution[1]}, {r, ℛsub}}];
Wolfram Language code: bi = BirnbaumImportance[ℛ, t]

绘制重要度与时间的关系曲线：

Wolfram Language code: Plot[Evaluate@MapThread[Tooltip, {bi, {z, r}}], {t, 0, 4}]

失效分布模型  (8)

任何两个基本事件导致顶事件：

Wolfram Language code: ℱ = FailureDistribution[x∨y, {{x, ExponentialDistribution[λ]}, {y, ExponentialDistribution[λ]}}];

对于任一事件的可靠性变化将导致顶事件可靠性的相同变化：

Wolfram Language code: BirnbaumImportance[ℱ, t]

仅在两个基本事件一起时导致顶事件：

Wolfram Language code: ℱ = FailureDistribution[x∧y, {{x, ExponentialDistribution[λ]}, {y, ExponentialDistribution[λ]}}];

对于任一事件的可靠性变化将导致顶事件可靠性的相同变化：

Wolfram Language code: BirnbaumImportance[ℱ, t]

表决门，基本事件具有相同的分布：

Wolfram Language code: ℱ = FailureDistribution[BooleanCountingFunction[{2, 3}, {x, y, z}], {{x, ExponentialDistribution[λ]}, {y, ExponentialDistribution[λ]}, {z, ExponentialDistribution[λ]}}];

对于任一事件的可靠性变化将导致顶事件可靠性的相同变化：

Wolfram Language code: BirnbaumImportance[ℱ, t]//Simplify

同时具有 And 和 Or 门的简单系统：

Wolfram Language code: d = ExponentialDistribution[1];
Wolfram Language code: ℱ = FailureDistribution[x∧(y∨z), {{x, d}, {y, d}, {z, d}}];

基本事件 最重要：

Wolfram Language code: bi = BirnbaumImportance[ℱ, t]

改变事件 的可靠性对顶事件的可靠性影响最大：

Wolfram Language code: Plot[Evaluate@MapThread[Tooltip, {bi, {x, y, z}}], {t, 0, 4}, PlotRange -> All]

同时具有 And 和 Or 门的简单系统：

Wolfram Language code: d = ExponentialDistribution[1];
Wolfram Language code: ℱ = FailureDistribution[x∨(y∧z), {{x, d}, {y, d}, {z, d}}];

计算重要度：

Wolfram Language code: bi = BirnbaumImportance[ℱ, t]

改进事件 对防止顶事件的发生影响最大：

Wolfram Language code: Plot[Evaluate@MapThread[Tooltip, {bi, {x, y, z}}], {t, 0, 4}, PlotRange -> All]

研究简单混合系统中参数变化的影响：

Wolfram Language code: {Subscript[d, 1], Subscript[d, 2], Subscript[d, 3]} = {ExponentialDistribution[1], ExponentialDistribution[1], ExponentialDistribution[λ]};
Wolfram Language code: ℱ = FailureDistribution[x∧(y∨z), {{x, Subscript[d, 1]}, {y, Subscript[d, 2]}, {z, Subscript[d, 3]}}];

计算重要度：

Wolfram Language code: bi = BirnbaumImportance[ℱ, t]

当基本事件之一 恶化时，显示重要度的变化：

Wolfram Language code: Table[ Plot[Evaluate@MapThread[Tooltip, {bi /. λ -> k, {x, y, z}}], {t, 0, 2}, PlotRange -> All, PlotLabel -> k] , {k, 1, 5, 2}]

可以使用任何有效的 FailureDistribution：

Wolfram Language code: {Subscript[𝒟, 1], Subscript[𝒟, 2]} = {ExponentialDistribution[1], ExponentialDistribution[2]};
Wolfram Language code: ℱ = FailureDistribution[x∧y, {{x, Subscript[𝒟, 1]}, {y, StandbyDistribution[Subscript[𝒟, 2], {Subscript[𝒟, 2], Subscript[𝒟, 2]}]}}];
Wolfram Language code: bi = BirnbaumImportance[ℱ, t]

在寿命初期，改变待机组分 的可靠性，将有更多的影响：

Wolfram Language code: Plot[bi, {t, 0, 5}]

分步模拟系统，从而度量子系统的重要度：

Wolfram Language code: ℱsub = FailureDistribution[x∨y, {{x, ExponentialDistribution[1]}, {y, ExponentialDistribution[1]}}];
Wolfram Language code: ℱ = ReliabilityDistribution[z∧f, {{z, ExponentialDistribution[1]}, {f, ℱsub}}];
Wolfram Language code: bi = BirnbaumImportance[ℱ, t]

绘制重要度与时间的关系曲线：

Wolfram Language code: Plot[Evaluate@bi, {t, 0, 4}, PlotLegends -> {"z", "f"}]

应用  (5)

对于一个任务时间为3个小时的系统，找出哪些组分最应该改进：

Wolfram Language code: {Subscript[𝒟, 1], Subscript[𝒟, 2], Subscript[𝒟, 3], Subscript[𝒟, 4]} = {ExponentialDistribution[1], ExponentialDistribution[2], WeibullDistribution[1, 2], ErlangDistribution[1, 2]};
Wolfram Language code: ℛ = ReliabilityDistribution[(x∨y)∧(z∨v), {{x, Subscript[𝒟, 1]}, {y, Subscript[𝒟, 2]}, {z, Subscript[𝒟, 3]}, {v, Subscript[𝒟, 4]}}];
Wolfram Language code: bi = BirnbaumImportance[ℛ, t]//FunctionExpand//Simplify

绘制重要度与时间的关系曲线：

Wolfram Language code: Plot[Evaluate@MapThread[Tooltip, {bi, {x, y, z, v}}], {t, 0, 4}, Filling -> Axis, PlotRange -> {0, 1}]

对于一个任务时间为3个小时的系统，改进组分 x 将使系统得到最大改进：

Wolfram Language code: PieChart[bi /. t -> 3//N, ChartLabels -> {x, y, z, v}]

研究由一个组分串联且两个组分并联的系统. 根据 Birnbaum 重要度确定最重要的组分:

Wolfram Language code: lifetimes = {{x, ExponentialDistribution[10.0]}, {y, ExponentialDistribution[1.2]}, {z, ExponentialDistribution[1]}};
Wolfram Language code: ℛ = ReliabilityDistribution[(x∨y)∧z, lifetimes];
Wolfram Language code: bi = BirnbaumImportance[ℛ, t];
Wolfram Language code: Plot[bi, {t, 0, 6}, Filling -> Axis, PlotRange -> {0, 1}]

求在整个寿命期间的累积 Birnbaum 重要度：

Wolfram Language code: Integrate[bi, {t, 0, ∞}]

累积 Birnbaum 重要度给出距离故障的平均时间之差：

Wolfram Language code: ℛ1 = ReliabilityDistribution[(True∨y)∧z, lifetimes];
Wolfram Language code: ℛ2 = ReliabilityDistribution[(False∨y)∧z, lifetimes];
Wolfram Language code: Mean[ℛ1] - Mean[ℛ2]

假定下述系统：

Wolfram Language code: {Subscript[𝒟, 1], Subscript[𝒟, 2], Subscript[𝒟, 3]} = {ExponentialDistribution[1], ExponentialDistribution[1], ExponentialDistribution[1]};
Wolfram Language code: ℛ = ReliabilityDistribution[x∧(y∨z), {{x, Subscript[𝒟, 1]}, {y, Subscript[𝒟, 2]}, {z, Subscript[𝒟, 3]}}];

增加任意组分 的可靠性所需的成本由 给出：

Wolfram Language code: {Subscript[α, x], Subscript[α, y], Subscript[α, z]} = {2t, 2t, t};

求在 时刻，改进哪一组分能够使得收益最高且成本最低：

Wolfram Language code: BirnbaumImportance[ℛ, t] / {Subscript[α, x], Subscript[α, y], Subscript[α, z]}

改进组分 效果最佳. 改善组分 比改善组分 更符合成本效益：

Wolfram Language code: Plot[Evaluate@MapThread[Tooltip, {%, {x, y, z}}], {t, 0, 1}]

城市两点之间由一个水管 组成的网络相连. 求对保证供水最关键的管道：

Wolfram Language code: dists = ExponentialDistribution[1 / #]& /@ {0.91, 0.33, 0.45, 0.55, 0.1, 0.77};
Wolfram Language code: sys = (Subscript[x, 1]∧Subscript[x, 2])∨(Subscript[x, 1]∧Subscript[x, 5]∧Subscript[x, 6])∨(Subscript[x, 3]∧Subscript[x, 6])∨(Subscript[x, 4]∧Subscript[x, 6])∨(Subscript[x, 3]∧Subscript[x, 5]∧Subscript[x, 2])∨(Subscript[x, 4]∧Subscript[x, 5]∧Subscript[x, 2]);
Wolfram Language code: ℛ = ReliabilityDistribution[sys, Transpose[{Array[Subscript[x, #]&, 6], dists}]];
Wolfram Language code: bi = BirnbaumImportance[ℛ, t];
Wolfram Language code: Plot[Evaluate@bi, {t, 0, 3}, PlotRange -> All]

对于五个泵的石油管道系统，如果不多于两个连续泵出现故障，则管道系统将正常工作. 找到最重要的泵：

Wolfram Language code: ℛ = ReliabilityDistribution[BooleanConsecutiveFunction[{2}, {5}, {"Linear"}][Array[Subscript[x, #]&, 5]], Array[{Subscript[x, #], ExponentialDistribution[1]}&, 5]];
Wolfram Language code: bi = BirnbaumImportance[ℛ, t];
Wolfram Language code: Plot[Evaluate@bi, {t, 0, 5}]

属性和关系  (6)

BirnbaumImportance 可以用概率的形式定义：

Wolfram Language code: {Subscript[𝒟, 1], Subscript[𝒟, 2], Subscript[𝒟, 3], Subscript[𝒟, 4]} = {ExponentialDistribution[Subscript[λ, 1]], ExponentialDistribution[Subscript[λ, 2]], ExponentialDistribution[Subscript[λ, 3]], ExponentialDistribution[Subscript[λ, 4]]};
Wolfram Language code: ℛ = ReliabilityDistribution[(x∧y)∨(z∧v), {{x, Subscript[𝒟, 1]}, {y, Subscript[𝒟, 2]}, {z, Subscript[𝒟, 3]}, {v, Subscript[𝒟, 4]}}];
Wolfram Language code: BirnbaumImportance[ℛ, t]

它是完美组分和故障组分的系统可靠性之差：

Wolfram Language code: Table[Probability[τ > t, τ(ℛ /. c -> True)] - Probability[τ > t, τ(ℛ /. c -> False)], {c, ℛ[[2, All, 1]]}]//Refine[#, t > 0]&
Wolfram Language code: FullSimplify[%% - %]

CriticalityFailureImportance 与 BirnbaumImportance 有关：

Wolfram Language code: {𝒟1, 𝒟2} = {ExponentialDistribution[λ], ExponentialDistribution[μ]};
Wolfram Language code: ℛ = ReliabilityDistribution[x∧y, {{x, 𝒟1}, {y, 𝒟2}}];

组分权重是组分的不可靠性处以系统的不可靠性：

Wolfram Language code: cw = Table[CDF[𝒟, t] / CDF[ℛ, t], {𝒟, {𝒟1, 𝒟2}}]//Refine[#, t > 0]&
Wolfram Language code: BirnbaumImportance[ℛ, t]cw//Simplify

与 CriticalityFailureImportance 的定义比较：

Wolfram Language code: FullSimplify[% - CriticalityFailureImportance[ℛ, t]]

ImprovementImportance 与 BirnbaumImportance 有关：

Wolfram Language code: {𝒟1, 𝒟2} = {ExponentialDistribution[λ], ExponentialDistribution[μ]};
Wolfram Language code: ℛ = ReliabilityDistribution[x∨y, {{x, 𝒟1}, {y, 𝒟2}}];

组分的不可靠性：

Wolfram Language code: ur = Table[CDF[𝒟, t], {𝒟, {𝒟1, 𝒟2}}]//Refine[#, t > 0]&

改进重要度是组分不可靠性乘以 Birnbaum 重要度：

Wolfram Language code: BirnbaumImportance[ℛ, t] ur//Simplify

与 ImprovementImportance 的定义比较：

Wolfram Language code: FullSimplify[% - ImprovementImportance[ℛ, t]]

组分的 Birnbaum 重要度与它自己的寿命分布无关：

Wolfram Language code: ℛ1 = ReliabilityDistribution[x∨y, {{x, ExponentialDistribution[λ]}, {y, ExponentialDistribution[2]}}];
Wolfram Language code: ℛ2 = ReliabilityDistribution[x∨y, {{x, WeibullDistribution[μ, 2]}, {y, ExponentialDistribution[2]}}];
Wolfram Language code: First /@ {BirnbaumImportance[ℛ1, t], BirnbaumImportance[ℛ2, t]}

不相关组分的重要度为 0：

Wolfram Language code: 𝒟 = ExponentialDistribution[λ];
Wolfram Language code: BirnbaumImportance[ReliabilityDistribution[x∧y, {{x, 𝒟}, {y, 𝒟}, {z, 𝒟}}], t]

StructuralImportance 是组分可靠性为 的 Birnbaum 重要度：

Wolfram Language code: bexpr = y∧z;
Wolfram Language code: ℛ = ReliabilityDistribution[bexpr, {{y, BernoulliDistribution[1 / 2]}, {z, BernoulliDistribution[1 / 2]}}];
Wolfram Language code: Refine[BirnbaumImportance[ℛ, t], 0 < t < 1]
Wolfram Language code: StructuralImportance[bexpr, BooleanVariables[bexpr]]
Wolfram Language code: FullSimplify[%% - %]
Wolfram Research (2012)，BirnbaumImportance，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BirnbaumImportance.html.

文本

Wolfram Research (2012)，BirnbaumImportance，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BirnbaumImportance.html.

CMS

Wolfram 语言. 2012. "BirnbaumImportance." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/BirnbaumImportance.html.

APA

Wolfram 语言. (2012). BirnbaumImportance. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/BirnbaumImportance.html 年

BibTeX

@misc{reference.wolfram_2026_birnbaumimportance, author="Wolfram Research", title="{BirnbaumImportance}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/BirnbaumImportance.html}", note=[Accessed: 10-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_birnbaumimportance, organization={Wolfram Research}, title={BirnbaumImportance}, year={2012}, url={https://reference.wolfram.com/language/ref/BirnbaumImportance.html}, note=[Accessed: 10-August-2026]}