WOLFRAM

Wolfram 语言与系统参考资料中心

ChebyshevU[n,x]

给出了第二类切比雪夫多项式 TemplateBox[{n, x}, ChebyshevU].

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
数值计算  
特殊值  
可视化  
Show More Show More
函数的属性  
微分  
积分  
级数展开  
函数恒等式与简化  
推广和延伸  
应用  
属性和关系  
可能存在的问题  
参见
技术笔记
相关指南
相关链接
历史
按以下格式引用：

ChebyshevU

ChebyshevU[n,x]

给出了第二类切比雪夫多项式 TemplateBox[{n, x}, ChebyshevU].

更多信息

  • 数学函数，适宜于符号和数值计算.
  • 对于整数 n 给出了显式多项式.
  • TemplateBox[{n, {cos, (, theta, )}}, ChebyshevU]=sin[(n+1)theta]/sin theta.
  • 对于某些特殊参数，ChebyshevU 自动计算出精确值.
  • ChebyshevU 可以计算到任意数值精度.
  • ChebyshevU 自动逐项作用于列表的各个元素.
  • 对于非整数 n，ChebyshevU[n,z] 在复平面 z 上有分支切割，从 到 .
  • ChebyshevU 可与 Interval 和 CenteredInterval 对象一起使用. »

范例

打开所有单元 关闭所有单元

基本范例  (7)

数值化计算：

Wolfram Language code: ChebyshevU[2, 3]

计算10次的 ChebyshevU 多项式：

Wolfram Language code: ChebyshevU[10, x]

在实数的子集上绘图：

Wolfram Language code: Plot[ChebyshevU[10, x], {x, -1, 1}]

在复数的子集上绘图：

Wolfram Language code: ComplexPlot3D[ChebyshevU[5, z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

在原点处的级数展开式：

Wolfram Language code: Series[ChebyshevU[5, x], {x, 0, 5}]

在 Infinity 处的渐近展开式：

Wolfram Language code: Series[ChebyshevU[1 / 3, x], {x, ∞, 3}]//Normal//FullSimplify

在奇点处的渐近展开式：

Wolfram Language code: Series[ChebyshevU[1 / 3, x], {x, -1, 2}]//FullSimplify

范围  (44)

数值计算  (6)

数值化计算：

Wolfram Language code: ChebyshevU[2, 5]
Wolfram Language code: ChebyshevU[12, 2.5]

高精度计算：

Wolfram Language code: N[ChebyshevU[1 / 7, 1 / 3], 50]

输出的精度与输入的精度一致：

Wolfram Language code: ChebyshevU[0.3000000000000000000, 0]

复数输入：

Wolfram Language code: N[ChebyshevU[98 + I, I]]

高精度的高效计算：

Wolfram Language code: ChebyshevU[-1.5, -2.4`100]//Timing
Wolfram Language code: ChebyshevU[84, 63`10000000];//Timing

用 Interval 和 CenteredInterval 对象计算最坏情况下的区间：

Wolfram Language code: ChebyshevU[2, Interval[{1.9, 2.1}]]
Wolfram Language code: ChebyshevU[2, CenteredInterval[2, 1 / 100]]

或用 Around 计算一般情况下的统计区间：

Wolfram Language code: ChebyshevU[2, Around[2, 0.01]]

计算数组中每个元素的值：

Wolfram Language code: ChebyshevU[2, {{1, 2}, {3, 4}}]

或用 MatrixFunction 计算矩阵形式的 ChebyshevU 函数：

Wolfram Language code: MatrixFunction[ChebyshevU[2, #]&, {{1, 2}, {3, 4}}]

特殊值  (7)

在固定点的 ChebyshevU 的值：

Wolfram Language code: Table[ChebyshevU[n, Pi / 2], {n, 0, 3}]

符号 n 的 ChebyshevU:

Wolfram Language code: ChebyshevU[n, 0]

零处的值：

Wolfram Language code: ChebyshevU[0, 0]

无穷处的值：

Wolfram Language code: ChebyshevU[0, Infinity]
Wolfram Language code: ChebyshevU[Infinity, 0][[1, 1]]

求 ChebyshevU[5,x] 的第一个正极大值：

Wolfram Language code: xmax = x /. Solve[D[ChebyshevU[5, x], x] == 0 && 0 < x < π, x][[1]]
Wolfram Language code: Plot[ChebyshevU[5, x], {x, -1, 1}, Epilog -> Style[Point[{xmax, ChebyshevT[5, xmax]}], PointSize[Large], Red]]

计算相关的 ChebyshevU[7,x] 多项式：

Wolfram Language code: ChebyshevU[7, x]

计算 n 为半整数的 ChebyshevU[1/2,x] 多项式：

Wolfram Language code: ChebyshevU[1 / 2, x]

可视化  (3)

绘制各个阶数的 ChebyshevU 函数：

Wolfram Language code: Plot[{ChebyshevU[1, x], ChebyshevU[2, x], ChebyshevU[3, x], ChebyshevU[4, x]}, {x, -1, 1}]

绘制 TemplateBox[{3, z}, ChebyshevU] 实部：

Wolfram Language code: ComplexContourPlot[Re[ChebyshevU[3, z]], {z, -3 - 3 I, 3 + 3 I}, IconizedObject[«PlotOptions»]]

绘制 TemplateBox[{3, z}, ChebyshevU] 虚部：

Wolfram Language code: ComplexContourPlot[Im[ChebyshevU[3, z]], {z, -3 - 3 I, 3 + 3 I}, IconizedObject[«PlotOptions»]]

将切比雪夫多项式绘制成两个变量的函数：

Wolfram Language code: Plot3D[ChebyshevU[n, z], {n, 0, 5}, {z, -1, 1}]

函数的属性  (14)

ChebyshevU 对区间 [-1,∞] 内的所有实数有定义：

Wolfram Language code: FunctionDomain[ChebyshevU[n, x], x]

ChebyshevU 对除 外的所有复数都有定义：

Wolfram Language code: FunctionDomain[ChebyshevU[n, z], z, Complexes]

TemplateBox[{1, x}, ChebyshevU] 的值域是所有实数和复数：

Wolfram Language code: FunctionRange[ChebyshevU[1, x], x, y]
Wolfram Language code: FunctionRange[ChebyshevU[1, z], z, y, Complexes]

TemplateBox[{2, x}, ChebyshevU] 的实数值域：

Wolfram Language code: FunctionRange[ChebyshevU[2, x], x, y]

值域也包括所有复数：

Wolfram Language code: FunctionRange[ChebyshevU[2, z], z, y, Complexes]

奇数阶的 Chebyshev 多项式是奇函数：

Wolfram Language code: ChebyshevU[1, -x] == -ChebyshevU[1, x]

偶数阶的 Chebyshev 多项式是偶函数：

Wolfram Language code: ChebyshevU[2, -x] == ChebyshevU[2, x]

ChebyshevU 逐项作用于列表的各个元素：

Wolfram Language code: ChebyshevU[{1, 2, 3}, x]

Chebyshev 多项式是解析的：

Wolfram Language code: FunctionAnalytic[ChebyshevU[n, x], x, Assumptions -> n∈ℤ]

通常情况下，ChebyshevU 既不是解析函数也不是亚纯函数：

Wolfram Language code: FunctionAnalytic[ChebyshevU[1 / 3, x], x, ℂ]
Wolfram Language code: FunctionMeromorphic[ChebyshevU[1 / 3, x], x]

TemplateBox[{2, x}, ChebyshevU] 既不是非递增，也不是非递减：

Wolfram Language code: FunctionMonotonicity[ChebyshevU[2, x], x]

TemplateBox[{2, x}, ChebyshevU] 不是单射函数：

Wolfram Language code: FunctionInjective[ChebyshevU[2, x], x]

TemplateBox[{1, x}, ChebyshevU] 是单射函数：

Wolfram Language code: FunctionInjective[ChebyshevU[1, x], x]
Wolfram Language code: Plot[{ChebyshevU[1, x], ChebyshevU[2, x], 2}, {x, -1, 1}]

TemplateBox[{2, x}, ChebyshevU] 不是满射函数：

Wolfram Language code: FunctionSurjective[ChebyshevU[2, x], x]

TemplateBox[{1, x}, ChebyshevU] 是满射函数：

Wolfram Language code: FunctionSurjective[ChebyshevU[1, x], x]
Wolfram Language code: Plot[{ChebyshevU[1, x], ChebyshevU[2, x], -2}, {x, -1, 1}]

TemplateBox[{2, x}, ChebyshevU] 既不是非负，也不是非正：

Wolfram Language code: FunctionSign[ChebyshevU[2, x], x]

不是整数时，对于 ，TemplateBox[{n, x}, ChebyshevT] 有奇点和断点：

Wolfram Language code: FunctionSingularities[ChebyshevU[n, x], x]
Wolfram Language code: FunctionDiscontinuities[ChebyshevU[n, x], x]

TemplateBox[{2, x}, ChebyshevU] 是凸函数：

Wolfram Language code: FunctionConvexity[ChebyshevU[2, x], x]

TraditionalForm 格式：

Wolfram Language code: ChebyshevU[n, x]//TraditionalForm

微分  (3)

关于 x 的一阶导数：

Wolfram Language code: D[ChebyshevU[n, x] , x]

关于 x 的高阶导数：

Wolfram Language code: Table[D[ChebyshevU[n, x], {x, k}], {k, 1, 3}]//Simplify

绘制 n=5 时关于 x 的高阶导数：

Wolfram Language code: Plot[Evaluate[% /. n -> 5], {x, -10, 10}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]

关于 x 的 阶导数的公式：

Wolfram Language code: D[ChebyshevU[n, x], {x, k}]// FullSimplify

积分  (4)

使用 Integrate 计算不定积分：

Wolfram Language code: Integrate[ChebyshevU[n, x], x]

验证反导数：

Wolfram Language code: FullSimplify[D[%, x]]

定积分：

Wolfram Language code: Integrate[ChebyshevU[n, x], {x, 0, 4}]

奇整数阶数的 ChebyshevU 在一个周期内的定积分是 0：

Wolfram Language code: Integrate[ChebyshevU[2n - 1, x], {x, -5, 5}]
Wolfram Language code: Table[%, {n, 3, 11, 2}]//FullSimplify

更多积分：

Wolfram Language code: Integrate[ChebyshevU[3, x]ChebyshevT[5, x], x]//FullSimplify
Wolfram Language code: Integrate[Exp[x] ChebyshevU[5, x], {x, 0, 5}]//FullSimplify

级数展开  (3)

使用 Series 求泰勒展开：

Wolfram Language code: Series[ChebyshevU[n, x], {x, 0, 3}]

绘制 附近的前三个近似：

Wolfram Language code: terms = Normal@Table[Series[ChebyshevU[10, x], {x, 0, m}], {m, 1, 5, 2}]; Plot[{ChebyshevU[10, x], terms}, {x, -1, 1}, PlotRange -> {-3, 3}]

用 SeriesCoefficient 给出级数展开式的通项：

Wolfram Language code: SeriesCoefficient[ChebyshevU[n, x], {x, 0, n}]

普通点的泰勒展开：

Wolfram Language code: Series[ChebyshevU[n, x], {x, x0, 2}]

函数恒等式与简化  (4)

ChebyshevU 是通过以下三角恒等式定义的：

Wolfram Language code: ChebyshevU[n, Cos[θ]] == Sin[(n + 1) θ] / Sin[θ]//FullSimplify

ChebyshevU 的普通母函数：

Wolfram Language code: Sum[ChebyshevU[n, x]t^n, {n, 0, Infinity}]

ChebyshevU 的指数母函数：

Wolfram Language code: Sum[ChebyshevU[n, x]t^n / n!, {n, 0, Infinity}]

递归关系：

Wolfram Language code: ChebyshevU[n, z] == 2 z ChebyshevU[n + 1, z] - ChebyshevU[n + 2, z]//FullSimplify
Wolfram Language code: ChebyshevU[n - 1, z] + ChebyshevU[n + 1, z] == 2 z ChebyshevU[n, z]//FullSimplify

推广和延伸  (2)

可将 ChebyshevU 应用于幂级数：

Wolfram Language code: ChebyshevU[10, Log[1 + x] + O[x] ^ 6]

ChebyshevU 可用于 Interval：

Wolfram Language code: ChebyshevU[10, Interval[{-1, 1}]]

应用  (7)

在区间 上近似函数：

Wolfram Language code: coeffs = Table[((2/π)Subsuperscript[∫, -1, 1]Sqrt[1 - x^2] ChebyshevU[n, x] Sinc[2x π]ⅆx), {n, 0, 4}];
Wolfram Language code: Plot[{Sinc[2π x], Evaluate[coeffs.Table[ChebyshevU[n, x], {n, 0, 4}]]}, {x, -1, 1}]

构建一条通过给定点的曲线：

Wolfram Language code: curve[pts_List] := Function[x, Evaluate[Block[{n = Length[pts]}, pts.Table[ChebyshevU[n - 1, Sin[(k π/n)] Sqrt[1 - x^2] + x Cos[(π k/n)]], {k, 0, n - 1}] / n]]]
Wolfram Language code: points[pts_List] := MapIndexed[{-1. Cos[(First[#2]) * Pi / Length[pts]], #1}&, Reverse[pts]]
Wolfram Language code: Plot[Evaluate[curve[Range[15]][x]], {x, -1, 1}, Prolog -> {Red, PointSize[0.02], Point[points[Range[15]]]}]

光穿过 层玻璃的幅值变化：

Wolfram Language code: Plot[ Evaluate[Table[1 / (1 + k^2 ChebyshevU[n, Cos[k] + Sinc[k]]^2), {n, 0, 5}]], {k, 0, 10}, PlotRange -> All]

定义一个Toeplitz 三对角矩阵：

Wolfram Language code: toeplitzTridiagonal[a_, b_, c_, n_] := SparseArray[{Band[{2, 1}] -> a, Band[{1, 1}] -> b, Band[{1, 2}] -> c}, {n, n}]

展示 4×4 的情况：

Wolfram Language code: toeplitzTridiagonal[a, b, c, 4]//MatrixForm

Toeplitz 三对角矩阵的特征多项式可以用 ChebyshevU 来表示：

Wolfram Language code: cPoly[a_, b_, c_, n_, x_] := (-Sqrt[a c])^n ChebyshevU[n, (x - b/2Sqrt[a c])]

验证前几种情况：

Wolfram Language code: Table[CharacteristicPolynomial[toeplitzTridiagonal[a, b, c, n], x] == cPoly[a, b, c, n, x]//Simplify, {n, 2, 9}]

定义 Kac–Murdock–Szegő (KMS) 矩阵，它是一个对称的托普利兹矩阵：

Wolfram Language code: kms[ρ_, n_] := ToeplitzMatrix[ρ^Range[0, n - 1]]

KMS 矩阵是一阶自回归过程（即 AR(1) 过程）的相关矩阵：

Wolfram Language code: n = 6; kms[ρ, n] == Correlation[ARProcess[{ρ}, σ ^ 2][Range[n]]]//Simplify

KMS 矩阵的特征多项式可以用 ChebyshevU 表示：

Wolfram Language code: CharacteristicPolynomial[kms[ρ, n], λ] == With[{τ = (ρ^2(λ + 1) + λ - 1/2ρ λ)}, ((ρ λ)^n/1 - ρ^2)(ChebyshevU[n, τ] - 2ρ ChebyshevU[n - 1, τ] + ρ^2ChebyshevU[n - 2, τ])]//Simplify

用 ChebyshevU 函数作为非齐次部分，解微分方程：

Wolfram Language code: DSolve[y''[x] + ChebyshevU[n, x] == 0, y[x], x]

从其生成函数中求得切比雪夫多项式：

Wolfram Language code: Series[1 / (1 - 2 t x + t ^ 2), {t, 0, 4}]
Wolfram Language code: SeriesCoefficient[%, 4]
Wolfram Language code: ChebyshevU[4, x]

属性和关系  (7)

给出 ChebyshevU 多项式中的系数列表：

Wolfram Language code: CoefficientList[ ChebyshevU[10, x], x]

利用 FunctionExpand 展开三角函数：

Wolfram Language code: FunctionExpand[ChebyshevU[n, x]]

ChebyshevU 相对于 的导数：

Wolfram Language code: D[ChebyshevU[n, x], x]

可以用 DifferenceRoot 来表示ChebyshevU：

Wolfram Language code: DifferenceRootReduce[ChebyshevU[k, z], k]

ChebyshevU 级数展开式中的一般项：

Wolfram Language code: SeriesCoefficient[ChebyshevU[a, x], {x, 0, n}]

ChebyshevU 的母函数：

Wolfram Language code: GeneratingFunction[ChebyshevU[n, k], n, x]

ChebyshevU 的指数母函数：

Wolfram Language code: ExponentialGeneratingFunction[ChebyshevU[n, k], n, x]

可能存在的问题  (1)

多项式形式的相约可能导致不准确的数值结果：

Wolfram Language code: ChebyshevU[60, x] /. x -> N[2 / 3, 16]

直接计算函数：

Wolfram Language code: ChebyshevU[60, N[2 / 3, 16]]
Wolfram Research (1988)，ChebyshevU，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ChebyshevU.html （更新于 2022 年）.

文本

Wolfram Research (1988)，ChebyshevU，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ChebyshevU.html （更新于 2022 年）.

CMS

Wolfram 语言. 1988. "ChebyshevU." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2022. https://reference.wolfram.com/language/ref/ChebyshevU.html.

APA

Wolfram 语言. (1988). ChebyshevU. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/ChebyshevU.html 年

BibTeX

@misc{reference.wolfram_2026_chebyshevu, author="Wolfram Research", title="{ChebyshevU}", year="2022", howpublished="\url{https://reference.wolfram.com/language/ref/ChebyshevU.html}", note=[Accessed: 09-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_chebyshevu, organization={Wolfram Research}, title={ChebyshevU}, year={2022}, url={https://reference.wolfram.com/language/ref/ChebyshevU.html}, note=[Accessed: 09-August-2026]}