WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

CharacteristicFunction[dist,t]

分布 dist についての特性関数を変数 t の関数として与える．

CharacteristicFunction[dist,{t1,t2,…}]

多変量分布 dist の特性関数を変数 t1, t2, …の関数として与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
テクニカルノート
関連するガイド
履歴
引用書式

CharacteristicFunction

CharacteristicFunction[dist,t]

分布 dist についての特性関数を変数 t の関数として与える．

CharacteristicFunction[dist,{t1,t2,…}]

多変量分布 dist の特性関数を変数 t1, t2, …の関数として与える．

詳細

例題

すべて開く すべて閉じる

例  (4)

正規分布についての特性関数(cf)：

Wolfram Language code: CharacteristicFunction[NormalDistribution[μ, σ], t]

二項分布についての特性関数：

Wolfram Language code: CharacteristicFunction[BinomialDistribution[n, p], t]

二変量正規分布の特性関数：

Wolfram Language code: CharacteristicFunction[BinormalDistribution[ρ], {Subscript[t, 1], Subscript[t, 2]}]

多項分布の特性関数：

Wolfram Language code: CharacteristicFunction[MultinomialDistribution[n, {Subscript[p, 1], Subscript[p, 2], Subscript[p, 3]}], {Subscript[t, 1], Subscript[t, 2], Subscript[t, 3]}]

スコープ  (8)

特定の連続分布の特性関数：

Wolfram Language code: CharacteristicFunction[StudentTDistribution[5], t]

特定の離散分布の特性関数：

Wolfram Language code: CharacteristicFunction[DiscreteUniformDistribution[{4, 10}], t]

特定の値における特性関数：

Wolfram Language code: CharacteristicFunction[HalfNormalDistribution[1], 2]

数値的に評価された特性関数：

Wolfram Language code: CharacteristicFunction[LogisticDistribution[0, 1], 2.0]

任意精度で結果を求める：

Wolfram Language code: CharacteristicFunction[LogisticDistribution[0, 1], N[2, 25]]

定式化されている分布について特性関数を計算する：

Wolfram Language code: dist = ProbabilityDistribution[(BesselK[0, x]/Pi / 2), {x, 0, ∞}];
Wolfram Language code: CharacteristicFunction[dist, t]

母数混合分布の特性関数を求める：

Wolfram Language code: dist = ParameterMixtureDistribution[LaplaceDistribution[0, σ], σUniformDistribution[]];
Wolfram Language code: CharacteristicFunction[dist, t]//FullSimplify

ランダム過程のスライス分布についての特性関数：

Wolfram Language code: CharacteristicFunction[PoissonProcess[μ][s], t]

アプリケーション  (7)

ポアソン(Poisson)分布の原点の周りのモーメントを求める：

Wolfram Language code: cfun = CharacteristicFunction[PoissonDistribution[μ], t]

原点で特性関数の導関数を使った，最初の5つの原点の周りのモーメント：

Wolfram Language code: Table[Limit[D[cfun, {t, n}], t -> 0] / I ^ n, {n, 5}]

Momentを直接使う：

Wolfram Language code: Table[Moment[PoissonDistribution[μ], n], {n, 5}]
Wolfram Language code: Simplify[%% - %]

多変量 分布の，原点の周りの混合モーメントを計算する：

Wolfram Language code: CharacteristicFunction[MultivariateTDistribution[{{1, r}, {r, 1}}, 3], {t1, t2}]
Wolfram Language code: Limit[Limit[D[%, t1, t2], t1 -> 0], t2 -> 0] / I ^ 2

Momentを使って原点の周りのモーメントを直接得る：

Wolfram Language code: Moment[MultivariateTDistribution[{{1, r}, {r, 1}}, 3], {1, 1}]

スチューデント 分布の原点の周りのモーメントをその特性関数から求める：

Wolfram Language code: cfun = PiecewiseExpand[CharacteristicFunction[StudentTDistribution[5], t], t∈Reals]

を計算し，右側から極限を求めることでモーメントを抽出する：

Wolfram Language code: Table[Limit[(-I) ^ n D[cfun, {t, n}], t -> 0, Direction -> -1], {n, 5}]

極限を左側から計算する：

Wolfram Language code: Table[Limit[(-I) ^ n D[cfun, {t, n}], t -> 0, Direction -> 1], {n, 5}]

Momentを直接使って確認した通り，最初の4つのモーメントだけが定義される：

Wolfram Language code: Table[Moment[StudentTDistribution[5], r], {r, 5}]

逆フーリエ(Fourier)変換を使って特性関数に対応する確率密度関数を計算する：

Wolfram Language code: pdf = InverseFourierTransform[Exp[-t ^ 2], t, x, FourierParameters -> {1, 1}]
Wolfram Language code: Plot[pdf, {x, -5, 5}]
Wolfram Language code: NIntegrate[pdf, {x, -∞, ∞}]

対称LaplaceDistributionの例で中心極限定理を説明する：

Wolfram Language code: dist = LaplaceDistribution[0, σ];

再スケールされた確率変量の特性関数を求める：

Wolfram Language code: CharacteristicFunction[dist, t / Sqrt[n Variance[dist]]]

独立同分布に従う 個のそのような確率変量の和について，特性関数の大きい の極限を計算する：

Wolfram Language code: Limit[% ^ n, n -> Infinity]

標準正規変量の特性関数と比較する：

Wolfram Language code: CharacteristicFunction[NormalDistribution[], t]

滑らかな特性関数を使ってErlangDistributionの分布密度の上界を構築する：

Wolfram Language code: 𝒟 = ErlangDistribution[4, 1];
Wolfram Language code: chf = CharacteristicFunction[𝒟, t]
Wolfram Language code: UpperBound1 = (1/2Pi)Integrate[Abs[chf], {t, -Infinity, Infinity}]
Wolfram Language code: UpperBound2 = (1/2Pi)(1/x^2)Integrate[Abs[D[chf, {t, 2}]], {t, -Infinity, Infinity}]

上界ともとの密度をプロットする：

Wolfram Language code: Plot[{PDF[𝒟, x], UpperBound1, UpperBound2}, {x, 0, 10}]

総和 （ は独立同分布に従うBernoulliDistribution[1/2]の変量）は の値が大きいとUniformDistribution[]に近付くことを確かめる：

Wolfram Language code: Subscript[cf, k] = CharacteristicFunction[TransformedDistribution[(Subscript[d, k]/2^k), Subscript[d, k]BernoulliDistribution[(1/2)]], t]

積について組合せ方程式を使う：

Wolfram Language code: Table[Underoverscript[∏, k = 1, n]((1/2) + (1/2) E^(I t/2^k)) == (1/2^n)Underoverscript[∑, k = 0, 2^n - 1]Exp[(I t k/2^n)], {n, 6}]//Simplify

総和を評価する：

Wolfram Language code: chf = (1/2^n)Underoverscript[∑, k = 0, 2^n - 1]Exp[(I t k/2^n)]

極限を取り，これをUniformDistributionの特性関数と比較する：

Wolfram Language code: {Limit[ComplexExpand[chf], n -> ∞], CharacteristicFunction[UniformDistribution[], t]}//TrigToExp

特性と関係  (5)

CharacteristicFunctionは，実数 についての のExpectationである：

Wolfram Language code: Expectation[Exp[I t x], xUniformDistribution[{min, max}], Assumptions -> Element[t, Reals]]
Wolfram Language code: CharacteristicFunction[UniformDistribution[{min, max}], t]
Wolfram Language code: %% - %

特性関数は存在しているその他のすべての母関数に関連している：

Wolfram Language code: 𝒟 = PolyaAeppliDistribution[μ, p];
Wolfram Language code: {MomentGeneratingFunction[𝒟, I t], CharacteristicFunction[𝒟, t]}
Wolfram Language code: {Exp[CumulantGeneratingFunction[𝒟, I t]], CharacteristicFunction[𝒟, t]}
Wolfram Language code: {FactorialMomentGeneratingFunction[𝒟, t], CharacteristicFunction[𝒟, -I Log[t]]}

連続分布の特性関数は，そのPDFのFourierTransformに等しい：

Wolfram Language code: FourierTransform[PDF[CauchyDistribution[0, 1], x], x, t, FourierParameters -> {1, 1}]
Wolfram Language code: CharacteristicFunction[CauchyDistribution[0, 1], t]

離散分布の特性関数は，そのPDFのFourierSequenceTransformに等しい：

Wolfram Language code: FourierSequenceTransform[PDF[PoissonDistribution[μ], x], x, t, FourierParameters -> {1, 1}, Assumptions -> μ > 0]
Wolfram Language code: CharacteristicFunction[PoissonDistribution[μ], t]

確率密度関数は連続分布についての特性関数の逆フーリエ変換である：

Wolfram Language code: cf = CharacteristicFunction[NormalDistribution[μ, σ], t]
Wolfram Language code: InverseFourierTransform[cf, t, x, Assumptions -> μ∈Reals && σ > 0, FourierParameters -> {1, 1}]
Wolfram Language code: PDF[NormalDistribution[μ, σ], x]
Wolfram Language code: Simplify[%% - %, σ > 0]

PDFは離散分布についての特性関数の逆フーリエ数列変換である：

Wolfram Language code: cf = CharacteristicFunction[GeometricDistribution[p], t]
Wolfram Language code: InverseFourierSequenceTransform[cf, t, -n, FourierParameters -> {1, 1}]//FullSimplify[#, 0 < p < 1]&//PiecewiseExpand
Wolfram Language code: PDF[GeometricDistribution[p], n]
Wolfram Language code: % - %%

考えられる問題  (1)

記号的な閉形式が存在しない分布もある：

Wolfram Language code: CharacteristicFunction[LogNormalDistribution[μ, σ], t]

おもしろい例題  (1)

BinomialDistributionのランダムな例についてCharacteristicFunctionの実部と虚部を可視化する：

Wolfram Language code: Plot[MapThread[ReIm[CharacteristicFunction[BinomialDistribution[#1, #2], t]]&, {RandomInteger[{4, 16}, 5], RandomReal[1, 5]}]//Flatten//Evaluate, {t, -4, 4}, PlotRange -> All]
Wolfram Research (2007), CharacteristicFunction, Wolfram言語関数， https://reference.wolfram.com/language/ref/CharacteristicFunction.html （2010年に更新）.

テキスト

Wolfram Research (2007), CharacteristicFunction, Wolfram言語関数， https://reference.wolfram.com/language/ref/CharacteristicFunction.html （2010年に更新）.

CMS

Wolfram Language. 2007. "CharacteristicFunction." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2010. https://reference.wolfram.com/language/ref/CharacteristicFunction.html.

APA

Wolfram Language. (2007). CharacteristicFunction. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CharacteristicFunction.html

BibTeX

@misc{reference.wolfram_2026_characteristicfunction, author="Wolfram Research", title="{CharacteristicFunction}", year="2010", howpublished="\url{https://reference.wolfram.com/language/ref/CharacteristicFunction.html}", note=[Accessed: 11-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_characteristicfunction, organization={Wolfram Research}, title={CharacteristicFunction}, year={2010}, url={https://reference.wolfram.com/language/ref/CharacteristicFunction.html}, note=[Accessed: 11-September-2026]}