WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

BooleanMinimize[expr]

expr の表現の最も短い選言標準形を求める．

BooleanMinimize[expr,form]

expr の最も短い表現を指定形式で求める．

BooleanMinimize[expr,form,cond]

cond が真であるとき，expr と等価である最も短い式を指定形式で求める．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
最小サイズの分布  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

BooleanMinimize

BooleanMinimize[expr]

expr の表現の最も短い選言標準形を求める．

BooleanMinimize[expr,form]

expr の最も短い表現を指定形式で求める．

BooleanMinimize[expr,form,cond]

cond が真であるとき，expr と等価である最も短い式を指定形式で求める．

詳細とオプション

  • BooleanMinimize[expr,form]は常に expr と等価である式を生成する．
  • 使用可能な形式
  • "DNF","SOP"選言標準形，積の総和
    "CNF","POS"連言標準形，総和の積
    "ANF"代数標準形
    "NOR"2レベルのNorとNot
    "NAND"2レベルのNandとNot
    "AND"2レベルのAndとNot
    "OR"2レベルのOrとNot
  • 一般に，特定の形式の特定の式にはいくつかの最短表現があることがある．BooleanMinimizeはそのうちの1つを与える．
  • BooleanMinimizeは使用するメソッドの詳細を指定するMethodオプションをサポートする．

例題

すべて開く すべて閉じる

例  (2)

最小の選言標準形を求める：

Wolfram Language code: BooleanMinimize[a∧b∨¬a∧b]

選言標準形によるブールの数え上げ関数：

Wolfram Language code: BooleanCountingFunction[{2, 3}, {a, b, c, d}]

最短の選言標準形を求める：

Wolfram Language code: BooleanMinimize[%]

スコープ  (2)

選言標準形による五変数ブール関数表現：

Wolfram Language code: expr = BooleanCountingFunction[{2, 3}, {a, b, c, d, e}]

選言標準形の最短の長さ：

Wolfram Language code: m1 = BooleanMinimize[expr, "DNF"]
Wolfram Language code: {Length[m1], Length[expr]}

連言標準形による最短の長さ：

Wolfram Language code: m2 = BooleanMinimize[expr, "CNF"]

NAND（否定論理積）形式による最短の長さ：

Wolfram Language code: m3 = BooleanMinimize[expr, "NAND"]

NOR（否定論理和）形式による最短の長さ：

Wolfram Language code: m4 = BooleanMinimize[expr, "NOR"]

ANF（代数標準形）による最短の長さ：

Wolfram Language code: m5 = BooleanMinimize[expr, "ANF"]

すべての形が等価であることを示す：

Wolfram Language code: TautologyQ[Equivalent[expr, m1, m2, m3, m4, m5]]

「care set」すなわち条件を使ってブール関数を最小化する：

Wolfram Language code: f = BooleanCountingFunction[{2, 3}, 4][a, b, c, d]
Wolfram Language code: cond = Xor[a, b, c, d]
Wolfram Language code: g = BooleanMinimize[f, cond]
Wolfram Language code: h = BooleanMinimize[f, "CNF", cond]

結果の形は cond が真である場合は等しい：

Wolfram Language code: TautologyQ[Implies[cond, Equivalent[f, g, h]]]

両者は条件なしでは等しくない：

Wolfram Language code: TautologyQ[Equivalent[f, g, h]]

一般に，条件がない方が形は長くなる：

Wolfram Language code: BooleanMinimize[f]
Wolfram Language code: BooleanMinimize[f, "CNF"]

アプリケーション  (1)

最小サイズの分布  (1)

最小のDNF表記を計算する：

Wolfram Language code: size[h_] := If[Head[h] === Or, Length[h], 1]
Wolfram Language code: data = Table[{i, size@BooleanMinimize[BooleanFunction[i, {x, y, z}]]}, {i, 0, 2 ^ 2 ^ 3 - 1}];

サイズを指標の関数としてプロットする：

Wolfram Language code: ListLinePlot[data]

分布を見る：

Wolfram Language code: ListLinePlot[Tally[data[[All, -1]]]]

最初の1000個を変数関数について計算する：

Wolfram Language code: data = Table[{i, size@BooleanMinimize[BooleanFunction[i, {x, y, z, w}]]}, {i, 0, 999}];
Wolfram Language code: ListLinePlot[data]
Wolfram Language code: ListLinePlot[Tally[data[[All, -1]]]]

特性と関係  (4)

BooleanMinimizeの出力はその入力に等しい：

Wolfram Language code: f = BooleanFunction[228, {a, b, c}]
Wolfram Language code: g = BooleanMinimize[f]
Wolfram Language code: TautologyQ[Equivalent[f, g]]

条件付きのBooleanMinimizeの出力はその入力と条件付きで等しい：

Wolfram Language code: f = BooleanFunction[158, {a, b, c}]
Wolfram Language code: cond = a || b || c;
Wolfram Language code: g = BooleanMinimize[f, "DNF", cond]

f と g の形は cond が真のときは等しい：

Wolfram Language code: TautologyQ[Implies[cond, Equivalent[f, g]]]

両者はそれら自身では等しくない：

Wolfram Language code: TautologyQ[Equivalent[f, g]]

"DNF"，"CNF"，"NAND"あるいは"NOR"の最短の長さは一意的ではない：

Wolfram Language code: e = BooleanCountingFunction[{1, 2}, {a, b, c}]

BooleanMinimizeは長さ3の式を生成する：

Wolfram Language code: f = BooleanMinimize[e]

長さが3のその他の等しい式は b と c 入れ換えることで得られる：

Wolfram Language code: g = f /. {b -> c, c -> b}
Wolfram Language code: TautologyQ[Equivalent[f, g]]

"CNF"，"NAND"，"NOR"の類似の例題：

Wolfram Language code: {f = BooleanMinimize[Not[e], "CNF"], g = f /. {b -> c, c -> b}, TautologyQ[Equivalent[f, g]]}
Wolfram Language code: {f = BooleanMinimize[e, "NAND"], g = f /. {b -> c, c -> b}, TautologyQ[Equivalent[f, g]]}
Wolfram Language code: {f = BooleanMinimize[Not[e], "NOR"], g = f /. {b -> c, c -> b}, TautologyQ[Equivalent[f, g]]}

最短形が必要ではない場合はBooleanConvertを使う：

Wolfram Language code: BooleanConvert[BooleanCountingFunction[{1, 2}, 3][a, b, c]]
Wolfram Language code: BooleanMinimize[BooleanCountingFunction[{1, 2}, 3][a, b, c]]

BooleanConvertは追加的な形へも変換できる：

Wolfram Language code: BooleanConvert[BooleanCountingFunction[{1, 2}, 3][a, b, c], "Implies"]
Wolfram Research (2008), BooleanMinimize, Wolfram言語関数， https://reference.wolfram.com/language/ref/BooleanMinimize.html.

テキスト

Wolfram Research (2008), BooleanMinimize, Wolfram言語関数， https://reference.wolfram.com/language/ref/BooleanMinimize.html.

CMS

Wolfram Language. 2008. "BooleanMinimize." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/BooleanMinimize.html.

APA

Wolfram Language. (2008). BooleanMinimize. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/BooleanMinimize.html

BibTeX

@misc{reference.wolfram_2026_booleanminimize, author="Wolfram Research", title="{BooleanMinimize}", year="2008", howpublished="\url{https://reference.wolfram.com/language/ref/BooleanMinimize.html}", note=[Accessed: 17-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_booleanminimize, organization={Wolfram Research}, title={BooleanMinimize}, year={2008}, url={https://reference.wolfram.com/language/ref/BooleanMinimize.html}, note=[Accessed: 17-August-2026]}