WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

CosIntegral[z]

余弦積分関数 TemplateBox[{z}, CosIntegral]を与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
数値評価  
特定の値  
可視化  
Show More Show More
関数の特性  
微分  
積分  
級数展開  
関数の恒等式と簡約  
関数表現  
一般化と拡張  
アプリケーション  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

CosIntegral

CosIntegral[z]

余弦積分関数 TemplateBox[{z}, CosIntegral]を与える．

詳細

  • 記号操作・数値操作の両方に適した数学関数である．
  • TemplateBox[{z}, CosIntegral]=-int_z^inftycos(t)/tdt
  • CosIntegral[z]は，複素 z 平面上，-∞〜0の範囲で不連続な分枝切断線を持つ．
  • 特別な引数の場合，CosIntegralは，自動的に厳密値を計算する．
  • CosIntegralは任意の数値精度で評価できる．
  • CosIntegralは，自動的にリストに縫い込まれる．
  • CosIntegralはIntervalオブジェクトおよびCenteredIntervalオブジェクトに使うことができる． »

例題

すべて開く すべて閉じる

例  (6)

数値的に評価する：

Wolfram Language code: CosIntegral[2.8]

実数の部分集合乗でプロットする：

Wolfram Language code: Plot[CosIntegral[x], {x, 0, 20}]

複素数の部分集合乗でプロットする：

Wolfram Language code: ComplexPlot3D[CosIntegral[z ^ 2], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

原点いおける級数展開：

Wolfram Language code: Series[CosIntegral[x], {x, 0, 10}]

Infinityにおける漸近展開：

Wolfram Language code: Series[CosIntegral[x], {x, ∞, 3}]//Normal

特異点における漸近展開：

Wolfram Language code: Series[CosIntegral[x], {x, -1, 3}, Assumptions -> z > 0]//Normal

スコープ  (37)

数値評価  (6)

高精度で数値評価する：

Wolfram Language code: N[CosIntegral[2], 50]

出力の精度は入力の精度に従う：

Wolfram Language code: CosIntegral[2.0000000000000000000000000000000000000]

複素引数について評価する：

Wolfram Language code: CosIntegral[2.5 + I]

CosIntegralを高精度で効率よく評価する：

Wolfram Language code: CosIntegral[2`500]//Timing
Wolfram Language code: CosIntegral[2`10000];//Timing

CosIntegralは要素単位でリストと行列に縫い込まれる：

Wolfram Language code: CosIntegral[{1.2, 1.5, 1.8}]
Wolfram Language code: CosIntegral[(| | | | :- | :- | | 0 | u | | v | ∞ |) ]//MatrixForm

IntervalオブジェクトとCenteredIntervalオブジェクトを使って最悪の場合に保証される区間を計算する：

Wolfram Language code: CosIntegral[Interval[{1.9, 2.1}]]
Wolfram Language code: CosIntegral[CenteredInterval[2, 1 / 100]]

Aroundを使って平均的な場合の統計間隔を計算することもできる．

Wolfram Language code: CosIntegral[Around[2, 0.01]]

任意の配列の要素単位の値を計算する：

Wolfram Language code: CosIntegral[{{.2, 0}, {0, .2 }}]

MatrixFunctionを使って行列のCosIntegral関数を計算することもできる：

Wolfram Language code: MatrixFunction[CosIntegral, {{.2, 0}, {0, .2 }}]

特定の値  (3)

固定点における値：

Wolfram Language code: CosIntegral[0]

無限大における値：

Wolfram Language code: CosIntegral[{-Infinity, Infinity, -I Infinity, I Infinity}]
Wolfram Language code: CosIntegral[ComplexInfinity]

極大値を(dTemplateBox[{x}, CosIntegral])/(dx)=0の根として求める：

Wolfram Language code: xmax = Solve[D[CosIntegral[x], x] == 0 && 0 < x < 2, x][[1, 1]]
Wolfram Language code: Plot[CosIntegral[x], {x, 0, 3π}, Epilog -> Style[Point[{xmax[[2]], CosIntegral[xmax[[2]]]}], PointSize[Large], Red]]

可視化  (2)

CosIntegral関数をプロットする：

Wolfram Language code: Plot[CosIntegral[x], {x, 0, 4π}]

TemplateBox[{z}, CosIntegral]の実部をプロットする：

Wolfram Language code: ComplexContourPlot[Re[CosIntegral[z]], {z, -3π - π I, 3π + π I}, Contours -> 24]

TemplateBox[{z}, CosIntegral]の虚部をプロットする：

Wolfram Language code: ComplexContourPlot[Im[CosIntegral[z]], {z, -3π - π I, 3π + π I}, Contours -> 24]

関数の特性  (8)

CosIntegralは，すべての正の実数値について定義される：

Wolfram Language code: FunctionDomain[CosIntegral[x], x]

複素領域：

Wolfram Language code: FunctionDomain[CosIntegral[z], z, Complexes]

CosIntegralは解析関数ではない：

Wolfram Language code: FunctionAnalytic[CosIntegral[x], x]

有理型でもない：

Wolfram Language code: FunctionMeromorphic[CosIntegral[x], x]

CosIntegralは非減少でも非増加でもない：

Wolfram Language code: FunctionMonotonicity[CosIntegral[x], x, PositiveReals]

CosIntegralは単射ではない：

Wolfram Language code: FunctionInjective[CosIntegral[x], x]
Wolfram Language code: Plot[{CosIntegral[x], .3}, {x, 0, 10}]

CosIntegralは全射ではない：

Wolfram Language code: FunctionSurjective[CosIntegral[x], x]
Wolfram Language code: Plot[{CosIntegral[x], 1}, {x, 0, 10}]

CosIntegralは非負でも非正でもない：

Wolfram Language code: FunctionSign[{CosIntegral[x], x > 0}, x]

(-∞,0]に特異点と不連続点の両方を持つ：

Wolfram Language code: FunctionSingularities[CosIntegral[x], x]
Wolfram Language code: FunctionDiscontinuities[CosIntegral[x], x]

CosIntegralは凸でも凹でもない：

Wolfram Language code: FunctionConvexity[{CosIntegral[x], x > 0}, x]

微分  (3)

一次導関数：

Wolfram Language code: D[CosIntegral[x], x]

高次導関数：

Wolfram Language code: Table[D[CosIntegral[x], {x, n}], {n, 1, 4}]
Wolfram Language code: Plot[Evaluate[%], {x, 0, 4π}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

次導関数の式：

Wolfram Language code: D[CosIntegral[x], {x, n}]

積分  (3)

CosIntegralの不定積分：

Wolfram Language code: Integrate[CosIntegral[x], x]

CosIntegralの，その実領域全体の上での定積分：

Wolfram Language code: Integrate[CosIntegral[x], {x, 0, Infinity}]

その他の積分例：

Wolfram Language code: Integrate[x CosIntegral[Sqrt[x]], x]
Wolfram Language code: Integrate[CosIntegral[x]Cos[x], x]
Wolfram Language code: Integrate[CosIntegral[x^a], x]

級数展開  (3)

の周りのCosIntegralのテイラー(Taylor)展開：

Wolfram Language code: Series[CosIntegral[x], {x, π, 5}]

の周りのCosIntegralの最初の3つの近似をプロットする：

Wolfram Language code: terms = Normal@Table[Series[CosIntegral[x], {x, π, m}], {m, 1, 3}]; Plot[{CosIntegral[x], terms}, {x, 1, 5}]

無限大における級数展開を求める：

Wolfram Language code: Series[CosIntegral[x], {x, Infinity, 4}]//Normal

CosIntegralはベキ級数に適用できる：

Wolfram Language code: CosIntegral[1 + x + (x^2/2) + (x^3/9) + O[x]^4]

関数の恒等式と簡約  (4)

FullSimplifyを使って余弦積分を含む式を簡約する：

Wolfram Language code: FullSimplify[MeijerG[{{}, {1}}, {{0, 0}, {(1/ 2)}}, (z^2/4)] - CosIntegral[z], z > 0]

FunctionExpandを使って，他の関数を介してCosIntegralを表現する：

Wolfram Language code: FunctionExpand[CosIntegral[z] - CosIntegral[-z]]

式を簡約してCosIntegralにする：

Wolfram Language code: Log[z] - (1/2)(Gamma[0, -I z] + Gamma[0, I z] + Log[-I z] + Log[I z])//FullSimplify

引数の簡約：

Wolfram Language code: CosIntegral[-z]//FunctionExpand
Wolfram Language code: CosIntegral[I z]//FunctionExpand
Wolfram Language code: CosIntegral[Sqrt[z^2]]//FunctionExpand

関数表現  (5)

CosIntegralの主定義：

Wolfram Language code: Integrate[(Cos[t] - 1/t), {t, 0, z}] + Log[z] + EulerGamma

CosIntegralの級数表現：

Wolfram Language code: Log[z] + EulerGamma + (1/2)Sum[((-1)^k z^2k/k (2k)!), {k, 1, Infinity}]//FullSimplify

CosIntegralはMeijerGによって表すことができる：

Wolfram Language code: MeijerGReduce[CosIntegral[x], x]
Wolfram Language code: Activate[%]//FullSimplify

CosIntegralはDifferentialRootとして表すことができる：

Wolfram Language code: DifferentialRootReduce[CosIntegral[x], x]

TraditionalFormによる表示：

Wolfram Language code: CosIntegral[z]//TraditionalForm

一般化と拡張  (1)

無限大における級数展開を求める：

Wolfram Language code: Series[CosIntegral[x], {x, Infinity, 4}]

アプリケーション  (6)

細い線形の半波長アンテナの平均的な放射電力：

Wolfram Language code: Integrate[(Cos[Pi Cos[θ]] - Cos[Pi]) ^ 2 / Sin[θ], {θ, 0, Pi}]

複素平面上で虚部をプロットする：

Wolfram Language code: Plot3D[Im[CosIntegral[x + I y]], {x, -20, 20}, {y, -3, 3}]

複素平面の絶対値の対数をプロットする：

Wolfram Language code: ContourPlot[Log[Abs[CosIntegral[x + I y]]], {x, -10, 10}, {y, -10, 10}]

微分方程式を解く：

Wolfram Language code: DSolve[x (y[x] + Derivative[2][y][x]) == Cos[x], y[x], x]

オイラー・ハイゼンベルグ(Euler–Heisenberg)の有効作用の実部：

Wolfram Language code: action[k_, {m_, e_}, {a_, b_}] := With[{x = k π (m^2/e a), y = k π (m^2/e b)}, -(e^2a b/4 π^3k)(Coth[k π (b/a)](CosIntegral[x] Cos[x] + (SinIntegral[x] - π / 2)Sin[x]) - Coth[k π (a/b)](ExpIntegralEi[y] Exp[-y] + ExpIntegralEi[-y] Exp[y]) / 2)]

の最高次の項を求める：

Wolfram Language code: Assuming[{q > 0 && a > 0 && b > 0 && m > 0 && k > 0}, Series[action[k, {m, q}, {a, b}], {q, 0, 4}]//Normal//FullSimplify]

Nielsenの螺線をプロットする：

Wolfram Language code: nielsen[t_] := {CosIntegral[t], SinIntegral[t]}
Wolfram Language code: ParametricPlot[nielsen[t], {t, 1 / 25, 25}, PlotRange -> All]

曲率はパラメータの単純な関数である：

Wolfram Language code: FullSimplify[FrenetSerretSystem[nielsen[t], t][[1, 1]], t∈Reals]

特性と関係  (7)

FullSimplifyを使って余弦積分を含む式を簡約する：

Wolfram Language code: FullSimplify[MeijerG[{{}, {1}}, {{0, 0}, {(1/ 2)}}, (z^2/4)] - CosIntegral[z], z > 0]

FunctionExpandを使ってCosIntegralを他の関数で表現する：

Wolfram Language code: FunctionExpand[CosIntegral[z] - CosIntegral[-z]]

近似根を数値的に求める：

Wolfram Language code: FindRoot[CosIntegral[z] == 1 / 4, {z, 1}]

積分と総和からCosIntegralを求める：

Wolfram Language code: Integrate[(Cos[t]/t), {t, z, Infinity}]
Wolfram Language code: Underoverscript[∑, k = 1, ∞]((-1)^k z^2 k/k (2 k)!)

微分方程式からCosIntegralを求める：

Wolfram Language code: DSolve[z Derivative[3][w][z] + 2 Derivative[2][w][z] + z Derivative[1][w][z] == 0, w[z], z]//FunctionExpand

ロンスキ(Wronski)の行列式を計算する：

Wolfram Language code: Det[Outer[D[#1, {x, #2}]&, {1, SinIntegral[x], CosIntegral[x]}, {0, 1, 2}]]//FullSimplify

ラプラス(Laplace)変換：

Wolfram Language code: LaplaceTransform[CosIntegral[t], t, s]

考えられる問題  (2)

CosIntegralは中程度の大きさの引数の大きい値を取ることができる：

Wolfram Language code: CosIntegral[Sqrt[I] 10. ^ 6 ]

$MaxExtraPrecisionの設定値を大きくする必要があるかもしれない：

Wolfram Language code: N[CosIntegral[10 ^ 60 ], 20]
Wolfram Language code: Block[{$MaxExtraPrecision = 200}, N[CosIntegral[10 ^ 60 ], 20]]

おもしろい例題  (1)

ネストした積分：

Wolfram Language code: NestList[Integrate[#, x]&, CosIntegral[ x], 4]
Wolfram Research (1991), CosIntegral, Wolfram言語関数， https://reference.wolfram.com/language/ref/CosIntegral.html （2022年に更新）.

テキスト

Wolfram Research (1991), CosIntegral, Wolfram言語関数， https://reference.wolfram.com/language/ref/CosIntegral.html （2022年に更新）.

CMS

Wolfram Language. 1991. "CosIntegral." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2022. https://reference.wolfram.com/language/ref/CosIntegral.html.

APA

Wolfram Language. (1991). CosIntegral. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CosIntegral.html

BibTeX

@misc{reference.wolfram_2026_cosintegral, author="Wolfram Research", title="{CosIntegral}", year="2022", howpublished="\url{https://reference.wolfram.com/language/ref/CosIntegral.html}", note=[Accessed: 05-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_cosintegral, organization={Wolfram Research}, title={CosIntegral}, year={2022}, url={https://reference.wolfram.com/language/ref/CosIntegral.html}, note=[Accessed: 05-September-2026]}