WOLFRAM

Wolfram 语言与系统参考资料中心

Check[expr,failexpr]

计算 expr 并返回结果，但如果有提示消息生成，则计算并返回 failexpr.

Check[expr,failexpr,{s1::t1,s2::t2,…}]

仅对指定的消息进行校验.

Check[expr,failexpr,"name"]

仅校验已命名消息组中的消息.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
应用  
属性和关系  
可能存在的问题  
参见
技术笔记
相关指南
相关的工作流程
历史
按以下格式引用：

Check

Check[expr,failexpr]

计算 expr 并返回结果，但如果有提示消息生成，则计算并返回 failexpr.

Check[expr,failexpr,{s1::t1,s2::t2,…}]

仅对指定的消息进行校验.

Check[expr,failexpr,"name"]

仅校验已命名消息组中的消息.

更多信息

  • Check 具有属性 HoldAll.
  • Check 对于利用 Off、或者通过利用在其内出现的 Quiet 断开的消息不进行测试.
  • Check 的操作不受将其封闭在内的 Quiet 的影响.
  • 在 Check[expr,failexpr,"name"] 中，$MessageGroups 给出可能的命名消息组.
  • 形如 s::t 的显式消息名可以与已命名消息组混合在一起使用.

范例

打开所有单元 关闭所有单元

基本范例  (2)

当发出任何信息时，返回 err：

Wolfram Language code: Check[1 ^ 0, err]
Wolfram Language code: Check[0 ^ 0, err]

仅对指定的消息校验：

Wolfram Language code: Check[Sin[0 ^ 0], err, Sin::argx]
Wolfram Language code: Check[Sin[x, y], err, Sin::argx]

范围  (3)

校验来自特定函数的信息：

Wolfram Language code: Check[0 ^ 0, "message issued", Power::indet]

ArcTan::indet 未被 Check 捕获：

Wolfram Language code: Check[ArcTan[0, 0], "message issued", Power::indet]

使用标头 General 可捕捉来自任何函数的信息：

Wolfram Language code: Check[ArcTan[0, 0], "message issued", General::indet]

捕获多条信息：

Wolfram Language code: Check[Sin[0 ^ 0], err, {General::infy, General::indet, General::argx}]
Wolfram Language code: Check[1 / 0, err, {General::infy, General::indet, General::argx}]

校验命名组的信息：

Wolfram Language code: f = Compile[{{x, _Real}}, x]
Wolfram Language code: Check[f[I], "message issued", "Compiler"]
Wolfram Language code: Check[f[I], "message issued", "Graphics"]

应用  (1)

使用 Check 和 Quiet 为函数不适用的参数提供值：

Wolfram Language code: f[x_] := Quiet[Check[StringTake[x, 4], x, StringTake::take], StringTake::take]

如果参数是长度小于 4 的字符串，则此函数只返回其参数：

Wolfram Language code: f /@ {"abcdef", "ab", "eg3j"}

如果没有 Check 和 Quiet，将返回带有消息的未被计算的中间输入：

Wolfram Language code: StringTake["ab", 4]

属性和关系  (3)

Check 不会阻止发出消息：

Wolfram Language code: Check[Sin[x, y], "too many", General::argx]

Check 不会检测内部 Quiet 抑制的消息：

Wolfram Language code: Check[Quiet[1 / 0], error]

但是，Check 的操作不受是在 Quiet 内部的影响：

Wolfram Language code: Quiet[Check[1 / 0, error]]

Check 不会报告已关闭的信息：

Wolfram Language code: Off[Power::infy]
Wolfram Language code: Check[1 / 0, "message issued"]

恢复信息：

Wolfram Language code: On[Power::infy]

可能存在的问题  (1)

嵌套的 Check 不会抑制内部的 Check 的消息：

Wolfram Language code: Check[Check[1 / 0, inner, Power::infy], outer, Power::infy]

在中间使用 Quiet 可阻止内部的 Check 对消息作出反应：

Wolfram Language code: Check[Quiet[Check[1 / 0, inner, Power::infy], Power::infy], outer, Power::infy]
Wolfram Research (1988)，Check，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Check.html （更新于 2008 年）.

文本

Wolfram Research (1988)，Check，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Check.html （更新于 2008 年）.

CMS

Wolfram 语言. 1988. "Check." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2008. https://reference.wolfram.com/language/ref/Check.html.

APA

Wolfram 语言. (1988). Check. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/Check.html 年

BibTeX

@misc{reference.wolfram_2026_check, author="Wolfram Research", title="{Check}", year="2008", howpublished="\url{https://reference.wolfram.com/language/ref/Check.html}", note=[Accessed: 11-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_check, organization={Wolfram Research}, title={Check}, year={2008}, url={https://reference.wolfram.com/language/ref/Check.html}, note=[Accessed: 11-September-2026]}