WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

ChebyshevU[n,x]

第2種チェビシェフ(Chebyshev)多項式 TemplateBox[{n, x}, ChebyshevU]を与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
数値評価  
特定の値  
可視化  
Show More Show More
関数の特性  
微分  
積分  
級数展開  
関数の恒等式と簡約  
一般化と拡張  
アプリケーション  
特性と関係  
考えられる問題  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

ChebyshevU

ChebyshevU[n,x]

第2種チェビシェフ(Chebyshev)多項式 TemplateBox[{n, x}, ChebyshevU]を与える．

詳細

  • 記号操作・数値操作の両方に適した数学関数である．
  • 整数 n について具体的な多項式が与えられる．
  • TemplateBox[{n, {cos, (, theta, )}}, ChebyshevU]=sin[(n+1)theta]/sin theta
  • 特別な引数の場合，ChebyshevUは，自動的に厳密値を計算する．
  • ChebyshevUは任意の数値精度で評価できる．
  • ChebyshevUは自動的にリストに縫い込まれる．
  • ChebyshevU[n,z]は，非整数nについて複素 z 平面上，〜の範囲で不連続な分枝切断線を持つ．
  • ChebyshevUはIntervalオブジェクトおよびCenteredIntervalオブジェクトに使うことができる． »

例題

すべて開く すべて閉じる

例  (7)

数値的に評価する：

Wolfram Language code: ChebyshevU[2, 3]

十次のChebyshevU多項式を計算する：

Wolfram Language code: ChebyshevU[10, x]

実数の部分集合上でプロットする：

Wolfram Language code: Plot[ChebyshevU[10, x], {x, -1, 1}]

複素数の部分集合上でプロットする：

Wolfram Language code: ComplexPlot3D[ChebyshevU[5, z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

原点における級数展開：

Wolfram Language code: Series[ChebyshevU[5, x], {x, 0, 5}]

Infinityにおける漸近展開：

Wolfram Language code: Series[ChebyshevU[1 / 3, x], {x, ∞, 3}]//Normal//FullSimplify

特異点における漸近展開：

Wolfram Language code: Series[ChebyshevU[1 / 3, x], {x, -1, 2}]//FullSimplify

スコープ  (44)

数値評価  (6)

数値的に評価する：

Wolfram Language code: ChebyshevU[2, 5]
Wolfram Language code: ChebyshevU[12, 2.5]

高精度で評価する：

Wolfram Language code: N[ChebyshevU[1 / 7, 1 / 3], 50]

出力精度は入力精度に従う：

Wolfram Language code: ChebyshevU[0.3000000000000000000, 0]

複素数入力：

Wolfram Language code: N[ChebyshevU[98 + I, I]]

高精度で効率的に評価する：

Wolfram Language code: ChebyshevU[-1.5, -2.4`100]//Timing
Wolfram Language code: ChebyshevU[84, 63`10000000];//Timing

IntervalオブジェクトとCenteredIntervalオブジェクトを使って最悪のケースにおける補償区間を計算する：

Wolfram Language code: ChebyshevU[2, Interval[{1.9, 2.1}]]
Wolfram Language code: ChebyshevU[2, CenteredInterval[2, 1 / 100]]

Aroundを使って平均的なケースの統計区間を計算することもできる：

Wolfram Language code: ChebyshevU[2, Around[2, 0.01]]

配列の要素単位の値を計算する：

Wolfram Language code: ChebyshevU[2, {{1, 2}, {3, 4}}]

MatrixFunctionを使って行列のChebyshevU関数を計算することもできる：

Wolfram Language code: MatrixFunction[ChebyshevU[2, #]&, {{1, 2}, {3, 4}}]

特定の値  (7)

固定点におけるChebyshevUの値：

Wolfram Language code: Table[ChebyshevU[n, Pi / 2], {n, 0, 3}]

記号的な n についてのChebyshevU：

Wolfram Language code: ChebyshevU[n, 0]

ゼロにおける値：

Wolfram Language code: ChebyshevU[0, 0]

無限大における値：

Wolfram Language code: ChebyshevU[0, Infinity]
Wolfram Language code: ChebyshevU[Infinity, 0][[1, 1]]

ChebyshevU[5,x]の最初の正の最大値を求める：

Wolfram Language code: xmax = x /. Solve[D[ChebyshevU[5, x], x] == 0 && 0 < x < π, x][[1]]
Wolfram Language code: Plot[ChebyshevU[5, x], {x, -1, 1}, Epilog -> Style[Point[{xmax, ChebyshevT[5, xmax]}], PointSize[Large], Red]]

陪多項式ChebyshevU[7,x]を計算する：

Wolfram Language code: ChebyshevU[7, x]

半整数 n について陪多項式ChebyshevU[1/2,x]を計算する：

Wolfram Language code: ChebyshevU[1 / 2, x]

可視化  (3)

ChebyshevU関数をさまざまな次数で計算する：

Wolfram Language code: Plot[{ChebyshevU[1, x], ChebyshevU[2, x], ChebyshevU[3, x], ChebyshevU[4, x]}, {x, -1, 1}]

TemplateBox[{3, z}, ChebyshevU]の実部をプロットする：

Wolfram Language code: ComplexContourPlot[Re[ChebyshevU[3, z]], {z, -3 - 3 I, 3 + 3 I}, IconizedObject[«PlotOptions»]]

TemplateBox[{3, z}, ChebyshevU]の虚部をプロットする：

Wolfram Language code: ComplexContourPlot[Im[ChebyshevU[3, z]], {z, -3 - 3 I, 3 + 3 I}, IconizedObject[«PlotOptions»]]

チェビシェフ多項式と2変数の関数としてプロットする：

Wolfram Language code: Plot3D[ChebyshevU[n, z], {n, 0, 5}, {z, -1, 1}]

関数の特性  (14)

ChebyshevUは，区間[-1,∞]からのすべての実数値について定義される：

Wolfram Language code: FunctionDomain[ChebyshevU[n, x], x]

ChebyshevUは，以外のすべての複素値について定義される：

Wolfram Language code: FunctionDomain[ChebyshevU[n, z], z, Complexes]

TemplateBox[{1, x}, ChebyshevU]はすべての実数と複素数に達する：

Wolfram Language code: FunctionRange[ChebyshevU[1, x], x, y]
Wolfram Language code: FunctionRange[ChebyshevU[1, z], z, y, Complexes]

TemplateBox[{2, x}, ChebyshevU]の実数領域：

Wolfram Language code: FunctionRange[ChebyshevU[2, x], x, y]

これは，すべての複素数に達する：

Wolfram Language code: FunctionRange[ChebyshevU[2, z], z, y, Complexes]

奇次数のチェビシェフ多項式は奇多項式である：

Wolfram Language code: ChebyshevU[1, -x] == -ChebyshevU[1, x]

偶次数のチェビシェフ多項式は偶多項式である：

Wolfram Language code: ChebyshevU[2, -x] == ChebyshevU[2, x]

ChebyshevUは要素単位でリストに縫い込まれる：

Wolfram Language code: ChebyshevU[{1, 2, 3}, x]

チェビシェフ多項式は解析的である：

Wolfram Language code: FunctionAnalytic[ChebyshevU[n, x], x, Assumptions -> n∈ℤ]

一般に，ChebyshevUは解析的でも有理型でもない：

Wolfram Language code: FunctionAnalytic[ChebyshevU[1 / 3, x], x, ℂ]
Wolfram Language code: FunctionMeromorphic[ChebyshevU[1 / 3, x], x]

TemplateBox[{2, x}, ChebyshevU]は非減少でも非増加でもない：

Wolfram Language code: FunctionMonotonicity[ChebyshevU[2, x], x]

TemplateBox[{2, x}, ChebyshevU]は単射ではない：

Wolfram Language code: FunctionInjective[ChebyshevU[2, x], x]

TemplateBox[{1, x}, ChebyshevU]は単射である：

Wolfram Language code: FunctionInjective[ChebyshevU[1, x], x]
Wolfram Language code: Plot[{ChebyshevU[1, x], ChebyshevU[2, x], 2}, {x, -1, 1}]

TemplateBox[{2, x}, ChebyshevU]は全射ではない：

Wolfram Language code: FunctionSurjective[ChebyshevU[2, x], x]

TemplateBox[{1, x}, ChebyshevU]は全射である：

Wolfram Language code: FunctionSurjective[ChebyshevU[1, x], x]
Wolfram Language code: Plot[{ChebyshevU[1, x], ChebyshevU[2, x], -2}, {x, -1, 1}]

TemplateBox[{2, x}, ChebyshevU]は非負でも非正でもない：

Wolfram Language code: FunctionSign[ChebyshevU[2, x], x]

TemplateBox[{n, x}, ChebyshevU]は，で が整数ではないとき，特異点と不連続点を持つ：

Wolfram Language code: FunctionSingularities[ChebyshevU[n, x], x]
Wolfram Language code: FunctionDiscontinuities[ChebyshevU[n, x], x]

TemplateBox[{2, x}, ChebyshevU]は凸である：

Wolfram Language code: FunctionConvexity[ChebyshevU[2, x], x]

TraditionalFormによる表示：

Wolfram Language code: ChebyshevU[n, x]//TraditionalForm

微分  (3)

x についての一次導関数：

Wolfram Language code: D[ChebyshevU[n, x] , x]

x についての高次導関数：

Wolfram Language code: Table[D[ChebyshevU[n, x], {x, k}], {k, 1, 3}]//Simplify

n=5のときの x についての高次導関数をプロットする：

Wolfram Language code: Plot[Evaluate[% /. n -> 5], {x, -10, 10}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]

x についての 次導関数の式：

Wolfram Language code: D[ChebyshevU[n, x], {x, k}]// FullSimplify

積分  (4)

Integrateを使って不定積分を計算する：

Wolfram Language code: Integrate[ChebyshevU[n, x], x]

不定積分を確認する：

Wolfram Language code: FullSimplify[D[%, x]]

定積分：

Wolfram Language code: Integrate[ChebyshevU[n, x], {x, 0, 4}]

奇整数についての1周期のChebyshevUの定積分は0である：

Wolfram Language code: Integrate[ChebyshevU[2n - 1, x], {x, -5, 5}]
Wolfram Language code: Table[%, {n, 3, 11, 2}]//FullSimplify

その他の積分例：

Wolfram Language code: Integrate[ChebyshevU[3, x]ChebyshevT[5, x], x]//FullSimplify
Wolfram Language code: Integrate[Exp[x] ChebyshevU[5, x], {x, 0, 5}]//FullSimplify

級数展開  (3)

Seriesを使ってテイラー(Taylor)展開を求める：

Wolfram Language code: Series[ChebyshevU[n, x], {x, 0, 3}]

の周りの最初の3つの近似のプロット：

Wolfram Language code: terms = Normal@Table[Series[ChebyshevU[10, x], {x, 0, m}], {m, 1, 5, 2}]; Plot[{ChebyshevU[10, x], terms}, {x, -1, 1}, PlotRange -> {-3, 3}]

SeriesCoefficientを使った級数展開における一般項：

Wolfram Language code: SeriesCoefficient[ChebyshevU[n, x], {x, 0, n}]

生成点におけるテイラー展開：

Wolfram Language code: Series[ChebyshevU[n, x], {x, x0, 2}]

関数の恒等式と簡約  (4)

ChebyshevUは，以下の三角恒等式を通して定義される：

Wolfram Language code: ChebyshevU[n, Cos[θ]] == Sin[(n + 1) θ] / Sin[θ]//FullSimplify

ChebyshevUの通常の母関数：

Wolfram Language code: Sum[ChebyshevU[n, x]t^n, {n, 0, Infinity}]

ChebyshevUの指数型母関数：

Wolfram Language code: Sum[ChebyshevU[n, x]t^n / n!, {n, 0, Infinity}]

漸化式：

Wolfram Language code: ChebyshevU[n, z] == 2 z ChebyshevU[n + 1, z] - ChebyshevU[n + 2, z]//FullSimplify
Wolfram Language code: ChebyshevU[n - 1, z] + ChebyshevU[n + 1, z] == 2 z ChebyshevU[n, z]//FullSimplify

一般化と拡張  (2)

ChebyshevUはベキ級数に適用できる：

Wolfram Language code: ChebyshevU[10, Log[1 + x] + O[x] ^ 6]

ChebyshevUはIntervalに適用できる：

Wolfram Language code: ChebyshevU[10, Interval[{-1, 1}]]

アプリケーション  (7)

区間で関数を近似する：

Wolfram Language code: coeffs = Table[((2/π)Subsuperscript[∫, -1, 1]Sqrt[1 - x^2] ChebyshevU[n, x] Sinc[2x π]ⅆx), {n, 0, 4}];
Wolfram Language code: Plot[{Sinc[2π x], Evaluate[coeffs.Table[ChebyshevU[n, x], {n, 0, 4}]]}, {x, -1, 1}]

指定した点を通る曲線を構築する：

Wolfram Language code: curve[pts_List] := Function[x, Evaluate[Block[{n = Length[pts]}, pts.Table[ChebyshevU[n - 1, Sin[(k π/n)] Sqrt[1 - x^2] + x Cos[(π k/n)]], {k, 0, n - 1}] / n]]]
Wolfram Language code: points[pts_List] := MapIndexed[{-1. Cos[(First[#2]) * Pi / Length[pts]], #1}&, Reverse[pts]]
Wolfram Language code: Plot[Evaluate[curve[Range[15]][x]], {x, -1, 1}, Prolog -> {Red, PointSize[0.02], Point[points[Range[15]]]}]

層のガラスを通る低振幅のトランスミッション：

Wolfram Language code: Plot[ Evaluate[Table[1 / (1 + k^2 ChebyshevU[n, Cos[k] + Sinc[k]]^2), {n, 0, 5}]], {k, 0, 10}, PlotRange -> All]

テプリッツ(Toeplitz)三重対角行列を定義する：

Wolfram Language code: toeplitzTridiagonal[a_, b_, c_, n_] := SparseArray[{Band[{2, 1}] -> a, Band[{1, 1}] -> b, Band[{1, 2}] -> c}, {n, n}]

4×4の場合を表示する：

Wolfram Language code: toeplitzTridiagonal[a, b, c, 4]//MatrixForm

テプリッツ行列の特性多項式はChebyshevUによって表すことができる：

Wolfram Language code: cPoly[a_, b_, c_, n_, x_] := (-Sqrt[a c])^n ChebyshevU[n, (x - b/2Sqrt[a c])]

最初のいくつかのケースを確認する：

Wolfram Language code: Table[CharacteristicPolynomial[toeplitzTridiagonal[a, b, c, n], x] == cPoly[a, b, c, n, x]//Simplify, {n, 2, 9}]

Kac–Murdock–Szegő (KMS)行列（対称テプリッツ行列）を定義する：

Wolfram Language code: kms[ρ_, n_] := ToeplitzMatrix[ρ^Range[0, n - 1]]

KMS行列は一次元自己回帰過程（AR(1)過程）の相関行列である：

Wolfram Language code: n = 6; kms[ρ, n] == Correlation[ARProcess[{ρ}, σ ^ 2][Range[n]]]//Simplify

KMS行列の固有多項式はChebyshevUによって表すことができる：

Wolfram Language code: CharacteristicPolynomial[kms[ρ, n], λ] == With[{τ = (ρ^2(λ + 1) + λ - 1/2ρ λ)}, ((ρ λ)^n/1 - ρ^2)(ChebyshevU[n, τ] - 2ρ ChebyshevU[n - 1, τ] + ρ^2ChebyshevU[n - 2, τ])]//Simplify

ChebyshevU関数を不均一部分として微分方程式を解く：

Wolfram Language code: DSolve[y''[x] + ChebyshevU[n, x] == 0, y[x], x]

チェビシェフ多項式をその母関数から求める：

Wolfram Language code: Series[1 / (1 - 2 t x + t ^ 2), {t, 0, 4}]
Wolfram Language code: SeriesCoefficient[%, 4]
Wolfram Language code: ChebyshevU[4, x]

特性と関係  (7)

ChebyshevU多項式中の係数のリストを得る：

Wolfram Language code: CoefficientList[ ChebyshevU[10, x], x]

FunctionExpandを使って三角関数を通して展開する：

Wolfram Language code: FunctionExpand[ChebyshevU[n, x]]

についてのChebyshevUの導関数：

Wolfram Language code: D[ChebyshevU[n, x], x]

ChebyshevUはDifferenceRootとして表すことができる：

Wolfram Language code: DifferenceRootReduce[ChebyshevU[k, z], k]

ChebyshevUの級数展開における一般項：

Wolfram Language code: SeriesCoefficient[ChebyshevU[a, x], {x, 0, n}]

ChebyshevUの母関数：

Wolfram Language code: GeneratingFunction[ChebyshevU[n, k], n, x]

ChebyshevUの指数母関数：

Wolfram Language code: ExponentialGeneratingFunction[ChebyshevU[n, k], n, x]

考えられる問題  (1)

多項式の簡約により結果が不正確になることがある：

Wolfram Language code: ChebyshevU[60, x] /. x -> N[2 / 3, 16]

関数を直接評価する：

Wolfram Language code: ChebyshevU[60, N[2 / 3, 16]]
Wolfram Research (1988), ChebyshevU, Wolfram言語関数， https://reference.wolfram.com/language/ref/ChebyshevU.html （2022年に更新）.

テキスト

Wolfram Research (1988), ChebyshevU, Wolfram言語関数， https://reference.wolfram.com/language/ref/ChebyshevU.html （2022年に更新）.

CMS

Wolfram Language. 1988. "ChebyshevU." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2022. https://reference.wolfram.com/language/ref/ChebyshevU.html.

APA

Wolfram Language. (1988). ChebyshevU. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ChebyshevU.html

BibTeX

@misc{reference.wolfram_2026_chebyshevu, author="Wolfram Research", title="{ChebyshevU}", year="2022", howpublished="\url{https://reference.wolfram.com/language/ref/ChebyshevU.html}", note=[Accessed: 14-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_chebyshevu, organization={Wolfram Research}, title={ChebyshevU}, year={2022}, url={https://reference.wolfram.com/language/ref/ChebyshevU.html}, note=[Accessed: 14-September-2026]}