WOLFRAM

Wolfram 语言与系统参考资料中心

CoprimeQ[n1,n2]

如果 n1 和 n2 互质，得出 True；否则得出 False.

CoprimeQ[n1,n2,…]

如果 ni 的所有成对的数互质，得出 True；否则得出 False.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
选项  
GaussianIntegers  
应用  
基本应用  
数论  
属性和关系  
巧妙范例  
参见
技术笔记
相关指南
历史
按以下格式引用：

CoprimeQ

CoprimeQ[n1,n2]

如果 n1 和 n2 互质，得出 True；否则得出 False.

CoprimeQ[n1,n2,…]

如果 ni 的所有成对的数互质，得出 True；否则得出 False.

更多信息

  • CoprimeQ 通常用于测试两个数字是否互质.
  • 如果整数的最大公约数为 1，则这些整数互质.
  • 除非 n1,n2 明显互质，否则 CoprimeQ[n1,n2] 返回 False.
  • 通过设置 GaussianIntegers->True，CoprimeQ 检验高斯整数是否互质.
  • CoprimeQ 适用于高斯整数.

范例

打开所有单元 关闭所有单元

基本范例  (2)

检验两个数是否互质：

Wolfram Language code: CoprimeQ[8, 11]

整数 和 不是互质的：

Wolfram Language code: CoprimeQ[2, 4]

范围  (4)

CoprimeQ 适应于整数：

Wolfram Language code: CoprimeQ[2, 3, -5, 7]

高斯整数：

Wolfram Language code: CoprimeQ[5 + I, 1 - I]
Wolfram Language code: CoprimeQ[5, 7, GaussianIntegers -> True]

检验大型整数：

Wolfram Language code: CoprimeQ[2 ^ 100 - 1, 3 ^ 100 - 1]

CoprimeQ 按元素遍历列表：

Wolfram Language code: CoprimeQ[{1, 2, 3, 4, 5}, 6]

选项  (1)

GaussianIntegers  (1)

检验两个数是否互质：

Wolfram Language code: CoprimeQ[2, 3]

高斯整数：

Wolfram Language code: CompositeQ[{2, 3}, GaussianIntegers -> True]

应用  (8)

基本应用  (3)

高亮显示与 互质的数：

Wolfram Language code: Multicolumn[If[CoprimeQ[#, 12], Style[#, Red, Bold], #]& /@ Range[100], 10, ...]

生成与给定数值互质的随机数：

Wolfram Language code: randomCoprime[x_Integer] := RandomChoice[Pick[Range[x], CoprimeQ[x, Range[x]]]];
Wolfram Language code: randomCoprime[15]
Wolfram Language code: CoprimeQ[15, %]

绘制随机的互质数对：

Wolfram Language code: ListPlot[{#, randomCoprime[#]}& /@ RandomInteger[{3, 100}, 500]]

当两个数字互质时可视化：

Wolfram Language code: ArrayPlot[Table[Boole[CoprimeQ[i, j]], {i, 50}, {j, 50}]]

数论  (5)

使用 CoprimeQ 计算欧拉函数：

Wolfram Language code: eulerPhi[n_] := Length[Select[Range[n], CoprimeQ[#, n] == True&]];
Wolfram Language code: ListPlot[Table[eulerPhi[n], {n, 100}]]

使用 CoprimeQ 检查普通的最大公约数：

Wolfram Language code: CoprimeQ[5, 6]
Wolfram Language code: GCD[5, 6]

找到的互素的前 个数字的分数：

Wolfram Language code: Total[Boole[Array[CoprimeQ, {100, 100}]], 2] / 10 ^ 4//N

结果接近于 ：

Wolfram Language code: N[1 / Zeta[2]]

计算互质数的模逆：

Wolfram Language code: CoprimeQ[5, 3]
Wolfram Language code: ModularInverse[5, 3]

使用 ExtendedGCD：

Wolfram Language code: ExtendedGCD[5, 3][[2, 2]]

数据库加密和解密：

Wolfram Language code: data = {145895125, 148963155, 789524465, 489325698, 598632147};

密钥生成：

Wolfram Language code: keys = RandomPrime[{10 ^ 9, 10 ^ 12}, 5]
Wolfram Language code: CoprimeQ@@keys

加密的数据：

Wolfram Language code: encrypted = ChineseRemainder[data, keys]

解密数据：

Wolfram Language code: Mod[encrypted, keys]

属性和关系  (9)

互质数的最大公约数 GCD 等于 ：

Wolfram Language code: CoprimeQ[8, 9]
Wolfram Language code: GCD[8, 9]

两个互质数的最小公倍数 LCM 等于其乘积：

Wolfram Language code: CoprimeQ[6, 11]
Wolfram Language code: LCM[6, 11] == 6 11

一个数的除数的个数保留了互质数的乘法：

Wolfram Language code: CoprimeQ[5, 12]
Wolfram Language code: Length[Divisors[5]]Length[Divisors[12]] == Length[Divisors[5 12]]

对于某些整数 x 和 y，互质数 a 和 b 满足 ：

Wolfram Language code: a = 7; b = 15;
Wolfram Language code: CoprimeQ[a, b]
Wolfram Language code: FindInstance[a * x + b * y == 1, {x, y}, Integers]

与每个整数均互质的数只有 和 ：

Wolfram Language code: Table[CoprimeQ[1, n], {n, 10}]
Wolfram Language code: Table[CoprimeQ[-1, n], {n, 10}]

质数之间互为质数：

Wolfram Language code: CoprimeQ[Prime[10], Prime[15], Prime[20], Prime[25]]

EulerPhi 给出最多为 n 的正整数的计数，这些正整数与 n 互质：

Wolfram Language code: EulerPhi[20]

互质数 a 和 n 满足 ：

Wolfram Language code: CoprimeQ[7, 10]
Wolfram Language code: PowerMod[7, EulerPhi[10], 10]

如果 a 和 b 互质，则它们的任何次幂 和 也互质：

Wolfram Language code: a = 6;b = 25;
Wolfram Language code: CoprimeQ[a, b]
Wolfram Language code: Flatten[Table[CoprimeQ[a ^ k, b ^ m], {k, 3}, {m, 3}]]

巧妙范例  (2)

绘制互质数的图形：

Wolfram Language code: ArrayMesh[Boole[Table[CoprimeQ[a, b, c], {a, 10}, {b, 10}, {c, 10}]]]

绘制一系列互质数的乌岚螺旋：

Wolfram Language code: ulam[n_] := Partition[Permute[Range[n ^ 2], Accumulate[Take[Flatten[{{n ^ 2 + 1} / 2, Table [(-1) ^ j i, {j, n}, {i, {-1, n}}, {j}]}], n ^ 2]]], n];
Wolfram Language code: ArrayPlot[Boole[CoprimeQ[ulam[101], ulam[101] ^ 15 + 9]], ColorFunction -> "Rainbow"]
Wolfram Research (2007)，CoprimeQ，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CoprimeQ.html.

文本

Wolfram Research (2007)，CoprimeQ，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CoprimeQ.html.

CMS

Wolfram 语言. 2007. "CoprimeQ." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/CoprimeQ.html.

APA

Wolfram 语言. (2007). CoprimeQ. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/CoprimeQ.html 年

BibTeX

@misc{reference.wolfram_2026_coprimeq, author="Wolfram Research", title="{CoprimeQ}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/CoprimeQ.html}", note=[Accessed: 10-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_coprimeq, organization={Wolfram Research}, title={CoprimeQ}, year={2007}, url={https://reference.wolfram.com/language/ref/CoprimeQ.html}, note=[Accessed: 10-September-2026]}