WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

ColorData["scheme"]

パラメータ値に適用されたときに指定されたカラースキームで色を生成する関数を返す．

ColorData["scheme","property"]

カラースキームの指定の特性を返す．

ColorData["collection"]

名前付きの集合中のカラースキームのリストを返す．

ColorData[]

カラースキーム中の名前付き集合のリストを返す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
スキームと集合  
特性  
特性の値  
一般化と拡張  
アプリケーション  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

ColorData

ColorData["scheme"]

パラメータ値に適用されたときに指定されたカラースキームで色を生成する関数を返す．

ColorData["scheme","property"]

カラースキームの指定の特性を返す．

ColorData["collection"]

名前付きの集合中のカラースキームのリストを返す．

ColorData[]

カラースキーム中の名前付き集合のリストを返す．

詳細

  • ColorData["scheme"][par]またはColorData["scheme",par]は，指定されたスキームのパラメータ値 par に対応するRGBColorオブジェクトを返す．
  • 典型的なスキームの集合
  • "Gradients"連続的な正規化された色階調度
    "Indexed"連続した整数で指標が付けられた色
    "Named"名前付きの色の集合
    "Physical"物理的なパラメータで決定された色
  • デフォルトで，色階調度は0から1までの範囲の1つのパラメータを持つ．
  • ColorData[{"gradient","Reverse"}]は0から1までの範囲の色の順位が逆になった色階調度を与える．
  • ColorData[{"gradient",{min,max}}]は min から max までの範囲の色階調度を与える．
  • ColorData[n,…]は n 番目の指標が付いた色パレットを使う．
  • ColorData["scheme","property"]の可能な特性
  • "ColorFunction"パラメータに適用される色関数
    "ColorList"有限の指標付きのカラースキームのための色リスト
    "ColorRules"離散的な色のスキームのための色規則
    "Image"そのスキームでの色を示している画像
    "Name"カラースキームの英語名
    "Panel"当該スキームによる色を表すクリック可能なパネル
    "ParameterCount"スキームで使われているパラメータ数
    "Range"第1パラメータの可能な値の範囲
    {"Range",i} 番目のパラメータの可能な値の範囲
  • 範囲はスライダーでのように指定される．
  • {xmin,xmax}xmin から xmaxまでの連続した値
    {xmin,xmax,dx}刻み幅 dx の離散的な値
    {{x1,x2,…}}特定の離散的な値
  • ColorData["DefaultPlotColors"]は，PlotやListPlot等の関数で使われるデフォルトの色のシーケンスを与える．
  • ColorData["DefaultChartColors"]は，PieChartやBarChart等の関数で使われるデフォルトの色のシーケンスを与える．
  • ColorData["scheme"]はColorDataFunctionオブジェクトを返す．

例題

すべて開く すべて閉じる

例  (5)

色を生成する関数を返す：

Wolfram Language code: ColorData["TemperatureMap"]

色階調度を使って曲面をプロットする：

Wolfram Language code: Plot3D[Exp[-x ^ 2 - y ^ 2], {x, -2, 2}, {y, -2, 2}, ColorFunction -> (ColorData["TemperatureMap"][#3]&)]

色階調度の順序を逆にする：

Wolfram Language code: Plot3D[Exp[-x ^ 2 - y ^ 2], {x, -2, 2}, {y, -2, 2}, ColorFunction -> (ColorData[{"TemperatureMap", "Reverse"}][#3]&)]

プロットスタイルに指標付きのカラースキームを使う：

Wolfram Language code: Plot[Evaluate[Table[Sin[x + Pi n / 4], {n, 0, 7}]], {x, 0, 2Pi}, Filling -> Axis, PlotStyle -> ColorData[3, "ColorList"]]

等高線の陰影付けに指標付きのカラースキームを使う：

Wolfram Language code: ContourPlot[x + Sin[x ^ 2 + y ^ 2], {x, -4, 4}, {y, -4, 4}, Contours -> 9, ContourShading -> ColorData[35, "ColorList"]]

スコープ  (23)

スキームと集合  (6)

集合のリストを求める：

Wolfram Language code: ColorData[]

各集合に属するスキームを求める：

Wolfram Language code: Short[ColorData["Gradients"]]
Wolfram Language code: Short[ColorData["Indexed"]]
Wolfram Language code: ColorData["Named"]
Wolfram Language code: ColorData["Physical"]

階調度はColorFunctionにふさわしい連続する色関数である：

Wolfram Language code: DensityPlot[y + Sin[x ^ 2 + 3y], {x, -3, 3}, {y, -3, 3}, ColorFunction -> ColorData["SunsetColors"]]

ColorData[{"gradient","Reverse"}]は色の順序が逆の色階調度関数を返す：

Wolfram Language code: DensityPlot[y + Sin[x ^ 2 + 3y], {x, -3, 3}, {y, -3, 3}, ColorFunction -> ColorData[{"SunsetColors", "Reverse"}]]

指標スキームは離散値に関連した色のリストからなっている：

Wolfram Language code: Short[ColorData[3, "ColorList"], 4]
Wolfram Language code: data = Table[RandomReal[{2i, 2 i + 1}, {20}], {i, 7}];
Wolfram Language code: ListLinePlot[data, PlotStyle -> ColorData[3, "ColorList"], InterpolationOrder -> 2]

名前付きスキームはよく知られた名前付きの色の集合である：

Wolfram Language code: Graphics[{ColorData["HTML", "Violet"], Disk[], ColorData["HTML", "MidnightBlue"], Disk[{1, 0}]}]

物理スキームは物理的な値に基づいた色を返す：

Wolfram Language code: DensityPlot[x, {x, 380, 750}, {y, 0, 50}, ColorFunction -> ColorData["VisibleSpectrum"], ColorFunctionScaling -> False, AspectRatio -> Automatic, PlotRangePadding -> 10, FrameTicks -> {{None, None}, {Automatic, None}}]

特性  (10)

カラースキームの全特性を求める：

Wolfram Language code: ColorData["Properties"]

"ColorFunction"はColorDataFunctionオブジェクトを返す：

Wolfram Language code: ColorData["SouthwestColors", "ColorFunction"]

離散的カラースキームの色のリストを得る：

Wolfram Language code: ColorData[38, "ColorList"]
Wolfram Language code: Short[ColorData["Atoms", "ColorList"]]

階調度スキームと物理スキームは色のリストを返すことができない：

Wolfram Language code: ColorData["PlumColors", "ColorList"]

離散的なカラースキームから色の代替規則を得る：

Wolfram Language code: ColorData[42, "ColorRules"]
Wolfram Language code: Short[ColorData["Legacy", "ColorRules"], 3]

スキームの代表的な画像を得る：

Wolfram Language code: ColorData["DarkRainbow", "Image"]
Wolfram Language code: ColorData[22, "Image"]
Wolfram Language code: ColorData["HTML", "Image"]
Wolfram Language code: ColorData["VisibleSpectrum", "Image"]

カラースキーム名を得る：

Wolfram Language code: ColorData["HTML", "Name"]

スキームのクリックできるパネルを得る：

Wolfram Language code: ColorData["SunsetColors", "Panel"]
Wolfram Language code: ColorData[17, "Panel"]
Wolfram Language code: ColorData["GeologicAges", "Panel"]
Wolfram Language code: ColorData["BlackBodySpectrum", "Panel"]

スキームに必要なパラメータの数を得る：

Wolfram Language code: ColorData["AuroraColors", "ParameterCount"]

第1パラメータの可能な値の範囲を得る：

Wolfram Language code: ColorData["GrayYellowTones", "Range"]
Wolfram Language code: ColorData[12, "Range"]
Wolfram Language code: Short[ColorData["HTML", "Range"]]
Wolfram Language code: ColorData["VisibleSpectrum", "Range"]

範囲の値はSliderのようなコントロールで直接使うことができる：

Wolfram Language code: {Slider[Dynamic[w], ColorData["GrayYellowTones", "Range"]], Dynamic[w]}
Wolfram Language code: {Slider[Dynamic[x], ColorData[12, "Range"]], Dynamic[x]}
Wolfram Language code: {Slider[Dynamic[y], ColorData["HTML", "Range"]], Dynamic[y]}
Wolfram Language code: {Slider[Dynamic[z], ColorData["VisibleSpectrum", "Range"]], Dynamic[z]}

特性の値  (7)

特性の値は任意の有効なWolfram言語の式でよい：

Wolfram Language code: ColorData["HypsometricTints", "Image"]
Wolfram Language code: Take[ColorData[37, "ColorRules"], 3]
Wolfram Language code: ColorData["SouthwestColors", 0.5]

各スキームはColorDataFunctionオブジェクトを返す：

Wolfram Language code: ColorData["GrayYellowTones"]
Wolfram Language code: ColorData[12]
Wolfram Language code: ColorData["HTML"]
Wolfram Language code: ColorData["VisibleSpectrum"]

特定の範囲の値に適用されると，ColorDataFunctionはRGBカラーを返す：

Wolfram Language code: ColorData["GrayYellowTones"][.5] %//InputForm
Wolfram Language code: ColorData[12][7] %//InputForm
Wolfram Language code: ColorData["HTML"]["WhiteSmoke"] %//InputForm
Wolfram Language code: ColorData["VisibleSpectrum"][550] %//InputForm

階調度と物理スキームは連続区間で定義される：

Wolfram Language code: ColorData["GrayYellowTones", "Range"]
Wolfram Language code: ColorData["VisibleSpectrum", "Range"]

指標付きスキームは離散値上に定義される：

Wolfram Language code: ColorData[12, "Range"]

指標付きの範囲はRangeを適用してリストにできる：

Wolfram Language code: Apply[Range, %]

名前付きスキームは特定の値の集合上に定義される：

Wolfram Language code: Short[ColorData["HTML", "Range"]]

適用できない特性はMissing["NotApplicable"]を返す：

Wolfram Language code: ColorData["SouthwestColors", "ColorList"]
Wolfram Language code: ColorData["SouthwestColors", "ColorRules"]

一般化と拡張  (2)

スキームの中には特化された画像とパネルを持つものもある：

Wolfram Language code: ColorData["Atoms", "Image"]
Wolfram Language code: ColorData["Atoms", "Panel"]

指標付きのスキームの中には自然数について定義されるものもある：

Wolfram Language code: ColorData[1, "Range"]

これらの場合，リストと規則の一部だけが返される：

Wolfram Language code: ColorData[1, "ColorList"]
Wolfram Language code: ColorData[1, "ColorRules"]

アプリケーション  (9)

階調度を使って色関数を定義する：

Wolfram Language code: dem = Import["http://exampledata.wolfram.com/hailey.dem.gz", "Data"];
Wolfram Language code: ReliefPlot[dem, MaxPlotPoints -> 300, ColorFunction -> ColorData["BrightBands"]]

階調度を使って人口を表す：

Wolfram Language code: Graphics[{EdgeForm[{StandardGray, Opacity[.5]}], With[{p = QuantityMagnitude[CountryData[#, "Population"]]}, {If[NumberQ[p], ColorData["SolarColors"][1. - p 10 ^ -9], White], CountryData[#, {"SchematicPolygon", "Robinson"}]}]& /@ CountryData[]}, PlotRange -> Automatic]

Directiveを使ってさまざまな曲面の特性とColorDataを組み合せる：

Wolfram Language code: Plot3D[Evaluate[ D[(x^2 + y^2) Exp[1 - x^2 - y^2], y]], {x, -2, 2}, {y, -2, 2}, ColorFunction -> (Directive[Opacity[#3], ColorData["ThermometerColors"][#3]]&), PlotRange -> All, Mesh -> None]

ContourShadingで指標付きスキームの色のリストを使う：

Wolfram Language code: ContourPlot[Sin[x]Sin[y], {x, -0, 3Pi}, {y, 0, 3Pi}, ContourShading -> ColorData[8, "ColorList"], FrameTicks -> False]

MeshShadingで色のリストのパーティションを使う：

Wolfram Language code: ParametricPlot3D[{(2 + Cos[v])Cos[u], (2 + Cos[v])Sin[u], Sin[v]}, {u, 0, 2Pi}, {v, 0, 2Pi}, Mesh -> 15, Lighting -> "Neutral", MeshShading -> Partition[ColorData[9, "ColorList"], 2]]

色規則を使ってHTMLカラー名をRGBの値で置き換える：

Wolfram Language code: Grid[{{a, b, c}, {d, e, f}, {g, h, i}}, Frame -> All, Background -> {{"LightSteelBlue", "Salmon", "PaleGreen"}}] /. ColorData["HTML", "ColorRules"]

ArrayPlotで色の名前と色規則を組み合せて使う：

Wolfram Language code: w = Partition[First@ColorData["WebSafe", "Range"], 12];
Wolfram Language code: Short[w, 3]
Wolfram Language code: ArrayPlot[w, ColorRules -> ColorData["WebSafe", "ColorRules"]]

原子を適切な色で表す：

Wolfram Language code: Graphics3D[{Specularity[White, 50], ColorData["Atoms", "H"], Sphere[{0, 0, 0}, .7], Sphere[{1.4, 0, 0}, .7], ColorData["Atoms", "O"], Sphere[{.7, 0, .7}]}, Lighting -> "Neutral"]

物理スキームを使ってさまざまなスペクトルを表す：

Wolfram Language code: Blackbody[T_] := With[{h = 6.6262 10 ^ -34, c = 2.99792458 10 ^ 8, k = 1.3807 10 ^ -23}, Plot[(2h c ^ 2 / λ ^ 5 ) / (Exp[h c / (λ k T)] - 1), {λ, 10 ^ -9, 1000 10 ^ -9}, MaxRecursion -> 0, ColorFunction -> (ColorData["VisibleSpectrum"][10 ^ 9#]&), ColorFunctionScaling -> False, Filling -> Axis, Ticks -> None, PlotLabel -> Row[{T, " K"}]]]
Wolfram Language code: Row[Table[Blackbody[t], {t, {2000, 4000, 6000, 8000}}], Spacer[2]]

異なる温度について積分されたスペクトルの色：

Wolfram Language code: Graphics[{EdgeForm[Gray], Table[{ColorData["BlackBodySpectrum", 1000 t], Text[1000t"K", {2t, 1.5}, {-1, 0}, {0, 1}], Disk[{2t, 0}, .9]}, {t, 10}]}]

特性と関係  (5)

階調度を名前で参照できるのはColorFunctionにおいてだけである：

Wolfram Language code: DensityPlot[Sin[x]Sin[y], {x, -4, 4}, {y, -3, 3}, ColorFunction -> "AvocadoColors"]

階調度と物理的スキームは範囲外の値を切り取る：

Wolfram Language code: DensityPlot[x, {x, -1, 2}, {y, 0, 1}, ColorFunction -> ColorData["SunsetColors"], ColorFunctionScaling -> False]
Wolfram Language code: DensityPlot[x, {x, 300, 800}, {y, 0, 1}, ColorFunction -> ColorData["VisibleSpectrum"], ColorFunctionScaling -> False]

指標付きスキームは周期的に色を繰り返す：

Wolfram Language code: ArrayPlot[{Range[40]}, ColorFunction -> ColorData[10], ColorFunctionScaling -> False, AspectRatio -> .3]

指標付きスキームは下限として整数ではない数を取る：

Wolfram Language code: ColorData[10][2]//InputForm
Wolfram Language code: ColorData[10][2.5]//InputForm

ChemicalDataは元素の色にColorData["Atoms"]を使う：

Wolfram Language code: ChemicalData["Benzthiazuron", "MoleculePlot"]
Wolfram Language code: ChemicalData["Benzthiazuron", "HillFormula"]

考えられる問題  (3)

名前付きのスキームは"Range"として名前のリストを返す：

Wolfram Language code: r = ColorData["HTML", "Range"];
Wolfram Language code: Short[r, 4]
Wolfram Language code: Dimensions[r]

Firstを使って名前のリストを取ることができる：

Wolfram Language code: n = First[ColorData["HTML", "Range"]];
Wolfram Language code: Short[n, 4]

複数のColorFunctionスロットがあるプロットでは，特に指定がなければ最初のスロットが選ばれる：

Wolfram Language code: Plot3D[ Exp[1 - x^2 - y^2], {x, -2, 2}, {y, -2, 2}, ColorFunction -> ColorData["Rainbow"], PlotRange -> All, Mesh -> None]

プロットが高さの値で色付けされるように純関数を指定する：

Wolfram Language code: Plot3D[ Exp[1 - x^2 - y^2], {x, -2, 2}, {y, -2, 2}, ColorFunction -> Function[{x, y, z}, ColorData["Rainbow"][z]], PlotRange -> All, Mesh -> None]

階調度の中には，サンプル不足のために不自然な結果を返すものもある：

Wolfram Language code: Plot3D[ Exp[1 - x^2 - y^2], {x, -2, 2}, {y, -2, 2}, ColorFunction -> (ColorData["BrightBands"][#3]&), PlotRange -> All, Mesh -> None]

PlotPointsの値を大きくすると問題が小さくなることがある：

Wolfram Language code: Plot3D[ Exp[1 - x^2 - y^2], {x, -2, 2}, {y, -2, 2}, ColorFunction -> (ColorData["BrightBands"][#3]&), PlotPoints -> 80, PlotRange -> All, Mesh -> None]

おもしろい例題  (4)

粒子の質感をランダムなノイズから生成する：

Wolfram Language code: ReliefPlot[Table[RandomReal[](Sin[x + y ^ 2] + Sin[x ^ 2 + 3y]), {x, -3, 3, .01}, {y, -3, 3, .01}], ColorFunction -> ColorData["SouthwestColors"]]

虹色を使用したランダムな凹凸パターン:

Wolfram Language code: ReliefPlot[Table[Evaluate[Sum[Sin[RandomReal[4, 2].{x, y}], {5}]], {x, 0, 10, .05}, {y, 0, 10, .05}], ColorFunction -> ColorData["Rainbow"]]

すべての階調度のサムネイル：

Wolfram Language code: Grid[Partition[Show[ColorData[#, "Image"], ImageSize -> 110]& /@ ColorData["Gradients"], 4, 4, 1, {}], Spacings -> .5]

すべての指標付きスキームのサムネイル：

Wolfram Language code: Grid[Partition[Framed[Show[ColorData[#, "Image"], ImageSize -> 100], FrameStyle -> Gray]& /@ ColorData["Indexed"], 4, 4, 1, {}], Spacings -> .25]
Wolfram Research (2007), ColorData, Wolfram言語関数， https://reference.wolfram.com/language/ref/ColorData.html （2026年に更新）.

テキスト

Wolfram Research (2007), ColorData, Wolfram言語関数， https://reference.wolfram.com/language/ref/ColorData.html （2026年に更新）.

CMS

Wolfram Language. 2007. "ColorData." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2026. https://reference.wolfram.com/language/ref/ColorData.html.

APA

Wolfram Language. (2007). ColorData. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ColorData.html

BibTeX

@misc{reference.wolfram_2026_colordata, author="Wolfram Research", title="{ColorData}", year="2026", howpublished="\url{https://reference.wolfram.com/language/ref/ColorData.html}", note=[Accessed: 08-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_colordata, organization={Wolfram Research}, title={ColorData}, year={2026}, url={https://reference.wolfram.com/language/ref/ColorData.html}, note=[Accessed: 08-September-2026]}