WOLFRAM

Wolfram 语言与系统参考资料中心

ConstantRegionQ[reg]

如果 reg 是恒定区域，给出 True，否则给出 False.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
特殊区域  
公式区域  
网格区域  
导出区域  
CSG 区域  
Subdivision 区域  
应用  
属性和关系  
可能存在的问题  
参见
相关指南
历史
按以下格式引用：

ConstantRegionQ

ConstantRegionQ[reg]

如果 reg 是恒定区域，给出 True，否则给出 False.

更多信息

  • ConstantRegionQ 也称作无参数区域.
  • 如果一个区域不依赖于符号参数，则被认为是恒定的.
  • 只有恒定区域可以使用 DiscretizeRegion 离散，或者使用 Graphics 等被渲染.

范例

打开所有单元 关闭所有单元

基本范例  (3)

恒定区域：

Wolfram Language code: ConstantRegionQ[Disk[{0, 0}, 1]]

不恒定区域：

Wolfram Language code: ConstantRegionQ[Disk[{x, y}, 1]]

代表了整个区域家族的不恒定区域，以下是随机实例：

Wolfram Language code: Graphics[{Opacity[0.2], Table[Disk[p, 1], {p, RandomReal[10, {100, 2}]}]}]

有些运算需要恒定区域：

Wolfram Language code: ConstantRegionQ[Ball[]]
Wolfram Language code: BoundaryDiscretizeRegion[Ball[]]

有些运算可以给出不恒定区域的结果：

Wolfram Language code: ConstantRegionQ[Ball[{0, 0, 0}, r]]
Wolfram Language code: RegionMeasure[Ball[{0, 0, 0}, r]]

范围  (18)

特殊区域  (4)

中包括 Point 的区域：

Wolfram Language code: ConstantRegionQ[Point[{1}]]

该区域不恒定，因为它含有符号式参数：

Wolfram Language code: ConstantRegionQ[Point[{x}]]

Interval：

Wolfram Language code: ℛ = Interval[{1, 2}]; NumberLinePlot[ℛ]
Wolfram Language code: ConstantRegionQ[ℛ]

中包括 Point 的区域：

Wolfram Language code: ℛ = Point[Tuples[Range[5], 2]]; Region[ℛ]
Wolfram Language code: ConstantRegionQ[ℛ]

Line：

Wolfram Language code: ℛ = Line[{{1, 2}, {4, 3}}]; Region[ℛ]
Wolfram Language code: ConstantRegionQ[ℛ]

Disk：

Wolfram Language code: ℛ = Disk[{1, 2}, {4, 3}]; Region[ℛ]
Wolfram Language code: ConstantRegionQ[ℛ]

具有符号式参数的 Circle 不是恒定的：

Wolfram Language code: ConstantRegionQ[Circle[{x, y}, 3]]

中包括 Point 的区域：

Wolfram Language code: ℛ = Point[Tuples[Range[5], 3]]; Region[ℛ, Boxed -> True]
Wolfram Language code: ConstantRegionQ[ℛ]

Line：

Wolfram Language code: ℛ = Line[{{1, 2, 3}, {6, 5, 4}}]; Region[ℛ, Boxed -> True]
Wolfram Language code: ConstantRegionQ[ℛ]

Polygon：

Wolfram Language code: ℛ = Polygon[{{0, 0, 0}, {2, -1, 0}, {1, 0, 0}, {2, 1, 0}}]; Region[ℛ, Boxed -> True]
Wolfram Language code: ConstantRegionQ[ℛ]

Cylinder：

Wolfram Language code: ℛ = Cylinder[{{0, 0, 0}, {1, 1, 1}}, 2]; Region[ℛ, Boxed -> True]
Wolfram Language code: ConstantRegionQ[ℛ]

中包括 中 Simplex 的区域：

Wolfram Language code: ConstantRegionQ[Simplex[{{1, 0, 0, 0}, {0, 1, 0, 0}, {0, 0, 1, 0}, {0, 0, 0, 1}}]]

中的 Cuboid：

Wolfram Language code: ConstantRegionQ[Cuboid[{1, 2, 3, 4, 5}, {6, 7, 8, 9, 10}]]

的 Ball：

Wolfram Language code: ConstantRegionQ[Ball[{1, 2, 3, 4, 5, 6, 7}, 8]]

在有参数时，它不再是恒定的：

Wolfram Language code: ConstantRegionQ[Ball[{1, 2, 3, 4, 5, 6, 7}, r]]

公式区域  (3)

表示为 ImplicitRegion 的圆盘：

Wolfram Language code: ConstantRegionQ[ImplicitRegion[x^2 + y^2 ≤ 1, {x, y}]]

圆柱体：

Wolfram Language code: ConstantRegionQ[ImplicitRegion[x^2 + y^2 ≤ 1, {x, y, {z, 0, 2}}]]

由于 不是其中的一个变量，区域不再恒定：

Wolfram Language code: ConstantRegionQ[ImplicitRegion[x^2 + y^2 ≤ c, {x, y}]]

表示为 ParametricRegion 的圆盘：

Wolfram Language code: ConstantRegionQ[ParametricRegion[{r Cos[θ], r Sin[θ]}, {{r, 0, 1}, {θ, 0, 2π}}]]

使用圆盘的有理参数化：

Wolfram Language code: ConstantRegionQ[ParametricRegion[{r(1 - t^2/1 + t^2), r(2t/1 + t^2)}, {t, {r, 0, 1}}]]

圆柱体：

Wolfram Language code: ConstantRegionQ[ParametricRegion[{r Cos[θ], r Sin[θ], z}, {{r, 0, 1}, {θ, 0, 2π}, {z, 0, 2}}]]

由于 不是其中的一个变量，该区域不再恒定：

Wolfram Language code: ConstantRegionQ[ParametricRegion[{t + x, t}, {t}]]

ImplicitRegion 可以有不同维度的多个组件：

Wolfram Language code: ℛ = ImplicitRegion[x^2 + y^2 ≤ 1 || x == y, {{x, -2, 2}, y}];
Wolfram Language code: Region[ℛ]
Wolfram Language code: ConstantRegionQ[ℛ]

网格区域  (4)

MeshRegion 总是恒定的，包括一维：

Wolfram Language code: DelaunayMesh[RandomReal[1, {10, 1}]]
Wolfram Language code: ConstantRegionQ[%]

二维：

Wolfram Language code: DelaunayMesh[RandomReal[1, {50, 2}]]
Wolfram Language code: ConstantRegionQ[%]

三维：

Wolfram Language code: DelaunayMesh[RandomReal[1, {100, 3}]]
Wolfram Language code: ConstantRegionQ[%]

一维 BoundaryMeshRegion：

Wolfram Language code: ConvexHullMesh[RandomReal[1, {10, 1}]]
Wolfram Language code: ConstantRegionQ[%]

二维：

Wolfram Language code: ConvexHullMesh[RandomReal[1, {50, 2}]]
Wolfram Language code: ConstantRegionQ[%]

三维：

Wolfram Language code: ConvexHullMesh[RandomReal[1, {100, 3}]]
Wolfram Language code: ConstantRegionQ[%]

表示二维中一条曲线的 MeshRegion：

Wolfram Language code: ℛ = MeshRegion[{{0, 0}, {1, 0}, {2, -1}, {2, 1}}, {Line[{{1, 2, 3, 4, 2}}]}]
Wolfram Language code: ConstantRegionQ[ℛ]

MeshRegion 可以具有不同维度的组件：

Wolfram Language code: ℛ = MeshRegion[{{0, 0}, {1, 0}, {2, -1}, {2, 1}}, {Line[{{1, 2}}], Polygon[{{2, 3, 4}}]}]
Wolfram Language code: ConstantRegionQ[ℛ]

导出区域  (5)

两个区域的 RegionIntersection：

Wolfram Language code: ℛ = RegionIntersection[Disk[{0, 0}, 1], Disk[{0, 1}, 1]];
Wolfram Language code: Region[ℛ]
Wolfram Language code: ConstantRegionQ[ℛ]

混合维度区域的 RegionUnion：

Wolfram Language code: ℛ = RegionUnion[Circle[{1, 0}, 1], Disk[{0, 0}, 1]];
Wolfram Language code: Region[ℛ]
Wolfram Language code: ConstantRegionQ[ℛ]

具有参数化变换函数的 TransformedRegion 不是恒定的：

Wolfram Language code: Subscript[ℛ, 1] = TransformedRegion[Disk[{0, 0}, 1], ScalingTransform[{x, y}]];
Wolfram Language code: ConstantRegionQ[Subscript[ℛ, 1]]

替换符号式参数，使得区域恒定：

Wolfram Language code: Subscript[ℛ, 2] = Subscript[ℛ, 1] /. {x -> 3, y -> 2}; Region[Subscript[ℛ, 2]]
Wolfram Language code: ConstantRegionQ[Subscript[ℛ, 2]]

RegionBoundary：

Wolfram Language code: Subscript[ℛ, 1] = Disk[]; Subscript[ℛ, 2] = RegionBoundary[Subscript[ℛ, 1]]
Wolfram Language code: {Region[Subscript[ℛ, 1]], Region[Subscript[ℛ, 2]]}
Wolfram Language code: {ConstantRegionQ[Subscript[ℛ, 1]], ConstantRegionQ[Subscript[ℛ, 2]]}

不恒定区域的 RegionUnion 是不恒定区域：

Wolfram Language code: ConstantRegionQ[RegionUnion[Disk[{0, 0}, r], Disk[{0, 1}, 1]]]

CSG 区域  (1)

二维 CSGRegion：

Wolfram Language code: CSGRegion["Difference", {Disk[], Disk[{1 / 2, 1 / 2}]}]
Wolfram Language code: ConstantRegionQ[%]

三维：

Wolfram Language code: CSGRegion["Difference", {Cube[2], Cylinder[{{1, 1, 1}, {1, -1, 1}}]}]
Wolfram Language code: ConstantRegionQ[%]

Subdivision 区域  (1)

二维 SubdivisionRegion：

Wolfram Language code: SubdivisionRegion[Rectangle[]]
Wolfram Language code: ConstantRegionQ[%]

三维：

Wolfram Language code: SubdivisionRegion[Tetrahedron[]]
Wolfram Language code: ConstantRegionQ[%]

应用  (2)

创建仅适用于恒定区域的定义：

Wolfram Language code: f[r_ ? ConstantRegionQ] := DiscretizeRegion[r]
Wolfram Language code: f /@ {Disk[{1, 2}, 3], Disk[{x, y}, r]}

仅选择一个区域列表中的恒定区域：

Wolfram Language code: regs = {Sphere[{1, 2, 3}], Sphere[{x, y, z}], ImplicitRegion[x ^ 2 + y ^ 2 + z ^ 2 == 1, {x, y, z}]};
Wolfram Language code: cregs = Select[regs, ConstantRegionQ]

只有恒定区域能被离散化：

Wolfram Language code: DiscretizeRegion /@ cregs

属性和关系  (3)

如果 ConstantRegionQ 为 True，则 RegionQ 亦为 True：

Wolfram Language code: ℛ = Disk[];
Wolfram Language code: {ConstantRegionQ[ℛ], RegionQ[ℛ]}

MeshRegionQ 和 BoundaryMeshRegionQ 可用于检查更加特殊化的区域类型：

Wolfram Language code: Subscript[ℛ, 1] = DelaunayMesh[RandomReal[1, {10, 2}]]; Subscript[ℛ, 2] = ConvexHullMesh[RandomReal[1, {10, 2}]];
Wolfram Language code: MeshRegionQ /@ {Subscript[ℛ, 1], Subscript[ℛ, 2]}
Wolfram Language code: BoundaryMeshRegionQ /@ {Subscript[ℛ, 1], Subscript[ℛ, 2]}

网格区域恒为 ConstantRegionQ：

Wolfram Language code: ConstantRegionQ /@ {Subscript[ℛ, 1], Subscript[ℛ, 2]}

BoundedRegionQ 可用于检查区域是否有界：

Wolfram Language code: BoundedRegionQ /@ {Disk[], InfiniteLine[{0, 0}, {1, 1}]}

可能存在的问题  (2)

有些函数要求有恒定区域：

Wolfram Language code: Subscript[ℛ, 1] = Disk[{x, y}, 2];
Wolfram Language code: ConstantRegionQ[Subscript[ℛ, 1]]
Wolfram Language code: {DiscretizeRegion[Subscript[ℛ, 1]], BoundaryDiscretizeRegion[Subscript[ℛ, 1]]}

替换符号式参数，使得区域恒定：

Wolfram Language code: Subscript[ℛ, 2] = Subscript[ℛ, 1] /. {x -> 1, y -> 2};
Wolfram Language code: ConstantRegionQ[Subscript[ℛ, 2]]
Wolfram Language code: {DiscretizeRegion[Subscript[ℛ, 2]], BoundaryDiscretizeRegion[Subscript[ℛ, 2]]}

如果区域是恒定的，RegionMember 返回 True 或 False：

Wolfram Language code: Subscript[ℛ, 1] = Disk[{0, 0}, 2]; Subscript[ℛ, 2] = Disk[{x, y}, 2];
Wolfram Language code: {ConstantRegionQ[Subscript[ℛ, 1]], RegionMember[Subscript[ℛ, 1], {0, 0}]}

如果区域不是恒定的，RegionMember 返回条件：

Wolfram Language code: {ConstantRegionQ[Subscript[ℛ, 2]], RegionMember[Subscript[ℛ, 2], {0, 0}]}
Wolfram Research (2014)，ConstantRegionQ，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ConstantRegionQ.html.

文本

Wolfram Research (2014)，ConstantRegionQ，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ConstantRegionQ.html.

CMS

Wolfram 语言. 2014. "ConstantRegionQ." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/ConstantRegionQ.html.

APA

Wolfram 语言. (2014). ConstantRegionQ. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/ConstantRegionQ.html 年

BibTeX

@misc{reference.wolfram_2026_constantregionq, author="Wolfram Research", title="{ConstantRegionQ}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/ConstantRegionQ.html}", note=[Accessed: 16-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_constantregionq, organization={Wolfram Research}, title={ConstantRegionQ}, year={2014}, url={https://reference.wolfram.com/language/ref/ConstantRegionQ.html}, note=[Accessed: 16-September-2026]}