WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Cot[z]

z の余接を与える．

詳細
Details and Options Details and Options
予備知識
例題  
例  
スコープ  
数値評価  
特定の値  
可視化  
Show More Show More
関数の特性  
微分  
積分  
級数展開  
関数の恒等式と簡約  
関数表現  
アプリケーション  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

Cot

Cot[z]

z の余接を与える．

詳細

  • 記号操作・数値操作の両方に適した数学関数である．
  • Cotの引数はラジアンで与える．（度数の角度は，係数Degreeを掛け合せラジアン角にしてから使う．）
  • Cos[z]/Sin[z]は自動的にCot[z]に変換される．分解するにはTrigFactorList[expr]を使う．
  • 特別な引数の場合，Cotは自動的に厳密値を計算する．
  • Cotは任意の数値精度で評価できる．
  • Cotは自動的にリストに縫い込まれる． »
  • CotはIntervalオブジェクトおよびCenteredIntervalオブジェクトに使うことができる． »

予備知識

  • Cotは，三角法で出会う基本関数の1つの余接関数である．これは，正接関数の逆関数として定義される．直角三角形における角 の余接の学校教科書での同等の定義は， に隣接する辺とその反対側の辺の長さの比（正接の逆数）である．
  • Cotは，引数が の単純な有理倍数の場合は，自動的に厳密値に評価される．より複雑な有理倍数については，FunctionExpandを使って明示的な厳密値が得られることがある．TrigFactorListを使ってCotを含む式をSinおよびCosを含む項に因子分解することができる．度で測られた角を使って引数を指定するときは，記号Degreeを乗数として使うことができる（例：Cot[30 Degree]）．引数として厳密な数式が与えられると，Cotは任意の数値精度に評価できることがある．Cotを含む記号式の役に立つ操作には，TrigToExp，TrigExpand，Simplify，FullSimplify等がある．
  • Cotは要素単位でリストおよび行列に縫い込まれる．対照的に，MatrixFunctionを使って正方行列の余接（通常のベキを行列ベキで置換した，余接関数についてのベキ級数）を個々の行列要素の余接に対立するものとして得ることができる．
  • Cotは，FunctionPeriodにあるように， を周期として周期的である．Cotは，恒等式を満足する．これは，ピタゴラスの定理に等しい．余接関数の定義は，定義を使って複素引数 にまで拡張することができる．ただし， は自然対数の底である．Cotは整数 について に極を持ち，これらの点で評価するとComplexInfinityになる．Cot[z]は，原点付近で級数展開sum_(k=0)^infty((-1)^k 2^(2 k) TemplateBox[{{2, , k}}, BernoulliB] )/((2 k)!)z^(2 k-1)を持つ．これはベルヌーイ(Bernoulli)数BernoulliBによって表すことができる．
  • Cotの逆関数はArcCotである．双曲線余接はCothで与えられる．他の関連する数学関数にはTan，Cos等がある．

例題

すべて開く すべて閉じる

例  (6)

引数はラジアンで与えられる：

Wolfram Language code: Cot[Pi / 3]

Degreeを用いて引数を度で指定する：

Wolfram Language code: Cot[60Degree]

実数の部分集合上でプロットする：

Wolfram Language code: Plot[Cot[x], {x, -Pi, Pi}]

複素数の部分集合上でプロットする：

Wolfram Language code: ComplexPlot3D[Cot[z], {z, -π - 2I, π + 2I}, PlotLegends -> Automatic]

0における級数展開：

Wolfram Language code: Series[Cot[x], {x, 0, 10}]

特異点における漸近展開：

Wolfram Language code: Series[Cot[x], {x, -π, 5}]

スコープ  (46)

数値評価  (6)

数値的に評価する：

Wolfram Language code: Cot[1.2]

高精度で評価する：

Wolfram Language code: N[Cot[12 / 10], 50]

出力の精度は入力の精度に従う：

Wolfram Language code: Cot[1.20000000000000000000000]

Cotは複素数の入力を取ることができる：

Wolfram Language code: Cot[2.5 + I]

Cotを高精度で効率よく評価する：

Wolfram Language code: Cot[1.2`500]//Timing
Wolfram Language code: Cot[1.2`100000];//Timing

自動縫込みを使って配列の要素ごとの値を計算する：

Wolfram Language code: Cot[ {{5π / 6, π / 2}, {3π / 2, -π / 6}}]

MatrixFunctionを使って行列のCot関数を計算することもできる：

Wolfram Language code: MatrixFunction[Cot[#]&, {{5π / 6, π / 2}, {3π / 2, -π / 6}}]

IntervalオブジェクトとCenteredIntervalオブジェクトを使って最悪の場合に保証される区間を計算する：

Wolfram Language code: Cot[Interval[{-π / 4, π / 4}]]
Wolfram Language code: Cot[CenteredInterval[1, 1 / 100]]
Wolfram Language code: Cot[CenteredInterval[2 + 3I, (1 + I) / 100]]

Aroundを使って平均的な場合の統計区間を計算することもできる：

Wolfram Language code: Cot[Around[3, 0.01]]

特定の値  (5)

固定点におけるCotの値：

Wolfram Language code: Table[Cot[n(π/6)], {n, 1, 5}]

無限大における値：

Wolfram Language code: Cot[Infinity]
Wolfram Language code: Cot[ComplexInfinity]

Cotの零点：

Wolfram Language code: Assuming[m∈Integers, Refine[Cot[π((1/2) + m)]]]

Solveを使ってCotの零点を求める：

Wolfram Language code: sol = Solve[Cot[x] == 0 && 0 < x < π, x]

結果を代入する：

Wolfram Language code: xzero = x /. First[sol]

結果を可視化する：

Wolfram Language code: Plot[Cot[x], {x, 0, π}, Epilog -> Style[Point[{xzero, Cot[xzero]}], PointSize[Large], Red]]

Cotの特異点：

Wolfram Language code: Assuming[m∈Integers, FullSimplify[Refine[Cot[π m]]]]

簡単な厳密値は自動的に生成される：

Wolfram Language code: Cot[Pi / 6]

より複雑な場合にはFunctionExpandを明示的に使う：

Wolfram Language code: Cot[Pi / 8]
Wolfram Language code: FunctionExpand[%]

可視化  (3)

Cot関数をプロットする：

Wolfram Language code: Plot[Cot[x], {x, -π, π}]

の実部をプロットする：

Wolfram Language code: ComplexContourPlot[Re[Cot[z]], {z, -π - I, π + I}, IconizedObject[«PlotOptions»]]

の虚部をプロットする：

Wolfram Language code: ComplexContourPlot[Im[Cot[z]], {z, -π - I, π + I}, IconizedObject[«PlotOptions»]]

の極プロット：

Wolfram Language code: Table[PolarPlot[Cot[k ϕ], {ϕ, 0.01, 3π}, Sequence[Frame -> True, Exclusions -> All, FrameTicks -> {{{-1, -0.5, 0, 0.5, 1}, None}, {{-1, -0.5, 0, 0.5, 1}, None}}, PlotLabel -> "k=" <> ToString[k], PlotRange -> {{-1, 1}, {-1, 1}}]], {k, 1, 4}]

関数の特性  (13)

Cotの実領域：

Wolfram Language code: FunctionDomain[Cot[x], x]

複素領域：

Wolfram Language code: FunctionDomain[Cot[z], z, Complexes]

Cotはすべての実数値に達する：

Wolfram Language code: FunctionRange[Cot[x], x, y]

Cotは， を周期とする周期関数である：

Wolfram Language code: FunctionPeriod[Cot[x], x]

Cotは奇関数である：

Wolfram Language code: Cot[-x]

Cotは鏡特性cot(TemplateBox[{z}, Conjugate])=TemplateBox[{{cot, (, z, )}}, Conjugate]を有する：

Wolfram Language code: FullSimplify[Cot[Conjugate[z]] == Conjugate[Cot[z]]]

Cotは解析関数ではない：

Wolfram Language code: FunctionAnalytic[Cot[x], x]

しかし，有理型ではある：

Wolfram Language code: FunctionMeromorphic[Cot[x], x]

Cotは特定の値域で単調である：

Wolfram Language code: FunctionMonotonicity[Cot[x], x]
Wolfram Language code: FunctionMonotonicity[{Cot[x], 0 < x < π / 2}, x]

Cotは単射ではない：

Wolfram Language code: FunctionInjective[Cot[x], x]
Wolfram Language code: Plot[{Cot[x], 1}, {x, -2π, 2π}]

Cotは全射である：

Wolfram Language code: FunctionSurjective[Cot[x], x]
Wolfram Language code: Plot[{Cot[x], 20}, {x, -2π, 2π}]

Cotは非負でも非正でもない：

Wolfram Language code: FunctionSign[Cot[x], x]

Cotは π の倍数の点で特異点と不連続点の両方を持つ：

Wolfram Language code: FunctionSingularities[Cot[x], x]
Wolfram Language code: FunctionDiscontinuities[Cot[x], x]

Cotは凸でも凹でもない：

Wolfram Language code: FunctionConvexity[Cot[x], x]

TraditionalFormによる表示：

Wolfram Language code: Cot[α]//TraditionalForm

微分  (3)

一次導関数：

Wolfram Language code: D[Cot[x], x]

高次導関数：

Wolfram Language code: Table[D[Cot[x], {x, n}], {n, 1, 3}]
Wolfram Language code: Plot[Evaluate[%], {x, -π, π}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]

次導関数の式：

Wolfram Language code: D[Cot[x], {x, n}]
Wolfram Language code: Table[%, {n, 1, 3}]//Activate//Simplify

積分  (3)

Cotの不定積分：

Wolfram Language code: Integrate[Cot[x], x]

Cotの，周期上での定積分：

Wolfram Language code: Integrate[Cot[x], {x, -(π/2), (π/2)}, PrincipalValue -> True]

その他の積分例：

Wolfram Language code: Integrate[Cot[x]Sin[x], x]
Wolfram Language code: Integrate[Cot[z]^a, z]

級数展開  (3)

Seriesを使ってテーラ(Taylor)展開を求める：

Wolfram Language code: Series[Cot[x], {x, π / 2, 7}]

の周りのCotの最初の3つの近似をプロットする：

Wolfram Language code: terms = Normal@Table[Series[Cot[x], {x, π / 2, m}], {m, 0, 5, 2}]; Plot[{Cot[x], terms}, {x, 0, π}, PlotRange -> {{0, π}, Automatic}]

Cotの級数展開における一般項：

Wolfram Language code: SeriesCoefficient[Cot[x], {x, 0, n}]

Cotはベキ級数に適用できる：

Wolfram Language code: Cot[(π/2) + x + (x^2/2) + (x^3/3) + O[x]^4]

関数の恒等式と簡約  (6)

倍角のCot：

Wolfram Language code: Expand[Cot[2x], Trig -> True]

総和のCot：

Wolfram Language code: TrigExpand[Cot[x + y]]

マルチアングルの式を変換する：

Wolfram Language code: TrigExpand[Cot[4x]]
Wolfram Language code: TrigReduce[%]

三角関数の和を積に変換する：

Wolfram Language code: TrigFactor[Cot[x] + Cot[y]]

実変数 および を仮定して展開する：

Wolfram Language code: ComplexExpand[Cot[x + I y]]

複素指数関数に変換する：

Wolfram Language code: TrigToExp[Cot[z]]

関数表現  (4)

Tanを介した表現：

Wolfram Language code: Simplify[Tan[(Pi/2) - x]]

ヤコビ関数を介した表現：

Wolfram Language code: Simplify[JacobiCS[z, 0]]
Wolfram Language code: Simplify[I JacobiNS[I z, 1]]

SphericalHarmonicYを介した表現：

Wolfram Language code: Simplify[Sqrt[1 / 2]SphericalHarmonicY[1, 0, θ, 0] / SphericalHarmonicY[1, -1, θ, 0]]

マシュー(Mathieu)関数を介した表現：

Wolfram Language code: Simplify[(MathieuC[1, 0, z]/MathieuS[1, 0, z])]

アプリケーション  (4)

極を除いてプロットを生成する：

Wolfram Language code: Plot[Cot[x], {x, -Pi / 2, 3 / 2Pi}, Exclusions -> Sin[x] == 0]

複素引数平面上にプロットを生成する：

Wolfram Language code: Plot3D[Re[Cot[x + I y]], {x, -Pi, Pi}, {y, 0, 3}]

余接関数は適合的に放物線を単位円板にマップする：

Wolfram Language code: With[{parabola = Table[1 - x ^ 2 / 4 + I x, {x, 0, 20, 1 / 10}], pnts = Point[ReIm@#]&, opts = {Axes -> True, PlotRange -> All}}, {Graphics[pnts[parabola], opts], Graphics[pnts[Cot[π / 4.Sqrt[parabola]] ^ 2], opts]}]

微分方程式を解く：

Wolfram Language code: DSolve[y'[x] + y[x] + Cot[x] == 0, y[x], x]

特性と関係  (12)

余接関数の基本的なパリティと周期性の性質は自動的に適用される：

Wolfram Language code: Cot[x + Pi]
Wolfram Language code: Cot[-x]
Wolfram Language code: Cot[I x]
Wolfram Language code: 1 / Cot[x]

CotをSinとCosに因数分解するのにはTrigFactorListを用いる：

Wolfram Language code: Cos[x] / Sin[x]
Wolfram Language code: TrigFactorList[Cot[x]]

三角関数を含む複雑な式は自動的には簡約されない：

Wolfram Language code: Cot[z] + Tan[z]
Wolfram Language code: Simplify[%]

パラメータについての仮定をして簡約する：

Wolfram Language code: Cot[-x + k Pi]
Wolfram Language code: Simplify[%, k∈Integers]

逆関数を用いて構築する：

Wolfram Language code: {Cot[ArcCot[z]], Cot[2ArcCot[z]], Cot[3ArcCot[z]]}
Wolfram Language code: FunctionExpand[%]//Together

1ラジアンは度である：

Wolfram Language code: Cot[1] == CotDegrees[180 / π]//Simplify

三角方程式を解く：

Wolfram Language code: Reduce[Cot[z]^2 - 2Cot[z + Pi / 4] == 4, z]

ゼロと極について解く：

Wolfram Language code: Reduce[Cot[α x + β] == 0, x]
Wolfram Language code: Reduce[1 / Cot[α x + β] == 0, x]

超越方程式の根を数値的に求める：

Wolfram Language code: FindRoot[Cot[z]^2 + 3Cot[z + Pi / 6] + z == 4, {z, 2}]

Cotは多くの数学関数の特殊形に現れる：

Wolfram Language code: {BesselJ[-(1/2), z] / BesselJ[(1/2), z], (MathieuC[1, 0, z]/MathieuS[1, 0, z]), JacobiCS[z, 0], JacobiSC[(π/2) - z, 0], JacobiNS[I z, 1], JacobiSN[(π I/2) - I z, 1], HypergeometricPFQ[{}, {(1/2)}, -z] / HypergeometricPFQ[{}, {(3/2)}, -z]}

剰余を記号的・数値的に計算する：

Wolfram Language code: Table[Residue[Cot[z]^k, {z, 0}], {k, 10}]
Wolfram Language code: (1/2π I)NIntegrate[Cot[z], {z, -(1/4), -(I/4), +(1/4), +(I/4), -(1/4)}]

Cotは数値関数である：

Wolfram Language code: Attributes[Cot]
Wolfram Language code: NumericQ[Cot[2 + E]]

考えられる問題  (3)

機械精度の入力では正解を出すのに不十分である：

Wolfram Language code: Cot[10. ^ 30]

厳密な入力を使うと，正しい答が得られる：

Wolfram Language code: N[Cot[10 ^ 30], 20]

$MaxExtraPrecisionの設定値を大きくする必要がある：

Wolfram Language code: N[Cot[10 ^ 100], 20]
Wolfram Language code: Block[{$MaxExtraPrecision = 200}, N[Cot[10 ^ 100], 20]]

出力精度は入力精度よりはるかに低くなることがある：

Wolfram Language code: Cot[1.5707963267948966192213216916397514421]

おもしろい例題  (6)

余接の積を計算する：

Wolfram Language code: Underoverscript[∏, k = 1, n - 1] Cot[z + (k π/n)]

は整数であると仮定して，結果を簡約する：

Wolfram Language code: Simplify[%, (n/2)∈Integers]

は整数であると仮定して，結果を簡約する：

Wolfram Language code: Simplify[%%, (n - 1/2)∈Integers]

余接の関数を積分する：

Wolfram Language code: Integrate[Cot[ArcTan[z]], z]

整数点でCotをプロットする：

Wolfram Language code: ArrayPlot[Table[ArcCot[Abs[Cot[x y]]], {x, -20, 20}, {y, -20, 20}]]

ネストした根基表現を与える：

Wolfram Language code: Cot[(π/2^12)]//FunctionExpand

連分数は極めて規則的である：

Wolfram Language code: ContinuedFraction[Cot[1], 22]

Cot[n]は整数 n における超越数である：

Wolfram Language code: Element[Cot[1], Algebraics]
Wolfram Research (1988), Cot, Wolfram言語関数， https://reference.wolfram.com/language/ref/Cot.html （2021年に更新）.

テキスト

Wolfram Research (1988), Cot, Wolfram言語関数， https://reference.wolfram.com/language/ref/Cot.html （2021年に更新）.

CMS

Wolfram Language. 1988. "Cot." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2021. https://reference.wolfram.com/language/ref/Cot.html.

APA

Wolfram Language. (1988). Cot. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Cot.html

BibTeX

@misc{reference.wolfram_2026_cot, author="Wolfram Research", title="{Cot}", year="2021", howpublished="\url{https://reference.wolfram.com/language/ref/Cot.html}", note=[Accessed: 16-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_cot, organization={Wolfram Research}, title={Cot}, year={2021}, url={https://reference.wolfram.com/language/ref/Cot.html}, note=[Accessed: 16-September-2026]}