WOLFRAM

Wolfram 语言与系统参考资料中心

CaputoD[f,{x,α}]

给出函数 的卡普托分数阶积分 .

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
选项  
Assumptions  
应用  
属性和关系  
可能存在的问题  
巧妙范例  
参见
技术笔记
相关指南
历史
按以下格式引用：

CaputoD

CaputoD[f,{x,α}]

给出函数 的卡普托分数阶积分 .

更多信息和选项

  • CaputoD 也称为 f 的卡普托分数导数微分.
  • CaputoD 将 D 推广到分数阶，并统一了微积分的导数和积分的概念.
  • CaputoD 在使用分数微分方程的初始值问题来建模系统方面已经有广泛应用.
  • 的 阶卡普托分数导数的定义为 ，其中 n=max(0,TemplateBox[{alpha}, Ceiling]).
  • 分数阶导数在整数阶导数之间进行“插值”，如下例所示，函数 的 阶分数导数由 2/TemplateBox[{{3, -, alpha}}, Gamma] x^(2-alpha) 给出，其中 ：
  • 卡普托分数导数通过公式 与 FractionalD（黎曼-刘维尔分数导数）相连接.
  • 分数导数的阶 α 可以是符号数或任意实数.
  • CaputoD[{array},{x,α}] 将 CaputoD 遍历 array 的各个元素.
  • CaputoD 对输入函数的参数采取不同的 Assumptions.
  • 所有表达式，只要不显式依赖给定变量 ，都被解释为常量.

范例

打开所有单元 关闭所有单元

基本范例  (4)

计算二次函数关于 x 的半阶卡普托分数导数：

Wolfram Language code: CaputoD[x^2, {x, 1 / 2}]

二次函数关于 x 的任意阶卡普托分数导数：

Wolfram Language code: CaputoD[x^2, {x, α}]

绘制不同 时的分数导数：

Wolfram Language code: Plot[Evaluate[% /. α -> {0, 1 / 2, 9 / 10, 1}], {x, 0, 1}, Rule[...]]

对于 大于零，常数关于 x 的卡普托分数导数为 0：

Wolfram Language code: CaputoD[c, {x, 2 / 3}]

MittagLefflerE 的卡普托分数导数：

Wolfram Language code: CaputoD[MittagLefflerE[a, x], {x, 1 / 2}]

范围  (4)

Exp 函数关于 x 的卡普托分数导数：

Wolfram Language code: CaputoD[Exp[x], {x, 1 / 2}]

Sin 函数关于 x 的卡普托分数导数：

Wolfram Language code: CaputoD[Sin[x], {x, 5 / 2}]

这个表达式可以进一步化简：

Wolfram Language code: %//FunctionExpand//FullSimplify

某些 BesselJ 函数的卡普托分数导数：

Wolfram Language code: CaputoD[BesselJ[1 / 3, x], {x, 1 / 2}]

CaputoD 函数的一般形式的拉普拉斯变换：

Wolfram Language code: LaplaceTransform[CaputoD[f[t], {t, 3 / 2}], t, s]

将公式应用于 Sin：

Wolfram Language code: % /. {f[t_] -> Sin[t], f'[t_] -> Cos[t]}//Simplify

将 LaplaceTransform 应用于 Sin 的 CaputoD 得到相同的结果：

Wolfram Language code: LaplaceTransform[CaputoD[Sin[t], {t, 3 / 2}], t, s]//FullSimplify

选项  (1)

Assumptions  (1)

CaputoD 可能返回 ConditionalExpression：

Wolfram Language code: CaputoD[MittagLefflerE[a, x], {x, 1 / 2}]

使用 Assumptions 限制参数将简化输出：

Wolfram Language code: CaputoD[MittagLefflerE[a, x], {x, 1 / 2}, Assumptions -> {a > 0}]

应用  (8)

计算三次函数的半阶卡普托分数导数：

Wolfram Language code: CaputoD[x ^ 3, {x, 1 / 2}]

重复半阶卡普托分数导数，得到三次函数的常导数：

Wolfram Language code: CaputoD[%, {x, 1 / 2}]

使用卡普托分数积分运算恢复初始函数：

Wolfram Language code: CaputoD[CaputoD[CaputoD[%, {x, -1 / 3}], {x, -1 / 3}], {x, -1 / 3}]

求解包含半阶卡普托导数的分数导数方程：

Wolfram Language code: sol = DSolve[CaputoD[y[x], {x, 1 / 2}] - y[x] == 0, y[x], x]

添加一个初始条件：

Wolfram Language code: sol = DSolve[{CaputoD[y[x], {x, 1 / 2}] - y[x] == 0, y[0] == 1 / 2}, y[x], x]

绘制该解的图形：

Wolfram Language code: Plot[Evaluate[y[x] /. sol[[1]]], {x, 0, 1}]

求解分数微分方程：

Wolfram Language code: sol = DSolve[{CaputoD[y[x], {x, 21 / 10}] + 10y[x] == 0, y[0] == 1, y'[0] == 0, y''[0] == 0}, y[x], x]

绘制解的图形：

Wolfram Language code: Plot[y[x] /. %, {x, 0, 10}]

求解一个混合分数阶微分积分方程：

Wolfram Language code: DSolve[{CaputoD[y[x], {x, 1 / 2}] - CaputoD[y[x], {x, -1 / 2}] == 1, y[0] == 0}, y[x], x]

求解包含两个不同阶卡普托导数的分数微分方程：

Wolfram Language code: sol = DSolve[{CaputoD[y[x], {x, 3 / 4}] == -2CaputoD[y[x], {x, 1 / 2}] + y[x], y[0] == 1}, y[x], x]//FullSimplify

求解由两个分数微分方程组成的方程组，包括函数的 CaputoD 分数导数：

Wolfram Language code: eqns = {CaputoD[x1[t], {t, 0.95}] == 2x1[t] - x2[t], CaputoD[x2[t], {t, 0.95}] == 4x1[t] - 3x2[t], x1[0] == 1.2, x2[0] == 4.2}; sol = DSolve[eqns, {x1, x2}, t]

验证解：

Wolfram Language code: eqns /. sol//Simplify

此解的参数图：

Wolfram Language code: ParametricPlot[Evaluate[{x1[t], x2[t]} /. sol], {t, 0, 2}]

求解向量形式的由两个分数微分方程组成的方程组：

Wolfram Language code: B = {{0, 1}, {-1, 0}}; a = 16 / 17; v = {-3, 5}; sol = DSolve[{CaputoD[x[t], {t, a}] == B. x[t], x[0] == v}, Element[x[t], Vectors[2]], t]

绘制解的图形：

Wolfram Language code: Plot[Evaluate[x[t] /. sol[[1]]], {t, 0, 10}]

以参数方式绘制解的图形：

Wolfram Language code: ParametricPlot[Evaluate[x[t] /. sol[[1]]], {t, 0, 20}]

求解向量形式的由三个分数微分方程组成的方程组：

Wolfram Language code: B = {{-1, 0, 0}, {2, 1, -9}, {3, 6, 1}}; a = 0.95; v = {-3, 5, 0}; sol = DSolve[{CaputoD[x[t], {t, a}] == B. x[t], x[0] == v}, Element[x[t], Vectors[3]], t]

绘制解的图形：

Wolfram Language code: Plot[Evaluate[x[t] /. sol[[1]]], {t, 0, 1}]

以参数方式绘制解的图形：

Wolfram Language code: ParametricPlot3D[Evaluate[x[t] /. sol[[1]]], {t, 0, 1}]

属性和关系  (7)

CaputoD 对于全体实数 有定义：

Wolfram Language code: CaputoD[x ^ 2, {x, 4 / 5}]
Wolfram Language code: CaputoD[x ^ 2, {x, -4 / 5}]

0 阶卡普托分数导数是函数本身：

Wolfram Language code: CaputoD[x ^ 2, {x, 0}]

CaputoD 对于复数阶 没有定义：

Wolfram Language code: CaputoD[x ^ 2, {x, -4 / 5 + I}]

对于正分数阶，常数的卡普托分数导数为 0：

Wolfram Language code: CaputoD[c, {x, 1 / 2}]

而一般规则是：

Wolfram Language code: CaputoD[c, {x, α}]

对于所有负数阶 ，CaputoD 与 FractionalD 一致：

Wolfram Language code: CaputoD[Sin[a x], {x, -1 / 2}]

与 FractionalD 的输出比较：

Wolfram Language code: FractionalD[Sin[a x], {x, -1 / 2}]

将阶数 限制为负值，CaputoD 将自动生成 FractionalD 输出：

Wolfram Language code: CaputoD[Sin[a x], {x, α}, Assumptions -> {α < 0}]
Wolfram Language code: % /. α -> -1 / 2

计算一个函数在某点的卡普托分数导数：

Wolfram Language code: N[CaputoD[Sin[x]Cos[x - 1], {x, 1 / 2}] /. x -> 1 / 3]//AbsoluteTiming

使用 NCaputoD 函数可以加快数值计算：

Wolfram Language code: NCaputoD[Sin[x]Cos[x - 1], {x, 1 / 2}, 1 / 3]//AbsoluteTiming

可能存在的问题  (1)

CaputoD 分数导数可能对某些分数阶数没有定义：

Wolfram Language code: CaputoD[x^1 / 3, {x, 5 / 3}]

对于其他分数阶数该函数有定义：

Wolfram Language code: CaputoD[x^1 / 3, {x, 2 / 3}]

巧妙范例  (1)

为一些特殊函数创建一个半阶卡普托分数导数表：

Wolfram Language code: flist = {E ^ (x), x ^ 2, Sin[x], ArcTan[x], BesselJ[0, x], Hypergeometric1F1[a, b, x]};
Wolfram Language code: Grid[Join[{{f[x], Subsuperscript[D, x, α][f[x]]}}, Transpose[{flist, Map[CaputoD[#, {x, 1 / 2}]&, flist]}]], IconizedObject[«Grid options»]]//TraditionalForm//FullSimplify
Wolfram Research (2022)，CaputoD，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CaputoD.html.

文本

Wolfram Research (2022)，CaputoD，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CaputoD.html.

CMS

Wolfram 语言. 2022. "CaputoD." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/CaputoD.html.

APA

Wolfram 语言. (2022). CaputoD. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/CaputoD.html 年

BibTeX

@misc{reference.wolfram_2026_caputod, author="Wolfram Research", title="{CaputoD}", year="2022", howpublished="\url{https://reference.wolfram.com/language/ref/CaputoD.html}", note=[Accessed: 16-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_caputod, organization={Wolfram Research}, title={CaputoD}, year={2022}, url={https://reference.wolfram.com/language/ref/CaputoD.html}, note=[Accessed: 16-August-2026]}