Wolfram 语言与系统参考资料中心

Cells

Cells[]

返回当前笔记本中对应于单元的 CellObject 表达式列表.

Cells[obj]

返回 obj 中 CellObject 表达式的列表.

Cells[NotebookSelection[notebook]]

对当前选中的单元，返回 CellObject 表达式列表.

更多信息和选项

如果 obj 的值有效，Cells 总是返回一个列表，否则返回 $Failed.
obj 可以是 NotebookObject 或者 CellObject. 如果 obj 是 CellObject，则 Cells 返回在指定单元中的内嵌单元.
Cells 能够通过指定一个或者多个下列选项，进一步修正返回的 CellObject 表达式的列表.

	AttachedCell	如果为 True，则只匹配由 AttachCell 创建的单元
	CellID	需要匹配的单元 ID
	CellLabel	需要匹配的 In/Out 标签字符串
	CellStyle	需要匹配的已命名单元样式
	CellTags	需要匹配的单元标签
	CounterAssignments	计数器数值与给定数值匹配的单元
	CounterIncrements	对给定计数器累加的单元
	DockedCell	如果为 True，则只匹配由 DockedCells 创建的单元
	Evaluator	匹配指定计算器的单元
	StripCellGrouping	是否在结果中包含单元分组信息
	GeneratedCell	如果 True，只匹配生成的输出单元，如果 False，只匹配非生成单元

当传递给 Cells 多个选项时，返回的结果将只包含满足所有条件的匹配单元的 CellObject 表达式.
如果对 Cells 的任意单个选项给出一个数值列表，那么它会匹配任意给定数值.
如果笔记本中的选择位于单元内，那么 Cells[NotebookSelection[notebook]] 返回包含选择内容的单元.
设置 StripCellGroupingFalse，单元组将在结果中以可能嵌套的列表表示.

范例

打开所有单元关闭所有单元

基本范例 (4)

返回计算笔记本中的单元范围：

Wolfram Language code: Cells[][[30 ;; 35]]

返回给定笔记本中所有单元：

Wolfram Language code: Cells[CreateDocument[{TextCell["1", "Title"], TextCell["2", "Text"]}]]

返回给定单元中的所有内联单元：

Wolfram Language code:

CellPrint[ExpressionCell[Row[{"outer", TextCell["inner1"], TextCell["inner2"]}, " "], "Print", CellTags -> "basic example"]];
c = First[Cells[CellTags -> "basic example"]];
Cells[c]

返回计算笔记本中的前三个输入单元：

Wolfram Language code: Cells[CellStyle -> {"Input"}][[1 ;; 3]]

范围 (5)

返回任意选择单元的列表：

Wolfram Language code:

SelectionMove[EvaluationNotebook[], All, EvaluationCell];
Cells[NotebookSelection[EvaluationNotebook[]]]

对一个选项给出一个数值列表，以选择匹配任意数值的单元：

Wolfram Language code:

nb = CreateDocument[{TextCell["a", "Title"], Cell["b", "Subtitle"], Cell["c", "Text"]}];
Cells[nb, CellStyle -> {"Title", "Subtitle"}]

使用多个选项，以选择匹配所有列出标准的单元的交集：

Wolfram Language code:

nb = CreateDocument[{TextCell["a", "Title", CellTags -> {"1234"}], TextCell["b", "Text", CellTags -> {"1234"}], TextCell["c", "Title"]}];
Cells[nb, CellStyle -> "Title", CellTags -> "1234"]

使用 NotebookSelection 识别选定单元：

Wolfram Language code: SelectionMove[EvaluationCell[], Before, CellContents];Cells[NotebookSelection[EvaluationNotebook[]]]

使用 NotebookSelection 识别在范围选择中的所有选定单元：

Wolfram Language code:

Do[CellPrint[TextCell["example", "Print", CellTags -> "range example"]], 3];
NotebookLocate["range example"];
Cells[NotebookSelection[EvaluationNotebook[]]]

选项 (9)

AttachedCell (1)

将一个单元附加到该输入单元中：

Wolfram Language code:

parentCell = EvaluationCell[];
AttachCell[parentCell, TextCell["abc"]];

返回附加到该单元上的所有单元：

Wolfram Language code: Cells[parentCell, AttachedCell -> True]

删除所有附加单元：

Wolfram Language code: NotebookDelete[%]

CellID (1)

返回具有给定 CellID 的单元：

Wolfram Language code:

CellPrint[TextCell["Cell with ID", "Output", CellID -> 56789]];
Cells[CellID -> 56789]

CellLabel (1)

返回具有给定单元标签的所有单元：

Wolfram Language code: Cells[CellLabel -> "In[1]:="]

CellStyle (1)

返回具有给定样式的所有单元：

Wolfram Language code: Cells[CellStyle -> "ExampleSubsection"]

CellTags (1)

返回具有给定单元标签的单元：

Wolfram Language code:

CellPrint[TextCell["abc", "Output", CellTags -> {"abcxyz"}, ShowCellTags -> True]];
Cells[CellTags -> {"abcxyz"}]

DockedCell (1)

创建一个有停驻单元的笔记本：

Wolfram Language code:

nb = CreateNotebook[DockedCells -> {Cell["a docked cell"]}, WindowToolbars -> {}];
Cells[nb, DockedCell -> True]

读取停驻单元：

Wolfram Language code: NotebookRead[First[%]]

Evaluator (1)

用给定计算器返回所有单元：

Wolfram Language code:

CellPrint[TextCell["abc", "Output", Evaluator -> "My Kernel"]];
Cells[Evaluator -> "My Kernel"]

GeneratedCell (1)

只从笔记本获取生成单元，包括输出和打印单元：

Wolfram Language code:

nb = CreateDocument[{TextCell["Section", "Section"], ExpressionCell[Defer[Print["stuff"];2 + 2], "Input"]}];
NotebookEvaluate[nb, InsertResults -> True];
Cells[nb, GeneratedCell -> True]

只获取非生成的单元：

Wolfram Language code: Cells[nb, GeneratedCell -> False]

StripCellGrouping (1)

返回有关单元分组方式的信息：

Wolfram Language code:

nb = CreateDocument[{TextCell["Section", "Section"], ExpressionCell[Defer[2 + 2], "Input"], ExpressionCell[4, "Output"]}];
Cells[nb, StripCellGrouping -> False]

应用 (2)

删除笔记本中所有的生成的单元：

Wolfram Language code:

nb = CreateDocument[Table[ExpressionCell[n, "Input"], {n, 10}]];
NotebookEvaluate[nb, InsertResults -> True];

Wolfram Language code: NotebookDelete[Cells[nb, GeneratedCell -> True]]

把所有单元的给定样式改成另一个样式：

Wolfram Language code:

nb = CreateDocument[{TextCell["abc", "Section"], TextCell["def", "Text"], TextCell["ghi", "Section"], TextCell["jkl", "Text"]}];

Wolfram Language code: Scan[(CurrentValue[#, StyleNames] = "Subsection")&, Cells[nb, CellStyle -> "Section"]]

属性和关系 (1)

为了与标准匹配，Cells 只扫描顶层单元，而不是内联单元：

Wolfram Language code:

nb = CreateDocument[{ExpressionCell[Row[{a, TextCell["b", "Text"]}], "InlineFormula"]}];
Cells[nb, CellStyle -> "Text"]

但是，如果所选择的对象位于内联单元中，您可以获取内联单元的 CellObject：

Wolfram Language code:

NotebookFind[nb, "b"];
Cells[NotebookSelection[nb]]

可能存在的问题 (1)

如果 NotebookObject 不存在，Cells 返回 $Failed：

Wolfram Language code:

NotebookClose[nb = CreateDocument[]];
Cells[nb]

Top

更多学习资源

技术支持

数据科学、金融与商业

工程

科学与技术

教育科技

教育举措

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

Cells

更多信息和选项

范例

基本范例 (4)

范围 (5)

选项 (9)

AttachedCell (1)

CellID (1)

CellLabel (1)

CellStyle (1)

CellTags (1)

DockedCell (1)

Evaluator (1)

GeneratedCell (1)

StripCellGrouping (1)

应用 (2)

属性和关系 (1)

可能存在的问题 (1)

文本

CMS

APA

BibTeX

BibLaTeX

Cells

更多信息和选项

范例

基本范例 (4)

范围 (5)

选项 (9)

AttachedCell (1)

CellID (1)

CellLabel (1)

CellStyle (1)

CellTags (1)

DockedCell (1)

Evaluator (1)

GeneratedCell (1)

StripCellGrouping (1)

应用 (2)

属性和关系 (1)

可能存在的问题 (1)

参见

相关指南

相关的工作流程

历史

文本

CMS

APA

BibTeX

BibLaTeX