CloudEvaluate

CloudEvaluate[expr]

クラウド内で expr を評価し，結果を返す．

CloudEvaluate[expr,h]

結果を返す前にその前後を頭部 h で囲む．

詳細とオプション

CloudEvaluateは属性HoldFirstを有する．
CloudEvaluate[expr]は，CloudSaveと同じように，expr の評価に必要なすべての定義を自動的に含める．
CloudEvaluateには次のオプションがある．
CloudBase Automatic 評価をどのクラウドで行うか

IncludeDefinitions True 従属関係を自動的に含めるかどうか
IncludeDefinitionsTrueのとき，expr の評価に必要な定義はCloudEvaluateによって自動的にクラウドに送られる．
IncludeDefinitions->Falseのときは，expr の評価に必要な定義を expr の評価中にロードして明示的に評価しなければならない．

例題

すべて開くすべて閉じる

例 (3)

クラウド中のメルセンヌ素数を検索する：

Wolfram Language code: CloudEvaluate[Table[If[MersennePrimeExponentQ[i], i, Nothing], {i, 1000}]]

クラウドでマシンに特有の設定を評価する：

Wolfram Language code: CloudEvaluate[{$OperatingSystem, $MachineID}]

ローカルの結果と比較する：

Wolfram Language code: {$OperatingSystem, $MachineID}

クラウド評価の結果に適用する頭部を与える：

Wolfram Language code: CloudEvaluate[Fibonacci[100], f]

スコープ (1)

クラウドに3D等高線プロットを作成する：

Wolfram Language code: CloudEvaluate[ContourPlot3D[x ^ 3 + y ^ 2 - z ^ 2 == 0, {x, -2, 2}, {y, -2, 2}, {z, -2, 2}]]

クラウドを使って画像のコンテンツを識別する：

Wolfram Language code: CloudEvaluate[ImageIdentify[[image]]]

クラウドを使って画像解析を行う：

Wolfram Language code:

CloudEvaluate[
	painting = Entity["Artwork", "NightWatch::Rembrandt"]["Image"];
	<|painting -> DominantColors[painting]|>
	]

一般化と拡張 (1)

局所変数のクラウド評価のホールドされたものとホールドされていないものを比較する（g の自動クラウド定義はクリアされている点に注意のこと）：

Wolfram Language code:

g = Pi;
{CloudEvaluate[Clear[g];g], 
	CloudEvaluate[Clear[g];g, Hold]
	}

オプション (2)

CloudBase (1)

$CloudBaseを変えずに特定のクラウド上で評価する：

Wolfram Language code: CloudEvaluate[$MachineName, CloudBase -> "https://www.epc.example.com"]

IncludeDefinitions (1)

デフォルトでは，ローカル関数およびその他のシンボル定義は，クラウドで評価される式に含まれる：

Wolfram Language code:

count = 99;
f[x_] := x + 1
CloudEvaluate[f[count], Hold]

ローカル定義を含まないようにする：

Wolfram Language code:

count = 99;
f[x_] := x + 1
CloudEvaluate[f[count], Hold, IncludeDefinitions -> False]

特性と関係 (3)

CloudEvaluateは，評価中に出された任意のメッセージを表示する：

Wolfram Language code: CloudEvaluate[1 / 0]

しかし，印刷用の出力等，その他のいかなるノートブック操作も再生することはできない：

Wolfram Language code: CloudEvaluate[Print["text"]]

クラウド評価では，$CloudEvaluationがTrueに設定されている：

Wolfram Language code: CloudEvaluate[$CloudEvaluation]

個々のクラウド評価は別々のプロセスで行われることが多い：

Wolfram Language code: {CloudEvaluate[$ProcessID], CloudEvaluate[$ProcessID]}

クラウドでの評価中にCloudEvaluateを使うと，常に同じプロセスで実行される：

Wolfram Language code: CloudEvaluate[{$ProcessID, CloudEvaluate[$ProcessID]}]

考えられる問題 (3)

クラウド評価の結果はローカルセッションでの評価に従う．複数の評価には複数のメッセージが出ることがある：

Wolfram Language code: CloudEvaluate[Plot[]]

頭部Holdを適用して2番目の局所評価を防ぐ：

Wolfram Language code: CloudEvaluate[Plot[], Hold]

IncludeDefinitionsTrueのデフォルト設定では，式に現れるシンボルのローカル定義は，それが使用されていない場合であっても含まれる．

大きな式をシンボルに設定する：

Wolfram Language code: ByteCount[data = ByteArray[RandomInteger[{0, 255}, 10 * 2 ^ 20]]]

ローカルのカーネルセッションで設定されたシンボルを参照するCloudEvaluateは，その定義がクラウドへ送信されるため，予想よりも長い時間を要する場合がある：

Wolfram Language code:

AbsoluteTiming[
	CloudEvaluate[
	incomingSize = ByteCount[data];data = ByteArray[RandomInteger[{0, 255}, 10000]];  {incomingSize, ByteCount[data]}
	]
	]

ローカル定義を含めないようにしたければ，IncludeDefinitionsFalseを使用する：

Wolfram Language code:

AbsoluteTiming[
	CloudEvaluate[
	incomingSize = ByteCount[data];data = ByteArray[RandomInteger[{0, 255}, 10000]];  {incomingSize, ByteCount[data]}, 
	IncludeDefinitions -> False
	]
	]

クラウド評価には，メモリ使用量と評価時間の制限がある．CloudEvaluateの制限はユーザのクラウドプランによって決定される．具体的な数値はCloudAccountDataの"DeployedMemoryLimit"および"DeployedEvaluationTimeLimit"で確認できる：

Wolfram Language code: CloudAccountData /@ {"DeployedMemoryLimit", "DeployedEvaluationTimeLimit"}

Top

その他のラーニングリソース

テクニカルサポート

データサイエンス，金融，ビジネス

工学

科学とテクノロジー

教育のためのテクノロジー

教育イニシアチブ

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

CloudEvaluate

詳細とオプション

例題

例 (3)

スコープ (1)

一般化と拡張 (1)

オプション (2)

CloudBase (1)

IncludeDefinitions (1)

特性と関係 (3)

考えられる問題 (3)

テキスト

CMS

APA

BibTeX

BibLaTeX

	CloudBase	Automatic	評価をどのクラウドで行うか
	IncludeDefinitions	True	従属関係を自動的に含めるかどうか

CloudEvaluate

詳細とオプション

例題

例 (3)

スコープ (1)

一般化と拡張 (1)

オプション (2)

CloudBase (1)

IncludeDefinitions (1)

特性と関係 (3)

考えられる問題 (3)

関連項目

関連するガイド

履歴

テキスト

CMS

APA

BibTeX

BibLaTeX