WOLFRAM

Wolfram 语言与系统参考资料中心

BiweightLocation[list]

给出 list 中元素的双权位置估计量的值.

BiweightLocation[list,c]

给出缩放参数为 c 的双权位置估计量的值.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
选项  
MaxIterations  
Method  
应用  
属性和关系  
巧妙范例  
参见
相关指南
历史
按以下格式引用：

BiweightLocation

BiweightLocation[list]

给出 list 中元素的双权位置估计量的值.

BiweightLocation[list,c]

给出缩放参数为 c 的双权位置估计量的值.

更多信息和选项

范例

打开所有单元 关闭所有单元

基本范例  (4)

列表的 BiweightLocation：

Wolfram Language code: BiweightLocation[{6.5, 3.8, 6.6, 5.7, 6.0, 6.4, 5.3}]

矩阵的列的 BiweightLocation：

Wolfram Language code: BiweightLocation[{{1., 2.}, {4., 8.}, {5., 3.}, {2., 15.}}]

缩放参数为 7 时列表的 BiweightLocation ：

Wolfram Language code: BiweightLocation[{1., 2., 3., 2., 1.}, 7]

日期列表的 BiweightLocation：

Wolfram Language code: RandomDate[4]
Wolfram Language code: BiweightLocation[%]

范围  (8)

同样的输入，不同的精度：

Wolfram Language code: BiweightLocation[N[{1, 2, 3, 4, 9, 10}]]
Wolfram Language code: BiweightLocation[N[{1, 2, 3, 4, 9, 10}, 20]]

不同缩放参数时的双权位置：

Wolfram Language code: BiweightLocation[{1.2, 3.8, 4.2, -0.5, -5.2}, 10]
Wolfram Language code: BiweightLocation[{1.2, 3.8, 4.2, -0.5, -5.2}, 100]

矩阵的双权位置给出的是按列估计的结果：

Wolfram Language code: BiweightLocation[RandomReal[1, {50, 3}]]

一个大数组的双权位置：

Wolfram Language code: BiweightLocation[RandomReal[1, 10 ^ 6]]
Wolfram Language code: BiweightLocation[RandomReal[1, {10 ^ 6, 3}]]

求 TimeSeries 的双权位置：

Wolfram Language code: ts = TemporalData[TimeSeries, {{{3, 8, 4, 11, 9, 2}}, {{{1, 3, 5, 7, 8, 10}}}, 1, {"Continuous", 1}, {"Discrete", 1}, 1, {ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}}}, False, 10.1];
Wolfram Language code: BiweightLocation[ts]

双权位置只取决于值：

Wolfram Language code: BiweightLocation[ts["Values"]]

可将双权位置用于含有量的数据：

Wolfram Language code: data = Quantity[RandomReal[1, 6], "Meters"]
Wolfram Language code: BiweightLocation[data]

计算日期的双加权位置：

Wolfram Language code: dates = WolframLanguageData[All, "DateIntroduced"];
Wolfram Language code: DateHistogram[dates]
Wolfram Language code: BiweightLocation[dates]

计算时间的双加权位置：

Wolfram Language code: RandomTime[3]
Wolfram Language code: BiweightLocation[%]

不同时区规格的时间列表：

Wolfram Language code: {TimeObject[{12}, TimeZone -> 0], TimeObject[{12}, TimeZone -> 2], TimeObject[{12}, TimeZone -> "Asia/Tokyo"]}
Wolfram Language code: BiweightLocation[%]

选项  (2)

MaxIterations  (1)

BiweightLocation 的值是迭代式算出的. 限制计算时迭代的次数：

Wolfram Language code: BiweightLocation[{1.2, -3., 4.1, 2.9, 6., -2.}, MaxIterations -> 5]
Wolfram Language code: BiweightLocation[{1.2, -3., 4.1, 2.9, 6., -2.}, MaxIterations -> 10]

Method  (1)

调整 BiweightLocation 计算中的初值：

Wolfram Language code: BiweightLocation[{1.2, -3., 4.1, 2.9, 6., -2.}, Method -> {"InitialPoint" -> 1.5}]

选择好一点的初值，限制迭代的次数：

Wolfram Language code: BiweightLocation[{1.2, -3., 4.1, 2.9, 6., -2.}, Method -> {"InitialPoint" -> 1.56702}, MaxIterations -> 5]
Wolfram Language code: BiweightLocation[{1.2, -3., 4.1, 2.9, 6., -2.}, MaxIterations -> 5]

应用  (3)

当异常值出现时，对位置进行稳健估计：

Wolfram Language code: BiweightLocation[{1, 5, 2, 6, 10, 10 ^ 5, 5, 4, -200, 5}, .1]//N

极值对 Mean 的影响较大：

Wolfram Language code: Mean[{1, 5, 2, 6, 10, 10 ^ 5, 5, 4, -200, 5}]//N

考虑来自高斯混合分布的数据：

Wolfram Language code: dist = MixtureDistribution[{0.98, 0.02}, {BinormalDistribution[0], BinormalDistribution[{0, 0}, {1000, 1000}, 0.5]}]; BlockRandom[SeedRandom[1]; data = RandomVariate[dist, 10 ^ 3];]
Wolfram Language code: Histogram3D[data, PlotTheme -> "Detailed"]

用 Mean 估计中心：

Wolfram Language code: Mean[data]

对于非高斯分布数据，样本均值估计量有较大的展布 (spread). 估计量的标准偏差为：

Wolfram Language code: StandardDeviation[dist] / Sqrt[Length[data]]

用 BiweightLocation 来估计中心：

Wolfram Language code: BiweightLocation[data]

用自助法评估双权位置估计量的展布：

Wolfram Language code: StandardDeviation[res = Table[BiweightLocation[RandomChoice[data, 10 ^ 3]], {10 ^ 3}]]

仿真带有重尾测量噪声的轨迹：

Wolfram Language code: n[] := RandomVariate[CauchyDistribution[0, 1.2]] f[] := {u Cos[u] + n[], u Sin[u] + n[]}; data = Table[f[], {u, 0, 6π, 1 / 100}];

底层信号和带有噪声的仿真路径：

Wolfram Language code: {ParametricPlot[{u Cos[u], u Sin[u]}, {u, 0, 6π}], pd = ListPlot[data, AspectRatio -> 1]}

用移动 BiweightLocation 平滑轨迹：

Wolfram Language code: td = TimeSeries[data, {0., 6π}, ValueDimensions -> 2];
Wolfram Language code: smooth[r_] := MovingMap[BiweightLocation, td, {Quantity[r, "Events"], Center}]

增加区块大小可以使轨迹更平滑：

Wolfram Language code: Quiet@Table[ParametricPlot[Evaluate[smooth[r]["PathFunction"][t]], {t, 0, 6π}], {r, {25, 50, 100}}]

属性和关系  (3)

计算样本的双权位置：

Wolfram Language code: data = {-1000, 3, 10, 20, 1, -3, 5, 0, 6, 1000};
Wolfram Language code: x0 = BiweightLocation[data]

区间 之外的值对统计量没有影响. 这里 是双权位置的值， 是关于 的绝对中位差. 是缩放参数，默认值为 6：

Wolfram Language code: δ = Median[Abs[data - x0]]

计算双权位置所用加权函数 w(x) 的形状：

Wolfram Language code: Plot[Max[1 - ((x - x0) / (6 δ)) ^ 2, 0] ^ 2, {x, -60, 70}]

把样本中的最小值和最大值乘以 2，再次计算双权位置：

Wolfram Language code: data[[{1, -1}]] *= 2;
Wolfram Language code: nx0 = BiweightLocation[data]
Wolfram Language code: x0 == nx0

对于正态分布的样本，BiweightLocation 和 Mean 几乎相等：

Wolfram Language code: data1 = RandomVariate[NormalDistribution[1, 2], 10 ^ 5];
Wolfram Language code: Mean[data1]
Wolfram Language code: BiweightLocation[data1]

对于非正态分布的样本，如来自 CauchyDistribution 的数据，BiweightLocation 给出的中心位置的估计比 Mean 给出的要更好：

Wolfram Language code: data2 = RandomVariate[CauchyDistribution[1, 2], 10 ^ 5];
Wolfram Language code: Mean[data2]
Wolfram Language code: BiweightLocation[data2]

当 c 取较大值时，BiweightLocation 接近 Mean：

Wolfram Language code: data = RandomReal[StudentTDistribution[1], 1000];
Wolfram Language code: mean = Mean[data]
Wolfram Language code: Plot[{BiweightLocation[data, c], mean}, {c, 5, 5 10 ^ 3}, AxesLabel -> {c}, PlotRange -> All, PlotLegends -> {"biweight location", "mean"}]

巧妙范例  (2)

单变量数据的双权位置围绕均值的变化取决于缩放因子 c：

Wolfram Language code: data = RandomVariate[SkewNormalDistribution[1, .2, 2], 30]; cvals = {1 / 10, 1 / 2, 1, 3, 4, 5, 6, 8}; m = Mean[data]; loc = Table[{BiweightLocation[data, c]}, {c, cvals}];
Wolfram Language code: legend = PointLegend[Join[{"data"}, Row[{"c = ", #}]& /@ cvals], LegendLayout -> {"ReversedRow", 5}];
Wolfram Language code: NumberLinePlot[Join[{data}, loc], Epilog -> Line[{{m, 0}, {m, 9.5}}], Ticks -> {{{m, "Mean"}}, None}, PlotLegends -> legend]

双变量数据的双权位置围绕均值的变化取决于缩放因子 c：

Wolfram Language code: Manipulate[ SeedRandom[12];data = Join[RandomPoint[Disk[{0, 0}, 1], 40], {{-2, .1}, {-1.6, -.1}, {-1.5, -.3}}];Legended[Graphics[{GrayLevel[.5], PointSize[.015], Point[data], Green, PointSize[.025], Point[Mean[data]], Red, PointSize[.025], Point[BiweightLocation[data, c]]}, ImageSize -> 300], PointLegend[{Green, Red}, {"Mean", "Biweight Location"}]], {{c, 1}, .01, 20}, SaveDefinitions -> True]
Wolfram Research (2017)，BiweightLocation，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BiweightLocation.html （更新于 2024 年）.

文本

Wolfram Research (2017)，BiweightLocation，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BiweightLocation.html （更新于 2024 年）.

CMS

Wolfram 语言. 2017. "BiweightLocation." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2024. https://reference.wolfram.com/language/ref/BiweightLocation.html.

APA

Wolfram 语言. (2017). BiweightLocation. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/BiweightLocation.html 年

BibTeX

@misc{reference.wolfram_2026_biweightlocation, author="Wolfram Research", title="{BiweightLocation}", year="2024", howpublished="\url{https://reference.wolfram.com/language/ref/BiweightLocation.html}", note=[Accessed: 18-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_biweightlocation, organization={Wolfram Research}, title={BiweightLocation}, year={2024}, url={https://reference.wolfram.com/language/ref/BiweightLocation.html}, note=[Accessed: 18-August-2026]}