WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

CoifletWavelet[]

次数2のCoifletウェーブレットを表す．

CoifletWavelet[n]

次数 n のCoifletウェーブレットを表す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
基本的な用法  
ウェーブレット変換  
より高い次元  
アプリケーション  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
テクニカルノート
関連するガイド
履歴
引用書式

CoifletWavelet

CoifletWavelet[]

次数2のCoifletウェーブレットを表す．

CoifletWavelet[n]

次数 n のCoifletウェーブレットを表す．

詳細

  • CoifletWaveletは直交ウェーブレット族を定義する．
  • CoifletWavelet[n]は1から5までの正の整数 n について定義される
  • スケーリング関数()とウェーブレット関数()は長さのコンパクトサポートを持つ．スケーリング関数は個のバニッシングモーメントを持ち，ウェーブレット関数は 個のバニッシングモーメントを持つ．
  • CoifletWaveletはDiscreteWaveletTransform，WaveletPhi，WaveletPsi等の関数で使うことができる．

例題

すべて開く すべて閉じる

例  (3)

スケーリング関数：

Wolfram Language code: Plot[WaveletPhi[CoifletWavelet[1], x], {x, -2, 3}, PlotRange -> All]
Wolfram Language code: WaveletPhi[CoifletWavelet[1], x]

ウェーブレット関数：

Wolfram Language code: Plot[WaveletPsi[CoifletWavelet[1], x], {x, -2, 3}, PlotRange -> All]
Wolfram Language code: WaveletPsi[CoifletWavelet[1], x]

フィルタ係数：

Wolfram Language code: WaveletFilterCoefficients[CoifletWavelet[1], {"PrimalLowpass", "PrimalHighpass"}]

スコープ  (12)

基本的な用法  (7)

主ローパスフィルタ係数を計算する：

Wolfram Language code: WaveletFilterCoefficients[CoifletWavelet[1], "PrimalLowpass"]

主ハイパスフィルタ係数：

Wolfram Language code: WaveletFilterCoefficients[CoifletWavelet[1], "PrimalHighpass"]

リフティングフィルタ係数：

Wolfram Language code: WaveletFilterCoefficients[CoifletWavelet[2], "LiftingFilter"]
Wolfram Language code: %[{"LiftingMatrixForm", z}]

関数を生成してリフティングウェーブレット変換を計算する：

Wolfram Language code: lf = WaveletFilterCoefficients[CoifletWavelet[2], "LiftingFilter"]
Wolfram Language code: lf["ForwardLiftingFunction"][Range[8]]
Wolfram Language code: lf["InverseLiftingFunction"][%]

次数1のCoifletスケーリング関数：

Wolfram Language code: Plot[WaveletPhi[CoifletWavelet[1], x], {x, -2, 3}, PlotRange -> All]

次数4のCoifletスケーリング関数：

Wolfram Language code: Plot[WaveletPhi[CoifletWavelet[4], x], {x, -5, 5}, PlotRange -> All]

異なる精緻化のスケールでスケーリング関数をプロットする：

Wolfram Language code: Table[Plot[WaveletPhi[CoifletWavelet[1], x, MaxRecursion -> i], {x, -2, 3}, PlotLabel -> "scale " <> ToString[i]], {i, 1, 8, 2}]

次数1のCoifletウェーブレット関数：

Wolfram Language code: Plot[WaveletPsi[CoifletWavelet[1], x], {x, -2, 3}, PlotRange -> All]

次数4のCoifletウェーブレット関数：

Wolfram Language code: Plot[WaveletPsi[CoifletWavelet[4], x], {x, -3, 4}, PlotRange -> All]

異なる精緻化のスケールでウェーブレット関数をプロットする：

Wolfram Language code: Table[Plot[WaveletPsi[CoifletWavelet[1], x, MaxRecursion -> i], {x, -2, 3}, PlotLabel -> "scale " <> ToString[i], PlotRange -> All], {i, 1, 8, 2}]

ウェーブレット変換  (4)

DiscreteWaveletTransformを計算する：

Wolfram Language code: data = Table[Tanh[t^2], {t, -3π, 3π, (6π/1023)}];
Wolfram Language code: ListLinePlot[data, PlotRange -> All]
Wolfram Language code: dwt = DiscreteWaveletTransform[data, CoifletWavelet[2], 2]

ウェーブレット係数の木を見る：

Wolfram Language code: dwt["TreeView"]

ウェーブレット係数の次元を得る：

Wolfram Language code: dwt["Dimensions"]

ウェーブレット係数をプロットする：

Wolfram Language code: WaveletListPlot[dwt, PlotLayout -> "CommonXAxis"]

DiscreteWaveletPacketTransformを計算する：

Wolfram Language code: data = Table[Tanh[t^2], {t, -3π, 3π, (6π/1023)}];
Wolfram Language code: dwpt = DiscreteWaveletPacketTransform[data, CoifletWavelet[2], 2]

ウェーブレット係数の木を見る：

Wolfram Language code: dwpt["TreeView"]

ウェーブレット係数の次元を得る：

Wolfram Language code: dwpt["Dimensions"]

ウェーブレット係数をプロットする：

Wolfram Language code: WaveletListPlot[dwpt, PlotLayout -> "CommonXAxis"]

StationaryWaveletTransformを計算する：

Wolfram Language code: data = Table[Tanh[t^2], {t, -3π, 3π, (6π/1023)}];
Wolfram Language code: swt = StationaryWaveletTransform[data, CoifletWavelet[2], 2];

ウェーブレット係数の木を見る：

Wolfram Language code: swt["TreeView"]

ウェーブレット係数の次元を得る：

Wolfram Language code: swt["Dimensions"]

ウェーブレット係数をプロットする：

Wolfram Language code: WaveletListPlot[swt, PlotLayout -> "CommonXAxis"]

StationaryWaveletPacketTransformを計算する：

Wolfram Language code: data = Table[Tanh[t^2], {t, -3π, 3π, (6π/1023)}];
Wolfram Language code: swpt = StationaryWaveletPacketTransform[data, CoifletWavelet[2], 2];

ウェーブレット係数の木を見る：

Wolfram Language code: swpt["TreeView"]

ウェーブレット係数の次元を得る：

Wolfram Language code: swpt["Dimensions"]

ウェーブレット係数をプロットする：

Wolfram Language code: WaveletListPlot[swpt, PlotLayout -> "CommonXAxis"]

より高い次元  (1)

多変量スケーリング関数と多変量ウェーブレット関数はそれぞれの一変量関数の積である：

Wolfram Language code: ϕ = WaveletPhi[CoifletWavelet[1]]; ψ = WaveletPsi[CoifletWavelet[1]];
Wolfram Language code: Plot3D[Evaluate[ϕ[x]ϕ[y]], {x, -2, 3}, {y, -2, 3}, Axes -> None, ColorFunction -> "SolarColors", PlotRange -> All, Mesh -> None]
Wolfram Language code: Plot3D[Evaluate[ϕ[x]ψ[y]], {x, -2, 3}, {y, -2, 3}, Axes -> None, ColorFunction -> "SolarColors", PlotRange -> All, Mesh -> None]
Wolfram Language code: Plot3D[Evaluate[ψ[x]ϕ[y]], {x, -2, 3}, {y, -2, 3}, Axes -> None, ColorFunction -> "SolarColors", PlotRange -> All, Mesh -> None]
Wolfram Language code: Plot3D[Evaluate[ψ[x]ψ[y]], {x, -2, 3}, {y, -2, 3}, Axes -> None, ColorFunction -> "SolarColors", PlotRange -> All, Mesh -> None]

アプリケーション  (3)

Haarウェーブレット係数を使って関数を近似する：

Wolfram Language code: data = Table[Abs[Sin[2π x]] + 1.5Abs[Cos[2π x - π]], {x, 0, 1, (1/2^6 - 1)}];

LiftingWaveletTransformを行う：

Wolfram Language code: dwd = DiscreteWaveletTransform[data, CoifletWavelet[1]];

n 個の最大係数を保ちその他すべてを閾値化することでもとのデータを近似する：

Wolfram Language code: {data8, data16, data32} = Table[InverseWaveletTransform@WaveletThreshold[dwd, {"LargestCoefficients", n}, Automatic], {n, {8, 16, 32}}];

他の近似と比較する：

Wolfram Language code: ListLinePlot[{data, data8, data16, data32}, PlotRange -> All]

インパルスを含む信号の多重解像度表現を計算する：

Wolfram Language code: data = Table[Sin[4π t] + 2Exp[-10 ^ 5(1 / 3 - t) ^ 2], {t, 0, 1, (1/2^9)}];
Wolfram Language code: ListLinePlot[data]
Wolfram Language code: dwt = DiscreteWaveletTransform[data, CoifletWavelet[1], 4]
Wolfram Language code: WaveletListPlot[dwt, {{1}, {0, 1}, {0, 0, 1}, {0, 0, 0}}, PlotLayout -> "CommonXAxis", Method -> {"Inverse" -> True}]

信号の累積エネルギーをそのウェーブレット係数と比較する：

Wolfram Language code: data = Table[Sin[2π t], {t, 0, 1, 1 / 63}];
Wolfram Language code: ListPlot[data]

信号の順序化された累積エネルギーを計算する：

Wolfram Language code: cumulativeEnergy[data_] := Module[{c = Sort[Flatten[data]^2, Greater]}, Accumulate[c] / Total[c]]
Wolfram Language code: ListPlot[cumulativeEnergy[data]]

信号のエネルギーは比較的少ないウェーブレット係数で捉えられる：

Wolfram Language code: dwd1 = DiscreteWaveletTransform[data, CoifletWavelet[1], 1];
Wolfram Language code: dwd2 = DiscreteWaveletTransform[data, CoifletWavelet[1], 2];
Wolfram Language code: ListPlot[{cumulativeEnergy[data], cumulativeEnergy[Last /@ dwd1[Automatic]], cumulativeEnergy[Last /@ dwd2[Automatic]]}, PlotStyle -> {Red, Blue, Orange}]

特性と関係  (11)

ローパスフィルタ係数の総和は単位元である．：

Wolfram Language code: WaveletFilterCoefficients[CoifletWavelet[2]][[All, 2]]//Total//Chop

ハイパスフィルタ係数の総和は0である．：

Wolfram Language code: WaveletFilterCoefficients[CoifletWavelet[2], "PrimalHighpass"][[All, 2]]//Total//Chop

スケーリング関数を積分すると単位元になる．：

Wolfram Language code: ϕ = WaveletPhi[CoifletWavelet[3]];
Wolfram Language code: Integrate[ϕ[x], {x, -∞, ∞}]

とりわけ ：

Wolfram Language code: Table[NIntegrate[ϕ[(x/2^j)], {x, -∞, ∞}, AccuracyGoal -> 4] - 2^j, {j, 0, 3}]

ウェーブレット関数を積分すると0になる．：

Wolfram Language code: Integrate[WaveletPsi[CoifletWavelet[3], x], {x, -∞, ∞}]

ウェーブレット関数は同じスケールのスケーリング関数と直交する．：

Wolfram Language code: NIntegrate[WaveletPsi[CoifletWavelet[4], x] WaveletPhi[CoifletWavelet[4], x], {x, -∞, ∞}, AccuracyGoal -> 4]

ローパスフィルタ係数とハイパスフィルタ係数は直交する．：

Wolfram Language code: WaveletFilterCoefficients[CoifletWavelet[4]][[All, 2]].WaveletFilterCoefficients[CoifletWavelet[4], "PrimalHighpass"][[All, 2]]

は再帰方程式 を満足する：

Wolfram Language code: ϕ = WaveletPhi[CoifletWavelet[2]];
Wolfram Language code: a = WaveletFilterCoefficients[CoifletWavelet[2], "PrimalLowpass"];

構成要素と再帰の総和をプロットする：

Wolfram Language code: scalet[x_, ϕ_, a_] := 2Table[a[[i, 2]]ϕ[2x - a[[i, 1]]], {i, Length[a]}]
Wolfram Language code: {Plot[Evaluate@scalet[x, ϕ, a], {x, -4, 7}, PlotRange -> All], Plot[Total@scalet[x, ϕ, a], {x, -4, 7}, PlotRange -> All]}

は再帰方程式 を満足する：

Wolfram Language code: ϕ = WaveletPhi[CoifletWavelet[2]];
Wolfram Language code: b = WaveletFilterCoefficients[CoifletWavelet[2], "PrimalHighpass"];

構成要素と再帰の総和をプロットする：

Wolfram Language code: wavelet[x_, ϕ_, b_] := 2Table[b[[i, 2]]ϕ[2x - b[[i, 1]]], {i, Length[b]}]
Wolfram Language code: {Plot[Evaluate@wavelet[x, ϕ, b], {x, -5, 6}, PlotRange -> All], Plot[Total@wavelet[x, ϕ, b], {x, -5, 6}, PlotRange -> All]}

に対する周波数応答は で与えられる：

Wolfram Language code: h[wav_, ω_] := With[{a = WaveletFilterCoefficients[wav]}, Sum[a[[i, 2]]Exp[-I a[[i, 1]]ω], {i, Length[a]}]]

フィルタはローパスフィルタである：

Wolfram Language code: Plot[Abs[h[CoifletWavelet[2], ω]], {ω, -π, π}, Ticks -> {{-π, -(π/2), 0, (π/2), π}, Automatic}, AxesLabel -> {ω, Abs[H[ω]]}]

次数 n が高くなるにつれ，最後の応答関数は平坦になる：

Wolfram Language code: Plot[{Abs[h[CoifletWavelet[2], ω]], Abs[h[CoifletWavelet[5], ω]]}, {ω, -π, π}, Ticks -> {{-π, -(π/2), 0, (π/2), π}, Automatic}, AxesLabel -> {ω, Abs[H[ω]]}]

のフーリエ(Fourier)変換はで与えられる：

Wolfram Language code: h[wav_, ω_] := With[{a = WaveletFilterCoefficients[wav]}, Sum[a[[i, 2]]Exp[-I a[[i, 1]]ω], {i, Length[a]}]]
Wolfram Language code: fh[wav_, ω_, j_] := Abs[Product[h[wav, (ω/2^i)], {i, j}]]
Wolfram Language code: Plot[fh[CoifletWavelet[4], ω, 10], {ω, -5Pi, 5Pi}, PlotRange -> All, AxesLabel -> {ω, Abs[ Overscript[ϕ, ^ ][ω]]}]

に対する周波数応答はで与えられる：

Wolfram Language code: g[wav_, ω_] := With[{b = WaveletFilterCoefficients[wav, "PrimalHighpass"]}, Sum[b[[i, 2]]Exp[-I b[[i, 1]]ω], {i, Length[b]}] ]

フィルタはハイパスフィルタである：

Wolfram Language code: Plot[Abs[g[CoifletWavelet[2], ω]], {ω, -π, π}, Ticks -> {{-π, -(π/2), 0, (π/2), π}, Automatic}, AxesLabel -> {ω, Abs[G[ω]]}]

次数 n が高くなるにつれ，最後の応答関数は平坦になる：

Wolfram Language code: Plot[{Abs[g[CoifletWavelet[2], ω]], Abs[g[CoifletWavelet[5], ω]]}, {ω, -π, π}, Ticks -> {{-π, -(π/2), 0, (π/2), π}, Automatic}, AxesLabel -> {ω, Abs[G[ω]]}]

のフーリエ変換は で与えられる：

Wolfram Language code: h[wav_, ω_] := With[{a = WaveletFilterCoefficients[wav]}, Sum[a[[i, 2]]Exp[-I a[[i, 1]]ω], {i, Length[a]}]]
Wolfram Language code: g[wav_, ω_] := With[{b = WaveletFilterCoefficients[wav, "PrimalHighpass"]}, Sum[b[[i, 2]]Exp[-I b[[i, 1]]ω], {i, Length[b]}] ]
Wolfram Language code: fg[wav_, ω_, j_] := Abs[g[wav, (ω/2)]Product[h[wav, (ω/2^i)], {i, 2, j}]]
Wolfram Language code: Plot[fg[CoifletWavelet[2], ω, 10], {ω, -5Pi, 5Pi}, PlotRange -> All, AxesLabel -> {ω, Abs[ Overscript[ψ, ^ ][ω]]}]

考えられる問題  (1)

CoifletWaveletでは n は5より小さくなければならない：

Wolfram Language code: WaveletPhi[CoifletWavelet[6]]

n が正の機械整数でなければ，CoifletWaveletは定義されない：

Wolfram Language code: WaveletPhi[CoifletWavelet[2 + I]]

おもしろい例題  (2)

スケーリング関数の平行移動と膨張をプロットする：

Wolfram Language code: ϕ[x_, j_, k_] := 2^j / 2WaveletPhi[CoifletWavelet[1], 2^jx - k]
Wolfram Language code: Plot[Evaluate@Table[ϕ[x, j, 0], {j, 0, 4}], {x, -0.5, 0.5}, Filling -> Axis, PlotRange -> All]
Wolfram Language code: Plot[Evaluate@Table[ϕ[x, 2, k], {k, 0, 2^2 - 1}], {x, -0.5, 1.5}, Filling -> Axis, PlotRange -> All]

ウェーブレット関数の平行移動と膨張をプロットする：

Wolfram Language code: ψ[x_, j_, k_] := 2^j / 2WaveletPsi[CoifletWavelet[1], 2^jx - k]
Wolfram Language code: Plot[Evaluate@Table[ψ[x, j, 0], {j, 0, 4}], {x, -0.5, 1}, Filling -> Axis, PlotRange -> All]
Wolfram Language code: Plot[Evaluate@Table[ψ[x, 2, k], {k, 0, 2^2 - 1}], {x, -0.5, 1.5}, Filling -> Axis, PlotRange -> All]
Wolfram Research (2010), CoifletWavelet, Wolfram言語関数， https://reference.wolfram.com/language/ref/CoifletWavelet.html.

テキスト

Wolfram Research (2010), CoifletWavelet, Wolfram言語関数， https://reference.wolfram.com/language/ref/CoifletWavelet.html.

CMS

Wolfram Language. 2010. "CoifletWavelet." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/CoifletWavelet.html.

APA

Wolfram Language. (2010). CoifletWavelet. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CoifletWavelet.html

BibTeX

@misc{reference.wolfram_2026_coifletwavelet, author="Wolfram Research", title="{CoifletWavelet}", year="2010", howpublished="\url{https://reference.wolfram.com/language/ref/CoifletWavelet.html}", note=[Accessed: 08-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_coifletwavelet, organization={Wolfram Research}, title={CoifletWavelet}, year={2010}, url={https://reference.wolfram.com/language/ref/CoifletWavelet.html}, note=[Accessed: 08-September-2026]}