WOLFRAM

Wolfram 语言与系统参考资料中心

BooleanMinimize[expr]

求出 expr 的最小长度的析取范式.

BooleanMinimize[expr,form]

求出指定形式下 expr 的最小长度表示.

BooleanMinimize[expr,form,cond]

当 cond 为真时，求出指定形式下等价于 expr 的最小长度的表达式.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
应用  
最小尺寸的分布  
属性和关系  
参见
相关指南
历史
按以下格式引用：

BooleanMinimize

BooleanMinimize[expr]

求出 expr 的最小长度的析取范式.

BooleanMinimize[expr,form]

求出指定形式下 expr 的最小长度表示.

BooleanMinimize[expr,form,cond]

当 cond 为真时，求出指定形式下等价于 expr 的最小长度的表达式.

更多信息和选项

  • BooleanMinimize[expr,form] 总是生成等价于 expr 的表达式.
  • 可用的形式有：
  • "DNF","SOP"析取范式，乘积和
    "CNF","POS"合取范式，和的乘积
    "ANF"代数规范形式
    "NOR"二级 Nor 和 Not
    "NAND"二级 Nand 和 Not
    "AND"二级 And 和 Not
    "OR"二级 Or 和 Not
  • 通常，一个特定的表达式在特定形式下可能有多种最小长度的表示形式. BooleanMinimize 给出其中一种.
  • BooleanMinimize 支持 Method 选项，它指定使用的具体方法.

范例

打开所有单元 关闭所有单元

基本范例  (2)

求出最小析取范式：

Wolfram Language code: BooleanMinimize[a∧b∨¬a∧b]

析取范式下一个布尔计数函数：

Wolfram Language code: BooleanCountingFunction[{2, 3}, {a, b, c, d}]

求出一个最小析取范式：

Wolfram Language code: BooleanMinimize[%]

范围  (2)

五元变量的布尔函数，用析取范式表示：

Wolfram Language code: expr = BooleanCountingFunction[{2, 3}, {a, b, c, d, e}]

最小长度的析取范式：

Wolfram Language code: m1 = BooleanMinimize[expr, "DNF"]
Wolfram Language code: {Length[m1], Length[expr]}

最小长度的合取范式：

Wolfram Language code: m2 = BooleanMinimize[expr, "CNF"]

最小长度 NAND 形式：

Wolfram Language code: m3 = BooleanMinimize[expr, "NAND"]

最小长度 NOR 形式：

Wolfram Language code: m4 = BooleanMinimize[expr, "NOR"]

最小长度 ANF：

Wolfram Language code: m5 = BooleanMinimize[expr, "ANF"]

显示相等的所有形式：

Wolfram Language code: TautologyQ[Equivalent[expr, m1, m2, m3, m4, m5]]

用一个 "care set" 或条件来使一个布尔函数最小：

Wolfram Language code: f = BooleanCountingFunction[{2, 3}, 4][a, b, c, d]
Wolfram Language code: cond = Xor[a, b, c, d]
Wolfram Language code: g = BooleanMinimize[f, cond]
Wolfram Language code: h = BooleanMinimize[f, "CNF", cond]

当 cond 为真时，结果的形式是相等的：

Wolfram Language code: TautologyQ[Implies[cond, Equivalent[f, g, h]]]

不设置条件下它们不相等：

Wolfram Language code: TautologyQ[Equivalent[f, g, h]]

通常不设置条件下，形式比较长：

Wolfram Language code: BooleanMinimize[f]
Wolfram Language code: BooleanMinimize[f, "CNF"]

应用  (1)

最小尺寸的分布  (1)

计算最小析取范式的表示：

Wolfram Language code: size[h_] := If[Head[h] === Or, Length[h], 1]
Wolfram Language code: data = Table[{i, size@BooleanMinimize[BooleanFunction[i, {x, y, z}]]}, {i, 0, 2 ^ 2 ^ 3 - 1}];

以指针的函数形式，绘制尺寸：

Wolfram Language code: ListLinePlot[data]

获得它的分布：

Wolfram Language code: ListLinePlot[Tally[data[[All, -1]]]]

计算前 1000 个四元函数的大小：

Wolfram Language code: data = Table[{i, size@BooleanMinimize[BooleanFunction[i, {x, y, z, w}]]}, {i, 0, 999}];
Wolfram Language code: ListLinePlot[data]
Wolfram Language code: ListLinePlot[Tally[data[[All, -1]]]]

属性和关系  (4)

BooleanMinimize 的输出等价于它的输入：

Wolfram Language code: f = BooleanFunction[228, {a, b, c}]
Wolfram Language code: g = BooleanMinimize[f]
Wolfram Language code: TautologyQ[Equivalent[f, g]]

有条件的 BooleanMinimize 输出在条件下等价于它的输入：

Wolfram Language code: f = BooleanFunction[158, {a, b, c}]
Wolfram Language code: cond = a || b || c;
Wolfram Language code: g = BooleanMinimize[f, "DNF", cond]

当 cond 为真时，形式 f 和 g 是相等的：

Wolfram Language code: TautologyQ[Implies[cond, Equivalent[f, g]]]

它们和自身并不相等：

Wolfram Language code: TautologyQ[Equivalent[f, g]]

最小长度 "DNF"，"CNF"，"NAND" 或 "NOR" 不唯一：

Wolfram Language code: e = BooleanCountingFunction[{1, 2}, {a, b, c}]

BooleanMinimize 将产生长度为 3 的表达式：

Wolfram Language code: f = BooleanMinimize[e]

其它长度为 3 的等价表达式由交换 b 和 c 给出：

Wolfram Language code: g = f /. {b -> c, c -> b}
Wolfram Language code: TautologyQ[Equivalent[f, g]]

"CNF"、"NAND" 和 "NOR" 的相似例子：

Wolfram Language code: {f = BooleanMinimize[Not[e], "CNF"], g = f /. {b -> c, c -> b}, TautologyQ[Equivalent[f, g]]}
Wolfram Language code: {f = BooleanMinimize[e, "NAND"], g = f /. {b -> c, c -> b}, TautologyQ[Equivalent[f, g]]}
Wolfram Language code: {f = BooleanMinimize[Not[e], "NOR"], g = f /. {b -> c, c -> b}, TautologyQ[Equivalent[f, g]]}

当不需要最小长度形式时用 BooleanConvert：

Wolfram Language code: BooleanConvert[BooleanCountingFunction[{1, 2}, 3][a, b, c]]
Wolfram Language code: BooleanMinimize[BooleanCountingFunction[{1, 2}, 3][a, b, c]]

BooleanConvert 也可以转换到其它形式：

Wolfram Language code: BooleanConvert[BooleanCountingFunction[{1, 2}, 3][a, b, c], "Implies"]
Wolfram Research (2008)，BooleanMinimize，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BooleanMinimize.html.

文本

Wolfram Research (2008)，BooleanMinimize，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BooleanMinimize.html.

CMS

Wolfram 语言. 2008. "BooleanMinimize." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/BooleanMinimize.html.

APA

Wolfram 语言. (2008). BooleanMinimize. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/BooleanMinimize.html 年

BibTeX

@misc{reference.wolfram_2026_booleanminimize, author="Wolfram Research", title="{BooleanMinimize}", year="2008", howpublished="\url{https://reference.wolfram.com/language/ref/BooleanMinimize.html}", note=[Accessed: 09-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_booleanminimize, organization={Wolfram Research}, title={BooleanMinimize}, year={2008}, url={https://reference.wolfram.com/language/ref/BooleanMinimize.html}, note=[Accessed: 09-August-2026]}