WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

CMYKColor[cyan,magenta,yellow,black]

シアン，マゼンタ，黄，黒の成分からなるCMYK色空間の色を表す．

CMYKColor[c,m,y,k,a]

不透明度 a を指定する．

CMYKColor["string"]

HTMLの色の名前等から色を返す．

CMYKColor[color]

color のCMYK表現を返す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
3Dの色  
色の操作  
一般化と拡張  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

CMYKColor

CMYKColor[cyan,magenta,yellow,black]

シアン，マゼンタ，黄，黒の成分からなるCMYK色空間の色を表す．

CMYKColor[c,m,y,k,a]

不透明度 a を指定する．

CMYKColor["string"]

HTMLの色の名前等から色を返す．

CMYKColor[color]

color のCMYK表現を返す．

詳細

  • CMYKColorは，一般に印刷に用いられる，減色法モデルである．CMYKは，印刷に用いられるシアン，マゼンタ，黄色，黒のインクを意味する．
  • の任意の正の値について，他の色成分から をサブトラックすることで同じ色が生成できる．これは，黒いインクをより多く使うことでカラーインクの使用量を控えるためによく使われる．
  • 0から1の範囲を超える色および不透明度のレベルは切り取られる． »
  • 黒の成分が指定されていない場合，CMYKColor[c,m,y]はCMYKColor[c,m,y,0]に等しい．
  • CMYKColor指定は，擬似照明の計算の際，自動的にRGBColor指定に変換される． »
  • 不透明度が指定されていない場合，CMYKColor[c,m,y,k]はCMYKColor[c,m,y,k,1]と同等である．
  • CMYKColor[c,m,y,k,a]は{CMYKColor[c,m,y,k],Opacity[a]}に等しい．
  • 代替形のCMYKColor[{c,m,y,k}]およびCMYKColor[{c,m,y,k,a}]も使うことができる．
  • ColorConvertを使ってCMYKColorを他の色空間に変換することができる．
  • 色には次のラッパーを使うことができる．
  • ColorsNear[color,…]color の周りの領域を指定する
    Directive[…,color,…]色を他の指示子との組合せで指定する »
    Glow[color]照明とは無関係に色を指定する »
    Opacity[a,color]不透明度 a で色を指定する
    Style[expr,color]expr を指定の色で表示する »
  • 3D曲面については，明示的なCMYKColor指示子が曲面の色を指定する．最終的な陰影付けは，照明や鏡面性，輝き等に依存する． »

例題

すべて開く すべて閉じる

例  (4)

グラフィックスプリミティブの色を指定する：

Wolfram Language code: Graphics[{CMYKColor[0, 1, 1, .25], Disk[]}]

不透明度付きの色を指定する：

Wolfram Language code: Graphics3D[{CMYKColor[1, 0, 1, 0, .5], Sphere[]}]

式の出力の色を指定する：

Wolfram Language code: Style[x ^ 2 + y ^ 2, CMYKColor[1, .8, 0, .25]]

プロットの色を指定する：

Wolfram Language code: Plot[Sin[x ^ 2], {x, 0, 2Pi}, PlotStyle -> CMYKColor[0.3, 1, 0, .25]]

スコープ  (3)

3Dの色  (1)

拡散反射する表面色を使う：

Wolfram Language code: Graphics3D[{CMYKColor[0, 0.4, 1, 0], Sphere[]}]

拡散反射に鏡面反射を伴う色を表面色に使う：

Wolfram Language code: Graphics3D[{CMYKColor[0, 0.4, 1, 0], Specularity[White, 20], Sphere[]}]

拡散反射の表面色を黒とし，放光する色を使う：

Wolfram Language code: Graphics3D[{Black, Glow[CMYKColor[0, 0.4, 1, 0]], Sphere[]}]

色の操作  (2)

Blendを使って2色以上の色を混ぜる：

Wolfram Language code: {Graphics[{CMYKColor[0, 1, 0, 0], Disk[]}], Graphics[{Blend[{CMYKColor[0, 1, 0, 0], CMYKColor[0, 0, 1, 0]}], Disk[]}], Graphics[{CMYKColor[0, 0, 1, 0], Disk[]}]}

LighterとDarkerを使ってそれぞれ白と黒を混ぜる：

Wolfram Language code: {Graphics[{Lighter[CMYKColor[0, 0, 1, 0], .4], Disk[]}], Graphics[{CMYKColor[0, 0, 1, 0], Disk[]}], Graphics[{Darker[CMYKColor[0, 0, 1, 0], .4], Disk[]}]}

一般化と拡張  (2)

CMYKColor[{c,y,m,k}]はCMYKColor[c,y,m,k]に等しい：

Wolfram Language code: {Graphics[{CMYKColor[{1, 0, 0, .25}], Disk[]}], Graphics[{CMYKColor[1, 0, 0, .25], Disk[]}]}
Wolfram Language code: Map[Graphics[{CMYKColor[#], Disk[]}]&, {{1, 0, 0, 0}, {0, 1, 0, 0}, {0, 0, 1, 0}, {0, 0, 0, 1}}]

OpacityをCMYKColorとともに使う：

Wolfram Language code: Table[Graphics[{CMYKColor[1, 0, 0, 0], Disk[{1, 0}], Opacity[a], CMYKColor[0, 1, 0, 0], Disk[]}], {a, 0, 1, .33}]

CMYKColorで直接不透明度の引数を使う：

Wolfram Language code: Table[Graphics[{CMYKColor[1, 0, 0, 0], Disk[{1, 0}], CMYKColor[0, 1, 0, 0, a], Disk[]}], {a, 0, 1, .33}]

特性と関係  (3)

CMYKColorは以下のようにRGBColorに関連している：

Wolfram Language code: RGBToCMY[RGBColor[r_, g_, b_]] := CMYKColor[1 - r, 1 - g, 1 - b, 0]
Wolfram Language code: c = RGBColor@@RandomReal[{0, 1}, 3]; {Graphics[{c, Rectangle[]}], Graphics[{RGBToCMY[c], Rectangle[]}]}

経済効率のため，黒の出力は通常分離されている：

Wolfram Language code: RGBToCMYK[RGBColor[r_, g_, b_]] := Block[{k = Min[1 - r, 1 - g, 1 - b]}, CMYKColor[1 - r - k, 1 - g - k, 1 - b - k, k]]
Wolfram Language code: c = RGBColor@@RandomReal[{0, 1}, 3]; {Graphics[{c, Rectangle[]}], Graphics[{RGBToCMYK[c], Rectangle[]}]}

CMYKColorとRGBColorで同じパラメータを使うと補色が得られる：

Wolfram Language code: DynamicModule[{m = (1/2), y = (1/2)}, {Slider2D[Dynamic[{m, y}], {{0, 0}, {1, 1}}], Dynamic[Graphics[{{CMYKColor[0, m, y, 0], Rectangle[{0, 0}]}, {RGBColor[0, m, y], Rectangle[{1, 0}]}}]]}]

CMY値はRGB値と補色の関係にある：

Wolfram Language code: {Graphics[{CMYKColor[0, 1, 1, 0], Disk[]}], Graphics[{RGBColor[1, 0, 0], Disk[]}]}
Wolfram Language code: {Graphics[{CMYKColor[1, 0, 1, 0], Disk[]}], Graphics[{RGBColor[0, 1, 0], Disk[]}]}
Wolfram Language code: {Graphics[{CMYKColor[1, 1, 0, 0], Disk[]}], Graphics[{RGBColor[0, 0, 1], Disk[]}]}

考えられる問題  (1)

0, 1範囲外の値は切り取られる：

Wolfram Language code: Graphics[Table[{CMYKColor[c, 0, 0, 0], EdgeForm[Gray], Rectangle[{4c, 0}]}, {c, 0 - 1 / 4, 1 + 1 / 4, 1 / 4}]]

プロット関数で，ColorFunctionScalingを使って変数の大域的スケーリングを制御する：

Wolfram Language code: Table[DensityPlot[x, {x, -1, 2}, {y, 0, 1}, FrameTicks -> None, ColorFunction -> (CMYKColor[#, 0, 0, 0]&), ColorFunctionScaling -> t], {t, {False, True}}]

おもしろい例題  (2)

CMY色空間を可視化する：

Wolfram Language code: Graphics3D[{Opacity[.7], {CMYKColor[#], Cuboid[#, # + .1]}& /@ Tuples[Range[0, 1, .2], 3]}, Axes -> True, AxesLabel -> {"Cyan", "Magenta", "Yellow"}, Lighting -> "Neutral"]

不透明度のあるCMYKノイズ：

Wolfram Language code: Graphics[{Pink, Disk[{100, 100}, 40], Raster[RandomReal[1, {200, 200, 5}], ColorFunction -> CMYKColor]}]
Wolfram Research (1991), CMYKColor, Wolfram言語関数， https://reference.wolfram.com/language/ref/CMYKColor.html （2021年に更新）.

テキスト

Wolfram Research (1991), CMYKColor, Wolfram言語関数， https://reference.wolfram.com/language/ref/CMYKColor.html （2021年に更新）.

CMS

Wolfram Language. 1991. "CMYKColor." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2021. https://reference.wolfram.com/language/ref/CMYKColor.html.

APA

Wolfram Language. (1991). CMYKColor. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CMYKColor.html

BibTeX

@misc{reference.wolfram_2026_cmykcolor, author="Wolfram Research", title="{CMYKColor}", year="2021", howpublished="\url{https://reference.wolfram.com/language/ref/CMYKColor.html}", note=[Accessed: 10-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_cmykcolor, organization={Wolfram Research}, title={CMYKColor}, year={2021}, url={https://reference.wolfram.com/language/ref/CMYKColor.html}, note=[Accessed: 10-September-2026]}