WOLFRAM

Wolfram 语言与系统参考资料中心

ClickPane[image,func]

表示显示为 image 的可点击窗格，并将 func 应用于面板中每次点击时的 坐标.

ClickPane[image,{{xmin,ymin},{xmax,ymax}},func]

指定所用坐标的范围.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
选项  
Method  
PassEventsDown  
PassEventsUp  
应用  
属性和关系  
可能存在的问题  
参见
技术笔记
相关指南
相关的工作流程
历史
按以下格式引用：

ClickPane

ClickPane[image,func]

表示显示为 image 的可点击窗格，并将 func 应用于面板中每次点击时的 坐标.

ClickPane[image,{{xmin,ymin},{xmax,ymax}},func]

指定所用坐标的范围.

更多信息和选项

  • 点击窗格中的图像可为图形或任意其它表达式.
  • 对于 Graphics 对象 g，ClickPane[g,func] 缺省取 func 的坐标范围作为 g 中对应于 PlotRange 中的图形坐标范围.
  • 对于一般表达式，ClickPane[expr,func] 使坐标范围在每个方向都为 0 至 1.
  • ClickPane 接受以下选项：
  • Method "Preemptive"使用的计算方法
    PassEventsDown Automatic是否将事件传递给内部事件处理程序
    PassEventsUp True是否将事件传递给外部事件处理程序

范例

打开所有单元 关闭所有单元

基本范例  (2)

将点移至 “点击” 处：

Wolfram Language code: DynamicModule[{pt = {0, 0}}, ClickPane[Dynamic@Graphics[{Yellow, Disk[], Black, Point[pt]}, ImageSize -> Tiny], (pt = #)&]]

使圆盘的中心位于鼠标点击处：

Wolfram Language code: DynamicModule[{pt = {0, 0}}, ClickPane[Framed@Graphics[{Yellow, Dynamic@Disk[pt]}, PlotRange -> 5], (pt = #)&]]

范围  (2)

对于普通表达式，每个方向上坐标的范围被设定为从 0 到 1：

Wolfram Language code: DynamicModule[{pt = {0, 0}}, {ClickPane[Panel[20!], (pt = #)&], Dynamic[pt]}]

自动将坐标重新缩放为 到 的范围：

Wolfram Language code: DynamicModule[{pt = {0, 0}}, {ClickPane[Panel[20!], {{-5, -5}, {5, 5}}, (pt = #)&], Dynamic[pt]}]

选项  (3)

Method  (1)

默认情况下，在抢占式链接上计算函数，并在 5 秒后超时停止计算：

Wolfram Language code: DynamicModule[{pt = {0, 0}}, {ClickPane[Framed@Graphics[{Yellow, Dynamic@Disk[pt]}, PlotRange -> 5], (Pause[6];pt = #)&], Dynamic[pt]}]

通过设置 Method->"Queued" 在主链接上计算函数，不会超时停止计算：

Wolfram Language code: DynamicModule[{pt = {0, 0}}, {ClickPane[Framed@Graphics[{Yellow, Dynamic@Disk[pt]}, PlotRange -> 5], (Pause[6];pt = #)&, Method -> "Queued"], Dynamic[pt]}]

PassEventsDown  (1)

默认情况下，点击按钮将触发 ClickPane，但不是按钮：

Wolfram Language code: DynamicModule[{pt = {0, 0}}, {ClickPane[Framed[Graphics[Inset[Button["print", Print["fish"]]]]], (pt = #)&], Dynamic[pt]}]

用 PassEventsDown 启用点击，注册按钮：

Wolfram Language code: DynamicModule[{pt = {0, 0}}, {ClickPane[Framed[Graphics[Inset[Button["print", Print["fish"]]]]], (pt = #)&, PassEventsDown -> True], Dynamic[pt]}]

PassEventsUp  (1)

单击内部窗格将触发内部窗格和外部窗格：

Wolfram Language code: DynamicModule[{outer = {0, 0}, inner = {0, 0}}, Column[{Framed[ClickPane[Row[{"Outer click pane", Framed[ClickPane[{"Inner click pane"}, (inner = #)&]]}], (outer = #)&]], {"outer", Dynamic[outer]}, {"inner", Dynamic[inner]}}]]

用 PassEventsUp 在击内部窗格时禁用外部窗格：

Wolfram Language code: DynamicModule[{outer = {0, 0}, inner = {0, 0}}, Column[{Framed[ClickPane[Row[{"Outer click pane", Framed[ClickPane[{"Inner click pane"}, (inner = #)&, PassEventsUp -> False]]}], (outer = #)&]], {"outer", Dynamic[outer]}, {"inner", Dynamic[inner]}}]]

应用  (6)

用图形表示线性微分方程组 的解：

Wolfram Language code: ClickPane[Framed@Dynamic@ParametricPlot[f, {t, 0, 10}, PlotRange -> 5], (f = MatrixExp[(| | | | ---- | --- | | -1.1 | 0.9 | | -1.4 | 0.3 |)t].#)&]

追踪您所获得的所有解：

Wolfram Language code: DynamicModule[{f = {}}, ClickPane[Framed@Dynamic@ParametricPlot[f, {t, 0, 10}, PlotRange -> 5], (AppendTo[f, MatrixExp[(| | | | ---- | --- | | -1.1 | 0.9 | | -1.4 | 0.3 |)t].#])&]]

三点成圆[更多信息]：

Wolfram Language code: createCircle[{{x1_, y1_}, {x2_, y2_}, {x3_, y3_}}] := With[{a = Det[(| | | | | -- | -- | - | | x1 | y1 | 1 | | x2 | y2 | 1 | | x3 | y3 | 1 |)], d = -Det[(| | | | | ----------- | -- | - | | x1^2 + y1^2 | y1 | 1 | | x2^2 + y2^2 | y2 | 1 | | x3^2 + y3^2 | y3 | 1 |)], e = Det[(| | | | | ----------- | -- | - | | x1^2 + y1^2 | x1 | 1 | | x2^2 + y2^2 | x2 | 1 | | x3^2 + y3^2 | x3 | 1 |)], f = -Det[(| | | | | ----------- | -- | -- | | x1^2 + y1^2 | x1 | y1 | | x2^2 + y2^2 | x2 | y2 | | x3^2 + y3^2 | x3 | y3 |)]}, Circle[{-(d/2 a), -(e/2 a)}, Sqrt[(d^2 + e^2/4a^2) - (f/a)]]]
Wolfram Language code: createCircle[pts_] := {}
Wolfram Language code: DynamicModule[{pts = {}, c = {}}, ClickPane[Framed@Graphics[{Dynamic[c], Point[Dynamic[pts]]}, PlotRange -> 5], (If[Length[pts] < 3, AppendTo[pts, #], pts = {#}];c = createCircle[pts])&]]

检测在圆盘内或外：

Wolfram Language code: DynamicModule[{pt = {0, 0}, c = "Red"}, ClickPane[Framed@Graphics[{Red, Disk[], StandardGray, Dynamic@Arrow[{{-2, 0}, pt}], Dynamic@Text[Dynamic[c], {-2, 0}]}], (pt = #;c = If[Norm[pt] < 1, "Red", "White"])&]]

当点击窗格内部时，箭头符号对曲线的 “抽点”：

Wolfram Language code: DynamicModule[{pt = {π / 2, 3}}, ClickPane[Plot[3Sin[x], {x, -6, 6}, Epilog -> {Dynamic@Arrow[{{1, 5}, pt}], Text["Feature", {2, 5}]}, PlotRange -> 6], (pt = {#[[1]], 3Sin[#[[1]]]})&]]

绘制箭头符号对其中一个极值的 “抽点”：

Wolfram Language code: DynamicModule[{pt = {π / 2, 3}}, ClickPane[Plot[3Sin[x], {x, -6, 6}, Epilog -> {Dynamic@Arrow[{{1, 5}, pt}], Text["Extremum", {2, 5}]}, PlotRange -> 6], (With[{x = (2Round[-1 / 2 + #[[1]] / π] + 1)π / 2}, pt = {x, 3Sin[x]}])&]]

属性和关系  (1)

ClickPane 是 EventHandler 的一个特例：

Wolfram Language code: DynamicModule[{pts = {}}, ClickPane[Dynamic[Framed@Graphics[Line[pts], PlotRange -> 1]], AppendTo[pts, #]&]]
Wolfram Language code: DynamicModule[{pts = {}}, Dynamic@EventHandler[Framed@Graphics[Line[pts], PlotRange -> 1], "MouseClicked" :> AppendTo[pts, MousePosition["Graphics"]]]]

可能存在的问题  (1)

在同一点按下并放开鼠标才算一次 “点击”：

Wolfram Language code: DynamicModule[{pts = {}}, ClickPane[Dynamic@Framed@Graphics[Line[pts], PlotRange -> 1], AppendTo[pts, #]&]]

用 EventHandler 获取在事件寄存操作中的更多灵活性：

Wolfram Language code: DynamicModule[{pts = {}}, Dynamic@EventHandler[Framed@Graphics[Line[pts], PlotRange -> 1], "MouseDown" :> AppendTo[pts, MousePosition["Graphics"]]]]
Wolfram Research (2007)，ClickPane，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ClickPane.html.

文本

Wolfram Research (2007)，ClickPane，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ClickPane.html.

CMS

Wolfram 语言. 2007. "ClickPane." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/ClickPane.html.

APA

Wolfram 语言. (2007). ClickPane. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/ClickPane.html 年

BibTeX

@misc{reference.wolfram_2026_clickpane, author="Wolfram Research", title="{ClickPane}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/ClickPane.html}", note=[Accessed: 06-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_clickpane, organization={Wolfram Research}, title={ClickPane}, year={2007}, url={https://reference.wolfram.com/language/ref/ClickPane.html}, note=[Accessed: 06-September-2026]}