Cells

Cells[]

現行ノートブックのセルに対応するCellObject式のリストを返す．

Cells[obj]

obj 中のCellObject式のリストを返す．

Cells[NotebookSelection[notebook]]

現在選択中のセルのCellObject式のリストを返す．

詳細とオプション

Cellsは，obj の値が有効な場合は常にリストを返す．その他の場合は$Failedを返す．
obj はNotebookObjectあるいはCellObjectでよい．obj がCellObjectの場合，Cellsは指定されたセル中のインラインセルを返す．
Cellsは，以下のオプションを1つあるいはそれ以上指定することで，返されたCellObject式のリストをさらに精密にすることができる．

	AttachedCell	Trueの場合はAttachCellが作成したセルだけをマッチする
	CellID	マッチするセルID
	CellLabel	マッチするIn/Outラベルの文字列
	CellStyle	マッチする名前付きセルスタイル
	CellTags	マッチするセルタグ
	CounterAssignments	カウンタ値が与えられた値とマッチするセル
	CounterIncrements	指定されたカウンタを増分するセル
	DockedCell	Trueの場合はDockedCellsが作成したセルだけをマッチする
	Evaluator	指定された評価子にマッチするセル
	StripCellGrouping	結果にセルのグループ化情報を含めるかどうか
	GeneratedCell	Trueの場合は生成された出力セルのみをマッチし，Falseの場合は生成されたものではないセルのみをマッチする

Cellsに対して複数のオプションが与えられた場合，返される結果にはすべての条件を満足するセルにマッチするCellObject式のみが含まれる．
Cellsの任意の1つのオプションに値のリストが与えられた場合，そのオプションは与えられた値のどれともマッチする．
ノートブック内の選択範囲が1つのセル内の場合，Cells[NotebookSelection[notebook]]は選択範囲を含むセルを返す．
StripCellGroupingFalseの設定のとき，セルグループは結果でネストしたリストとして表される可能性がある．

例題

すべて開くすべて閉じる

例 (4)

評価ノートブックのセルの範囲を返す：

Wolfram Language code: Cells[][[30 ;; 35]]

指定されたノートブックのすべてのセルを返す：

Wolfram Language code: Cells[CreateDocument[{TextCell["1", "Title"], TextCell["2", "Text"]}]]

指定されたセル内のすべてのインラインセルを返す：

Wolfram Language code:

CellPrint[ExpressionCell[Row[{"outer", TextCell["inner1"], TextCell["inner2"]}, " "], "Print", CellTags -> "basic example"]];
c = First[Cells[CellTags -> "basic example"]];
Cells[c]

評価ノートブックの最初の3つの入力セルを返す：

Wolfram Language code: Cells[CellStyle -> {"Input"}][[1 ;; 3]]

スコープ (5)

選択された任意のセルのリストを返す：

Wolfram Language code:

SelectionMove[EvaluationNotebook[], All, EvaluationCell];
Cells[NotebookSelection[EvaluationNotebook[]]]

任意の値にマッチする選択されたセルのオプション値のリストを与える：

Wolfram Language code:

nb = CreateDocument[{TextCell["a", "Title"], Cell["b", "Subtitle"], Cell["c", "Text"]}];
Cells[nb, CellStyle -> {"Title", "Subtitle"}]

リストされたすべての基準にマッチするセルの共通集合を複数のオプションを使って選択する：

Wolfram Language code:

nb = CreateDocument[{TextCell["a", "Title", CellTags -> {"1234"}], TextCell["b", "Text", CellTags -> {"1234"}], TextCell["c", "Title"]}];
Cells[nb, CellStyle -> "Title", CellTags -> "1234"]

NotebookSelectionを使って選択したセルを識別する：

Wolfram Language code: SelectionMove[EvaluationCell[], Before, CellContents];Cells[NotebookSelection[EvaluationNotebook[]]]

NotebookSelectionを使って選択範囲で選択したすべてのセルを識別する：

Wolfram Language code:

Do[CellPrint[TextCell["example", "Print", CellTags -> "range example"]], 3];
NotebookLocate["range example"];
Cells[NotebookSelection[EvaluationNotebook[]]]

オプション (9)

AttachedCell (1)

この入力セルにセルを追加する：

Wolfram Language code:

parentCell = EvaluationCell[];
AttachCell[parentCell, TextCell["abc"]];

セルに貼付されたすべてのセルを返す：

Wolfram Language code: Cells[parentCell, AttachedCell -> True]

貼付されたセルを削除する：

Wolfram Language code: NotebookDelete[%]

CellID (1)

指定されたCellIDのセルを返す：

Wolfram Language code:

CellPrint[TextCell["Cell with ID", "Output", CellID -> 56789]];
Cells[CellID -> 56789]

CellLabel (1)

指定されたセルラベルを持つすべてのセルを返す：

Wolfram Language code: Cells[CellLabel -> "In[1]:="]

CellStyle (1)

指定されたスタイルのセルをすべて返す：

Wolfram Language code: Cells[CellStyle -> "ExampleSubsection"]

CellTags (1)

指定されたセルタグのセルを返す：

Wolfram Language code:

CellPrint[TextCell["abc", "Output", CellTags -> {"abcxyz"}, ShowCellTags -> True]];
Cells[CellTags -> {"abcxyz"}]

DockedCell (1)

ドックに入ったセルがあるノートブックを作成する：

Wolfram Language code:

nb = CreateNotebook[DockedCells -> {Cell["a docked cell"]}, WindowToolbars -> {}];
Cells[nb, DockedCell -> True]

ドックに入ったセルを読む：

Wolfram Language code: NotebookRead[First[%]]

Evaluator (1)

指定された評価器のセルをすべて返す：

Wolfram Language code:

CellPrint[TextCell["abc", "Output", Evaluator -> "My Kernel"]];
Cells[Evaluator -> "My Kernel"]

GeneratedCell (1)

出力スタイルと印刷スタイルのセルを含めて，生成されたセルのみをノートブックから取り出す：

Wolfram Language code:

nb = CreateDocument[{TextCell["Section", "Section"], ExpressionCell[Defer[Print["stuff"];2 + 2], "Input"]}];
NotebookEvaluate[nb, InsertResults -> True];
Cells[nb, GeneratedCell -> True]

生成されたものではないセルのみを取り出す：

Wolfram Language code: Cells[nb, GeneratedCell -> False]

StripCellGrouping (1)

セルがどのようにグループ化されているかについての情報を返す：

Wolfram Language code:

nb = CreateDocument[{TextCell["Section", "Section"], ExpressionCell[Defer[2 + 2], "Input"], ExpressionCell[4, "Output"]}];
Cells[nb, StripCellGrouping -> False]

アプリケーション (2)

ノートブック中の生成されたすべてのセルを削除する：

Wolfram Language code:

nb = CreateDocument[Table[ExpressionCell[n, "Input"], {n, 10}]];
NotebookEvaluate[nb, InsertResults -> True];

Wolfram Language code: NotebookDelete[Cells[nb, GeneratedCell -> True]]

指定されたスタイルのセルすべてを他のスタイルに変える：

Wolfram Language code:

nb = CreateDocument[{TextCell["abc", "Section"], TextCell["def", "Text"], TextCell["ghi", "Section"], TextCell["jkl", "Text"]}];

Wolfram Language code: Scan[(CurrentValue[#, StyleNames] = "Subsection")&, Cells[nb, CellStyle -> "Section"]]

特性と関係 (1)

Cellsは基準とマッチするかどうかを見るのにトップレベルのセルのみをスキャンする．インラインセルは見ない：

Wolfram Language code:

nb = CreateDocument[{ExpressionCell[Row[{a, TextCell["b", "Text"]}], "InlineFormula"]}];
Cells[nb, CellStyle -> "Text"]

しかし，選択範囲がインラインセル内にある合はインラインセルのCellObjectを得ることができる：

Wolfram Language code:

NotebookFind[nb, "b"];
Cells[NotebookSelection[nb]]

考えられる問題 (1)

CellsはNotebookObjectが存在しない場合は$Failedを返す：

Wolfram Language code:

NotebookClose[nb = CreateDocument[]];
Cells[nb]

Top

その他のラーニングリソース

テクニカルサポート

Wolframソリューション

教育のためのWolframソリューション

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

Cells

詳細とオプション

例題

例 (4)

スコープ (5)

オプション (9)

AttachedCell (1)

CellID (1)

CellLabel (1)

CellStyle (1)

CellTags (1)

DockedCell (1)

Evaluator (1)

GeneratedCell (1)

StripCellGrouping (1)

アプリケーション (2)

特性と関係 (1)

考えられる問題 (1)

テキスト

CMS

APA

BibTeX

BibLaTeX

Cells

詳細とオプション

例題

例 (4)

スコープ (5)

オプション (9)

AttachedCell (1)

CellID (1)

CellLabel (1)

CellStyle (1)

CellTags (1)

DockedCell (1)

Evaluator (1)

GeneratedCell (1)

StripCellGrouping (1)

アプリケーション (2)

特性と関係 (1)

考えられる問題 (1)

関連項目

関連するガイド

関連するワークフロー

履歴

テキスト

CMS

APA

BibTeX

BibLaTeX