WOLFRAM

Wolfram 语言与系统参考资料中心

CenterArray[a,n]

创建长度为 n 的列表，其中元素 a 居于中心位置，其他元素皆为零.

CenterArray[a,{n1,n2,…}]

创建 n1×n2×… 的数组，其中数组 a 居于中心位置，其他元素皆为零.

CenterArray[a,nspec,pad]

用 pad 代替零作为背景元素.

CenterArray[nspec]

创建一个数组，其中只有一个 1 居于中心位置，其他元素皆为零.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
数据  
输出维数  
填充  
应用  
属性和关系  
可能存在的问题  
参见
相关指南
历史
按以下格式引用：

CenterArray

CenterArray[a,n]

创建长度为 n 的列表，其中元素 a 居于中心位置，其他元素皆为零.

CenterArray[a,{n1,n2,…}]

创建 n1×n2×… 的数组，其中数组 a 居于中心位置，其他元素皆为零.

CenterArray[a,nspec,pad]

用 pad 代替零作为背景元素.

CenterArray[nspec]

创建一个数组，其中只有一个 1 居于中心位置，其他元素皆为零.

更多信息

  • 输入 a 可以是列表、完全数组、不规则数组或任何形式的数组，如 SparseArray 对象.
  • CenterArray 总是产生完全数组.
  • CenterArray[a,nspec,pad,SparseArray] 产生 SparseArray 对象.
  • 如果 expr 不是列表，则 CenterArray[expr,…] 等价于 CenterArray[{expr},…].
  • 在可能的情况下，CenterArray[a,n] 会尝试在 a 的两边放上同样多的填充元素. 如果不可能，将多余元素放在右边.
  • 在 CenterArray[a,{n1,n2,…}] 这种形式中，任意 ni 都可以被 Inherited，被认为是 a 的相应的维数，这时不添加任何填充元素.
  • 如果数字的秩较大，将 a 放在最深一层.
  • 如果想了解填充值 pad 的可能设置，请查看 ArrayPad 的参考页面.

范例

打开所有单元 关闭所有单元

基本范例  (3)

生成长度为 5 的列表，将 1 放在中间：

Wolfram Language code: CenterArray[5]

生成长度为 5 的列表，将指定元素放在中间：

Wolfram Language code: CenterArray[x, 5]

在二维数组的中心放置一个元素：

Wolfram Language code: CenterArray[x, {5, 5}]//MatrixForm

范围  (11)

数据  (9)

在二维数组中将列表置于中心：

Wolfram Language code: CenterArray[{1, 2, 3}, {5, 5}]//MatrixForm

创建稀疏数组：

Wolfram Language code: CenterArray[{1, 2, 3}, {5, 5}, 0, SparseArray]
Wolfram Language code: Normal[%]//MatrixForm

将矩阵居中，并使其有 3 行：

Wolfram Language code: CenterArray[{{1, 2, 3}, {4, 5, 6}}, 3]//MatrixForm

将矩阵居中，使其维数为 {3,4}：

Wolfram Language code: CenterArray[{{1, 2, 3}, {4, 5, 6}}, {3, 4}]//MatrixForm

创建不规则数组（ragged array）：

Wolfram Language code: CenterArray[{{1, 2}, {3}}, 2]//MatrixForm

将混合输入置于中心：

Wolfram Language code: CenterArray[{{1, 2, 3}, SparseArray[2 -> x, 3]}, {3, 4}]//MatrixForm

创建行数多于列数的数组：

Wolfram Language code: CenterArray[{{1, 2, 3}, {4, 5, 6}}, {4, 1}]//MatrixForm

将二维稀疏数组置中：

Wolfram Language code: CenterArray[SparseArray[{2, 2} -> x, {2, 3}, 9], {3, 5}]
Wolfram Language code: Normal[%]//MatrixForm

创建二维稀疏数组：

Wolfram Language code: CenterArray[{{1, 2, 3}}, 5, 0, SparseArray]
Wolfram Language code: Normal[%]//MatrixForm

输出维数  (1)

返回更小的列表：

Wolfram Language code: CenterArray[{1, 2, 3, 4, 5, 6, 7, 8, 9}, 3]

填充  (1)

默认填充为零：

Wolfram Language code: CenterArray[{1, 2, 3}, 6]

指定不同的填充：

Wolfram Language code: CenterArray[{1, 2, 3}, 6, Missing[]]

使用 "Extrapolated" 填充替代：

Wolfram Language code: CenterArray[{1, 2, 3}, 6, "Extrapolated"]

应用  (6)

提取数组中心的元素：

Wolfram Language code: CenterArray[(⁠| | | | | | | -- | -- | -- | -- | -- | | 1 | 2 | 3 | 4 | 5 | | 6 | 7 | 8 | 9 | 10 | | 11 | 12 | 13 | 14 | 15 |⁠), {2, 3}]

对几个数组进行操作，使得它们有同样的维数：

Wolfram Language code: list = {RandomReal[1, {10, 1}], RandomReal[1, {20, 3}], RandomReal[1, {5, 2}], RandomReal[1, {15, 2}]};
Wolfram Language code: c = CenterArray[list, Inherited];
Wolfram Language code: Dimensions[c]

对几个列表的元素进行操作，使得列表的长度都为 3：

Wolfram Language code: list = {{9}, {4, 5}, {5, 5, 3}};
Wolfram Language code: c = CenterArray[list, {Inherited, 3}]

对长度一致的列表应用对维数有要求的算符：

Wolfram Language code: SquaredEuclideanDistance[#, {1, -1, 0}]& /@ c

将维数不同的完全数组变成维数相同的完全数组：

Wolfram Language code: CenterArray[{{{1, 2, 3}, {4, 5, 6}}, {{a, b}, {c, d}, {e, f}}}, {All, All, All}]

根据低通核创建锐化核：

Wolfram Language code: lowpasskern = GaussianMatrix[3];
Wolfram Language code: sharpeningkern = CenterArray[2, Dimensions@lowpasskern] - lowpasskern;

通过与算出的核卷积锐化一幅图像：

Wolfram Language code: ImageConvolve[[image], sharpeningkern]

显示一组图，其中有些图形缺失：

Wolfram Language code: t = {{[image], [image], [image]}, {[image]}, {[image], [image]}};
Wolfram Language code: CenterArray[t, {3, 3}, Text[Style["?", Red, 50]]]//GraphicsGrid

缺省情况下，GraphicsGrid 将缺失的空位放在后面：

Wolfram Language code: t//GraphicsGrid

属性和关系  (3)

如果填充元素的数目是一个奇数，把多余元素放在右边：

Wolfram Language code: CenterArray[{1, 2}, 7]

二维输入：

Wolfram Language code: CenterArray[{{1, 2}, {3, 4}, {5, 6}}, {6, 3}]

不考虑指定的填充值，保留稀疏数组背景元素的值：

Wolfram Language code: sa = SparseArray[2 -> 5, 4, x]
Wolfram Language code: Normal[sa]
Wolfram Language code: CenterArray[sa, 8, 0]
Wolfram Language code: Normal[%]

结果的精度取输入数组和填充值中最小的精度：

Wolfram Language code: a = {1., 2.}; pad = 0;
Wolfram Language code: Precision /@ {a, pad}
Wolfram Language code: CenterArray[a, 4, pad]
Wolfram Language code: Precision[%]

可能存在的问题  (2)

不能用非恒定值填充空缺的值：

Wolfram Language code: CenterArray[{{1, 2}, {}}, {3, 3}, "Fixed"]

用常数来填充：

Wolfram Language code: CenterArray[{{1, 2}, {}}, {3, 3}, 5]

这里不能将不规则输入居中排列，因为输入不是深度相同的完全数组列表：

Wolfram Language code: x = {{1, 2}, {{3}}};
Wolfram Language code: Depth /@ x
Wolfram Language code: CenterArray[x, {4, 4, 2}]

使用指定深度：

Wolfram Language code: n = Max[Depth /@ x]; x2 = Table[CenterArray[a, ConstantArray[Inherited, n]], {a, x}]

将所得数组置于秩为 3 的数组的中心位置：

Wolfram Language code: CenterArray[x2, {4, 4, 2}]
Wolfram Research (2016)，CenterArray，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CenterArray.html.

文本

Wolfram Research (2016)，CenterArray，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CenterArray.html.

CMS

Wolfram 语言. 2016. "CenterArray." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/CenterArray.html.

APA

Wolfram 语言. (2016). CenterArray. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/CenterArray.html 年

BibTeX

@misc{reference.wolfram_2026_centerarray, author="Wolfram Research", title="{CenterArray}", year="2016", howpublished="\url{https://reference.wolfram.com/language/ref/CenterArray.html}", note=[Accessed: 17-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_centerarray, organization={Wolfram Research}, title={CenterArray}, year={2016}, url={https://reference.wolfram.com/language/ref/CenterArray.html}, note=[Accessed: 17-August-2026]}