WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

BooleanMaxterms[k,n]

n 変数の中の k 次の最大項を表す．

BooleanMaxterms[{k1,k2,…},n]

最大項 kiの連言を表す．

BooleanMaxterms[{{u1,…,un},{v1,…},…}]

指数ベクトル ui, vi, … で与えられる最大項の連言を表す．

BooleanMaxterms[spec,{a1,a2,…}]

spec で指定される最大項関数に対応する変数 aiにおけるブール式を返す．

BooleanMaxterms[spec,{a1,a2,…},form]

form で指定される形式のブール式を返す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

BooleanMaxterms

BooleanMaxterms[k,n]

n 変数の中の k 次の最大項を表す．

BooleanMaxterms[{k1,k2,…},n]

最大項 kiの連言を表す．

BooleanMaxterms[{{u1,…,un},{v1,…},…}]

指数ベクトル ui, vi, … で与えられる最大項の連言を表す．

BooleanMaxterms[spec,{a1,a2,…}]

spec で指定される最大項関数に対応する変数 aiにおけるブール式を返す．

BooleanMaxterms[spec,{a1,a2,…},form]

form で指定される形式のブール式を返す．

詳細

例題

すべて開く すべて閉じる

例  (4)

同じ最大項を指定する等価な方法：

Wolfram Language code: BooleanMaxterms[{{True, False, True}}, {a, b, c}]
Wolfram Language code: BooleanMaxterms[{{1, 0, 1}}, {a, b, c}]
Wolfram Language code: BooleanMaxterms[{5}, {a, b, c}]

最大項の連言を指定する：

Wolfram Language code: BooleanMaxterms[{1, 3, 5}, {a, b, c}]

最大項の連言を指定する等価の方法：

Wolfram Language code: And@@Table[BooleanMaxterms[{i}, {a, b, c}], {i, {1, 3, 5}}]
Wolfram Language code: TautologyQ[Equivalent[%%, %]]

最大項の連言を表すBooleanFunctionオブジェクトを返す：

Wolfram Language code: BooleanMaxterms[{1, 3, 5}, 3]@@{a, b, c}
Wolfram Language code: BooleanMaxterms[{1, 3, 5}, {a, b, c}]
Wolfram Language code: TautologyQ[Equivalent[%%, %]]

3つの変数のすべての最大項を列挙する：

Wolfram Language code: Table[BooleanMaxterms[{i}, {a, b, c}], {i, 0, 2 ^ 3 - 1}]

スコープ  (2)

結果に異なる形式を指定する：

Wolfram Language code: BooleanMaxterms[{1, 3, 5}, {a, b, c}, "CNF"]
Wolfram Language code: BooleanMaxterms[{1, 3, 5}, {a, b, c}, "DNF"]
Wolfram Language code: BooleanMaxterms[{1, 3, 5}, {a, b, c}, "ANF"]

指数ベクトルを使って最大項の連言を指定する：

Wolfram Language code: BooleanMaxterms[{{0, 1, 1}, {1, 0, 1}, {1, 1, 0}}]
Wolfram Language code: BooleanConvert[%[a, b, c], "CNF"]

アプリケーション  (1)

∏(1,3,5)連言標準形(Clausal normal form, CNF)の式を作成する：

Wolfram Language code: BooleanMaxterms[{1, 3, 5}, {x, y, z}]

特性と関係  (4)

BooleanTableのデフォルトの順序では，指標はFalseの位置に対応する：

Wolfram Language code: BooleanTable[BooleanMaxterms[{0, 3, 5, 7}, {a, b, c}], {a, b, c}]
Wolfram Language code: Position[%, False] - 1

BooleanMaxtermsは任意のBooleanFunctionを表すことができる：

Wolfram Language code: f = BooleanMaxterms[{1, 5, 7}, 3]
Wolfram Language code: g = BooleanFunction[FromDigits[{1, 0, 1, 1, 1, 0, 1, 0}, 2], 3]
Wolfram Language code: f === g

最大項から指標へのマッピング：

Wolfram Language code: maxdex[l_, k_] := FromDigits[Table[If[MemberQ[l, i], 0, 1], {i, 0, 2 ^ k - 1}], 2]
Wolfram Language code: maxdex[{1, 5, 7}, 3]

指標から最大項へのマッピング：

Wolfram Language code: indmax[m_, k_] := Flatten@Position[IntegerDigits[m, 2, 2 ^ k], 0] - 1
Wolfram Language code: indmax[186, 3]

ビットベクトルを使う：

Wolfram Language code: With[{m = 123, k = 4}, BooleanMaxterms[Select[Range[0, 2 ^ k - 1], BitAnd[2^2 ^ k - 1 - #, m] == 0&], k] == BooleanFunction[m, k]]

BooleanMaxtermsを使った可能なすべてのブール関数をSubsetsを使って列挙する：

Wolfram Language code: BooleanMaxterms[#, {a, b}]& /@ Subsets[Range[0, 2 ^ 2 - 1]]

BooleanMintermsはBooleanMaxtermsに関連している：

Wolfram Language code: f = BooleanMinterms[{1, 3, 5}, 3]
Wolfram Language code: g = BooleanMaxterms[{1, 3, 5}, 3]
Wolfram Language code: TautologyQ[Equivalent[f[a, b, c], ¬g[¬a, ¬b, ¬c]]]
Wolfram Research (2008), BooleanMaxterms, Wolfram言語関数， https://reference.wolfram.com/language/ref/BooleanMaxterms.html.

テキスト

Wolfram Research (2008), BooleanMaxterms, Wolfram言語関数， https://reference.wolfram.com/language/ref/BooleanMaxterms.html.

CMS

Wolfram Language. 2008. "BooleanMaxterms." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/BooleanMaxterms.html.

APA

Wolfram Language. (2008). BooleanMaxterms. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/BooleanMaxterms.html

BibTeX

@misc{reference.wolfram_2026_booleanmaxterms, author="Wolfram Research", title="{BooleanMaxterms}", year="2008", howpublished="\url{https://reference.wolfram.com/language/ref/BooleanMaxterms.html}", note=[Accessed: 10-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_booleanmaxterms, organization={Wolfram Research}, title={BooleanMaxterms}, year={2008}, url={https://reference.wolfram.com/language/ref/BooleanMaxterms.html}, note=[Accessed: 10-September-2026]}