WOLFRAM

Wolfram 语言与系统参考资料中心

CharacteristicPolynomial[m,x]

给出矩阵 m 的特征多项式.

CharacteristicPolynomial[{m,a},x]

给出关于 a 的广义特征多项式.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
基本用法  
广义特征值  
特殊矩阵  
应用  
属性和关系  
参见
技术笔记
相关指南
历史
按以下格式引用：

CharacteristicPolynomial

CharacteristicPolynomial[m,x]

给出矩阵 m 的特征多项式.

CharacteristicPolynomial[{m,a},x]

给出关于 a 的广义特征多项式.

更多信息

范例

打开所有单元 关闭所有单元

基本范例  (3)

求其中的项为整数的矩阵的特征多项式：

Wolfram Language code: CharacteristicPolynomial[{{1, 2}, {3, 4}}, x]

可视化多项式：

Wolfram Language code: Plot[%, {x, -5, 10}]

求符号矩阵 的特征多项式，以 表示：

Wolfram Language code: m = (⁠| | | | - | - | | a | b | | c | d |⁠);
Wolfram Language code: CharacteristicPolynomial[m, x]

与直接计算的结果相比较：

Wolfram Language code: Det[m - x IdentityMatrix[2]]

计算单位矩阵和零矩阵的特征多项式：

Wolfram Language code: CharacteristicPolynomial[IdentityMatrix[3], λ]
Wolfram Language code: CharacteristicPolynomial[ConstantArray[0, {10, 10}], λ]

范围  (17)

基本用法  (7)

求及其精度矩阵的特征多项式：

Wolfram Language code: CharacteristicPolynomial[{{1.1, 2.2, 3.25}, {0.76, 4.6, 5}, {0.1, 0.1, 6.1}}, x]

任意精度的矩阵：

Wolfram Language code: CharacteristicPolynomial[Table[N[1 / (i + j + 1), 20], {i, 3}, {j, 3}], x]

一个复矩阵的特征多项式：

Wolfram Language code: CharacteristicPolynomial[{{1.2 + I, 3 - 2 I, 3 π}, {-0.2, 5I, 2}, {1, 2.3, E}}, x]

精确矩阵的特征多项式：

Wolfram Language code: CharacteristicPolynomial[{{(1/3), (1/2), (3/5)}, {(1/2), (4/5), 1}, {(3/5), 1, (9/7)}}, x]

可视化结果：

Wolfram Language code: Plot[%, {x, -1.5, 2.5}]

高效计算大型数值矩阵的特征多项式：

Wolfram Language code: m = RandomReal[{1, 9}, {100, 100}];
Wolfram Language code: CharacteristicPolynomial[m, x];//Timing

具有有限场元素的矩阵的特征多项式：

Wolfram Language code: ℱ = FiniteField[43, 2]; CharacteristicPolynomial[{{ℱ[12], ℱ[23], ℱ[34]}, {ℱ[45], ℱ[56], ℱ[67]}, {ℱ[78], ℱ[89], ℱ[90]}}, x]

含有 CenteredInterval 对象的矩阵的特征多项式：

Wolfram Language code: (m = Map[CenteredInterval, RandomReal[{-10, 10}, {3, 3}, WorkingPrecision -> 10], {2}])//MatrixForm
Wolfram Language code: p = CharacteristicPolynomial[m, x]

找出 m 的随机表示 mrep：

Wolfram Language code: ranrep[e_CenteredInterval] := e["Center"] + RandomInteger[{-1000, 1000}] / 1000 e["Radius"] (mrep = Map[ranrep, m, {2}])//MatrixForm

验证 p 的系数包含 mrep 的特征多项式的系数：

Wolfram Language code: MapThread[IntervalMemberQ, {CoefficientList[p, x], CoefficientList[CharacteristicPolynomial[mrep, x], x]}]

广义特征值  (4)

兩个矩阵的广义特征多项式：

Wolfram Language code: m1 = {{1, 2}, {5, 4}};m2 = {{4, 3}, {6, 4}};
Wolfram Language code: CharacteristicPolynomial[{m1, m2}, x]

这相当于 ：

Wolfram Language code: Det[m1 - x m2]

广义的机器精度的特征多项式：

Wolfram Language code: a = {{1., 1.5, 2.}, {3.1, 2., 2.9}, {3., 2., 1.}};
Wolfram Language code: b = {{1.3, .5, 1.1}, {0., 1.5, 2.3}, {1., 0., 1.}};
Wolfram Language code: CharacteristicPolynomial[{a, b}, x]

求广义的精确的特征多项式：

Wolfram Language code: a = {{1, 1, 1}, {1, 0, 1}, {0, 0, 1}};
Wolfram Language code: b = {{0, 1, 1}, {0, 1, 1}, {1, 0, 0}};
Wolfram Language code: CharacteristicPolynomial[{a, b}, x]

项的缺失表示无限大的广义特征值：

Wolfram Language code: Eigenvalues[{a, b}]

与有限精度的结果相比较：

Wolfram Language code: CharacteristicPolynomial[N[{a, b}, 20], y]

求符号矩阵的广义特征多项式：

Wolfram Language code: a = {{x, 1 + x}, {1 - x, x}};b = {{1, 1}, {1, 2x}}; CharacteristicPolynomial[{a, b}, y]

特殊矩阵  (6)

系数矩阵的特征多项式：

Wolfram Language code: SparseArray[{{1, 3} -> 2, {2, 2} -> 3, {3, 1} -> 1, {4, 2} -> 5}, {4, 4}]
Wolfram Language code: CharacteristicPolynomial[%, x]
Wolfram Language code: SparseArray[{{x_, y_} /; Abs[x - y] < 3 -> 1}, {10, 10}]
Wolfram Language code: CharacteristicPolynomial[%, x]

结构化矩阵的特征多项式：

Wolfram Language code: SymmetrizedArray[{{1, 1} -> 2, {1, 2} -> 1}, {2, 2}, Symmetric[All]]
Wolfram Language code: CharacteristicPolynomial[%, x]
Wolfram Language code: QuantityArray[{{1, 2}, {3, 4}}, {"Meters", "Meters"}]
Wolfram Language code: CharacteristicPolynomial[%, x]

单位矩阵的特征多项式是二项展开式：

Wolfram Language code: CharacteristicPolynomial[IdentityMatrix[12], λ]
Wolfram Language code: Factor[%]

HilbertMatrix[n] 的特征多项式：

Wolfram Language code: CharacteristicPolynomial[HilbertMatrix[5], λ]

JordanMatrix[λ,n] 的特征多项式为 ：

Wolfram Language code: CharacteristicPolynomial[JordanMatrix[λ, 4], x] == (λ - x)^4//Simplify
Wolfram Language code: CharacteristicPolynomial[JordanMatrix[λ, 5], x] == (λ - x)^5//Simplify

CompanionMatrix[{c0,c1,…,cn}] 的最小多项式：

Wolfram Language code: CompanionMatrix[{c0, c1, c2, c3}]//MatrixForm
Wolfram Language code: CharacteristicPolynomial[%, x]

应用  (6)

求矩阵 的特征多项式，并比较 、 和 时的行为：

Wolfram Language code: m = (| | | | | -- | --- | --- | | -6 | 28 | 21 | | 4 | -15 | -12 | | -8 | a | 25 |)
Wolfram Language code: cp = CharacteristicPolynomial[m, x]

查看根，在 处有一个与 无关的根：

Wolfram Language code: roots = SolveValues[cp == 0, x]

对于 ， 处的根重复出现：

Wolfram Language code: roots /. a -> 32

对于 ，有三个不同的实根：

Wolfram Language code: roots /. a -> 31

对于 ， 是唯一的实根，另外两个根是复共轭对：

Wolfram Language code: roots /. a -> 33

可视化三个多项式，放大在双根 处的“反弹”：

Wolfram Language code: {Plot[Table[cp, {a, {32, 31, 33}}]//Evaluate, {x, -3, 6}, PlotLegends -> LineLegend[{a == 32, a == 31, a == 33}], ImageSize -> Small], Plot[cp /. a -> 32, {x, 0.5, 2.5}, PlotLegends -> LineLegend[{a == 32}], ImageSize -> Small]}//Row

计算矩阵的行列式，以作为其特征多项式中的常数项：

Wolfram Language code: m = {{6, 5, 8, 1, 4}, {8, 0, 2, 7, 1}, {7, 4, 0, 8, 3}, {2, 3, 1, 1, 6}, {0, 4, 8, 2, 3}};
Wolfram Language code: cp = CharacteristicPolynomial[m, x]

将 代入：

Wolfram Language code: cp /. x -> 0

这个结果也是特征多项式的根的乘积：

Wolfram Language code: Times @@ SolveValues[cp == 0, x] // FullSimplify

与用 Det 直接计算的结果相比较：

Wolfram Language code: Det[m]

计算矩阵的迹，以作为特征多项式中幂次次高的项的系数：

Wolfram Language code: m = {{4, 3, 8, 9}, {8, 1, 0, 7}, {1, 2, 6, 7}, {2, 5, 1, 2}};
Wolfram Language code: cp = CharacteristicPolynomial[m, x]

提取 的系数，其中 是矩阵的高度或宽度：

Wolfram Language code: (-1)^Length[m] - 1Coefficient[cp, x^Length[m] - 1]

这个结果也是特征多项式的根之和：

Wolfram Language code: Total[SolveValues[cp == 0, x]]//FullSimplify

与用 Tr 直接计算的结果相比较：

Wolfram Language code: Tr[m]

求矩阵的特征值，以作为特征多项式的根：

Wolfram Language code: m = {{1, 2, 3}, {4, 5, 6}, {7, 8, 9}};
Wolfram Language code: SolveValues[CharacteristicPolynomial[m, x] == 0, x]

与用 Eigenvalues 直接计算的结果相比较：

Wolfram Language code: Eigenvalues[m]

用特征多项式求矩阵 和 TemplateBox[{a}, Transpose] 的特征值和特征向量：

Wolfram Language code: a = {{3, 9, 4}, {3, 7, 1}, {8, 1, 8}};
Wolfram Language code: cp = CharacteristicPolynomial[a, x]

这两个矩阵具有相同的特征多项式：

Wolfram Language code: CharacteristicPolynomial[Transpose[a], x] == cp

因此，它们都将具有相同的特征值，即多项式的根：

Wolfram Language code: λ = SolveValues[cp == 0, x]

特征向量由 的零空间给出：

Wolfram Language code: Subscript[v, λ] = Join[NullSpace[a - λ[[1]]IdentityMatrix[3]], NullSpace[a - λ[[2]]IdentityMatrix[3]], NullSpace[a - λ[[3]]IdentityMatrix[3]]]//FullSimplify

Eigensystem 给出相同的结果，尽管它按绝对值对特征值进行排序：

Wolfram Language code: Eigensystem[a]

尽管 TemplateBox[{a}, Transpose] 与 的特征值相同，但特征向量不同：

Wolfram Language code: Subsuperscript[v, λ, * ] = Join[NullSpace[a - λ[[1]]IdentityMatrix[3]], NullSpace[a - λ[[2]]IdentityMatrix[3]], NullSpace[a - λ[[3]]IdentityMatrix[3]]]//FullSimplify

可视化两组特征向量：

Wolfram Language code: {MatrixPlot[Subscript[v, λ]], MatrixPlot[Subsuperscript[v, λ, * ]]}

求 相对于 的广义特征系统，以作为特征多项式的根：

Wolfram Language code: a = {{1., 1.5, 2.}, {3.1, 2., 2.9}, {3., 2., 1.}};
Wolfram Language code: b = {{1.3, .5, 1.1}, {0., 1.5, 2.3}, {1., 0., 1.}};
Wolfram Language code: CharacteristicPolynomial[{a, b}, x]

广义特征多项式的根是广义特征值：

Wolfram Language code: λ = SolveValues[% == 0, x]

广义特征向量由 的零空间给出：

Wolfram Language code: Subscript[v, λ] = Join[NullSpace[a - λ[[1]]b], NullSpace[a - λ[[2]]b], NullSpace[a - λ[[3]]b]]//FullSimplify

与用 Eigensystem 直接计算的结果相比较：

Wolfram Language code: Eigensystem[{a, b}]

属性和关系  (10)

特征多项式等价于 Det[m - id x]：

Wolfram Language code: m = RandomInteger[9, {10, 10}];
Wolfram Language code: cp = CharacteristicPolynomial[m, x]
Wolfram Language code: % == Det[m - IdentityMatrix[Length[m]] x]

广义的特征多项式等价于 Det[m-a x]:

Wolfram Language code: {m, a} = RandomInteger[9, {2, 5, 5}];
Wolfram Language code: CharacteristicPolynomial[{m, a}, x]
Wolfram Language code: % == Det[m - a x]

矩阵是其特征多项式的一个根 (Cayley–Hamilton 定理 [更多信息...]):

Wolfram Language code: m = RandomInteger[10, {10, 10}]; cp = CharacteristicPolynomial[m, x]; MatrixPolynomialValue[cp, m, x] == ConstantArray[0, {10, 10}]
Wolfram Language code: MatrixPolynomialValue[cp, m, x]//AbsoluteTiming

，等价于特征多项式，其中 是特征值：

Wolfram Language code: m = RandomReal[1, {10, 10}];
Wolfram Language code: Product[(v - x), {v, Eigenvalues[m]}] - CharacteristicPolynomial[m, x]//Simplify//Chop

特征多项式的根的和是矩阵的迹 (Tr):

Wolfram Language code: m = RandomReal[1, {10, 10}];
Wolfram Language code: roots = SolveValues[CharacteristicPolynomial[m, x] == 0, x];
Wolfram Language code: Total[roots] == Tr[m]

同样，根的积是行列式 (Det)：

Wolfram Language code: Times @@ roots == Det[m]

矩阵及其转置具有相同的特征多项式：

Wolfram Language code: m = RandomReal[1, {10, 10}];
Wolfram Language code: CharacteristicPolynomial[m, x] == CharacteristicPolynomial[Transpose[m], x]

所有对角线元素相同的三角矩阵的特征多项式都一样：

Wolfram Language code: t1 = (| | | | | - | - | - | | 1 | 0 | 0 | | 0 | 1 | 0 | | 0 | 0 | 1 |);t2 = (| | | | | - | - | - | | 1 | 4 | 0 | | 0 | 1 | 3 | | 0 | 0 | 1 |);t3 = (| | | | | - | - | - | | 1 | 0 | 0 | | 5 | 1 | 0 | | 6 | 7 | 1 |);
Wolfram Language code: CharacteristicPolynomial[t1, x] == CharacteristicPolynomial[t2, x] == CharacteristicPolynomial[t3, x]

如果 是一个首一多项式，则其伴随矩阵的特征多项式是 ：

Wolfram Language code: cl = RandomInteger[9, 10]; p = cl.x ^ Range[0, 9] + x ^ 10
Wolfram Language code: CharacteristicPolynomial[CompanionMatrix[cl], x] == p

MatrixMinimalPolynomial[m,λ] 整除 CharacteristicPolynomial[m,λ]，其商为一个（可能为常数的）多项式：

Wolfram Language code: mat = (⁠| | | | | - | -- | -- | | 0 | -1 | 1 | | 1 | 2 | -1 | | 1 | 1 | 0 |⁠); PolynomialQuotientRemainder[CharacteristicPolynomial[mat, t], MatrixMinimalPolynomial[mat, t], t]

最小多项式与特征多项式有一样的相异根：

Wolfram Language code: a = (| | | | | | -- | -- | - | - | | -6 | 4 | 0 | 9 | | -3 | 0 | 1 | 6 | | -1 | -2 | 1 | 0 | | -4 | 4 | 0 | 7 |); χ = CharacteristicPolynomial[a, λ]; μ = MatrixMinimalPolynomial[a, λ]; Roots[μ == 0, λ] == DeleteDuplicates[Roots[χ == 0, λ]]

具体而言，这意味着 整除 的 次方：

Wolfram Language code: PolynomialRemainder[μ ^ LCM@@(Max@Cases[#, λ ^ k_ :> k, -1]& /@ {μ, χ}), χ, λ]
Wolfram Research (2003)，CharacteristicPolynomial，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CharacteristicPolynomial.html （更新于 2024 年）.

文本

Wolfram Research (2003)，CharacteristicPolynomial，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CharacteristicPolynomial.html （更新于 2024 年）.

CMS

Wolfram 语言. 2003. "CharacteristicPolynomial." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2024. https://reference.wolfram.com/language/ref/CharacteristicPolynomial.html.

APA

Wolfram 语言. (2003). CharacteristicPolynomial. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/CharacteristicPolynomial.html 年

BibTeX

@misc{reference.wolfram_2026_characteristicpolynomial, author="Wolfram Research", title="{CharacteristicPolynomial}", year="2024", howpublished="\url{https://reference.wolfram.com/language/ref/CharacteristicPolynomial.html}", note=[Accessed: 13-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_characteristicpolynomial, organization={Wolfram Research}, title={CharacteristicPolynomial}, year={2024}, url={https://reference.wolfram.com/language/ref/CharacteristicPolynomial.html}, note=[Accessed: 13-September-2026]}