WOLFRAM

Wolfram 语言与系统参考资料中心

CMYKColor[c,m,y,k]

表示 CMYK 颜色空间中的一种颜色，其中含有青色、品红色、黄色和黑色分量.

CMYKColor[c,m,y,k,a]

指定不透明度 a.

CMYKColor["string"]

根据 HTML 颜色名称等返回颜色.

CMYKColor[color]

返回 color 的 CMYK 表示.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
三维颜色  
颜色操作  
推广和延伸  
属性和关系  
可能存在的问题  
巧妙范例  
参见
相关指南
历史
按以下格式引用：

CMYKColor

CMYKColor[c,m,y,k]

表示 CMYK 颜色空间中的一种颜色，其中含有青色、品红色、黄色和黑色分量.

CMYKColor[c,m,y,k,a]

指定不透明度 a.

CMYKColor["string"]

根据 HTML 颜色名称等返回颜色.

CMYKColor[color]

返回 color 的 CMYK 表示.

更多信息

  • CMYKColor 是一种减色模型，典型的用途是彩色印刷. CMYK 分别指在印刷中使用的青色、品红色、黄色和黑色墨.
  • 对于任意正的 值，相同的颜色可以通过从其他颜色分量中减去 来产生. 这通常用于通过使用更多黑色墨水来节省彩色墨水的消耗.
  • 颜色和不透明度级别在 0 到 1 范围以外将被剪切. »
  • 如果没有指定黑色分量，CMYKColor[c,m,y] 等价于 CMYKColor[c,m,y,0].
  • 当模拟照明计算完成时，CMYKColor 指定将自动转换为 RGBColor. »
  • 如果没有指定不透明度，CMYKColor[c,m,y,k] 等价于 CMYKColor[c,m,y,k,1].
  • 也可使用替代形式 CMYKColor[{c,m,y,k}] 和 CMYKColor[{c,m,y,k,a}].
  • CMYKColor[c,m,y,k,a] 等价于 {CMYKColor[c,m,y,k],Opacity[a]}.
  • ColorConvert 可用于将 CMYKColor 转换为其他色彩空间.
  • 可对颜色使用以下封装：
  • ColorsNear[color,…]指定 color 周围的区域
    Directive[…,color,…]结合其他指令指定颜色 »
    Glow[color]指定与亮度无关的颜色 »
    Opacity[a,color]指定具有不透明度 a 的颜色
    Style[expr,color]用指定颜色显示 expr »
  • 对于三维曲面，显式的 CMYKColor 指令定义曲面的颜色；最终的明暗取决于照明以及镜面反射和辉光的贡献. »

范例

打开所有单元 关闭所有单元

基本范例  (4)

指定图形基元的颜色：

Wolfram Language code: Graphics[{CMYKColor[0, 1, 1, .25], Disk[]}]

指定带有不透明度的颜色：

Wolfram Language code: Graphics3D[{CMYKColor[1, 0, 1, 0, .5], Sphere[]}]

指定表达式的输出颜色：

Wolfram Language code: Style[x ^ 2 + y ^ 2, CMYKColor[1, .8, 0, .25]]

指定绘图的颜色：

Wolfram Language code: Plot[Sin[x ^ 2], {x, 0, 2Pi}, PlotStyle -> CMYKColor[0.3, 1, 0, .25]]

范围  (3)

三维颜色  (1)

使用漫反射面颜色：

Wolfram Language code: Graphics3D[{CMYKColor[0, 0.4, 1, 0], Sphere[]}]

使用漫反射面和定向反射面颜色：

Wolfram Language code: Graphics3D[{CMYKColor[0, 0.4, 1, 0], Specularity[White, 20], Sphere[]}]

使用辉光颜色，设置散反射面颜色为黑色：

Wolfram Language code: Graphics3D[{Black, Glow[CMYKColor[0, 0.4, 1, 0]], Sphere[]}]

颜色操作  (2)

利用 Blend 混合两种或更多种颜色：

Wolfram Language code: {Graphics[{CMYKColor[0, 1, 0, 0], Disk[]}], Graphics[{Blend[{CMYKColor[0, 1, 0, 0], CMYKColor[0, 0, 1, 0]}], Disk[]}], Graphics[{CMYKColor[0, 0, 1, 0], Disk[]}]}

利用 Lighter 和 Darker 分别同白色和黑色混合：

Wolfram Language code: {Graphics[{Lighter[CMYKColor[0, 0, 1, 0], .4], Disk[]}], Graphics[{CMYKColor[0, 0, 1, 0], Disk[]}], Graphics[{Darker[CMYKColor[0, 0, 1, 0], .4], Disk[]}]}

推广和延伸  (2)

CMYKColor[{c,y,m,k}] 等价于 CMYKColor[c,y,m,k]：

Wolfram Language code: {Graphics[{CMYKColor[{1, 0, 0, .25}], Disk[]}], Graphics[{CMYKColor[1, 0, 0, .25], Disk[]}]}
Wolfram Language code: Map[Graphics[{CMYKColor[#], Disk[]}]&, {{1, 0, 0, 0}, {0, 1, 0, 0}, {0, 0, 1, 0}, {0, 0, 0, 1}}]

将 Opacity 与 CMYKColor 联用：

Wolfram Language code: Table[Graphics[{CMYKColor[1, 0, 0, 0], Disk[{1, 0}], Opacity[a], CMYKColor[0, 1, 0, 0], Disk[]}], {a, 0, 1, .33}]

在 CMYKColor 中直接地使用不透明参数：

Wolfram Language code: Table[Graphics[{CMYKColor[1, 0, 0, 0], Disk[{1, 0}], CMYKColor[0, 1, 0, 0, a], Disk[]}], {a, 0, 1, .33}]

属性和关系  (3)

CMYKColor 以下面的方式与 RGBColor 相关：

Wolfram Language code: RGBToCMY[RGBColor[r_, g_, b_]] := CMYKColor[1 - r, 1 - g, 1 - b, 0]
Wolfram Language code: c = RGBColor@@RandomReal[{0, 1}, 3]; {Graphics[{c, Rectangle[]}], Graphics[{RGBToCMY[c], Rectangle[]}]}

为了打印的经济性，黑色通常被分离出来：

Wolfram Language code: RGBToCMYK[RGBColor[r_, g_, b_]] := Block[{k = Min[1 - r, 1 - g, 1 - b]}, CMYKColor[1 - r - k, 1 - g - k, 1 - b - k, k]]
Wolfram Language code: c = RGBColor@@RandomReal[{0, 1}, 3]; {Graphics[{c, Rectangle[]}], Graphics[{RGBToCMYK[c], Rectangle[]}]}

通过在 CMYKColor 和 RGBColor 中使用同样的参数得到互补色：

Wolfram Language code: DynamicModule[{m = (1/2), y = (1/2)}, {Slider2D[Dynamic[{m, y}], {{0, 0}, {1, 1}}], Dynamic[Graphics[{{CMYKColor[0, m, y, 0], Rectangle[{0, 0}]}, {RGBColor[0, m, y], Rectangle[{1, 0}]}}]]}]

CMY 值与 RGB 值互补：

Wolfram Language code: {Graphics[{CMYKColor[0, 1, 1, 0], Disk[]}], Graphics[{RGBColor[1, 0, 0], Disk[]}]}
Wolfram Language code: {Graphics[{CMYKColor[1, 0, 1, 0], Disk[]}], Graphics[{RGBColor[0, 1, 0], Disk[]}]}
Wolfram Language code: {Graphics[{CMYKColor[1, 1, 0, 0], Disk[]}], Graphics[{RGBColor[0, 0, 1], Disk[]}]}

可能存在的问题  (1)

在 0, 1 范围外的值将被剪切：

Wolfram Language code: Graphics[Table[{CMYKColor[c, 0, 0, 0], EdgeForm[Gray], Rectangle[{4c, 0}]}, {c, 0 - 1 / 4, 1 + 1 / 4, 1 / 4}]]

在绘图函数中，利用 ColorFunctionScaling 控制变量的全局比例：

Wolfram Language code: Table[DensityPlot[x, {x, -1, 2}, {y, 0, 1}, FrameTicks -> None, ColorFunction -> (CMYKColor[#, 0, 0, 0]&), ColorFunctionScaling -> t], {t, {False, True}}]

巧妙范例  (2)

制作 CMY 颜色空间的视图：

Wolfram Language code: Graphics3D[{Opacity[.7], {CMYKColor[#], Cuboid[#, # + .1]}& /@ Tuples[Range[0, 1, .2], 3]}, Axes -> True, AxesLabel -> {"Cyan", "Magenta", "Yellow"}, Lighting -> "Neutral"]

带有不透明度的 CMYK 噪声：

Wolfram Language code: Graphics[{Pink, Disk[{100, 100}, 40], Raster[RandomReal[1, {200, 200, 5}], ColorFunction -> CMYKColor]}]
Wolfram Research (1991)，CMYKColor，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CMYKColor.html （更新于 2021 年）.

文本

Wolfram Research (1991)，CMYKColor，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CMYKColor.html （更新于 2021 年）.

CMS

Wolfram 语言. 1991. "CMYKColor." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2021. https://reference.wolfram.com/language/ref/CMYKColor.html.

APA

Wolfram 语言. (1991). CMYKColor. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/CMYKColor.html 年

BibTeX

@misc{reference.wolfram_2026_cmykcolor, author="Wolfram Research", title="{CMYKColor}", year="2021", howpublished="\url{https://reference.wolfram.com/language/ref/CMYKColor.html}", note=[Accessed: 08-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_cmykcolor, organization={Wolfram Research}, title={CMYKColor}, year={2021}, url={https://reference.wolfram.com/language/ref/CMYKColor.html}, note=[Accessed: 08-September-2026]}