WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

CDFWavelet[]

タイプ"9/7"のCohen–Daubechies–Feauveauウェーブレットを表す．

CDFWavelet["type"]

タイプ"type"のCohen–Daubechies–Feauveauウェーブレットを表す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
基本的な用法  
ウェーブレット変換  
より高い次元  
特性と関係  
おもしろい例題  
関連項目
テクニカルノート
関連するガイド
履歴
引用書式

CDFWavelet

CDFWavelet[]

タイプ"9/7"のCohen–Daubechies–Feauveauウェーブレットを表す．

CDFWavelet["type"]

タイプ"type"のCohen–Daubechies–Feauveauウェーブレットを表す．

詳細

  • CDFWaveletは双直交ウェーブレット群を定義する．
  • 使用可能な"type"の形
  • "5/3"JPEG2000の可逆圧縮で使われる
    "9/7"JPEG2000の非可逆圧縮で使われる
  • スケーリング関数()とウェーブレット関数()はコンパクトサポートを持つ．両関数は対称である．
  • CDFWaveletはDiscreteWaveletTransform，WaveletPhi等の関数で使うことができる．

例題

すべて開く すべて閉じる

例  (3)

スケーリング関数：

Wolfram Language code: Plot[WaveletPhi[CDFWavelet["9/7"], x], {x, -4, 4}, PlotRange -> All]
Wolfram Language code: WaveletPhi[CDFWavelet["9/7"], x]

ウェーブレット関数：

Wolfram Language code: Plot[WaveletPsi[CDFWavelet["9/7"], x], {x, -3, 4}, PlotRange -> All]
Wolfram Language code: WaveletPsi[CDFWavelet["9/7"], x]

フィルタ係数：

Wolfram Language code: WaveletFilterCoefficients[CDFWavelet["9/7"], {"PrimalLowpass", "PrimalHighpass"}]

スコープ  (16)

基本的な用法  (10)

主ローパスフィルタ係数を計算する：

Wolfram Language code: WaveletFilterCoefficients[CDFWavelet["9/7"], "PrimalLowpass"]

双対ローパスフィルタ係数：

Wolfram Language code: WaveletFilterCoefficients[CDFWavelet["9/7"], "DualLowpass"]

主ハイパスフィルタ係数：

Wolfram Language code: WaveletFilterCoefficients[CDFWavelet["9/7"], "PrimalHighpass"]

双対ハイパスフィルタ係数：

Wolfram Language code: WaveletFilterCoefficients[CDFWavelet["9/7"], "DualHighpass"]

リフティングフィルタ係数：

Wolfram Language code: WaveletFilterCoefficients[CDFWavelet["9/7"], "LiftingFilter"]
Wolfram Language code: %[{"LiftingMatrixForm", z}]

関数を生成してリフティングウェーブレット変換を計算する：

Wolfram Language code: lf = WaveletFilterCoefficients[CDFWavelet["9/7"], "LiftingFilter"]
Wolfram Language code: lf["ForwardLiftingFunction"][Range[8]]
Wolfram Language code: lf["InverseLiftingFunction"][%]

主スケーリング関数：

Wolfram Language code: Plot[WaveletPhi[CDFWavelet["9/7"], x], {x, -4, 4}, PlotRange -> All]

双対スケーリング関数：

Wolfram Language code: Plot[WaveletPhi[CDFWavelet["9/7"], x, "Dual"], {x, -3, 3}, PlotRange -> All]

異なる再帰レベルを使ってスケーリング関数をプロットする：

Wolfram Language code: Table[Plot[WaveletPhi[CDFWavelet["9/7"], x, MaxRecursion -> i], {x, -4, 4}, PlotLabel -> i, PlotRange -> All], {i, 1, 8, 2}]

主ウェーブレット関数：

Wolfram Language code: Plot[WaveletPsi[CDFWavelet["5/3"], x], {x, -3, 4}, PlotRange -> All]

双対ウェーブレット関数：

Wolfram Language code: Plot[WaveletPsi[CDFWavelet["5/3"], x, "Dual"], {x, -1, 2}, PlotRange -> All]

異なる再帰レベルを使ってウェーブレット関数をプロットする：

Wolfram Language code: Table[Plot[WaveletPsi[CDFWavelet["5/3"], x, "Dual", MaxRecursion -> i], {x, -1, 2}, PlotLabel -> i, PlotRange -> All], {i, 1, 8, 2}]

ウェーブレット変換  (5)

DiscreteWaveletTransformを計算する：

Wolfram Language code: dwt = DiscreteWaveletTransform[[image], CDFWavelet["9/7"], 2]

ウェーブレット係数の木を見る：

Wolfram Language code: dwt["TreeView"]

ウェーブレット係数の次元を得る：

Wolfram Language code: dwt["Dimensions"]

ウェーブレット係数をプロットする：

Wolfram Language code: WaveletImagePlot[dwt]

DiscreteWaveletPacketTransformを計算する：

Wolfram Language code: dwpt = DiscreteWaveletPacketTransform[[image], CDFWavelet["9/7"], 1]

ウェーブレット係数の木を見る：

Wolfram Language code: dwpt["TreeView"]

ウェーブレット係数の次元を得る：

Wolfram Language code: dwpt["Dimensions"]

ウェーブレット係数をプロットする：

Wolfram Language code: dwpt[All, "Image"]

StationaryWaveletTransformを計算する：

Wolfram Language code: swt = StationaryWaveletTransform[[image], CDFWavelet["9/7"], 2];

ウェーブレット係数の木を見る：

Wolfram Language code: swt["TreeView"]

ウェーブレット係数の次元を得る：

Wolfram Language code: swt["Dimensions"]

ウェーブレット係数をプロットする：

Wolfram Language code: swt[Automatic, "Image"]

StationaryWaveletPacketTransformを計算する：

Wolfram Language code: swpt = StationaryWaveletPacketTransform[[image], CDFWavelet["9/7"], 1];

ウェーブレット係数の木を見る：

Wolfram Language code: swpt["TreeView"]

ウェーブレット係数の次元を得る：

Wolfram Language code: swpt["Dimensions"]

ウェーブレット係数をプロットする：

Wolfram Language code: swpt[All, "Image"]

LiftingWaveletTransformを計算する：

Wolfram Language code: lwt = LiftingWaveletTransform[[image], CDFWavelet["9/7"], 2];

ウェーブレット係数の木を見る：

Wolfram Language code: lwt["TreeView"]

ウェーブレット係数の次元を得る：

Wolfram Language code: lwt["Dimensions"]

ウェーブレット係数をプロットする：

Wolfram Language code: WaveletImagePlot[lwt]

より高い次元  (1)

多変量スケーリング関数と多変量ウェーブレット関数はそれぞれの一変量関数の積である：

Wolfram Language code: ϕ = WaveletPhi[CDFWavelet[]]; ψ = WaveletPsi[CDFWavelet[]];
Wolfram Language code: Plot3D[Evaluate[ϕ[x]ψ[y]], {x, -4, 4}, {y, -4, 4}, PlotRange -> All, ColorFunction -> "SolarColors", Mesh -> None, Axes -> None]
Wolfram Language code: Plot3D[Evaluate[ϕ[x]ψ[y]], {x, -4, 4}, {y, -3, 4}, PlotRange -> All, ColorFunction -> "SolarColors", Mesh -> None, Axes -> None]
Wolfram Language code: Plot3D[Evaluate[ψ[x]ϕ[y]], {x, -3, 4}, {y, -4, 4}, PlotRange -> All, ColorFunction -> "SolarColors", Mesh -> None, Axes -> None]
Wolfram Language code: Plot3D[Evaluate[ψ[x]ψ[y]], {x, -3, 4}, {y, -3, 4}, PlotRange -> All, ColorFunction -> "SolarColors", Mesh -> None, Axes -> None]

特性と関係  (16)

ローパスフィルタ係数の総和は単位元である．：

Wolfram Language code: Total@WaveletFilterCoefficients[CDFWavelet["9/7"]][[All, 2]]

ハイパスフィルタ係数の総和は0である．：

Wolfram Language code: Total@WaveletFilterCoefficients[CDFWavelet["9/7"], "PrimalHighpass"][[All, 2]]

双対ローパスフィルタ係数の総和は単位元である．：

Wolfram Language code: Total@WaveletFilterCoefficients[CDFWavelet["9/7"], "DualLowpass"][[All, 2]]

双対ハイパスフィルタ係数の総和は0である．：

Wolfram Language code: Total@WaveletFilterCoefficients[CDFWavelet["9/7"], "DualHighpass"][[All, 2]]

スケーリング関数を積分すると単位元になる．：

Wolfram Language code: Integrate[WaveletPhi[CDFWavelet["5/3"], x], {x, -∞, ∞}]

双対スケーリング関数を積分すると単位元になる．：

Wolfram Language code: Integrate[WaveletPhi[CDFWavelet["5/3"], x, "Dual"], {x, -∞, ∞}]

ウェーブレット関数を積分すると0になる．：

Wolfram Language code: Integrate[WaveletPsi[CDFWavelet["5/3"], x], {x, -∞, ∞}]

双対ウェーブレット関数を積分すると0になる．：

Wolfram Language code: Integrate[WaveletPsi[CDFWavelet["5/3"], x, "Dual"], {x, -∞, ∞}]

は再帰方程式 を満足する：

Wolfram Language code: ϕ = WaveletPhi[CDFWavelet["9/7"]];
Wolfram Language code: a = WaveletFilterCoefficients[CDFWavelet["9/7"], "PrimalLowpass"];

構成要素と再帰の総和をプロットする：

Wolfram Language code: scalet[x_, ϕ_, a_] := 2Table[a[[i, 2]]ϕ[2x - a[[i, 1]]], {i, Length[a]}]
Wolfram Language code: {Plot[Evaluate@scalet[x, ϕ, a], {x, -4, 4}, PlotRange -> All], Plot[Total@scalet[x, ϕ, a], {x, -4, 4}, PlotRange -> All]}

は再帰方程式 を満足する：

Wolfram Language code: ϕ = WaveletPhi[CDFWavelet["9/7"]];
Wolfram Language code: b = WaveletFilterCoefficients[CDFWavelet["9/7"], "PrimalHighpass"];

構成要素と再帰の総和をプロットする：

Wolfram Language code: wavelet[x_, ϕ_, b_] := 2Table[b[[i, 2]]ϕ[2x - b[[i, 1]]], {i, Length[b]}]
Wolfram Language code: {Plot[Evaluate@wavelet[x, ϕ, b], {x, -3, 4}, PlotRange -> All], Plot[Total@wavelet[x, ϕ, b], {x, -3, 4}, PlotRange -> All]}

は再帰方程式 を満足する：

Wolfram Language code: Overscript[ϕ, ~] = ( Evaluate[WaveletPhi[CDFWavelet["9/7"], #, "Dual"]]&);
Wolfram Language code: Overscript[a, ~] = WaveletFilterCoefficients[CDFWavelet["9/7"], "DualLowpass"];

構成要素と再帰の総和をプロットする：

Wolfram Language code: scalet[x_, ϕ_, a_] := 2 Table[a[[i, 2]] ϕ[2 x - a[[i, 1]]], {i, Length[a]}]
Wolfram Language code: {Plot[Evaluate@scalet[x, Overscript[ϕ, ~], Overscript[a, ~]], {x, -3, 3}, PlotRange -> All], Plot[Total@scalet[x, Overscript[ϕ, ~], Overscript[a, ~]], {x, -3, 3}, PlotRange -> All]}

は再帰方程式 を満足する：

Wolfram Language code: Overscript[ϕ, ~] = ( Evaluate[WaveletPhi[CDFWavelet["9/7"], #, "Dual"]]&);
Wolfram Language code: Overscript[b, ~] = WaveletFilterCoefficients[CDFWavelet["9/7"], "DualHighpass"];

構成要素と再帰の総和をプロットする：

Wolfram Language code: wavelet[x_, ϕ_, b_] := 2Table[b[[i, 2]]ϕ[2x - b[[i, 1]]], {i, Length[b]}]
Wolfram Language code: {Plot[Evaluate@wavelet[x, Overscript[ϕ, ~], Overscript[b, ~]], {x, -3, 3}, PlotRange -> All], Plot[Total@wavelet[x, Overscript[ϕ, ~], Overscript[b, ~]], {x, -3, 3}, PlotRange -> All]}

に対する周波数応答は で与えられる：

Wolfram Language code: h[wav_, ω_] := With[{a = WaveletFilterCoefficients[wav]}, Sum[a[[i, 2]]Exp[-I a[[i, 1]]ω], {i, Length[a]}]]

フィルタはローパスフィルタである：

Wolfram Language code: Plot[Abs[h[CDFWavelet["9/7"], ω]], {ω, -π, π}, Ticks -> {{-π, -(π/2), 0, (π/2), π}, Automatic}, AxesLabel -> {ω, Abs[H[ω]]}]

Fのフーリエ(Fourier)変換は で与えられる：

Wolfram Language code: h[wav_, ω_] := With[{a = WaveletFilterCoefficients[wav]}, Sum[a[[i, 2]]Exp[-I a[[i, 1]]ω], {i, Length[a]}]]
Wolfram Language code: fh[wav_, ω_, j_] := Abs[Product[h[wav, (ω/2^i)], {i, j}]]
Wolfram Language code: Plot[fh[CDFWavelet["9/7"], ω, 10], {ω, -7Pi, 7Pi}, PlotRange -> All, AxesLabel -> {ω, Abs[ Overscript[ϕ, ^ ][ω]]}]

に対する周波数応答はで与えられる：

Wolfram Language code: Overscript[h, ~][wav_, ω_] := With[{a = WaveletFilterCoefficients[wav, "DualLowpass"]}, Sum[a[[i, 2]]Exp[-I a[[i, 1]]ω], {i, Length[a]}]]

フィルタは双対ローパスフィルタである：

Wolfram Language code: Plot[Abs[Overscript[h, ~][CDFWavelet["9/7"], ω]], {ω, -π, π}, Ticks -> {{-π, -(π/2), 0, (π/2), π}, Automatic}, AxesLabel -> {ω, Abs[Overscript[H, ~][ω]]}]

のフーリエ変換はで与えられる：

Wolfram Language code: Overscript[h, ~][wav_, ω_] := With[{a = WaveletFilterCoefficients[wav, "DualLowpass"]}, Sum[a[[i, 2]]Exp[-I a[[i, 1]]ω], {i, Length[a]}]]
Wolfram Language code: fh[wav_, ω_, j_] := Abs[Product[Overscript[h, ~][wav, (ω/2^i)], {i, j}]]
Wolfram Language code: Plot[fh[CDFWavelet["9/7"], ω, 10], {ω, -7Pi, 7Pi}, PlotRange -> All, AxesLabel -> {ω, Abs[ Overscript[Overscript[ϕ, ~], ^ ][ω]]}]

に対する周波数応答はで与えられる：

Wolfram Language code: g[wav_, ω_] := With[{b = WaveletFilterCoefficients[wav, "PrimalHighpass"]}, Sum[b[[i, 2]]Exp[-I b[[i, 1]]ω], {i, Length[b]}] ]

フィルタはローパスフィルタである：

Wolfram Language code: Plot[Abs[g[CDFWavelet["9/7"], ω]], {ω, -π, π}, Ticks -> {{-π, -(π/2), 0, (π/2), π}, Automatic}, AxesLabel -> {ω, Abs[G[ω]]}]

のフーリエ変換は で与えられる：

Wolfram Language code: h[wav_, ω_] := With[{a = WaveletFilterCoefficients[wav]}, Sum[a[[i, 2]]Exp[-I a[[i, 1]]ω], {i, Length[a]}]]
Wolfram Language code: g[wav_, ω_] := With[{b = WaveletFilterCoefficients[wav, "PrimalHighpass"]}, Sum[b[[i, 2]]Exp[-I b[[i, 1]]ω], {i, Length[b]}] ]
Wolfram Language code: fg[wav_, ω_, j_] := Abs[g[wav, (ω/2)]Product[h[wav, (ω/2^i)], {i, 2, j}]]
Wolfram Language code: Plot[fg[CDFWavelet["9/7"], ω, 10], {ω, -7Pi, 7Pi}, PlotRange -> All, AxesLabel -> {ω, Abs[Overscript[ψ, ^ ][ω]]}]

に対する周波数応答はで与えられる：

Wolfram Language code: Overscript[g, ~][wav_, ω_] := With[{b = WaveletFilterCoefficients[wav, "DualHighpass"]}, Sum[b[[i, 2]]Exp[-I b[[i, 1]]ω], {i, Length[b]}] ]

フィルタはローパスフィルタである：

Wolfram Language code: Plot[Abs[Overscript[g, ~][CDFWavelet["9/7"], ω]], {ω, -π, π}, Ticks -> {{-π, -(π/2), 0, (π/2), π}, Automatic}, AxesLabel -> {ω, Abs[Overscript[G, ~][ω]]}]

のフーリエ変換は で与えられる：

Wolfram Language code: Overscript[h, ~][wav_, ω_] := With[{a = WaveletFilterCoefficients[wav, "DualLowpass"]}, Sum[a[[i, 2]]Exp[-I a[[i, 1]]ω], {i, Length[a]}]]
Wolfram Language code: Overscript[g, ~][wav_, ω_] := With[{b = WaveletFilterCoefficients[wav, "DualHighpass"]}, Sum[b[[i, 2]]Exp[-I b[[i, 1]]ω], {i, Length[b]}] ]
Wolfram Language code: Overscript[fg, ~][wav_, ω_, j_] := Abs[Overscript[g, ~][wav, (ω/2)]Product[Overscript[h, ~][wav, (ω/2^i)], {i, 2, j}]]
Wolfram Language code: Plot[Overscript[fg, ~][CDFWavelet["9/7"], ω, 10], {ω, -7Pi, 7Pi}, PlotRange -> All, AxesLabel -> {ω, Abs[ Overscript[Overscript[ψ, ~], ^ ][ω]]}]

おもしろい例題  (2)

スケーリング関数の平行移動と膨張をプロットする：

Wolfram Language code: ϕ[x_, j_, k_] := 2^j / 2WaveletPhi[CDFWavelet["9/7"], 2^jx - k]
Wolfram Language code: Plot[Evaluate@Table[ϕ[x, j, 0], {j, 0, 4}], {x, -2, 2}, Filling -> Axis, PlotRange -> All, Axes -> {True, False}]
Wolfram Language code: Plot[Evaluate@Table[ϕ[x, 2, k], {k, 0, 2^2 - 1}], {x, -0.5, 2}, Filling -> Axis, PlotRange -> All]

ウェーブレット関数の平行移動と膨張をプロットする：

Wolfram Language code: ψ[x_, j_, k_] := 2^j / 2WaveletPsi[CDFWavelet["9/7"], 2^jx - k]
Wolfram Language code: Plot[Evaluate@Table[ψ[x, j, 0], {j, 0, 4}], {x, -0.5, 1}, Filling -> Axis, PlotRange -> All, Axes -> {True, False}]
Wolfram Language code: Plot[Evaluate@Table[ψ[x, 2, k], {k, 0, 2^2 - 1}], {x, -0.5, 1.5}, Filling -> Axis, PlotRange -> All]
Wolfram Research (2010), CDFWavelet, Wolfram言語関数， https://reference.wolfram.com/language/ref/CDFWavelet.html.

テキスト

Wolfram Research (2010), CDFWavelet, Wolfram言語関数， https://reference.wolfram.com/language/ref/CDFWavelet.html.

CMS

Wolfram Language. 2010. "CDFWavelet." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/CDFWavelet.html.

APA

Wolfram Language. (2010). CDFWavelet. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CDFWavelet.html

BibTeX

@misc{reference.wolfram_2026_cdfwavelet, author="Wolfram Research", title="{CDFWavelet}", year="2010", howpublished="\url{https://reference.wolfram.com/language/ref/CDFWavelet.html}", note=[Accessed: 07-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_cdfwavelet, organization={Wolfram Research}, title={CDFWavelet}, year={2010}, url={https://reference.wolfram.com/language/ref/CDFWavelet.html}, note=[Accessed: 07-August-2026]}