WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Cosh[z]

z の双曲線余弦を与える．

詳細
Details and Options Details and Options
予備知識
例題  
例  
スコープ  
数値評価  
特定の値  
可視化  
Show More Show More
関数の特性  
微分  
積分  
級数展開  
積分変換  
関数の恒等式と簡約  
関数表現  
アプリケーション  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

Cosh

Cosh[z]

z の双曲線余弦を与える．

詳細

  • 記号操作・数値操作の両方に適した数学関数である．
  • 特別な引数の場合，Coshは自動的に厳密値を計算する．
  • Coshは任意の数値精度で評価できる．
  • Coshは自動的にリストに縫い込まれる． »
  • CoshはIntervalオブジェクトおよびCenteredIntervalオブジェクトに使うことができる． »

予備知識

  • Coshは，双曲線余弦関数である．これは，三角法を通して使われる，Cos円関数の双曲線バージョンのようなものである．これは，実数について， の面積が，単位双曲線 と交わる原点からの放射線と 軸との間の面積の2倍になるようにすることで定義される．そうすると，Cosh[α]は交点の水平座標を表す．Coshはとしても定義される．ただし， は自然対数Logの底である．
  • Coshは，その引数が有理数の（自然）対数であるときは，自動的に厳密値に評価される．引数として厳密な数式が与えられると，Coshは任意の数値精度に評価されることがある．Coshを含む記号式の操作に便利なその他の演算には，TrigToExp，TrigExpand，Simplify，FullSimplifyがある．
  • Coshは要素単位でリストおよび行列に縫い込まれる．対照的に，MatrixFunctionを使って，平方行列の双曲線余弦（つまり，通常のベキが行列のベキで置き換えられた双曲線余弦関数のベキ級数）を与えることができる．
  • Cosh[x]は，x が に近付くにつれて，指数的に増大する．Coshは，Cosによって満足されるような，ピタゴラス(Pythagorean)の恒等式に似た恒等式を満足する．双曲線正弦関数の定義は，恒等式によって，複素引数 にまで拡張される．双曲線余弦関数は完全である．つまり，複素平面の有限なすべての点において複素微分が可能である．Cosh[z]は，原点付近で級数展開 を持つ．
  • Coshの逆関数はArcCoshである．他の関連する数学関数にはSinhおよびSechがある．

例題

すべて開く すべて閉じる

例  (4)

数値的に評価する：

Wolfram Language code: Cosh[1.2]

実数の部分集合上でプロットする：

Wolfram Language code: Plot[Cosh[x], {x, -4, 4}]

複素数の部分集合上でプロットする：

Wolfram Language code: ComplexPlot3D[Cosh[z], {z, -π / 4 - 4I, π / 4 + 4I}, PlotLegends -> Automatic]

0における級数展開：

Wolfram Language code: Series[Cosh[x], {x, 0, 10}]

スコープ  (48)

数値評価  (6)

数値的に評価する：

Wolfram Language code: Cosh[1.2]

高精度で評価する：

Wolfram Language code: N[Cosh[12 / 10], 50]

出力精度は入力精度に従う：

Wolfram Language code: Cosh[1.20000000000000000000000]

Coshは複素数を入力として取ることができる：

Wolfram Language code: Cosh[2.5 + I]

Coshを高精度で効率よく評価する：

Wolfram Language code: Cosh[1.2`500]//Timing
Wolfram Language code: Cosh[1.2`100000];//Timing

自動縫込みを使って配列の要素ごとの値を計算する：

Wolfram Language code: Cosh[{{(π/3)I, -(π/3)I}, {0, -(π/6)I}}]

MatrixFunctionを使って行列のCosh関数を計算することもできる：

Wolfram Language code: MatrixFunction[Cosh[#]&, {{(π/3)I, -(π/3)I}, {0, -(π/6)I}}]

IntervalオブジェクトとCenteredIntervalオブジェクトを使って最悪の場合に保証される区間を計算する：

Wolfram Language code: Cosh[Interval[{0, Log[3]}]]
Wolfram Language code: Cosh[CenteredInterval[-1, 1 / 100]]
Wolfram Language code: Cosh[CenteredInterval[2 + 3I, (1 + I) / 100]]

Aroundを使って平均的な場合の統計区間を計算することもできる：

Wolfram Language code: Cosh[Around[(2/Sqrt[3]), 0.1]]

特定の値  (4)

固定された純粋な虚点におけるCoshの値：

Wolfram Language code: Table[Cosh[I (π/6) n], {n, -3, 3}]

無限大における値：

Wolfram Language code: Cosh[Infinity]
Wolfram Language code: Cosh[ComplexInfinity]

Coshの最小値：

Wolfram Language code: Cosh[0]

最小値を の根として求める：

Wolfram Language code: sol = Solve[D[Cosh[x], x] == 0, x, Reals]

値を代入する：

Wolfram Language code: xmin = x /. First[sol]

結果を可視化する：

Wolfram Language code: Plot[Cosh[x], {x, -1, 1}, Epilog -> Style[Point[{xmin, Cosh[xmin]}], PointSize[Large], Red]]

単純で厳密な値は自動的に生成される：

Wolfram Language code: Cosh[I Pi / 5]

より複雑な場合は明示的にFunctionExpandを使う必要がある：

Wolfram Language code: Cosh[I Pi / 24]
Wolfram Language code: FunctionExpand[%]

可視化  (3)

Cosh関数をプロットする：

Wolfram Language code: Plot[Cosh[x], {x, -3, 3}]

の実部をプロットする：

Wolfram Language code: ComplexContourPlot[Re[Cosh[z]], {z, -3 - 4 I, 3 + 4 I}, IconizedObject[«PlotOptions»]]

の虚部をプロットする：

Wolfram Language code: ComplexContourPlot[Im[Cosh[z]], {z, -3 - 4 I, 3 + 4 I}, IconizedObject[«PlotOptions»]]

の極プロット：

Wolfram Language code: Table[PolarPlot[Cosh[k ϕ], {ϕ, -π, π}, Sequence[Frame -> True, PlotLabel -> "k=" <> ToString[k], PlotRange -> {{-10, 10}, {-40, 40}}, AspectRatio -> 0.8]], {k, 1, 4}]

関数の特性  (12)

Coshはすべての実数値と虚数値について定義される：

Wolfram Language code: FunctionDomain[Cosh[x], x]
Wolfram Language code: FunctionDomain[Cosh[z], z, Complexes]

Coshは1以上のすべての実数値に達する：

Wolfram Language code: FunctionRange[Cosh[x], x, y]

複素値の領域は平面全体である：

Wolfram Language code: FunctionRange[Cosh[z], z, y, Complexes]

Coshは偶関数である：

Wolfram Language code: Cosh[-x]

Coshは鏡特性cosh(TemplateBox[{z}, Conjugate])=TemplateBox[{{cosh, (, z, )}}, Conjugate]を有する：

Wolfram Language code: FullSimplify[Cosh[Conjugate[z]] == Conjugate[Cosh[z]]]

Coshは x の解析関数である：

Wolfram Language code: FunctionAnalytic[Cosh[x], x]

Coshは非減少でも非増加でもない：

Wolfram Language code: FunctionMonotonicity[Cosh[x], x]

Coshは単射ではない：

Wolfram Language code: FunctionInjective[Cosh[x], x]
Wolfram Language code: Plot[{Cosh[x], 5}, {x, -4, 4}]

Coshは全射ではない：

Wolfram Language code: FunctionSurjective[Cosh[x], x]
Wolfram Language code: Plot[{Cosh[x], -1}, {x, -2, 2}]

Coshは非負である：

Wolfram Language code: FunctionSign[Cosh[x], x]

特異点も不連続点も持たない：

Wolfram Language code: FunctionSingularities[Cosh[x], x]
Wolfram Language code: FunctionDiscontinuities[Cosh[x], x]

Coshは凸である：

Wolfram Language code: FunctionConvexity[Cosh[x], x]

TraditionalFormによる表示：

Wolfram Language code: Cosh[x]//TraditionalForm

微分  (3)

一次導関数：

Wolfram Language code: D[Cosh[x], x]

高次導関数：

Wolfram Language code: Table[D[Cosh[x], {x, n}], {n, 1, 4}]

次導関数の式：

Wolfram Language code: D[Cosh[x], {x, n}]

積分  (4)

Coshの不定積分：

Wolfram Language code: Integrate[Cosh[x], x]

Coshを含む三角関数の積の不定積分：

Wolfram Language code: Integrate[Sinh[x]Cosh[x], x]

原点を中心とした区間上のCoshの定積分：

Wolfram Language code: Integrate[Cosh[x], {x, -1, 1}]

これは半分の区間の積分の2倍である：

Wolfram Language code: 2 Integrate[Cosh[x], {x, 0, 1}]

その他の積分例：

Wolfram Language code: Table[Integrate[Cosh[x ^ n], x], {n, 3}]
Wolfram Language code: Integrate[Cosh[x] ^ a, x]

級数展開  (4)

Seriesを使ってテイラー(Taylor)展開を求める：

Wolfram Language code: Series[Cosh[x], {x, 0, 7}]

の周りのCoshの最初の3つの近似をプロットする：

Wolfram Language code: terms = Normal@Table[Series[Cosh[x], {x, 0, m}], {m, 2, 6, 2}]; Plot[{Cosh[x], terms}, {x, -5, 5}]

Coshの級数展開における一般項：

Wolfram Language code: SeriesCoefficient[Cosh[x], {x, 0, n}]

Coshのフーリエ(Fourier)級数の最初の数項：

Wolfram Language code: FourierSeries[Cosh[x], x, 2]

Coshはベキ級数に適用できる：

Wolfram Language code: Cosh[x + (x^2/2) + (x^3/9) + O[x]^4]

積分変換  (2)

LaplaceTransformを使ってラプラス変換を計算する：

Wolfram Language code: LaplaceTransform[Cosh[t], t, s]

HankelTransform：

Wolfram Language code: HankelTransform[Cosh[r], r, s]
Wolfram Language code: %//FullSimplify

関数の恒等式と簡約  (6)

倍角のCosh：

Wolfram Language code: Expand[Cosh[2x], Trig -> True]

総和のCosh：

Wolfram Language code: TrigExpand[Cosh[x + y]]

マルチアングルの式を変換する：

Wolfram Language code: TrigExpand[Cosh[4x]]
Wolfram Language code: TrigReduce[%]

双曲線関数の和を積に変換する：

Wolfram Language code: TrigFactor[Cosh[x] + Cosh[y]]

実変数 および を仮定して展開する：

Wolfram Language code: ComplexExpand[Cosh[x + I y]]

指数関数に変換する：

Wolfram Language code: TrigToExp[Cosh[z]]

関数表現  (4)

Cosを介した表現：

Wolfram Language code: Simplify[Cos[I y]]

ベッセル(Bessel)関数を介した表現：

Wolfram Language code: FullSimplify[I Sqrt[( x/2 Pi)]BesselK[(1/2), -x] + Sqrt[( x/2 Pi)]BesselK[(1/2), x], x > 0]
Wolfram Language code: Simplify[Sqrt[( π x/2)]BesselI[-(1/2), x]]

MeijerGによる表現：

Wolfram Language code: MeijerGReduce[Cosh[x], x]
Wolfram Language code: Activate[%]//FullSimplify

CoshはDifferentialRootとして表すことができる：

Wolfram Language code: DifferentialRootReduce[Cosh[x], x]

アプリケーション  (10)

双曲線を描く：

Wolfram Language code: ParametricPlot[{Sinh[t], Cosh[t]}, {t, -1, 1}]

無限小変換から双曲型空間の回転行列を構築する：

Wolfram Language code: MatrixPower[{{1, θ / n}, {θ / n, 1}}, n]
Wolfram Language code: Limit[%, n -> Infinity]//FullSimplify

相対論的なboost行列：

Wolfram Language code: Λ = {{Cosh[η], 0, 0, Sinh[η]}, {0, 1, 0, 0}, {0, 0, 1, 0}, {Sinh[η], 0, 0, Cosh[η]}}

この行列はミンコフスキー(Minkowski)計量について直交する：

Wolfram Language code: g = DiagonalMatrix[{1, 1, 1, -1}]; FullSimplify[Transpose[Λ].g.Λ]

速さ η についての相対論的座標変換を構築する：

Wolfram Language code: Simplify[With[{η = ArcTanh[v / c]}, {{Cosh[η], -Sinh[η]}, {-Sinh[η], Cosh[η]}}.{c t, x}], 0 < v < c]

非相対論的極限：

Wolfram Language code: Series[%, {c, Infinity, 0}]//Normal

正弦Gordon方程式の特殊解：

Wolfram Language code: u[x_, t_] = 4 ArcTan[(c/Sqrt[1 - c^2] ) (Sin[Sqrt[1 - c^2]t]/Cosh[c x])] ;

解を検証する：

Wolfram Language code: D[u[x, t], t, t] - D[u[x, t], x, x] + Sin[u[x, t]]//FullSimplify

双曲幾何学におけるピタゴラスの定理：

Wolfram Language code: Series[Cosh[t a] == Cosh[t b] Cosh[t c], {t, 0, 2}]

小さいt極限が通常のピタゴラスの定理を与える：

Wolfram Language code: Simplify[Normal[%], t > 0]

微分方程式を解く：

Wolfram Language code: DSolve[-Cos[x]^2 y[x] + Tan[x] Derivative[1][y][x] + Derivative[2][y][x] == 0, y[x], x]

異なる方程式の解の双曲線形を求める：

Wolfram Language code: DSolve[{y'[t] - 2 y[t] == 0}, y[t], t]
Wolfram Language code: ExpToTrig[%]

は のとき，小さい絶対誤差でを近似することを示す：

Wolfram Language code: AsymptoticLess[Cosh[x] - Exp[-x] / 2, 1, x -> -∞]

Cosh関数とSinh関数を使って双曲線上の点を求める：

Wolfram Language code: ContourPlot[x ^ 2 - y ^ 2 == 1, {x, -5, 5}, {y, -5, 5}, Epilog -> Style[Point[{Cosh[π / 2], Sinh[π / 2]}], PointSize[Large], Red], Axes -> True, Frame -> False, AxesLabel -> {x, y}]

特性と関係  (12)

Coshの基本的なパリティと周期性の特性は自動的に適用される：

Wolfram Language code: Cosh[x + 2Pi I]
Wolfram Language code: {Cosh[-x], Cosh[I x]}

双曲線関数を含む複雑な式は自動的には簡約されない：

Wolfram Language code: Cosh[x] ^ 2 - Sinh[x] ^ 2

Simplifyを使う：

Wolfram Language code: Simplify[%]

逆関数で構築する：

Wolfram Language code: {Cosh[ArcCosh[z]], Cosh[2ArcCosh[z]], Cosh[3ArcCosh[z]]}
Wolfram Language code: FunctionExpand[%]

双曲型方程式を解く：

Wolfram Language code: Reduce[Cosh[z]^2 + Cosh[z + 1] == 1, z]

超越方程式の根を数値的に求める：

Wolfram Language code: FindRoot[Cosh[z]^3 - 3 Cosh[z + 1] + z == 2, {z, 0}]

双曲型方程式を簡約する：

Wolfram Language code: Reduce[Cosh[a x + b] == 0, x]

積分：

Wolfram Language code: Table[Integrate[Cosh[x ^ n], x], {n, 3}]
Wolfram Language code: ∫Cosh[z]^aⅆz

積分変換：

Wolfram Language code: FourierSinTransform[1 / (Cosh[t] + 1), t, s]

Coshは多くの数学関数の特殊形に現れる：

Wolfram Language code: {BesselI[-(1/2), z], JacobiCD[I z, 0], Hypergeometric0F1[(1/2), z], MeijerG[{{}, {(1/2)}}, {{0}, {(1/2), (1/2)}}, z]}

Coshは数値関数である：

Wolfram Language code: Attributes[Cosh]
Wolfram Language code: NumericQ[Cosh[2 + E]]

Coshの母関数：

Wolfram Language code: GeneratingFunction[Cosh[n], n, x]

Coshの指数母関数：

Wolfram Language code: ExponentialGeneratingFunction[Cosh[n], n, x]

考えられる問題  (5)

機械精度の入力では正解を出すのに不十分である：

Wolfram Language code: Cosh[10. ^ 40 I]

厳密な入力を与えると答も正確になる：

Wolfram Language code: N[Cosh[10 ^ 40 I], 20]

$MaxExtraPrecisionの設定値を大きくする必要があるかもしれない：

Wolfram Language code: N[Cosh[10 ^ 100 I], 20]
Wolfram Language code: Block[{$MaxExtraPrecision = 200}, N[Cosh[10 ^ 100 I], 20]]

機械数の入力で高精度の結果が得られることがある：

Wolfram Language code: Cosh[10. ^ 3]
Wolfram Language code: MachineNumberQ[%]

無限大ではベキ級数は存在せず，Coshは真性特異点を持つ：

Wolfram Language code: Series[Cosh[x], {x, Infinity, 2}]

TraditionalFormでは，引数の周りに丸カッコが必要である：

Wolfram Language code: cosh x
Wolfram Language code: cosh(x)

おもしろい例題  (1)

複素平面上のネストした双曲型余弦関数：

Wolfram Language code: DensityPlot[Arg[Nest[Cosh, x + I y, 3]], {x, 0, 3}, {y, -2, 2}, MaxRecursion -> 5, ColorFunction -> Hue]
Wolfram Research (1988), Cosh, Wolfram言語関数， https://reference.wolfram.com/language/ref/Cosh.html （2021年に更新）.

テキスト

Wolfram Research (1988), Cosh, Wolfram言語関数， https://reference.wolfram.com/language/ref/Cosh.html （2021年に更新）.

CMS

Wolfram Language. 1988. "Cosh." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2021. https://reference.wolfram.com/language/ref/Cosh.html.

APA

Wolfram Language. (1988). Cosh. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Cosh.html

BibTeX

@misc{reference.wolfram_2026_cosh, author="Wolfram Research", title="{Cosh}", year="2021", howpublished="\url{https://reference.wolfram.com/language/ref/Cosh.html}", note=[Accessed: 12-October-2026]}

BibLaTeX

@online{reference.wolfram_2026_cosh, organization={Wolfram Research}, title={Cosh}, year={2021}, url={https://reference.wolfram.com/language/ref/Cosh.html}, note=[Accessed: 12-October-2026]}