WOLFRAM

Wolfram 语言与系统参考资料中心

CosIntegral[z]

给出余弦积分函数 TemplateBox[{z}, CosIntegral].

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
数值计算
特殊值  
可视化  
Show More Show More
函数的属性  
微分  
积分  
级数展开式  
函数属性和化简  
函数表示  
推广和延伸  
应用  
属性和关系  
可能存在的问题  
巧妙范例  
参见
技术笔记
相关指南
相关链接
历史
按以下格式引用：

CosIntegral

CosIntegral[z]

给出余弦积分函数 TemplateBox[{z}, CosIntegral].

更多信息

范例

打开所有单元 关闭所有单元

基本范例  (6)

数值运算：

Wolfram Language code: CosIntegral[2.8]

在实数的子集上绘图：

Wolfram Language code: Plot[CosIntegral[x], {x, 0, 20}]

在复数的子集上绘图：

Wolfram Language code: ComplexPlot3D[CosIntegral[z ^ 2], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

在原点的级数展开：

Wolfram Language code: Series[CosIntegral[x], {x, 0, 10}]

在 Infinity 的渐进展开：

Wolfram Language code: Series[CosIntegral[x], {x, ∞, 3}]//Normal

在奇点处的渐近展开：

Wolfram Language code: Series[CosIntegral[x], {x, -1, 3}, Assumptions -> z > 0]//Normal

范围  (37)

数值计算 (6)

高精度计算：

Wolfram Language code: N[CosIntegral[2], 50]

输出精度与输入精度一致：

Wolfram Language code: CosIntegral[2.0000000000000000000000000000000000000]

计算复变量：

Wolfram Language code: CosIntegral[2.5 + I]

在高精度条件下高效计算 CosIntegral：

Wolfram Language code: CosIntegral[2`500]//Timing
Wolfram Language code: CosIntegral[2`10000];//Timing

CosIntegral 依次逐项作用于列表和矩阵的各个元素：

Wolfram Language code: CosIntegral[{1.2, 1.5, 1.8}]
Wolfram Language code: CosIntegral[(| | | | :- | :- | | 0 | u | | v | ∞ |) ]//MatrixForm

用 Interval 和 CenteredInterval 对象计算最坏情况下的区间：

Wolfram Language code: CosIntegral[Interval[{1.9, 2.1}]]
Wolfram Language code: CosIntegral[CenteredInterval[2, 1 / 100]]

或用 Around 计算一般情况下的统计区间：

Wolfram Language code: CosIntegral[Around[2, 0.01]]

计算数组中每个元素的值：

Wolfram Language code: CosIntegral[{{.2, 0}, {0, .2 }}]

或用 MatrixFunction 计算矩阵形式的 CosIntegral 函数：

Wolfram Language code: MatrixFunction[CosIntegral, {{.2, 0}, {0, .2 }}]

特殊值  (3)

在固定点上的值：

Wolfram Language code: CosIntegral[0]

无穷处的值：

Wolfram Language code: CosIntegral[{-Infinity, Infinity, -I Infinity, I Infinity}]
Wolfram Language code: CosIntegral[ComplexInfinity]

求局部最大值，以作为 (dTemplateBox[{x}, CosIntegral])/(dx)=0 的根：

Wolfram Language code: xmax = Solve[D[CosIntegral[x], x] == 0 && 0 < x < 2, x][[1, 1]]
Wolfram Language code: Plot[CosIntegral[x], {x, 0, 3π}, Epilog -> Style[Point[{xmax[[2]], CosIntegral[xmax[[2]]]}], PointSize[Large], Red]]

可视化  (2)

绘制 CosIntegral 函数：

Wolfram Language code: Plot[CosIntegral[x], {x, 0, 4π}]

绘制 TemplateBox[{z}, CosIntegral] 的实部：

Wolfram Language code: ComplexContourPlot[Re[CosIntegral[z]], {z, -3π - π I, 3π + π I}, Contours -> 24]

绘制 TemplateBox[{z}, CosIntegral] 的虚部：

Wolfram Language code: ComplexContourPlot[Im[CosIntegral[z]], {z, -3π - π I, 3π + π I}, Contours -> 24]

函数的属性  (8)

CosIntegral 是针对所有正实数定义的：

Wolfram Language code: FunctionDomain[CosIntegral[x], x]

复定义域：

Wolfram Language code: FunctionDomain[CosIntegral[z], z, Complexes]

CosIntegral 不是解析函数：

Wolfram Language code: FunctionAnalytic[CosIntegral[x], x]

也不是亚纯函数：

Wolfram Language code: FunctionMeromorphic[CosIntegral[x], x]

CosIntegral 既不是非递增，也不是非递减：

Wolfram Language code: FunctionMonotonicity[CosIntegral[x], x, PositiveReals]

CosIntegral 不是单射函数：

Wolfram Language code: FunctionInjective[CosIntegral[x], x]
Wolfram Language code: Plot[{CosIntegral[x], .3}, {x, 0, 10}]

CosIntegral 不是满射函数：

Wolfram Language code: FunctionSurjective[CosIntegral[x], x]
Wolfram Language code: Plot[{CosIntegral[x], 1}, {x, 0, 10}]

CosIntegral 既不是非负，也不是非正：

Wolfram Language code: FunctionSign[{CosIntegral[x], x > 0}, x]

在 (-∞,0] 内有奇点和断点：

Wolfram Language code: FunctionSingularities[CosIntegral[x], x]
Wolfram Language code: FunctionDiscontinuities[CosIntegral[x], x]

CosIntegral 既不凸，也不凹：

Wolfram Language code: FunctionConvexity[{CosIntegral[x], x > 0}, x]

微分  (3)

一阶导数：

Wolfram Language code: D[CosIntegral[x], x]

高阶导数：

Wolfram Language code: Table[D[CosIntegral[x], {x, n}], {n, 1, 4}]
Wolfram Language code: Plot[Evaluate[%], {x, 0, 4π}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

阶导数的公式：

Wolfram Language code: D[CosIntegral[x], {x, n}]

积分  (3)

CosIntegral 的不定积分：

Wolfram Language code: Integrate[CosIntegral[x], x]

CosIntegral 在整个实数域上的定积分：

Wolfram Language code: Integrate[CosIntegral[x], {x, 0, Infinity}]

更多积分：

Wolfram Language code: Integrate[x CosIntegral[Sqrt[x]], x]
Wolfram Language code: Integrate[CosIntegral[x]Cos[x], x]
Wolfram Language code: Integrate[CosIntegral[x^a], x]

级数展开式  (3)

CosIntegral 在 处的泰勒展开式：

Wolfram Language code: Series[CosIntegral[x], {x, π, 5}]

绘制 CosIntegral 在 处的前三个近似式：

Wolfram Language code: terms = Normal@Table[Series[CosIntegral[x], {x, π, m}], {m, 1, 3}]; Plot[{CosIntegral[x], terms}, {x, 1, 5}]

求无穷处的级数展开式：

Wolfram Language code: Series[CosIntegral[x], {x, Infinity, 4}]//Normal

CosIntegral 可被应用于幂级数：

Wolfram Language code: CosIntegral[1 + x + (x^2/2) + (x^3/9) + O[x]^4]

函数属性和化简  (4)

用 FullSimplify 化简含有余弦积分的表达式：

Wolfram Language code: FullSimplify[MeijerG[{{}, {1}}, {{0, 0}, {(1/ 2)}}, (z^2/4)] - CosIntegral[z], z > 0]

通过 FunctionExpand 用其他函数表示 CosIntegral：

Wolfram Language code: FunctionExpand[CosIntegral[z] - CosIntegral[-z]]

把表达式化简为 CosIntegral：

Wolfram Language code: Log[z] - (1/2)(Gamma[0, -I z] + Gamma[0, I z] + Log[-I z] + Log[I z])//FullSimplify

参数化简：

Wolfram Language code: CosIntegral[-z]//FunctionExpand
Wolfram Language code: CosIntegral[I z]//FunctionExpand
Wolfram Language code: CosIntegral[Sqrt[z^2]]//FunctionExpand

函数表示  (5)

CosIntegral 的主定义：

Wolfram Language code: Integrate[(Cos[t] - 1/t), {t, 0, z}] + Log[z] + EulerGamma

CosIntegral 的级数表示：

Wolfram Language code: Log[z] + EulerGamma + (1/2)Sum[((-1)^k z^2k/k (2k)!), {k, 1, Infinity}]//FullSimplify

可用 MeijerG 来表示 CosIntegral：

Wolfram Language code: MeijerGReduce[CosIntegral[x], x]
Wolfram Language code: Activate[%]//FullSimplify

CosIntegral 可被表示为 DifferentialRoot：

Wolfram Language code: DifferentialRootReduce[CosIntegral[x], x]

TraditionalForm 格式：

Wolfram Language code: CosIntegral[z]//TraditionalForm

推广和延伸  (1)

求无穷处的级数展开：

Wolfram Language code: Series[CosIntegral[x], {x, Infinity, 4}]

应用  (6)

一个细线状半波天线的平均辐射电功率：

Wolfram Language code: Integrate[(Cos[Pi Cos[θ]] - Cos[Pi]) ^ 2 / Sin[θ], {θ, 0, Pi}]

绘制复平面内的虚部：

Wolfram Language code: Plot3D[Im[CosIntegral[x + I y]], {x, -20, 20}, {y, -3, 3}]

绘制复平面内绝对值的对数：

Wolfram Language code: ContourPlot[Log[Abs[CosIntegral[x + I y]]], {x, -10, 10}, {y, -10, 10}]

解微分方程：

Wolfram Language code: DSolve[x (y[x] + Derivative[2][y][x]) == Cos[x], y[x], x]

Euler–Heisenberg 有效作用的实部：

Wolfram Language code: action[k_, {m_, e_}, {a_, b_}] := With[{x = k π (m^2/e a), y = k π (m^2/e b)}, -(e^2a b/4 π^3k)(Coth[k π (b/a)](CosIntegral[x] Cos[x] + (SinIntegral[x] - π / 2)Sin[x]) - Coth[k π (a/b)](ExpIntegralEi[y] Exp[-y] + ExpIntegralEi[-y] Exp[y]) / 2)]

求 中次数最高的项：

Wolfram Language code: Assuming[{q > 0 && a > 0 && b > 0 && m > 0 && k > 0}, Series[action[k, {m, q}, {a, b}], {q, 0, 4}]//Normal//FullSimplify]

绘制 Nielsen 螺旋线：

Wolfram Language code: nielsen[t_] := {CosIntegral[t], SinIntegral[t]}
Wolfram Language code: ParametricPlot[nielsen[t], {t, 1 / 25, 25}, PlotRange -> All]

曲率是参数的一个简单函数：

Wolfram Language code: FullSimplify[FrenetSerretSystem[nielsen[t], t][[1, 1]], t∈Reals]

属性和关系  (7)

用 FullSimplify 来化简包含余弦积分的表达式：

Wolfram Language code: FullSimplify[MeijerG[{{}, {1}}, {{0, 0}, {(1/ 2)}}, (z^2/4)] - CosIntegral[z], z > 0]

通过 FunctionExpand 用其它函数来表示 CosIntegral：

Wolfram Language code: FunctionExpand[CosIntegral[z] - CosIntegral[-z]]

求数值根：

Wolfram Language code: FindRoot[CosIntegral[z] == 1 / 4, {z, 1}]

从积分与求和获得 CosIntegral：

Wolfram Language code: Integrate[(Cos[t]/t), {t, z, Infinity}]
Wolfram Language code: Underoverscript[∑, k = 1, ∞]((-1)^k z^2 k/k (2 k)!)

从微分方程获得 CosIntegral：

Wolfram Language code: DSolve[z Derivative[3][w][z] + 2 Derivative[2][w][z] + z Derivative[1][w][z] == 0, w[z], z]//FunctionExpand

计算 Wronskian：

Wolfram Language code: Det[Outer[D[#1, {x, #2}]&, {1, SinIntegral[x], CosIntegral[x]}, {0, 1, 2}]]//FullSimplify

拉普拉斯变换：

Wolfram Language code: LaplaceTransform[CosIntegral[t], t, s]

可能存在的问题  (2)

CosIntegral 对中等大小的变量采用大型数据值：

Wolfram Language code: CosIntegral[Sqrt[I] 10. ^ 6 ]

需要提高 $MaxExtraPrecision 的设置：

Wolfram Language code: N[CosIntegral[10 ^ 60 ], 20]
Wolfram Language code: Block[{$MaxExtraPrecision = 200}, N[CosIntegral[10 ^ 60 ], 20]]

巧妙范例  (1)

嵌套积分：

Wolfram Language code: NestList[Integrate[#, x]&, CosIntegral[ x], 4]
Wolfram Research (1991)，CosIntegral，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CosIntegral.html （更新于 2022 年）.

文本

Wolfram Research (1991)，CosIntegral，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CosIntegral.html （更新于 2022 年）.

CMS

Wolfram 语言. 1991. "CosIntegral." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2022. https://reference.wolfram.com/language/ref/CosIntegral.html.

APA

Wolfram 语言. (1991). CosIntegral. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/CosIntegral.html 年

BibTeX

@misc{reference.wolfram_2026_cosintegral, author="Wolfram Research", title="{CosIntegral}", year="2022", howpublished="\url{https://reference.wolfram.com/language/ref/CosIntegral.html}", note=[Accessed: 08-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_cosintegral, organization={Wolfram Research}, title={CosIntegral}, year={2022}, url={https://reference.wolfram.com/language/ref/CosIntegral.html}, note=[Accessed: 08-September-2026]}