WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

CapsuleShape[{{x1,y1,z1},{x2,y2,z2}},r]

点{xi,yi,zi}間の半径 r の塗り潰されたカプセルを表す．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
グラフィックス  
指定  
スタイル付け  
座標  
領域  
アプリケーション  
特性と関係  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

CapsuleShape

CapsuleShape[{{x1,y1,z1},{x2,y2,z2}},r]

点{xi,yi,zi}間の半径 r の塗り潰されたカプセルを表す．

詳細とオプション

例題

すべて開く すべて閉じる

例  (2)

原点を中心とした標準的なカプセル：

Wolfram Language code: CapsuleShape[]
Wolfram Language code: Graphics3D[%]

体積と重心：

Wolfram Language code: Volume[CapsuleShape[r]]
Wolfram Language code: RegionCentroid[CapsuleShape[]]

スコープ  (19)

グラフィックス  (9)

指定  (4)

標準的なカプセル：

Wolfram Language code: CapsuleShape[]
Wolfram Language code: Graphics3D[CapsuleShape[]]

端点が異なるカプセル：

Wolfram Language code: Graphics3D[{CapsuleShape[], CapsuleShape[{{0, 3, 0}, {0, 5, 0}}, 1]}]

半径が異なるカプセル：

Wolfram Language code: Graphics3D[{CapsuleShape[], CapsuleShape[{{-1, 5, 0}, {1, 5, 0}}, 2]}]

原点におけるカプセルの短縮形：

Wolfram Language code: Graphics3D[CapsuleShape[], Axes -> True]

スタイル付け  (4)

彩色されたカプセル：

Wolfram Language code: Table[Graphics3D[{c, CapsuleShape[]}], {c, {Red, Green, Blue, Yellow}}]

FaceFormを使って表面と裏面に異なる特性を指定することができる：

Wolfram Language code: Graphics3D[{FaceForm[Yellow, Blue], CapsuleShape[]}, PlotRange -> {{-2, 2}, {-.8, 1}, {-1, 1}}]

鏡面反射指数が異なるカプセル：

Wolfram Language code: Table[Graphics3D[{Orange, Specularity[White, n], CapsuleShape[]}], {n, {5, 20, 100}}]

赤く光る白いカプセル：

Wolfram Language code: Graphics3D[{Glow[Red], White, CapsuleShape[]}]

Opacityで曲面の不透明度を指定する：

Wolfram Language code: Table[Graphics3D[{Opacity[o], CapsuleShape[]}], {o, {0.3, 0.5, 0.9}}]

座標  (1)

点はDynamicでよい：

Wolfram Language code: DynamicModule[{x}, {Slider[Dynamic[x], {-0.5, 0.5}], Graphics3D[{CapsuleShape[], CapsuleShape[Dynamic[{{x, 1, 1}, {2, 1, 1}}], 1]}]}]

領域  (10)

埋込み次元はカプセルがある空間の次元である：

Wolfram Language code: RegionEmbeddingDimension[CapsuleShape[{{Subscript[x, 1], Subscript[y, 1], Subscript[z, 1]}, {Subscript[x, 2], Subscript[y, 2], Subscript[z, 2]}}, r]]

幾何次元は形それ自体の次元である：

Wolfram Language code: RegionDimension[CapsuleShape[{{Subscript[x, 1], Subscript[y, 1], Subscript[z, 1]}, {Subscript[x, 2], Subscript[y, 2], Subscript[z, 2]}}, r]]

帰属判定：

Wolfram Language code: ℛ = CapsuleShape[];
Wolfram Language code: {RegionMember[ℛ, {1, 0, 0}], RegionMember[ℛ, {0, 0, 0}], RegionMember[ℛ, {1, 1, 1}]}

点の帰属条件を得る：

Wolfram Language code: RegionMember[CapsuleShape[{{Subscript[x, 1], Subscript[y, 1], Subscript[z, 1]}, {Subscript[x, 2], Subscript[y, 2], Subscript[z, 2]}}, r], {x, y, z}]

体積：

Wolfram Language code: ℛ = CapsuleShape[];
Wolfram Language code: {Volume[ℛ], RegionMeasure[ℛ]}

重心：

Wolfram Language code: c = RegionCentroid[ℛ]
Wolfram Language code: Graphics3D[{{Opacity[0.5], LightBlue, ℛ}, {PointSize[Large], Red, Point[c]}}]

点からの距離：

Wolfram Language code: ℛ = CapsuleShape[];
Wolfram Language code: {RegionDistance[ℛ, {1, 0, 0}], RegionDistance[ℛ, {0, 0, 0}], RegionDistance[ℛ, {1, 1, 1}]}

点からの符号付き距離：

Wolfram Language code: ℛ = CapsuleShape[];
Wolfram Language code: {SignedRegionDistance[ℛ, {1, 0, 0}], SignedRegionDistance[ℛ, {1 / 2, 1 / 2, 1 / 2}], SignedRegionDistance[ℛ, {1, 1, 1}]}

領域内の最近点：

Wolfram Language code: ℛ = CapsuleShape[];
Wolfram Language code: {RegionNearest[ℛ, {1, 0, 0}], RegionNearest[ℛ, {2, 2, 2}]}

包み込んでいる球体までの最近点：

Wolfram Language code: spherePoints[{n_, m_}, c_, r_] := Flatten[Table[c + r{Cos[k 2π / n]Sin[l π / m], Sin[k 2π / n]Sin[l π / m], Cos[l π / m]}, {k, 0., n - 1}, {l, 0., m - 1}], 1];
Wolfram Language code: pl = spherePoints[{16, 8}, RegionCentroid[ℛ], 2]; npl = Table[RegionNearest[ℛ, p], {p, pl}];
Wolfram Language code: Legended[Graphics3D[{ℛ, {Thin, Gray, Line[Transpose[{pl, npl}]]}, {Red, Point[pl]}, {PointSize[Medium], Blue, Point[npl]}}, Lighting -> "Neutral", Boxed -> False], PointLegend[{Red, Blue}, {"start", "nearest"}]]

カプセルは有界である：

Wolfram Language code: ℛ = CapsuleShape[];
Wolfram Language code: BoundedRegionQ[ℛ]

その範囲を求める：

Wolfram Language code: b = RegionBounds[ℛ]
Wolfram Language code: Graphics3D[{{EdgeForm[White], Opacity[0.2, Yellow], Cuboid@@Transpose[b]}, ℛ}, Boxed -> False]

カプセル領域上で積分する：

Wolfram Language code: ℛ = CapsuleShape[1];
Wolfram Language code: Integrate[x y z, {x, y, z}∈ℛ]

カプセル領域上で最適化する：

Wolfram Language code: ℛ = CapsuleShape[{{1, 1, 1}, {0, 0, 0}}, 1];
Wolfram Language code: MinValue[{x y z - x y, {x, y, z}∈ℛ}, {x, y, z}]//Simplify

カプセル領域内で方程式を解く：

Wolfram Language code: ℛ = CapsuleShape[{{1, 0, 0}, {0, 0, 0}}, 1];
Wolfram Language code: Reduce[x^2 + y^2 + z^2 == 1 && x - y - z == -(1/2) && z^2 == x y + (1/4) && {x, y, z}∈ℛ, {x, y, z}]

アプリケーション  (6)

CapsuleShapeを使ってプラトンの立体を辺について可視化する：

Wolfram Language code: Row[Graphics3D[#, Boxed -> False, Method -> {"ShrinkWrap" -> True}]& /@ Apply[CapsuleShape[N[#], .1]&, PolyhedronData["Platonic", "Lines"], {2}]]

CapsuleShapeを使ってGraphPlot3Dの辺を描画する：

Wolfram Language code: GraphPlot3D[Table[i -> Mod[i ^ 2, 50], {i, 0, 50}] /. Rule[x_, x_] :> Nothing, EdgeShapeFunction -> (CapsuleShape[#, 0.1]&)]

CapsuleShapeを使ってGraphオブジェクトのために3Dで辺を描画する：

Wolfram Language code: g = SimpleGraph[Graph[Table[i -> Mod[i ^ 2, 50], {i, 0, 50}]], DirectedEdges -> False, ImageSize -> Small]

3Dにグラフを埋め込みCapsuleShapeを使う：

Wolfram Language code: Graph3D[g, EdgeShapeFunction -> (CapsuleShape[#, 0.1]&)]

CapsuleShapeを使って3D BoundaryMeshRegionオブジェクトとMeshRegionオブジェクトの辺を描画する：

Wolfram Language code: ConvexHullMesh[RandomReal[1, {25, 3}], MeshCellShapeFunction -> {1 -> (CapsuleShape[#, 0.02]&)}]

連続するカプセル（と球体）を使って棒人間を作ることができる：

Wolfram Language code: p0 = {0, 0, 0};p1 = {-6, -2, -6};p2 = {-5, -3, -15}; p3 = {-1, 2, -8};p4 = {1, 2, -16};p5 = {0, 0, 20}; p6 = {0, 0, 28};p7 = {-5, -5, 17};p8 = {-15, -3, 15}; p9 = {-7, 7, 22};p10 = {-14, 6, 21};
Wolfram Language code: leg1 = {CapsuleShape[{p0, p1}, 1], CapsuleShape[{p1, p2}, 1]}; leg2 = {CapsuleShape[{p0, p3}, 1], CapsuleShape[{p3, p4}, 1]}; back = CapsuleShape[{p0, p5}, 1]; neck = {CapsuleShape[{p5, p6}, 1], Ball[p6, 5]}; arm1 = {CapsuleShape[{p5, p7}, 1], CapsuleShape[{p7, p8}, 1]}; arm2 = {CapsuleShape[{p5, p9}, 1], CapsuleShape[{p9, p10}, 1]};
Wolfram Language code: Graphics3D[{back, leg1, leg2, neck, arm1, arm2}, ViewPoint -> {-20, -5, 0}, ImageSize -> {Automatic, 150}]

さらに，RotationTransformを使って棒人間の四肢を回転させることができる：

Wolfram Language code: r[region_, point_, angle_] := GeometricTransformation[region, RotationTransform[angle, {0, 1, 0}, point]]
Wolfram Language code: Manipulate[Graphics3D[{back, r[leg1, p0, a1], r[leg2, p0, a2], r[neck, p5, a5], r[arm1, p5, a3], r[arm2, p5, a4]}], {{a1, 0, "Left Leg"}, -Pi, Pi}, {{a2, 0, "Right Leg"}, -Pi, Pi}, {{a3, 0, "Lower Arm"}, -Pi, Pi}, {{a4, 0, "Higher Arm"}, -Pi, Pi}, {{a5, 0, "Neck"}, -Pi, Pi}, SaveDefinitions -> True]

CO2のカートリッジは，スポーツ，ソーダを作る，救命胴衣を作る等，いろいろなことに応用できる．直径約18.6ミリで，長さ約8.5ミリ，首の部分は長さ12ミリ，直径7.3ミリの12gのCO2カートリッジについて考える：

Wolfram Language code: cartrigeradius = Quantity[18.6 / 2, "Millimeters"]; neckradius = Quantity[7.3 / 2, "Millimeters"]; necklength = Quantity[12, "Millimeters"]; totallength = Quantity[82.5, "Millimeters"]; mass = Quantity[12, "Grams"];

これは，カプセルと円筒として近似することができる：

Wolfram Language code: capsulelength = totallength - necklength - 2 * cartrigeradius;
Wolfram Language code: cartridgevolume = RegionMeasure[CapsuleShape[{{0, 0, 0}, {capsulelength, 0, 0}}, cartrigeradius]] + RegionMeasure[Cylinder[{{0, 0, 0}, {necklength, 0, 0}}, neckradius]]

理想気体の法則には，（ただし， は一般ガス定数）とある．ここから，標準温度および圧力（73.15 K および1バール）におけるカートリッジ内のガスの体積を求めることができる：

Wolfram Language code: {sol} = Solve[Quantity[1, "Bars"] * volAtSTP == (mass / ChemicalData["CarbonDioxide", "MolarMass"]) * Quantity["MolarGasConstant"] * Quantity[273.15, "Kelvins"], volAtSTP]

一般的な体積と圧縮された体積の比を求めることができる：

Wolfram Language code: (volAtSTP / cartridgevolume) /. sol

特性と関係  (6)

CapsuleShapeの2DバージョンはStadiumShapeである：

Wolfram Language code: Region[StadiumShape[]]

Ballは，p1が p2に近付く際のCapsuleShapeの極限である：

Wolfram Language code: Manipulate[Graphics3D[{Yellow, Ball[], CapsuleShape[{{2, 0, 0}, {2 + n, 0, 0}}, 1]}, PlotRange -> {{-1, 5}, {-1, 1}, {-1, 1}}, ImageSize -> Small], {{n, 2}, 2, .00001}]

球体と円筒のRegionUnionから形成されたCapsuleShape：

Wolfram Language code: capsule = RegionUnion[Ball[{0, 0, 0}, 1], Cylinder[{{0, 0, 0}, {2, 0, 0}}, 1], Ball[{2, 0, 0}, 1]];
Wolfram Language code: Region[capsule]

体積は球体の体積と円筒の体積の和である：

Wolfram Language code: Volume[capsule]
Wolfram Language code: Volume[Ball[{0, 0, 0}, 1]] + Volume[Cylinder[{{0, 0, 0}, {2, 0, 0}}, 1]]

CapsuleShapeは，すべての点がLineから最大でも である：

Wolfram Language code: Subscript[ℛ, 1] = Line[{{-1, 0, 0}, {1, 0, 0}}]; Subscript[ℛ, 2] = CapsuleShape[{{-1, 0, 0}, {1, 0, 0}}, 1];
Wolfram Language code: Reduce[RegionDistance[Subscript[ℛ, 1], {x, y, z}] ≤ 1⧦RegionMember[Subscript[ℛ, 2], {x, y, z}], {x, y, z}, Reals]

ImplicitRegionは任意のCapsuleShapeを表すことができる：

Wolfram Language code: Subscript[ℛ, 1] = ImplicitRegion[(x + 1)^2 + y^2 + z^2 ≤ 1 || (x - 1)^2 + y^2 + z^2 ≤ 1 || (0 ≤ 1 + x ≤ 2 && y^2 + z^2 ≤ 1), {x, y, z}];
Wolfram Language code: Subscript[ℛ, 2] = CapsuleShape[{{-1, 0, 0}, {1, 0, 0}}, 1];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

丸いTubeはCapsuleShapeのように見える：

Wolfram Language code: Graphics3D[{CapForm["Round"], Tube[{{-1, 0, 0}, {1, 0, 0}}, 1]}]

おもしろい例題  (3)

ランダムな単位カプセル：

Wolfram Language code: Graphics3D[Table[{EdgeForm[Opacity[.3]], Hue[RandomReal[]], CapsuleShape[RandomReal[10, {2, 3}], 1]}, {20}]]

軸の周りでカプセルを回転させる：

Wolfram Language code: Graphics3D[{Opacity[0.3], EdgeForm[], Table[{ColorData["Rainbow"][Rescale[c, {0, 2Pi}]], GeometricTransformation[CapsuleShape[], RotationTransform[c, {-3, 2, -1}, {2, -1, 1}]]}, {c, 0, 2Pi, 2Pi / 18}]}]

ネストした透過的なカプセル：

Wolfram Language code: Graphics3D[{Opacity[.3], EdgeForm[Opacity[.3]], Table[CapsuleShape[{{0, 0, 0}, {0, 0, 2r}}, r], {r, 1, 5}]}, Boxed -> False]
Wolfram Research (2015), CapsuleShape, Wolfram言語関数， https://reference.wolfram.com/language/ref/CapsuleShape.html.

テキスト

Wolfram Research (2015), CapsuleShape, Wolfram言語関数， https://reference.wolfram.com/language/ref/CapsuleShape.html.

CMS

Wolfram Language. 2015. "CapsuleShape." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/CapsuleShape.html.

APA

Wolfram Language. (2015). CapsuleShape. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CapsuleShape.html

BibTeX

@misc{reference.wolfram_2026_capsuleshape, author="Wolfram Research", title="{CapsuleShape}", year="2015", howpublished="\url{https://reference.wolfram.com/language/ref/CapsuleShape.html}", note=[Accessed: 07-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_capsuleshape, organization={Wolfram Research}, title={CapsuleShape}, year={2015}, url={https://reference.wolfram.com/language/ref/CapsuleShape.html}, note=[Accessed: 07-August-2026]}