WOLFRAM

Wolfram 语言与系统参考资料中心

CoefficientList[poly,var]

给出在 poly 中 var 的幂系数的列表，从 0 次幂开始.

CoefficientList[poly,{var1,var2,…}]

给出 vari 的系数数组.

CoefficientList[poly,{var1,var2,…},{dim1,dim2,…}]

给出维数 {dim1,dim2,…} 的数组，在需要的时候还会删减或添加零.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
选项  
Modulus  
属性和关系  
参见
技术笔记
相关指南
相关链接
历史
按以下格式引用：

CoefficientList

CoefficientList[poly,var]

给出在 poly 中 var 的幂系数的列表，从 0 次幂开始.

CoefficientList[poly,{var1,var2,…}]

给出 vari 的系数数组.

CoefficientList[poly,{var1,var2,…},{dim1,dim2,…}]

给出维数 {dim1,dim2,…} 的数组，在需要的时候还会删减或添加零.

更多信息和选项

  • 由 CoefficientList 返回的数组维数由 Exponent[poly,vari] 的值确定.
  • 那些不包含特定变量的正整数次幂的项被包含在这个变量列表的第一个元素中.
  • CoefficientList 总是返回一个矩形全数组. 那些在 poly 中不出现的幂的组合在数组中为零.
  • CoefficientList[0,var] 给出 {}.
  • 无论 poly 是否显式地以展开形式给出，CoefficientList 都有效.

范例

打开所有单元 关闭所有单元

基本范例  (3)

求多项式中的系数：

Wolfram Language code: CoefficientList[1 + 6x - x ^ 4, x]

即使多项式还没有展开，CoefficientList 也有效：

Wolfram Language code: CoefficientList[(1 + x) ^ 10 , x]

二次函数的系数矩阵：

Wolfram Language code: CoefficientList[1 + a x ^ 2 + b x y + c y ^ 2, {x, y}]

范围  (2)

单变量多项式的系数列表：

Wolfram Language code: CoefficientList[(2x + 3) ^ 5, x]
Wolfram Language code: CoefficientList[a x ^ 4 + b x ^ 3 + c x ^ 2 + d x + e, x]

多变量多项式的系数列表：

Wolfram Language code: CoefficientList[(3x + 4 y + 1) ^ 3, {x, y}]
Wolfram Language code: CoefficientList[(x + y + z + 1)(2x + 3y ^ 2 + 4z ^ 3 + 5), {x, y, z}]

选项  (1)

Modulus  (1)

在整数模除2上的系数列表：

Wolfram Language code: CoefficientList[(x + 1) ^ 5, x, Modulus -> 2]

属性和关系  (4)

利用 Coefficient 得到这个变量的指定幂的系数：

Wolfram Language code: f = (2x + 3) ^ 3;
Wolfram Language code: Coefficient[f, x, 2]

系数列表可以利用 Coefficient 和 Exponent 得到：

Wolfram Language code: Coefficient[f, x, #]& /@ Range[0, Exponent[f, x]]
Wolfram Language code: CoefficientList[f, x]

FromDigits 可以根据其系数列表重建一个单变量多项式：

Wolfram Language code: CoefficientList[a + b x + c x ^ 2, x]
Wolfram Language code: FromDigits[Reverse[%], x]

将多变量多项式的运算叠起：

Wolfram Language code: CoefficientList[(x + 2y) ^ 3, {x, y}]
Wolfram Language code: Fold[FromDigits[Reverse[#1], #2]&, %, {x, y}]
Wolfram Language code: Expand[(x + 2y) ^ 3 - %]

多项式乘积是由 ListConvolve 完成的卷积：

Wolfram Language code: CoefficientList[(a + b x + c x ^ 2)(1 + 2x + 3x ^ 2 + 4x ^ 3), x]
Wolfram Language code: ListConvolve[{a, b, c}, {1, 2, 3, 4}, {1, -1}, 0]

对于多变量多项式 CoefficientList 给出系数的张量：

Wolfram Language code: f = (3x + 5y) ^ 4;
Wolfram Language code: cl = CoefficientList[f, {x, y}]

CoefficientArrays 给出多项式系数数组的列表，按总次数排序：

Wolfram Language code: ca = CoefficientArrays[f, {x, y}]

的系数：

Wolfram Language code: Coefficient[f, x y ^ 3]

在 cl 中, x^a y^b 的系数是位置在 {a+1,b+1} 的元素：

Wolfram Language code: cl[[1 + 1, 1 + 3]]

在 ca 中，此系数的位置是 a+b+1，随后是 a 个 1 和 b 个 2（1 和 2 表示第一个和第二个变量）：

Wolfram Language code: ca[[5, 1, 2, 2, 2]]
Wolfram Research (1988)，CoefficientList，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CoefficientList.html （更新于 2015 年）.

文本

Wolfram Research (1988)，CoefficientList，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CoefficientList.html （更新于 2015 年）.

CMS

Wolfram 语言. 1988. "CoefficientList." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2015. https://reference.wolfram.com/language/ref/CoefficientList.html.

APA

Wolfram 语言. (1988). CoefficientList. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/CoefficientList.html 年

BibTeX

@misc{reference.wolfram_2026_coefficientlist, author="Wolfram Research", title="{CoefficientList}", year="2015", howpublished="\url{https://reference.wolfram.com/language/ref/CoefficientList.html}", note=[Accessed: 11-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_coefficientlist, organization={Wolfram Research}, title={CoefficientList}, year={2015}, url={https://reference.wolfram.com/language/ref/CoefficientList.html}, note=[Accessed: 11-September-2026]}