WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

ConstantRegionQ[reg]

reg が定常領域の場合はTrueを，それ以外の場合はFalseを与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
特別な領域  
数式定義領域  
メッシュ領域  
派生領域  
CSG領域  
細分割領域  
アプリケーション  
特性と関係  
考えられる問題  
関連項目
関連するガイド
履歴
引用書式

ConstantRegionQ

ConstantRegionQ[reg]

reg が定常領域の場合はTrueを，それ以外の場合はFalseを与える．

詳細

  • ConstantRegionQはパラメータを持たない領域としても知られている．
  • 記号パラメータに依存していない領域は定まっているとみなされる．
  • DiscretizeRegionを使って離散化したりGraphics等を使って描画したりできるのは，定常領域のみである．

例題

すべて開く すべて閉じる

例  (3)

定常領域：

Wolfram Language code: ConstantRegionQ[Disk[{0, 0}, 1]]

定まっていない領域：

Wolfram Language code: ConstantRegionQ[Disk[{x, y}, 1]]

領域のグループ全体を表す，非定常領域．以下はランダムな例である：

Wolfram Language code: Graphics[{Opacity[0.2], Table[Disk[p, 1], {p, RandomReal[10, {100, 2}]}]}]

操作の中には定常領域を必要とするものもある：

Wolfram Language code: ConstantRegionQ[Ball[]]
Wolfram Language code: BoundaryDiscretizeRegion[Ball[]]

操作の中には，定まっていない領域についての結果が与えられるものもある：

Wolfram Language code: ConstantRegionQ[Ball[{0, 0, 0}, r]]
Wolfram Language code: RegionMeasure[Ball[{0, 0, 0}, r]]

スコープ  (18)

特別な領域  (4)

Pointを含むの領域：

Wolfram Language code: ConstantRegionQ[Point[{1}]]

この領域は，記号パラメータを含むので，定まっていない：

Wolfram Language code: ConstantRegionQ[Point[{x}]]

Interval：

Wolfram Language code: ℛ = Interval[{1, 2}]; NumberLinePlot[ℛ]
Wolfram Language code: ConstantRegionQ[ℛ]

Pointを含むの領域：

Wolfram Language code: ℛ = Point[Tuples[Range[5], 2]]; Region[ℛ]
Wolfram Language code: ConstantRegionQ[ℛ]

Line：

Wolfram Language code: ℛ = Line[{{1, 2}, {4, 3}}]; Region[ℛ]
Wolfram Language code: ConstantRegionQ[ℛ]

Disk：

Wolfram Language code: ℛ = Disk[{1, 2}, {4, 3}]; Region[ℛ]
Wolfram Language code: ConstantRegionQ[ℛ]

記号パラメータを含むCircleは定まっていない：

Wolfram Language code: ConstantRegionQ[Circle[{x, y}, 3]]

Pointを含むの領域：

Wolfram Language code: ℛ = Point[Tuples[Range[5], 3]]; Region[ℛ, Boxed -> True]
Wolfram Language code: ConstantRegionQ[ℛ]

Line：

Wolfram Language code: ℛ = Line[{{1, 2, 3}, {6, 5, 4}}]; Region[ℛ, Boxed -> True]
Wolfram Language code: ConstantRegionQ[ℛ]

Polygon：

Wolfram Language code: ℛ = Polygon[{{0, 0, 0}, {2, -1, 0}, {1, 0, 0}, {2, 1, 0}}]; Region[ℛ, Boxed -> True]
Wolfram Language code: ConstantRegionQ[ℛ]

Cylinder：

Wolfram Language code: ℛ = Cylinder[{{0, 0, 0}, {1, 1, 1}}, 2]; Region[ℛ, Boxed -> True]
Wolfram Language code: ConstantRegionQ[ℛ]

におけるSimplexを含むの領域：

Wolfram Language code: ConstantRegionQ[Simplex[{{1, 0, 0, 0}, {0, 1, 0, 0}, {0, 0, 1, 0}, {0, 0, 0, 1}}]]

におけるCuboid：

Wolfram Language code: ConstantRegionQ[Cuboid[{1, 2, 3, 4, 5}, {6, 7, 8, 9, 10}]]

におけるBall：

Wolfram Language code: ConstantRegionQ[Ball[{1, 2, 3, 4, 5, 6, 7}, 8]]

パラメータがあると定まらなくなる：

Wolfram Language code: ConstantRegionQ[Ball[{1, 2, 3, 4, 5, 6, 7}, r]]

数式定義領域  (3)

ImplicitRegionとして表された円板：

Wolfram Language code: ConstantRegionQ[ImplicitRegion[x^2 + y^2 ≤ 1, {x, y}]]

円柱：

Wolfram Language code: ConstantRegionQ[ImplicitRegion[x^2 + y^2 ≤ 1, {x, y, {z, 0, 2}}]]

は変数の1つではないので，この領域は定まっていない：

Wolfram Language code: ConstantRegionQ[ImplicitRegion[x^2 + y^2 ≤ c, {x, y}]]

ParametricRegionとして表された円板：

Wolfram Language code: ConstantRegionQ[ParametricRegion[{r Cos[θ], r Sin[θ]}, {{r, 0, 1}, {θ, 0, 2π}}]]

円板の有理パラメータ化を使う：

Wolfram Language code: ConstantRegionQ[ParametricRegion[{r(1 - t^2/1 + t^2), r(2t/1 + t^2)}, {t, {r, 0, 1}}]]

円柱：

Wolfram Language code: ConstantRegionQ[ParametricRegion[{r Cos[θ], r Sin[θ], z}, {{r, 0, 1}, {θ, 0, 2π}, {z, 0, 2}}]]

は変数の1つではないので，この領域は定まっていない：

Wolfram Language code: ConstantRegionQ[ParametricRegion[{t + x, t}, {t}]]

ImplicitRegionは次元が異なる複数の成分を持つことができる：

Wolfram Language code: ℛ = ImplicitRegion[x^2 + y^2 ≤ 1 || x == y, {{x, -2, 2}, y}];
Wolfram Language code: Region[ℛ]
Wolfram Language code: ConstantRegionQ[ℛ]

メッシュ領域  (4)

MeshRegionは1Dを含め常に定まっている：

Wolfram Language code: DelaunayMesh[RandomReal[1, {10, 1}]]
Wolfram Language code: ConstantRegionQ[%]

2D：

Wolfram Language code: DelaunayMesh[RandomReal[1, {50, 2}]]
Wolfram Language code: ConstantRegionQ[%]

3D：

Wolfram Language code: DelaunayMesh[RandomReal[1, {100, 3}]]
Wolfram Language code: ConstantRegionQ[%]

1DにおけるBoundaryMeshRegion：

Wolfram Language code: ConvexHullMesh[RandomReal[1, {10, 1}]]
Wolfram Language code: ConstantRegionQ[%]

2D：

Wolfram Language code: ConvexHullMesh[RandomReal[1, {50, 2}]]
Wolfram Language code: ConstantRegionQ[%]

3D：

Wolfram Language code: ConvexHullMesh[RandomReal[1, {100, 3}]]
Wolfram Language code: ConstantRegionQ[%]

2Dで曲線を表すMeshRegion：

Wolfram Language code: ℛ = MeshRegion[{{0, 0}, {1, 0}, {2, -1}, {2, 1}}, {Line[{{1, 2, 3, 4, 2}}]}]
Wolfram Language code: ConstantRegionQ[ℛ]

MeshRegionは次元が異なる成分を持つことができる：

Wolfram Language code: ℛ = MeshRegion[{{0, 0}, {1, 0}, {2, -1}, {2, 1}}, {Line[{{1, 2}}], Polygon[{{2, 3, 4}}]}]
Wolfram Language code: ConstantRegionQ[ℛ]

派生領域  (5)

2つの領域のRegionIntersection：

Wolfram Language code: ℛ = RegionIntersection[Disk[{0, 0}, 1], Disk[{0, 1}, 1]];
Wolfram Language code: Region[ℛ]
Wolfram Language code: ConstantRegionQ[ℛ]

混合次元領域のRegionUnion：

Wolfram Language code: ℛ = RegionUnion[Circle[{1, 0}, 1], Disk[{0, 0}, 1]];
Wolfram Language code: Region[ℛ]
Wolfram Language code: ConstantRegionQ[ℛ]

パラメータ化された変換関数によるTransformedRegionは定まっていない：

Wolfram Language code: Subscript[ℛ, 1] = TransformedRegion[Disk[{0, 0}, 1], ScalingTransform[{x, y}]];
Wolfram Language code: ConstantRegionQ[Subscript[ℛ, 1]]

記号パラメータを置換してこの領域を定まったものにする：

Wolfram Language code: Subscript[ℛ, 2] = Subscript[ℛ, 1] /. {x -> 3, y -> 2}; Region[Subscript[ℛ, 2]]
Wolfram Language code: ConstantRegionQ[Subscript[ℛ, 2]]

RegionBoundary：

Wolfram Language code: Subscript[ℛ, 1] = Disk[]; Subscript[ℛ, 2] = RegionBoundary[Subscript[ℛ, 1]]
Wolfram Language code: {Region[Subscript[ℛ, 1]], Region[Subscript[ℛ, 2]]}
Wolfram Language code: {ConstantRegionQ[Subscript[ℛ, 1]], ConstantRegionQ[Subscript[ℛ, 2]]}

定まっていない領域のRegionUnionは定まっていない領域である：

Wolfram Language code: ConstantRegionQ[RegionUnion[Disk[{0, 0}, r], Disk[{0, 1}, 1]]]

CSG領域  (1)

2DのCSGRegion：

Wolfram Language code: CSGRegion["Difference", {Disk[], Disk[{1 / 2, 1 / 2}]}]
Wolfram Language code: ConstantRegionQ[%]

3Dの場合：

Wolfram Language code: CSGRegion["Difference", {Cube[2], Cylinder[{{1, 1, 1}, {1, -1, 1}}]}]
Wolfram Language code: ConstantRegionQ[%]

細分割領域  (1)

2DのSubdivisionRegion：

Wolfram Language code: SubdivisionRegion[Rectangle[]]
Wolfram Language code: ConstantRegionQ[%]

3Dの場合：

Wolfram Language code: SubdivisionRegion[Tetrahedron[]]
Wolfram Language code: ConstantRegionQ[%]

アプリケーション  (2)

定常領域にのみ適用される定義を作る：

Wolfram Language code: f[r_ ? ConstantRegionQ] := DiscretizeRegion[r]
Wolfram Language code: f /@ {Disk[{1, 2}, 3], Disk[{x, y}, r]}

領域のリストから定常領域のみを選択する：

Wolfram Language code: regs = {Sphere[{1, 2, 3}], Sphere[{x, y, z}], ImplicitRegion[x ^ 2 + y ^ 2 + z ^ 2 == 1, {x, y, z}]};
Wolfram Language code: cregs = Select[regs, ConstantRegionQ]

定常領域のみが離散化できる：

Wolfram Language code: DiscretizeRegion /@ cregs

特性と関係  (3)

ConstantRegionQがTrueなら，RegionQもまたTrueである：

Wolfram Language code: ℛ = Disk[];
Wolfram Language code: {ConstantRegionQ[ℛ], RegionQ[ℛ]}

MeshRegionQおよびBoundaryMeshRegionQを使い，より特化された領域タイプをチェックすることができる：

Wolfram Language code: Subscript[ℛ, 1] = DelaunayMesh[RandomReal[1, {10, 2}]]; Subscript[ℛ, 2] = ConvexHullMesh[RandomReal[1, {10, 2}]];
Wolfram Language code: MeshRegionQ /@ {Subscript[ℛ, 1], Subscript[ℛ, 2]}
Wolfram Language code: BoundaryMeshRegionQ /@ {Subscript[ℛ, 1], Subscript[ℛ, 2]}

メッシュ領域は常にConstantRegionQである：

Wolfram Language code: ConstantRegionQ /@ {Subscript[ℛ, 1], Subscript[ℛ, 2]}

BoundedRegionQを使って領域が有界かどうかを調べることができる：

Wolfram Language code: BoundedRegionQ /@ {Disk[], InfiniteLine[{0, 0}, {1, 1}]}

考えられる問題  (2)

関数の中には定常領域が必要なものがある：

Wolfram Language code: Subscript[ℛ, 1] = Disk[{x, y}, 2];
Wolfram Language code: ConstantRegionQ[Subscript[ℛ, 1]]
Wolfram Language code: {DiscretizeRegion[Subscript[ℛ, 1]], BoundaryDiscretizeRegion[Subscript[ℛ, 1]]}

記号パラメータを置換して領域を定まったものにする：

Wolfram Language code: Subscript[ℛ, 2] = Subscript[ℛ, 1] /. {x -> 1, y -> 2};
Wolfram Language code: ConstantRegionQ[Subscript[ℛ, 2]]
Wolfram Language code: {DiscretizeRegion[Subscript[ℛ, 2]], BoundaryDiscretizeRegion[Subscript[ℛ, 2]]}

領域が定まっている場合，RegionMemberはTrueあるいはFalseを返す：

Wolfram Language code: Subscript[ℛ, 1] = Disk[{0, 0}, 2]; Subscript[ℛ, 2] = Disk[{x, y}, 2];
Wolfram Language code: {ConstantRegionQ[Subscript[ℛ, 1]], RegionMember[Subscript[ℛ, 1], {0, 0}]}

領域が定まっていなければ，RegionMemberは条件を返す：

Wolfram Language code: {ConstantRegionQ[Subscript[ℛ, 2]], RegionMember[Subscript[ℛ, 2], {0, 0}]}
Wolfram Research (2014), ConstantRegionQ, Wolfram言語関数， https://reference.wolfram.com/language/ref/ConstantRegionQ.html.

テキスト

Wolfram Research (2014), ConstantRegionQ, Wolfram言語関数， https://reference.wolfram.com/language/ref/ConstantRegionQ.html.

CMS

Wolfram Language. 2014. "ConstantRegionQ." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/ConstantRegionQ.html.

APA

Wolfram Language. (2014). ConstantRegionQ. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ConstantRegionQ.html

BibTeX

@misc{reference.wolfram_2026_constantregionq, author="Wolfram Research", title="{ConstantRegionQ}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/ConstantRegionQ.html}", note=[Accessed: 04-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_constantregionq, organization={Wolfram Research}, title={ConstantRegionQ}, year={2014}, url={https://reference.wolfram.com/language/ref/ConstantRegionQ.html}, note=[Accessed: 04-September-2026]}